lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::NNTP;
   4 use strict;
   5 use warnings;
   6 use base qw(Danga::Socket);
   7 use fields qw(nntpd article rbuf ng long_res);
   8 use PublicInbox::Msgmap;
   9 use PublicInbox::GitCatFile;
  10 use PublicInbox::MID qw(mid2path);
  11 use Email::MIME;
  12 use Data::Dumper qw(Dumper);
  13 use POSIX qw(strftime);
  14 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  15 use constant {
  16         r501 => '501 command syntax error',
  17         r221 => '221 Header follows',
  18         r224 => '224 Overview information follows (multi-line)',
  19         r430 => '430 No article with that message-id',
  20         long_response_limit => 0xffffffff,
  21 };
  22
  23 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  24
  25 my @OVERVIEW = qw(Subject From Date Message-ID References Bytes Lines);
  26 my %OVERVIEW = map { $_ => 1 } @OVERVIEW;
  27
  28 # disable commands with easy DoS potential:
  29 # LISTGROUP could get pretty bad, too...
  30 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  31
  32 sub new ($$$) {
  33         my ($class, $sock, $nntpd) = @_;
  34         my $self = fields::new($class);
  35         binmode $sock, ':utf8'; # RFC 3977
  36         $self->SUPER::new($sock);
  37         $self->{nntpd} = $nntpd;
  38         res($self, '201 server ready - post via email');
  39         $self->{rbuf} = '';
  40         $self->watch_read(1);
  41         $self;
  42 }
  43
  44 sub args_ok ($$) {
  45         my ($cb, $argc) = @_;
  46         my $tot = prototype $cb;
  47         my ($nreq, undef) = split(';', $tot);
  48         $nreq = ($nreq =~ tr/$//) - 1;
  49         $tot = ($tot =~ tr/$//) - 1;
  50         ($argc <= $tot && $argc >= $nreq);
  51 }
  52
  53 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  54 sub process_line ($$) {
  55         my ($self, $l) = @_;
  56         my ($req, @args) = split(/\s+/, $l);
  57         $req = lc($req);
  58         $req = eval {
  59                 no strict 'refs';
  60                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
  61         };
  62         return res($self, '500 command not recognized') unless $req;
  63         return res($self, r501) unless args_ok($req, scalar @args);
  64
  65         my $res = eval { $req->($self, @args) };
  66         my $err = $@;
  67         if ($err && !$self->{closed}) {
  68                 chomp($l = Dumper(\$l));
  69                 err($self, "error from: $l $err");
  70                 $res = '503 program fault - command not performed';
  71         }
  72         return 0 unless defined $res;
  73         res($self, $res);
  74 }
  75
  76 sub cmd_mode ($$) {
  77         my ($self, $arg) = @_;
  78         $arg = uc $arg;
  79         return r501 unless $arg eq 'READER';
  80         '200 reader status acknowledged';
  81 }
  82
  83 sub cmd_slave ($) { '202 slave status noted' }
  84
  85 sub cmd_xgtitle ($;$) {
  86         my ($self, $wildmat) = @_;
  87         more($self, '282 list of groups and descriptions follows');
  88         list_newsgroups($self, $wildmat);
  89         '.'
  90 }
  91
  92 sub list_overview_fmt ($$) {
  93         my ($self) = @_;
  94         more($self, $_ . ':') foreach @OVERVIEW;
  95 }
  96
  97 sub list_active ($;$) {
  98         my ($self, $wildmat) = @_;
  99         wildmat2re($wildmat);
 100         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 101                 $ng->{name} =~ $wildmat or next;
 102                 group_line($self, $ng);
 103         }
 104 }
 105
 106 sub list_active_times ($;$) {
 107         my ($self, $wildmat) = @_;
 108         wildmat2re($wildmat);
 109         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 110                 $ng->{name} =~ $wildmat or next;
 111                 my $c = eval { $ng->mm->created_at } || time;
 112                 more($self, "$ng->{name} $c $ng->{address}");
 113         }
 114 }
 115
 116 sub list_newsgroups ($;$) {
 117         my ($self, $wildmat) = @_;
 118         wildmat2re($wildmat);
 119         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 120                 $ng->{name} =~ $wildmat or next;
 121                 my $d = $ng->description;
 122                 more($self, "$ng->{name} $d");
 123         }
 124 }
 125
 126 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 127 sub cmd_list ($;$$) {
 128         my ($self, @args) = @_;
 129         if (scalar @args) {
 130                 my $arg = shift @args;
 131                 $arg =~ tr/A-Z./a-z_/;
 132                 $arg = "list_$arg";
 133                 return r501 if $DISABLED{$arg};
 134
 135                 $arg = eval {
 136                         no strict 'refs';
 137                         *{$arg}{CODE};
 138                 };
 139                 return r501 unless $arg && args_ok($arg, scalar @args);
 140                 more($self, '215 information follows');
 141                 $arg->($self, @args);
 142         } else {
 143                 more($self, '215 list of newsgroups follows');
 144                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 145                         group_line($self, $ng);
 146                 }
 147         }
 148         '.'
 149 }
 150
 151 sub cmd_listgroup ($;$) {
 152         my ($self, $group) = @_;
 153         if (defined $group) {
 154                 my $res = cmd_group($self, $group);
 155                 return $res if ($res !~ /\A211 /);
 156                 more($self, $res);
 157         }
 158
 159         $self->{ng} or return '412 no newsgroup selected';
 160         $self->long_response(0, long_response_limit, sub {
 161                 my ($i) = @_;
 162                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 163                         my ($ary) = @_;
 164                         more($self, join("\r\n", @$ary));
 165                 });
 166
 167                 # -1 to adjust for implicit increment in long_response
 168                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 169         });
 170 }
 171
 172 sub parse_time ($$;$) {
 173         my ($date, $time, $gmt) = @_;
 174         use Time::Local qw();
 175         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 176         if (defined $gmt) {
 177                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt\n";
 178                 $gmt = 1;
 179         }
 180         my @now = $gmt ? gmtime : localtime;
 181         my ($YYYY, $MM, $DD);
 182         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 183                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 184         } else { # legacy clients send YYMMDD
 185                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 186                 if ($YYYY > strftime('%y', @now)) {
 187                         my $cur_year = $now[5] + 1900;
 188                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 189                 }
 190         }
 191         if ($gmt) {
 192                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 193         } else {
 194                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 195         }
 196 }
 197
 198 sub group_line ($$) {
 199         my ($self, $ng) = @_;
 200         my ($min, $max) = $ng->mm->minmax;
 201         more($self, "$ng->{name} $max $min n") if defined $min && defined $max;
 202 }
 203
 204 sub cmd_newgroups ($$$;$$) {
 205         my ($self, $date, $time, $gmt, $dists) = @_;
 206         my $ts = eval { parse_time($date, $time, $gmt) };
 207         return r501 if $@;
 208
 209         # TODO dists
 210         more($self, '231 list of new newsgroups follows');
 211         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 212                 my $c = eval { $ng->mm->created_at } || 0;
 213                 next unless $c > $ts;
 214                 group_line($self, $ng);
 215         }
 216         '.'
 217 }
 218
 219 sub wildmat2re (;$) {
 220         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 221         my %keep;
 222         my $salt = rand;
 223         use Digest::SHA qw(sha1_hex);
 224         my $tmp = $_[0];
 225
 226         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 227                 my $orig = $1;
 228                 my $key = sha1_hex($orig . $salt);
 229                 $orig =~ s/([^\w\-])+/\Q$1/g;
 230                 $keep{$key} = $orig;
 231                 $key
 232                 #gex;
 233         my %map = ('*' => '.*', '?' => '.' );
 234         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 235         if (scalar %keep) {
 236                 $tmp =~ s#([a-f0-9]{40})#
 237                         my $orig = $keep{$1};
 238                         defined $orig ? $orig : $1;
 239                         #ge;
 240         }
 241         $_[0] = qr/\A$tmp\z/;
 242 }
 243
 244 sub ngpat2re (;$) {
 245         return $_[0] = qr/\A\z/ unless defined $_[0];
 246         my %map = ('*' => '.*', ',' => '|');
 247         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 248         $_[0] = qr/\A(?:$_[0])\z/;
 249 }
 250
 251 sub cmd_newnews ($$$$;$$) {
 252         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 253         my $ts = eval { parse_time($date, $time, $gmt) };
 254         return r501 if $@;
 255         more($self, '230 list of new articles by message-id follows');
 256         my ($keep, $skip) = split('!', $newsgroups, 2);
 257         ngpat2re($keep);
 258         ngpat2re($skip);
 259         my @srch;
 260         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 261                 $ng->{name} =~ $keep or next;
 262                 $ng->{name} =~ $skip and next;
 263                 my $srch = $ng->search or next;
 264                 push @srch, $srch;
 265         };
 266         return '.' unless @srch;
 267
 268         $ts .= '..';
 269         my $opts = { asc => 1, limit => 1000, offset => 0 };
 270         $self->long_response(0, long_response_limit, sub {
 271                 my ($i) = @_;
 272                 my $srch = $srch[0];
 273                 my $res = $srch->query($ts, $opts);
 274                 my $msgs = $res->{msgs};
 275                 if (my $nr = scalar @$msgs) {
 276                         more($self, '<' .
 277                                 join(">\r\n<", map { $_->mid } @$msgs ).
 278                                 '>');
 279                         $opts->{offset} += $nr;
 280                 } else {
 281                         shift @srch;
 282                         if (@srch) { # continue onto next newsgroup
 283                                 $opts->{offset} = 0;
 284                         } else { # break out of the long response.
 285                                 $$i = long_response_limit;
 286                         }
 287                 }
 288         });
 289 }
 290
 291 sub cmd_group ($$) {
 292         my ($self, $group) = @_;
 293         my $no_such = '411 no such news group';
 294         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 295
 296         $self->{ng} = $ng;
 297         my ($min, $max) = $ng->mm->minmax;
 298         $min ||= 0;
 299         $max ||= 0;
 300         $self->{article} = $min;
 301         my $est_size = $max - $min;
 302         "211 $est_size $min $max $group";
 303 }
 304
 305 sub article_adj ($$) {
 306         my ($self, $off) = @_;
 307         my $ng = $self->{ng} or return '412 no newsgroup selected';
 308
 309         my $n = $self->{article};
 310         defined $n or return '420 no current article has been selected';
 311
 312         $n += $off;
 313         my $mid = $ng->mm->mid_for($n);
 314         unless ($mid) {
 315                 $n = $off > 0 ? 'next' : 'previous';
 316                 return "421 no $n article in this group";
 317         }
 318         $self->{article} = $n;
 319         "223 $n <$mid> article retrieved - request text separately";
 320 }
 321
 322 sub cmd_next ($) { article_adj($_[0], 1) }
 323 sub cmd_last ($) { article_adj($_[0], -1) }
 324
 325 # We want to encourage using email and CC-ing everybody involved to avoid
 326 # the single-point-of-failure a single server provides.
 327 sub cmd_post ($) {
 328         my ($self) = @_;
 329         my $ng = $self->{ng};
 330         $ng ? "440 mailto:$ng->{address} to post" : '440 posting not allowed'
 331 }
 332
 333 sub cmd_quit ($) {
 334         my ($self) = @_;
 335         res($self, '205 closing connection - goodbye!');
 336         $self->close;
 337         undef;
 338 }
 339
 340 sub art_lookup ($$$) {
 341         my ($self, $art, $set_headers) = @_;
 342         my $ng = $self->{ng};
 343         my ($n, $mid);
 344         my $err;
 345         if (defined $art) {
 346                 if ($art =~ /\A\d+\z/o) {
 347                         $err = '423 no such article number in this group';
 348                         $n = int($art);
 349                         goto find_mid;
 350                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 351                         $mid = $1;
 352                         $err = r430;
 353                         $n = $ng->mm->num_for($mid) if $ng;
 354                         goto found if defined $n;
 355                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 356                                 $n = $g->mm->num_for($mid);
 357                                 if (defined $n) {
 358                                         $ng = $g;
 359                                         goto found;
 360                                 }
 361                         }
 362                         return $err;
 363                 } else {
 364                         return r501;
 365                 }
 366         } else {
 367                 $err = '420 no current article has been selected';
 368                 $n = $self->{article};
 369                 defined $n or return $err;
 370 find_mid:
 371                 $ng or return '412 no newsgroup has been selected';
 372                 $mid = $ng->mm->mid_for($n);
 373                 defined $mid or return $err;
 374         }
 375 found:
 376         my $o = 'HEAD:' . mid2path($mid);
 377         my $bytes;
 378         my $s = eval { Email::MIME->new($ng->gcf->cat_file($o, \$bytes)) };
 379         return $err unless $s;
 380         my $lines;
 381         if ($set_headers) {
 382                 $s->header_set('Newsgroups', $ng->{name});
 383                 $s->header_set('Xref', xref($ng, $n));
 384                 $lines = $s->body =~ tr!\n!\n!;
 385
 386                 # must be last
 387                 $s->body_set('') if ($set_headers == 2);
 388         }
 389         [ $n, $mid, $s, $bytes, $lines, $ng ];
 390 }
 391
 392 sub simple_body_write ($$) {
 393         my ($self, $s) = @_;
 394         my $body = $s->body;
 395         $s->body_set('');
 396         $body =~ s/^\./../smg;
 397         $body =~ s/(?<!\r)\n/\r\n/sg;
 398         do_more($self, $body);
 399         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 400         '.'
 401 }
 402
 403 sub set_art {
 404         my ($self, $art) = @_;
 405         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 406 }
 407
 408 sub cmd_article ($;$) {
 409         my ($self, $art) = @_;
 410         my $r = $self->art_lookup($art, 1);
 411         return $r unless ref $r;
 412         my ($n, $mid, $s) = @$r;
 413         set_art($self, $art);
 414         more($self, "220 $n <$mid> article retrieved - head and body follow");
 415         do_more($self, $s->header_obj->as_string);
 416         do_more($self, "\r\n");
 417         simple_body_write($self, $s);
 418 }
 419
 420 sub cmd_head ($;$) {
 421         my ($self, $art) = @_;
 422         my $r = $self->art_lookup($art, 2);
 423         return $r unless ref $r;
 424         my ($n, $mid, $s) = @$r;
 425         set_art($self, $art);
 426         more($self, "221 $n <$mid> article retrieved - head follows");
 427         do_more($self, $s->header_obj->as_string);
 428         '.'
 429 }
 430
 431 sub cmd_body ($;$) {
 432         my ($self, $art) = @_;
 433         my $r = $self->art_lookup($art, 0);
 434         return $r unless ref $r;
 435         my ($n, $mid, $s) = @$r;
 436         set_art($self, $art);
 437         more($self, "222 $n <$mid> article retrieved - body follows");
 438         simple_body_write($self, $s);
 439 }
 440
 441 sub cmd_stat ($;$) {
 442         my ($self, $art) = @_;
 443         my $r = $self->art_lookup($art, 0);
 444         return $r unless ref $r;
 445         my ($n, $mid, undef) = @$r;
 446         set_art($self, $art);
 447         "223 $n <$mid> article retrieved - request text separately";
 448 }
 449
 450 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 451
 452 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 453
 454 sub cmd_help ($) {
 455         my ($self) = @_;
 456         more($self, '100 help text follows');
 457         '.'
 458 }
 459
 460 sub get_range ($$) {
 461         my ($self, $range) = @_;
 462         my $ng = $self->{ng} or return '412 no news group has been selected';
 463         defined $range or return '420 No article(s) selected';
 464         my ($beg, $end);
 465         my ($min, $max) = $ng->mm->minmax;
 466         if ($range =~ /\A(\d+)\z/) {
 467                 $beg = $end = $1;
 468         } elsif ($range =~ /\A(\d+)-\z/) {
 469                 ($beg, $end) = ($1, $max);
 470         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 471                 ($beg, $end) = ($1, $2);
 472         } else {
 473                 return r501;
 474         }
 475         $beg = $min if ($beg < $min);
 476         $end = $max if ($end > $max);
 477         return '420 No article(s) selected' if ($beg > $end);
 478         [ $beg, $end ];
 479 }
 480
 481 sub hdr_val ($$) {
 482         my ($r, $header) = @_;
 483         return $r->[3] if $header =~ /\A:?bytes\z/i;
 484         return $r->[4] if $header =~ /\A:?lines\z/i;
 485         $r = $r->[2]->header_obj->header($header);
 486         defined $r or return;
 487         $r =~ s/[\r\n\t]+/ /sg;
 488         $r;
 489 }
 490
 491 sub long_response ($$$$) {
 492         my ($self, $beg, $end, $cb) = @_;
 493         die "BUG: nested long response" if $self->{long_res};
 494
 495         my $fd = $self->{fd};
 496         defined $fd or return;
 497         # make sure we disable reading during a long response,
 498         # clients should not be sending us stuff and making us do more
 499         # work while we are stream a response to them
 500         $self->watch_read(0);
 501         my $t0 = now();
 502         $self->{long_res} = sub {
 503                 # limit our own running time for fairness with other
 504                 # clients and to avoid buffering too much:
 505                 my $lim = 100;
 506
 507                 my $err;
 508                 do {
 509                         eval { $cb->(\$beg) };
 510                 } until (($err = $@) || $self->{closed} ||
 511                          ++$beg > $end || !--$lim || $self->{write_buf_size});
 512
 513                 if ($err || $self->{closed}) {
 514                         $self->{long_res} = undef;
 515
 516                         if ($err) {
 517                                 err($self,
 518                                     "$err during long response[$fd] - %0.6f",
 519                                         now() - $t0);
 520                         }
 521                         if ($self->{closed}) {
 522                                 out($self, " deferred[$fd] aborted - %0.6f",
 523                                            now() - $t0);
 524                         } else {
 525                                 $self->watch_read(1);
 526                         }
 527                 } elsif (!$lim || $self->{write_buf_size}) {
 528                         # no recursion, schedule another call ASAP
 529                         # but only after all pending writes are done
 530                         Danga::Socket->AddTimer(0, sub {
 531                                 $self->write($self->{long_res});
 532                         });
 533                 } else { # all done!
 534                         $self->{long_res} = undef;
 535                         $self->watch_read(1);
 536                         res($self, '.');
 537                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 538                 }
 539         };
 540         $self->{long_res}->(); # kick off!
 541         undef;
 542 }
 543
 544 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 545         my ($self, $xhdr, $range) = @_;
 546
 547         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 548                 my ($ng, $n) = mid_lookup($self, $1);
 549                 return r430 unless $n;
 550                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 551         } else { # numeric range
 552                 $range = $self->{article} unless defined $range;
 553                 my $r = get_range($self, $range);
 554                 return $r unless ref $r;
 555                 my $mm = $self->{ng}->mm;
 556                 my ($beg, $end) = @$r;
 557                 more($self, '221 Header follows');
 558                 $self->long_response($beg, $end, sub {
 559                         my ($i) = @_;
 560                         my $mid = $mm->mid_for($$i);
 561                         more($self, "$$i <$mid>") if defined $mid;
 562                 });
 563         }
 564 }
 565
 566 sub xref ($$) {
 567         my ($ng, $n) = @_;
 568         "$ng->{domain} $ng->{name}:$n"
 569 }
 570
 571 sub mid_lookup ($$) {
 572         my ($self, $mid) = @_;
 573         my $self_ng = $self->{ng};
 574         if ($self_ng) {
 575                 my $n = $self_ng->mm->num_for($mid);
 576                 return ($self_ng, $n) if defined $n;
 577         }
 578         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 579                 next if defined $self_ng && $ng eq $self_ng;
 580                 my $n = $ng->mm->num_for($mid);
 581                 return ($ng, $n) if defined $n;
 582         }
 583         (undef, undef);
 584 }
 585
 586 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 587         my ($self, $xhdr, $range) = @_;
 588
 589         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 590                 my ($ng, $n) = mid_lookup($self, $1);
 591                 return r430 unless $n;
 592                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 593         } else { # numeric range
 594                 $range = $self->{article} unless defined $range;
 595                 my $r = get_range($self, $range);
 596                 return $r unless ref $r;
 597                 my $ng = $self->{ng};
 598                 my $mm = $ng->mm;
 599                 my ($beg, $end) = @$r;
 600                 more($self, '221 Header follows');
 601                 $self->long_response($beg, $end, sub {
 602                         my ($i) = @_;
 603                         my $mid = $mm->mid_for($$i);
 604                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 605                 });
 606         }
 607 }
 608
 609 sub header_obj_for {
 610         my ($srch, $mid) = @_;
 611         eval {
 612                 my $smsg = $srch->lookup_message($mid);
 613                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 614                 $smsg->mini_mime->header_obj;
 615         };
 616 };
 617
 618 sub hdr_searchmsg ($$$$) {
 619         my ($self, $xhdr, $hdr, $range) = @_;
 620         my $filter;
 621         if ($hdr eq 'date') {
 622                 $hdr = 'X-PI-TS';
 623                 $filter = sub ($) {
 624                         strftime('%a, %d %b %Y %T %z', gmtime($_[0]));
 625                 };
 626         }
 627
 628         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 629                 my ($ng, $n) = mid_lookup($self, $1);
 630                 return r430 unless $n;
 631                 if (my $srch = $ng->search) {
 632                         my $m = header_obj_for($srch, $range);
 633                         my $v = $m->header($hdr);
 634                         $v = $filter->($v) if defined $v && $filter;
 635                         hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 636                 } else {
 637                         hdr_slow($self, $xhdr, $hdr, $range);
 638                 }
 639         } else { # numeric range
 640                 $range = $self->{article} unless defined $range;
 641                 my $srch = $self->{ng}->search or
 642                                 return hdr_slow($self, $xhdr, $hdr, $range);
 643                 my $mm = $self->{ng}->mm;
 644                 my $r = get_range($self, $range);
 645                 return $r unless ref $r;
 646                 my ($beg, $end) = @$r;
 647                 more($self, '221 Header follows');
 648                 $self->long_response($beg, $end, sub {
 649                         my ($i) = @_;
 650                         my $mid = $mm->mid_for($$i) or return;
 651                         my $m = header_obj_for($srch, $mid) or return;
 652                         my $v = $m->header($hdr);
 653                         defined $v or return;
 654                         $v = $filter->($v) if $filter;
 655                         more($self, "$$i $v");
 656                 });
 657         }
 658 }
 659
 660 sub do_hdr ($$$;$) {
 661         my ($self, $xhdr, $header, $range) = @_;
 662         my $sub = lc $header;
 663         if ($sub eq 'message-id') {
 664                 hdr_message_id($self, $xhdr, $range);
 665         } elsif ($sub eq 'xref') {
 666                 hdr_xref($self, $xhdr, $range);
 667         } elsif ($sub =~ /\A(subject|references|date)\z/) {
 668                 hdr_searchmsg($self, $xhdr, $sub, $range);
 669         } else {
 670                 hdr_slow($self, $xhdr, $header, $range);
 671         }
 672 }
 673
 674 # RFC 3977
 675 sub cmd_hdr ($$;$) {
 676         my ($self, $header, $range) = @_;
 677         do_hdr($self, 0, $header, $range);
 678 }
 679
 680 # RFC 2980
 681 sub cmd_xhdr ($$;$) {
 682         my ($self, $header, $range) = @_;
 683         do_hdr($self, 1, $header, $range);
 684 }
 685
 686 sub hdr_mid_prefix ($$$$$) {
 687         my ($self, $xhdr, $ng, $n, $mid) = @_;
 688         return $mid if $xhdr;
 689
 690         # HDR for RFC 3977 users
 691         if (my $self_ng = $self->{ng}) {
 692                 ($self_ng eq $ng) ? $n : '0';
 693         } else {
 694                 '0';
 695         }
 696 }
 697
 698 sub hdr_mid_response ($$$$$$) {
 699         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 700         my $res = '';
 701         if ($xhdr) {
 702                 $res .= r221 . "\r\n";
 703                 $res .= "$mid $v\r\n" if defined $v;
 704         } else {
 705                 $res .= r224 . "\r\n";
 706                 if (defined $v) {
 707                         my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 708                         $res .= "$pfx $v\r\n";
 709                 }
 710         }
 711         res($self, $res .= '.');
 712         undef;
 713 }
 714
 715 sub hdr_slow ($$$$) {
 716         my ($self, $xhdr, $header, $range) = @_;
 717
 718         if (defined $range && $range =~ /\A<.+>\z/) { # Message-ID
 719                 my $r = $self->art_lookup($range, 2);
 720                 return $r unless ref $r;
 721                 my ($n, $ng) = ($r->[0], $r->[5]);
 722                 my $v = hdr_val($r, $header);
 723                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 724         } else { # numeric range
 725                 $range = $self->{article} unless defined $range;
 726                 my $r = get_range($self, $range);
 727                 return $r unless ref $r;
 728                 my ($beg, $end) = @$r;
 729                 more($self, $xhdr ? r221 : r224);
 730                 $self->long_response($beg, $end, sub {
 731                         my ($i) = @_;
 732                         $r = $self->art_lookup($$i, 2);
 733                         return unless ref $r;
 734                         defined($r = hdr_val($r, $header)) or return;
 735                         more($self, "$$i $r");
 736                 });
 737         }
 738 }
 739
 740 sub cmd_xrover ($;$) {
 741         my ($self, $range) = @_;
 742         my $ng = $self->{ng} or return '412 no newsgroup selected';
 743         (defined $range && $range =~ /[<>]/) and
 744                 return '420 No article(s) selected'; # no message IDs
 745
 746         $range = $self->{article} unless defined $range;
 747         my $r = get_range($self, $range);
 748         return $r unless ref $r;
 749         my ($beg, $end) = @$r;
 750         my $mm = $ng->mm;
 751         my $srch = $ng->search;
 752         more($self, '224 Overview information follows');
 753         $self->long_response($beg, $end, sub {
 754                 my ($i) = @_;
 755                 my $mid = $mm->mid_for($$i) or return;
 756                 my $m = header_obj_for($srch, $mid) or return;
 757                 my $h = $m->header('references');
 758                 more($self, "$$i $h") if defined $h;
 759         });
 760 }
 761
 762 sub over_line ($$) {
 763         my ($self, $r) = @_;
 764
 765         more($self, join("\t", $r->[0], map {
 766                                 my $h = hdr_val($r, $_);
 767                                 defined $h ? $h : '';
 768                         } @OVERVIEW ));
 769 }
 770
 771 sub cmd_over ($;$) {
 772         my ($self, $range) = @_;
 773         if ($range && $range =~ /\A<.+>\z/) {
 774                 my $r = $self->art_lookup($range, 2);
 775                 return '430 No article with that message-id' unless ref $r;
 776                 more($self, '224 Overview information follows (multi-line)');
 777
 778                 # Only set article number column if it's the current group
 779                 my $ng = $self->{ng};
 780                 $r->[0] = 0 if (!$ng || $ng ne $r->[5]);
 781                 over_line($self, $r);
 782                 '.';
 783         } else {
 784                 cmd_xover($self, $range);
 785         }
 786 }
 787
 788 sub cmd_xover ($;$) {
 789         my ($self, $range) = @_;
 790         $range = $self->{article} unless defined $range;
 791         my $r = get_range($self, $range);
 792         return $r unless ref $r;
 793         my ($beg, $end) = @$r;
 794         more($self, "224 Overview information follows for $beg to $end");
 795         $self->long_response($beg, $end, sub {
 796                 my ($i) = @_;
 797                 my $r = $self->art_lookup($$i, 2);
 798                 return unless ref $r;
 799                 over_line($self, $r);
 800         });
 801 }
 802
 803 sub cmd_xpath ($$) {
 804         my ($self, $mid) = @_;
 805         return r501 unless $mid =~ /\A<(.+)>\z/;
 806         $mid = $1;
 807         my @paths;
 808         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 809                 my $n = $ng->mm->num_for($mid);
 810                 push @paths, "$ng->{name}/$n" if defined $n;
 811         }
 812         return '430 no such article on server' unless @paths;
 813         '223 '.join(' ', @paths);
 814 }
 815
 816 sub res ($$) {
 817         my ($self, $line) = @_;
 818         do_write($self, $line . "\r\n");
 819 }
 820
 821 sub more ($$) {
 822         my ($self, $line) = @_;
 823         do_more($self, $line . "\r\n");
 824 }
 825
 826 sub do_write ($$) {
 827         my ($self, $data) = @_;
 828         my $done = $self->write($data);
 829         die if $self->{closed};
 830
 831         # Do not watch for readability if we have data in the queue,
 832         # instead re-enable watching for readability when we can
 833         $self->watch_read(0) if (!$done || $self->{long_res});
 834
 835         $done;
 836 }
 837
 838 sub err ($$;@) {
 839         my ($self, $fmt, @args) = @_;
 840         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 841 }
 842
 843 sub out ($$;@) {
 844         my ($self, $fmt, @args) = @_;
 845         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 846 }
 847
 848 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 849
 850 sub do_more ($$) {
 851         my ($self, $data) = @_;
 852         if (MSG_MORE && !$self->{write_buf_size}) {
 853                 my $n = send($self->{sock}, $data, MSG_MORE);
 854                 if (defined $n) {
 855                         my $dlen = length($data);
 856                         return 1 if $n == $dlen; # all done!
 857                         $data = substr($data, $n, $dlen - $n);
 858                 }
 859         }
 860         $self->do_write($data);
 861 }
 862
 863 # callbacks for by Danga::Socket
 864
 865 sub event_hup { $_[0]->close }
 866 sub event_err { $_[0]->close }
 867
 868 sub event_write {
 869         my ($self) = @_;
 870         # only continue watching for readability when we are done writing:
 871         if ($self->write(undef) == 1 && !$self->{long_res}) {
 872                 $self->watch_read(1);
 873         }
 874 }
 875
 876 sub event_read {
 877         my ($self) = @_;
 878         use constant LINE_MAX => 512; # RFC 977 section 2.3
 879         my $r = 1;
 880
 881         my $buf = $self->read(LINE_MAX) or return $self->close;
 882         $self->{rbuf} .= $$buf;
 883         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 884                 my $line = $1;
 885                 my $t0 = now();
 886                 my $fd = $self->{fd};
 887                 $r = eval { $self->process_line($line) };
 888                 my $d = $self->{long_res} ?
 889                         " deferred[$fd]" : '';
 890                 out($self, "[$fd] $line - %0.6f$d", now() - $t0);
 891         }
 892
 893         return $self->close if $r < 0;
 894         my $len = length($self->{rbuf});
 895         return $self->close if ($len >= LINE_MAX);
 896 }
 897
 898 sub watch_read {
 899         my ($self, $bool) = @_;
 900         my $rv = $self->SUPER::watch_read($bool);
 901         if ($bool && $self->{rbuf} ne '') {
 902                 # Force another read if there is a pipelined request.
 903                 # We don't know if the socket has anything for us to read,
 904                 # and we must double-check again by the time the timer fires
 905                 # in case we really did dispatch a read event and started
 906                 # another long response.
 907                 Danga::Socket->AddTimer(0, sub {
 908                         if (&Danga::Socket::POLLIN & $self->{event_watch}) {
 909                                 $self->event_read;
 910                         }
 911                 });
 912         }
 913         $rv;
 914 }
 915
 916 sub busy () {
 917         my ($self) = @_;
 918         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size});
 919 }
 920
 921 1;