lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 # fields:
   6 # nntpd: PublicInbox::NNTPD ref
   7 # article: per-session current article number
   8 # ng: PublicInbox::Inbox ref
   9 # long_cb: long_response private data
  10 package PublicInbox::NNTP;
  11 use strict;
  12 use parent qw(PublicInbox::DS);
  13 use PublicInbox::MID qw(mid_escape $MID_EXTRACT);
  14 use PublicInbox::Eml;
  15 use POSIX qw(strftime);
  16 use PublicInbox::DS qw(now);
  17 use Digest::SHA qw(sha1_hex);
  18 use Time::Local qw(timegm timelocal);
  19 use PublicInbox::GitAsyncCat;
  20 use constant {
  21         LINE_MAX => 512, # RFC 977 section 2.3
  22         r501 => '501 command syntax error',
  23         r502 => '502 Command unavailable',
  24         r221 => '221 Header follows',
  25         r224 => '224 Overview information follows (multi-line)',
  26         r225 => '225 Headers follow (multi-line)',
  27         r430 => '430 No article with that message-id',
  28 };
  29 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  30 use Errno qw(EAGAIN);
  31 my $ONE_MSGID = qr/\A$MID_EXTRACT\z/;
  32 my @OVERVIEW = qw(Subject From Date Message-ID References);
  33 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  34                 "Xref:full\r\n";
  35 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  36                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  37 my $CAPABILITIES = <<"";
  38 101 Capability list:\r
  39 VERSION 2\r
  40 READER\r
  41 NEWNEWS\r
  42 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  43 HDR\r
  44 OVER\r
  45 COMPRESS DEFLATE\r
  46
  47 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  48
  49 sub new ($$$) {
  50         my ($class, $sock, $nntpd) = @_;
  51         my $self = bless { nntpd => $nntpd }, $class;
  52         my $ev = EPOLLIN;
  53         my $wbuf;
  54         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
  55                 return CORE::close($sock) if $! != EAGAIN;
  56                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
  57                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  58         }
  59         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  60         if ($wbuf) {
  61                 $self->{wbuf} = $wbuf;
  62         } else {
  63                 greet($self);
  64         }
  65         $self->update_idle_time;
  66         $self;
  67 }
  68
  69 sub args_ok ($$) {
  70         my ($cb, $argc) = @_;
  71         my $tot = prototype $cb;
  72         my ($nreq, undef) = split(';', $tot);
  73         $nreq = ($nreq =~ tr/$//) - 1;
  74         $tot = ($tot =~ tr/$//) - 1;
  75         ($argc <= $tot && $argc >= $nreq);
  76 }
  77
  78 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  79 sub process_line ($$) {
  80         my ($self, $l) = @_;
  81         my ($req, @args) = split(/[ \t]+/, $l);
  82         return 1 unless defined($req); # skip blank line
  83         $req = $self->can('cmd_'.lc($req));
  84         return res($self, '500 command not recognized') unless $req;
  85         return res($self, r501) unless args_ok($req, scalar @args);
  86
  87         my $res = eval { $req->($self, @args) };
  88         my $err = $@;
  89         if ($err && $self->{sock}) {
  90                 local $/ = "\n";
  91                 chomp($l);
  92                 err($self, 'error from: %s (%s)', $l, $err);
  93                 $res = '503 program fault - command not performed';
  94         }
  95         return 0 unless defined $res;
  96         res($self, $res);
  97 }
  98
  99 # The keyword argument is not used (rfc3977 5.2.2)
 100 sub cmd_capabilities ($;$) {
 101         my ($self, undef) = @_;
 102         my $res = $CAPABILITIES;
 103         if (!$self->{sock}->can('accept_SSL') &&
 104                         $self->{nntpd}->{accept_tls}) {
 105                 $res .= "STARTTLS\r\n";
 106         }
 107         $res .= '.';
 108 }
 109
 110 sub cmd_mode ($$) {
 111         my ($self, $arg) = @_;
 112         $arg = uc $arg;
 113         return r501 unless $arg eq 'READER';
 114         '201 Posting prohibited';
 115 }
 116
 117 sub cmd_slave ($) { '202 slave status noted' }
 118
 119 sub cmd_xgtitle ($;$) {
 120         my ($self, $wildmat) = @_;
 121         more($self, '282 list of groups and descriptions follows');
 122         list_newsgroups($self, $wildmat);
 123         '.'
 124 }
 125
 126 sub list_overview_fmt ($) {
 127         my ($self) = @_;
 128         $self->msg_more($OVERVIEW_FMT);
 129 }
 130
 131 sub list_headers ($;$) {
 132         my ($self) = @_;
 133         $self->msg_more($LIST_HEADERS);
 134 }
 135
 136 sub list_active ($;$) {
 137         my ($self, $wildmat) = @_;
 138         wildmat2re($wildmat);
 139         my $groups = $self->{nntpd}->{groups};
 140         for my $ngname (grep(/$wildmat/, @{$self->{nntpd}->{groupnames}})) {
 141                 group_line($self, $groups->{$ngname});
 142         }
 143 }
 144
 145 sub list_active_times ($;$) {
 146         my ($self, $wildmat) = @_;
 147         wildmat2re($wildmat);
 148         my $groups = $self->{nntpd}->{groups};
 149         for my $ngname (grep(/$wildmat/, @{$self->{nntpd}->{groupnames}})) {
 150                 my $ibx = $groups->{$ngname};
 151                 my $c = eval { $ibx->uidvalidity } // time;
 152                 more($self, "$ngname $c $ibx->{-primary_address}");
 153         }
 154 }
 155
 156 sub list_newsgroups ($;$) {
 157         my ($self, $wildmat) = @_;
 158         wildmat2re($wildmat);
 159         my $groups = $self->{nntpd}->{groups};
 160         for my $ngname (grep(/$wildmat/, @{$self->{nntpd}->{groupnames}})) {
 161                 more($self, "$ngname ".$groups->{$ngname}->description);
 162         }
 163 }
 164
 165 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 166 sub cmd_list ($;$$) {
 167         my ($self, @args) = @_;
 168         if (scalar @args) {
 169                 my $arg = shift @args;
 170                 $arg =~ tr/A-Z./a-z_/;
 171                 $arg = "list_$arg";
 172                 $arg = $self->can($arg);
 173                 return r501 unless $arg && args_ok($arg, scalar @args);
 174                 more($self, '215 information follows');
 175                 $arg->($self, @args);
 176         } else {
 177                 more($self, '215 list of newsgroups follows');
 178                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 179                         group_line($self, $ng);
 180                 }
 181         }
 182         '.'
 183 }
 184
 185 sub listgroup_range_i {
 186         my ($self, $beg, $end) = @_;
 187         my $r = $self->{ng}->mm->msg_range($beg, $end, 'num');
 188         scalar(@$r) or return;
 189         more($self, join("\r\n", map { $_->[0] } @$r));
 190         1;
 191 }
 192
 193 sub listgroup_all_i {
 194         my ($self, $num) = @_;
 195         my $ary = $self->{ng}->mm->ids_after($num);
 196         scalar(@$ary) or return;
 197         more($self, join("\r\n", @$ary));
 198         1;
 199 }
 200
 201 sub cmd_listgroup ($;$$) {
 202         my ($self, $group, $range) = @_;
 203         if (defined $group) {
 204                 my $res = cmd_group($self, $group);
 205                 return $res if ($res !~ /\A211 /);
 206                 more($self, $res);
 207         }
 208         $self->{ng} or return '412 no newsgroup selected';
 209         if (defined $range) {
 210                 my $r = get_range($self, $range);
 211                 return $r unless ref $r;
 212                 long_response($self, \&listgroup_range_i, @$r);
 213         } else { # grab every article number
 214                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 215         }
 216 }
 217
 218 sub parse_time ($$;$) {
 219         my ($date, $time, $gmt) = @_;
 220         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 221         if (defined $gmt) {
 222                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 223                 $gmt = 1;
 224         }
 225         my ($YYYY, $MM, $DD);
 226         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 227                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 228         } else { # legacy clients send YYMMDD
 229                 my $YY;
 230                 ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 231                 my @now = $gmt ? gmtime : localtime;
 232                 my $cur_year = $now[5] + 1900;
 233                 my $cur_cent = int($cur_year / 100) * 100;
 234                 $YYYY = (($YY + $cur_cent) > $cur_year) ?
 235                         ($YY + 1900) : ($YY + $cur_cent);
 236         }
 237         if ($gmt) {
 238                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 239         } else {
 240                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 241         }
 242 }
 243
 244 sub group_line ($$) {
 245         my ($self, $ng) = @_;
 246         my ($min, $max) = $ng->mm->minmax;
 247         more($self, "$ng->{newsgroup} $max $min n");
 248 }
 249
 250 sub cmd_newgroups ($$$;$$) {
 251         my ($self, $date, $time, $gmt, $dists) = @_;
 252         my $ts = eval { parse_time($date, $time, $gmt) };
 253         return r501 if $@;
 254
 255         # TODO dists
 256         more($self, '231 list of new newsgroups follows');
 257         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 258                 my $c = eval { $ng->uidvalidity } // 0;
 259                 next unless $c > $ts;
 260                 group_line($self, $ng);
 261         }
 262         '.'
 263 }
 264
 265 sub wildmat2re (;$) {
 266         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 267         my %keep;
 268         my $salt = rand;
 269         my $tmp = $_[0];
 270
 271         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 272                 my $orig = $1;
 273                 my $key = sha1_hex($orig . $salt);
 274                 $orig =~ s/([^\w\-])+/\Q$1/g;
 275                 $keep{$key} = $orig;
 276                 $key
 277                 #gex;
 278         my %map = ('*' => '.*', '?' => '.' );
 279         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 280         if (scalar %keep) {
 281                 $tmp =~ s#([a-f0-9]{40})#
 282                         my $orig = $keep{$1};
 283                         defined $orig ? $orig : $1;
 284                         #ge;
 285         }
 286         $_[0] = qr/\A$tmp\z/;
 287 }
 288
 289 sub ngpat2re (;$) {
 290         return $_[0] = qr/\A\z/ unless defined $_[0];
 291         my %map = ('*' => '.*', ',' => '|');
 292         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 293         $_[0] = qr/\A(?:$_[0])\z/;
 294 }
 295
 296 sub newnews_i {
 297         my ($self, $overs, $ts, $prev) = @_;
 298         my $over = $overs->[0];
 299         my $msgs = $over->query_ts($ts, $$prev);
 300         if (scalar @$msgs) {
 301                 more($self, '<' .
 302                         join(">\r\n<", map { $_->{mid} } @$msgs ).
 303                         '>');
 304                 $$prev = $msgs->[-1]->{num};
 305         } else {
 306                 shift @$overs;
 307                 if (@$overs) { # continue onto next newsgroup
 308                         $$prev = 0;
 309                         return 1;
 310                 } else { # break out of the long response.
 311                         return;
 312                 }
 313         }
 314 }
 315
 316 sub cmd_newnews ($$$$;$$) {
 317         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 318         my $ts = eval { parse_time($date, $time, $gmt) };
 319         return r501 if $@;
 320         more($self, '230 list of new articles by message-id follows');
 321         my ($keep, $skip) = split('!', $newsgroups, 2);
 322         ngpat2re($keep);
 323         ngpat2re($skip);
 324         my @overs;
 325         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 326                 $ng->{newsgroup} =~ $keep or next;
 327                 $ng->{newsgroup} =~ $skip and next;
 328                 my $over = $ng->over or next;
 329                 push @overs, $over;
 330         };
 331         return '.' unless @overs;
 332
 333         my $prev = 0;
 334         long_response($self, \&newnews_i, \@overs, $ts, \$prev);
 335 }
 336
 337 sub cmd_group ($$) {
 338         my ($self, $group) = @_;
 339         my $no_such = '411 no such news group';
 340         my $nntpd = $self->{nntpd};
 341         my $ng = $nntpd->{groups}->{$group} or return $no_such;
 342         $nntpd->idler_start;
 343
 344         $self->{ng} = $ng;
 345         my ($min, $max) = $ng->mm->minmax;
 346         $self->{article} = $min;
 347         my $est_size = $max - $min;
 348         "211 $est_size $min $max $group";
 349 }
 350
 351 sub article_adj ($$) {
 352         my ($self, $off) = @_;
 353         my $ng = $self->{ng} or return '412 no newsgroup selected';
 354
 355         my $n = $self->{article};
 356         defined $n or return '420 no current article has been selected';
 357
 358         $n += $off;
 359         my $mid = $ng->mm->mid_for($n);
 360         unless ($mid) {
 361                 $n = $off > 0 ? 'next' : 'previous';
 362                 return "421 no $n article in this group";
 363         }
 364         $self->{article} = $n;
 365         "223 $n <$mid> article retrieved - request text separately";
 366 }
 367
 368 sub cmd_next ($) { article_adj($_[0], 1) }
 369 sub cmd_last ($) { article_adj($_[0], -1) }
 370
 371 # We want to encourage using email and CC-ing everybody involved to avoid
 372 # the single-point-of-failure a single server provides.
 373 sub cmd_post ($) {
 374         my ($self) = @_;
 375         my $ng = $self->{ng};
 376         $ng ? "440 mailto:$ng->{-primary_address} to post"
 377                 : '440 posting not allowed'
 378 }
 379
 380 sub cmd_quit ($) {
 381         my ($self) = @_;
 382         res($self, '205 closing connection - goodbye!');
 383         $self->shutdn;
 384         undef;
 385 }
 386
 387 sub header_append ($$$) {
 388         my ($hdr, $k, $v) = @_;
 389         my @v = $hdr->header_raw($k);
 390         foreach (@v) {
 391                 return if $v eq $_;
 392         }
 393         $hdr->header_set($k, @v, $v);
 394 }
 395
 396 sub xref ($$$$) {
 397         my ($self, $ng, $n, $mid) = @_;
 398         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 399
 400         # num_for is pretty cheap and sometimes we'll lookup the existence
 401         # of an article without getting even the OVER info.  In other words,
 402         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 403         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 404         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 405                 next if $ng eq $other;
 406                 my $num = eval { $other->mm->num_for($mid) } or next;
 407                 $ret .= " $other->{newsgroup}:$num";
 408         }
 409         $ret;
 410 }
 411
 412 sub set_nntp_headers ($$) {
 413         my ($hdr, $smsg) = @_;
 414         my ($mid) = $smsg->{mid};
 415
 416         # leafnode (and maybe other NNTP clients) have trouble dealing
 417         # with v2 messages which have multiple Message-IDs (either due
 418         # to our own content-based dedupe or buggy git-send-email versions).
 419         my @mids = $hdr->header_raw('Message-ID');
 420         if (scalar(@mids) > 1) {
 421                 my $mid0 = "<$mid>";
 422                 $hdr->header_set('Message-ID', $mid0);
 423                 my @alt = $hdr->header_raw('X-Alt-Message-ID');
 424                 my %seen = map { $_ => 1 } (@alt, $mid0);
 425                 push(@alt, grep { !$seen{$_}++ } @mids);
 426                 $hdr->header_set('X-Alt-Message-ID', @alt);
 427         }
 428
 429         # clobber some existing headers
 430         my $ibx = $smsg->{-ibx};
 431         my $xref = xref($smsg->{nntp}, $ibx, $smsg->{num}, $mid);
 432         $hdr->header_set('Xref', $xref);
 433
 434         # RFC 5536 3.1.4
 435         my ($server_name, $newsgroups) = split(/ /, $xref, 2);
 436         $newsgroups =~ s/:[0-9]+\b//g; # drop NNTP article numbers
 437         $newsgroups =~ tr/ /,/;
 438         $hdr->header_set('Newsgroups', $newsgroups);
 439
 440         # *something* here is required for leafnode, try to follow
 441         # RFC 5536 3.1.5...
 442         $hdr->header_set('Path', $server_name . '!not-for-mail');
 443
 444         header_append($hdr, 'List-Post', "<mailto:$ibx->{-primary_address}>");
 445         if (my $url = $ibx->base_url) {
 446                 $mid = mid_escape($mid);
 447                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 448                 header_append($hdr, 'List-Archive', "<$url>");
 449         }
 450 }
 451
 452 sub art_lookup ($$$) {
 453         my ($self, $art, $code) = @_;
 454         my $ng = $self->{ng};
 455         my ($n, $mid);
 456         my $err;
 457         if (defined $art) {
 458                 if ($art =~ /\A[0-9]+\z/) {
 459                         $err = '423 no such article number in this group';
 460                         $n = int($art);
 461                         goto find_mid;
 462                 } elsif ($art =~ $ONE_MSGID) {
 463                         $mid = $1;
 464                         $err = r430;
 465                         $n = $ng->mm->num_for($mid) if $ng;
 466                         goto found if defined $n;
 467                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 468                                 $n = $g->mm->num_for($mid);
 469                                 if (defined $n) {
 470                                         $ng = $g;
 471                                         goto found;
 472                                 }
 473                         }
 474                         return $err;
 475                 } else {
 476                         return r501;
 477                 }
 478         } else {
 479                 $err = '420 no current article has been selected';
 480                 $n = $self->{article};
 481                 defined $n or return $err;
 482 find_mid:
 483                 $ng or return '412 no newsgroup has been selected';
 484                 $mid = $ng->mm->mid_for($n);
 485                 defined $mid or return $err;
 486         }
 487 found:
 488         my $smsg = $ng->over->get_art($n) or return $err;
 489         $smsg->{-ibx} = $ng;
 490         if ($code == 223) { # STAT
 491                 set_art($self, $n);
 492                 "223 $n <$smsg->{mid}> article retrieved - " .
 493                         "request text separately";
 494         } else { # HEAD | BODY | ARTICLE
 495                 $smsg->{nntp} = $self;
 496                 $smsg->{nntp_code} = $code;
 497                 set_art($self, $art);
 498                 # this dereferences to `undef'
 499                 ${git_async_cat($ng->git, $smsg->{blob}, \&blob_cb, $smsg)};
 500         }
 501 }
 502
 503 sub msg_body_write ($$) {
 504         my ($self, $msg) = @_;
 505
 506         # these can momentarily double the memory consumption :<
 507         $$msg =~ s/^\./../smg;
 508         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 509         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 510         $self->msg_more($$msg);
 511 }
 512
 513 sub set_art {
 514         my ($self, $art) = @_;
 515         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 516 }
 517
 518 sub msg_hdr_write ($$) {
 519         my ($eml, $smsg) = @_;
 520         set_nntp_headers($eml, $smsg);
 521
 522         my $hdr = $eml->{hdr} // \(my $x = '');
 523         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 524         $$hdr =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 525         $$hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 526
 527         # for leafnode compatibility, we need to ensure Message-ID headers
 528         # are only a single line.
 529         $$hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 530         $smsg->{nntp}->msg_more($$hdr);
 531 }
 532
 533 sub blob_cb { # called by git->cat_async via git_async_cat
 534         my ($bref, $oid, $type, $size, $smsg) = @_;
 535         my $self = $smsg->{nntp};
 536         my $code = $smsg->{nntp_code};
 537         if (!defined($oid)) {
 538                 # it's possible to have TOCTOU if an admin runs
 539                 # public-inbox-(edit|purge), just move onto the next message
 540                 warn "E: $smsg->{blob} missing in $smsg->{-ibx}->{inboxdir}\n";
 541                 return $self->requeue;
 542         } elsif ($smsg->{blob} ne $oid) {
 543                 $self->close;
 544                 die "BUG: $smsg->{blob} != $oid";
 545         }
 546         my $r = "$code $smsg->{num} <$smsg->{mid}> article retrieved - ";
 547         my $eml = PublicInbox::Eml->new($bref);
 548         if ($code == 220) {
 549                 more($self, $r .= 'head and body follow');
 550                 msg_hdr_write($eml, $smsg);
 551                 $self->msg_more("\r\n");
 552                 msg_body_write($self, $bref);
 553         } elsif ($code == 221) {
 554                 more($self, $r .= 'head follows');
 555                 msg_hdr_write($eml, $smsg);
 556         } elsif ($code == 222) {
 557                 more($self, $r .= 'body follows');
 558                 msg_body_write($self, $bref);
 559         } else {
 560                 $self->close;
 561                 die "BUG: bad code: $r";
 562         }
 563         $self->write(\".\r\n"); # flushes (includes ->zflush)
 564         $self->requeue;
 565 }
 566
 567 sub cmd_article ($;$) {
 568         my ($self, $art) = @_;
 569         art_lookup($self, $art, 220);
 570 }
 571
 572 sub cmd_head ($;$) {
 573         my ($self, $art) = @_;
 574         art_lookup($self, $art, 221);
 575 }
 576
 577 sub cmd_body ($;$) {
 578         my ($self, $art) = @_;
 579         art_lookup($self, $art, 222);
 580 }
 581
 582 sub cmd_stat ($;$) {
 583         my ($self, $art) = @_;
 584         art_lookup($self, $art, 223); # art may be msgid
 585 }
 586
 587 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 588
 589 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 590
 591 sub cmd_help ($) {
 592         my ($self) = @_;
 593         more($self, '100 help text follows');
 594         '.'
 595 }
 596
 597 sub get_range ($$) {
 598         my ($self, $range) = @_;
 599         my $ng = $self->{ng} or return '412 no news group has been selected';
 600         defined $range or return '420 No article(s) selected';
 601         my ($beg, $end);
 602         my ($min, $max) = $ng->mm->minmax;
 603         if ($range =~ /\A([0-9]+)\z/) {
 604                 $beg = $end = $1;
 605         } elsif ($range =~ /\A([0-9]+)-\z/) {
 606                 ($beg, $end) = ($1, $max);
 607         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 608                 ($beg, $end) = ($1, $2);
 609         } else {
 610                 return r501;
 611         }
 612         $beg = $min if ($beg < $min);
 613         $end = $max if ($end > $max);
 614         return '420 No article(s) selected' if ($beg > $end);
 615         [ \$beg, $end ];
 616 }
 617
 618 sub long_step {
 619         my ($self) = @_;
 620         # wbuf is unset or empty, here; {long} may add to it
 621         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
 622         my $more = eval { $cb->($self, @args) };
 623         if ($@ || !$self->{sock}) { # something bad happened...
 624                 delete $self->{long_cb};
 625                 my $elapsed = now() - $t0;
 626                 if ($@) {
 627                         err($self,
 628                             "%s during long response[$fd] - %0.6f",
 629                             $@, $elapsed);
 630                 }
 631                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 632                 $self->close;
 633         } elsif ($more) { # $self->{wbuf}:
 634                 $self->update_idle_time;
 635
 636                 # COMPRESS users all share the same DEFLATE context.
 637                 # Flush it here to ensure clients don't see
 638                 # each other's data
 639                 $self->zflush;
 640
 641                 # no recursion, schedule another call ASAP, but only after
 642                 # all pending writes are done.  autovivify wbuf:
 643                 my $new_size = push(@{$self->{wbuf}}, \&long_step);
 644
 645                 # wbuf may be populated by $cb, no need to rearm if so:
 646                 $self->requeue if $new_size == 1;
 647         } else { # all done!
 648                 delete $self->{long_cb};
 649                 res($self, '.');
 650                 my $elapsed = now() - $t0;
 651                 my $fd = fileno($self->{sock});
 652                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 653                 my $wbuf = $self->{wbuf}; # do NOT autovivify
 654                 $self->requeue unless $wbuf && @$wbuf;
 655         }
 656 }
 657
 658 sub long_response ($$;@) {
 659         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 660
 661         my $sock = $self->{sock} or return;
 662         # make sure we disable reading during a long response,
 663         # clients should not be sending us stuff and making us do more
 664         # work while we are stream a response to them
 665         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
 666         long_step($self); # kick off!
 667         undef;
 668 }
 669
 670 sub hdr_msgid_range_i {
 671         my ($self, $beg, $end) = @_;
 672         my $r = $self->{ng}->mm->msg_range($beg, $end);
 673         @$r or return;
 674         more($self, join("\r\n", map { "$_->[0] <$_->[1]>" } @$r));
 675         1;
 676 }
 677
 678 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 679         my ($self, $xhdr, $range) = @_;
 680
 681         if (defined $range && $range =~ $ONE_MSGID) {
 682                 my ($ng, $n) = mid_lookup($self, $1);
 683                 return r430 unless $n;
 684                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 685         } else { # numeric range
 686                 $range = $self->{article} unless defined $range;
 687                 my $r = get_range($self, $range);
 688                 return $r unless ref $r;
 689                 more($self, $xhdr ? r221 : r225);
 690                 long_response($self, \&hdr_msgid_range_i, @$r);
 691         }
 692 }
 693
 694 sub mid_lookup ($$) {
 695         my ($self, $mid) = @_;
 696         my $self_ng = $self->{ng};
 697         if ($self_ng) {
 698                 my $n = $self_ng->mm->num_for($mid);
 699                 return ($self_ng, $n) if defined $n;
 700         }
 701         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 702                 next if defined $self_ng && $ng eq $self_ng;
 703                 my $n = $ng->mm->num_for($mid);
 704                 return ($ng, $n) if defined $n;
 705         }
 706         (undef, undef);
 707 }
 708
 709 sub xref_range_i {
 710         my ($self, $beg, $end) = @_;
 711         my $ng = $self->{ng};
 712         my $r = $ng->mm->msg_range($beg, $end);
 713         @$r or return;
 714         more($self, join("\r\n", map {
 715                 my $num = $_->[0];
 716                 "$num ".xref($self, $ng, $num, $_->[1]);
 717         } @$r));
 718         1;
 719 }
 720
 721 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 722         my ($self, $xhdr, $range) = @_;
 723
 724         if (defined $range && $range =~ $ONE_MSGID) {
 725                 my $mid = $1;
 726                 my ($ng, $n) = mid_lookup($self, $mid);
 727                 return r430 unless $n;
 728                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 729                                 xref($self, $ng, $n, $mid));
 730         } else { # numeric range
 731                 $range = $self->{article} unless defined $range;
 732                 my $r = get_range($self, $range);
 733                 return $r unless ref $r;
 734                 more($self, $xhdr ? r221 : r225);
 735                 long_response($self, \&xref_range_i, @$r);
 736         }
 737 }
 738
 739 sub over_header_for {
 740         my ($over, $num, $field) = @_;
 741         my $smsg = $over->get_art($num) or return;
 742         return PublicInbox::Smsg::date($smsg) if $field eq 'date';
 743         $smsg->{$field};
 744 }
 745
 746 sub smsg_range_i {
 747         my ($self, $beg, $end, $field) = @_;
 748         my $over = $self->{ng}->over;
 749         my $msgs = $over->query_xover($$beg, $end);
 750         scalar(@$msgs) or return;
 751         my $tmp = '';
 752
 753         # ->{$field} is faster than ->$field invocations, so favor that.
 754         if ($field eq 'date') {
 755                 for my $s (@$msgs) {
 756                         $tmp .= "$s->{num} ".PublicInbox::Smsg::date($s)."\r\n"
 757                 }
 758         } else {
 759                 for my $s (@$msgs) {
 760                         $tmp .= "$s->{num} $s->{$field}\r\n";
 761                 }
 762         }
 763         utf8::encode($tmp);
 764         $self->msg_more($tmp);
 765         $$beg = $msgs->[-1]->{num} + 1;
 766 }
 767
 768 sub hdr_smsg ($$$$) {
 769         my ($self, $xhdr, $field, $range) = @_;
 770         if (defined $range && $range =~ $ONE_MSGID) {
 771                 my ($ng, $n) = mid_lookup($self, $1);
 772                 return r430 unless defined $n;
 773                 my $v = over_header_for($ng->over, $n, $field);
 774                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 775         } else { # numeric range
 776                 $range = $self->{article} unless defined $range;
 777                 my $r = get_range($self, $range);
 778                 return $r unless ref $r;
 779                 more($self, $xhdr ? r221 : r225);
 780                 long_response($self, \&smsg_range_i, @$r, $field);
 781         }
 782 }
 783
 784 sub do_hdr ($$$;$) {
 785         my ($self, $xhdr, $header, $range) = @_;
 786         my $sub = lc $header;
 787         if ($sub eq 'message-id') {
 788                 hdr_message_id($self, $xhdr, $range);
 789         } elsif ($sub eq 'xref') {
 790                 hdr_xref($self, $xhdr, $range);
 791         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 792                                 bytes|lines)\z/x) {
 793                 hdr_smsg($self, $xhdr, $sub, $range);
 794         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 795                 hdr_smsg($self, $xhdr, $1, $range);
 796         } else {
 797                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 798         }
 799 }
 800
 801 # RFC 3977
 802 sub cmd_hdr ($$;$) {
 803         my ($self, $header, $range) = @_;
 804         do_hdr($self, 0, $header, $range);
 805 }
 806
 807 # RFC 2980
 808 sub cmd_xhdr ($$;$) {
 809         my ($self, $header, $range) = @_;
 810         do_hdr($self, 1, $header, $range);
 811 }
 812
 813 sub hdr_mid_prefix ($$$$$) {
 814         my ($self, $xhdr, $ng, $n, $mid) = @_;
 815         return $mid if $xhdr;
 816
 817         # HDR for RFC 3977 users
 818         if (my $self_ng = $self->{ng}) {
 819                 ($self_ng eq $ng) ? $n : '0';
 820         } else {
 821                 '0';
 822         }
 823 }
 824
 825 sub hdr_mid_response ($$$$$$) {
 826         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 827         my $res = '';
 828         if ($xhdr) {
 829                 $res .= r221 . "\r\n";
 830                 $res .= "$mid $v\r\n";
 831         } else {
 832                 $res .= r225 . "\r\n";
 833                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 834                 $res .= "$pfx $v\r\n";
 835         }
 836         res($self, $res .= '.');
 837         undef;
 838 }
 839
 840 sub xrover_i {
 841         my ($self, $beg, $end) = @_;
 842         my $h = over_header_for($self->{ng}->over, $$beg, 'references');
 843         more($self, "$$beg $h") if defined($h);
 844         $$beg++ < $end;
 845 }
 846
 847 sub cmd_xrover ($;$) {
 848         my ($self, $range) = @_;
 849         my $ng = $self->{ng} or return '412 no newsgroup selected';
 850         (defined $range && $range =~ /[<>]/) and
 851                 return '420 No article(s) selected'; # no message IDs
 852
 853         $range = $self->{article} unless defined $range;
 854         my $r = get_range($self, $range);
 855         return $r unless ref $r;
 856         more($self, '224 Overview information follows');
 857         long_response($self, \&xrover_i, @$r);
 858 }
 859
 860 sub over_line ($$$$) {
 861         my ($self, $ng, $num, $smsg) = @_;
 862         # n.b. field access and procedural calls can be
 863         # 10%-15% faster than OO method calls:
 864         my $s = join("\t", $num,
 865                 $smsg->{subject},
 866                 $smsg->{from},
 867                 PublicInbox::Smsg::date($smsg),
 868                 "<$smsg->{mid}>",
 869                 $smsg->{references},
 870                 $smsg->{bytes},
 871                 $smsg->{lines},
 872                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 873         utf8::encode($s);
 874         $s
 875 }
 876
 877 sub cmd_over ($;$) {
 878         my ($self, $range) = @_;
 879         if ($range && $range =~ $ONE_MSGID) {
 880                 my ($ng, $n) = mid_lookup($self, $1);
 881                 defined $n or return r430;
 882                 my $smsg = $ng->over->get_art($n) or return r430;
 883                 more($self, '224 Overview information follows (multi-line)');
 884
 885                 # Only set article number column if it's the current group
 886                 my $self_ng = $self->{ng};
 887                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 888                 more($self, over_line($self, $ng, $n, $smsg));
 889                 '.';
 890         } else {
 891                 cmd_xover($self, $range);
 892         }
 893 }
 894
 895 sub xover_i {
 896         my ($self, $beg, $end) = @_;
 897         my $ng = $self->{ng};
 898         my $msgs = $ng->over->query_xover($$beg, $end);
 899         my $nr = scalar @$msgs or return;
 900
 901         # OVERVIEW.FMT
 902         more($self, join("\r\n", map {
 903                 over_line($self, $ng, $_->{num}, $_);
 904                 } @$msgs));
 905         $$beg = $msgs->[-1]->{num} + 1;
 906 }
 907
 908 sub cmd_xover ($;$) {
 909         my ($self, $range) = @_;
 910         $range = $self->{article} unless defined $range;
 911         my $r = get_range($self, $range);
 912         return $r unless ref $r;
 913         my ($beg, $end) = @$r;
 914         more($self, "224 Overview information follows for $$beg to $end");
 915         long_response($self, \&xover_i, @$r);
 916 }
 917
 918 sub compressed { undef }
 919
 920 sub cmd_starttls ($) {
 921         my ($self) = @_;
 922         my $sock = $self->{sock} or return;
 923         # RFC 4642 2.2.1
 924         return r502 if ($sock->can('accept_SSL') || $self->compressed);
 925         my $opt = $self->{nntpd}->{accept_tls} or
 926                 return '580 can not initiate TLS negotiation';
 927         res($self, '382 Continue with TLS negotiation');
 928         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 929         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 930         undef;
 931 }
 932
 933 # RFC 8054
 934 sub cmd_compress ($$) {
 935         my ($self, $alg) = @_;
 936         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 937         return r502 if $self->compressed;
 938         PublicInbox::NNTPdeflate->enable($self);
 939         $self->requeue;
 940         undef
 941 }
 942
 943 sub zflush {} # overridden by NNTPdeflate
 944
 945 sub cmd_xpath ($$) {
 946         my ($self, $mid) = @_;
 947         return r501 unless $mid =~ $ONE_MSGID;
 948         $mid = $1;
 949         my @paths;
 950         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 951                 my $n = $ng->mm->num_for($mid);
 952                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 953         }
 954         return '430 no such article on server' unless @paths;
 955         '223 '.join(' ', @paths);
 956 }
 957
 958 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 959
 960 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 961
 962 sub do_write ($$) {
 963         my $self = $_[0];
 964         my $done = $self->write(\($_[1]));
 965         return 0 unless $self->{sock};
 966
 967         $done;
 968 }
 969
 970 sub err ($$;@) {
 971         my ($self, $fmt, @args) = @_;
 972         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 973 }
 974
 975 sub out ($$;@) {
 976         my ($self, $fmt, @args) = @_;
 977         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 978 }
 979
 980 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 981 sub event_step {
 982         my ($self) = @_;
 983
 984         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
 985
 986         $self->update_idle_time;
 987         # only read more requests if we've drained the write buffer,
 988         # otherwise we can be buffering infinitely w/o backpressure
 989
 990         my $rbuf = $self->{rbuf} // \(my $x = '');
 991         my $line = index($$rbuf, "\n");
 992         while ($line < 0) {
 993                 return $self->close if length($$rbuf) >= LINE_MAX;
 994                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
 995                 $line = index($$rbuf, "\n");
 996         }
 997         $line = substr($$rbuf, 0, $line + 1, '');
 998         $line =~ s/\r?\n\z//s;
 999         return $self->close if $line =~ /[[:cntrl:]]/s;
1000
1001         my $t0 = now();
1002         my $fd = fileno($self->{sock});
1003         my $r = eval { process_line($self, $line) };
1004         my $pending = $self->{wbuf} ? ' pending' : '';
1005         out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
1006         return $self->close if $r < 0;
1007         $self->rbuf_idle($rbuf);
1008         $self->update_idle_time;
1009
1010         # maybe there's more pipelined data, or we'll have
1011         # to register it for socket-readiness notifications
1012         $self->requeue unless $pending;
1013 }
1014
1015 # for graceful shutdown in PublicInbox::Daemon:
1016 sub busy {
1017         my ($self, $now) = @_;
1018         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1019 }
1020
1021 1;