lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article ng);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 PublicInbox::DS->import(qw(now msg_more));
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26 };
  27 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  28 use Errno qw(EAGAIN);
  29
  30 my @OVERVIEW = qw(Subject From Date Message-ID References Xref);
  31 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  32 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  33                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  34
  35 # disable commands with easy DoS potential:
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $expt;
  40 our $EXPTIME = 180; # 3 minutes
  41
  42 sub update_idle_time ($) {
  43         my ($self) = @_;
  44         my $sock = $self->{sock} or return;
  45         $EXPMAP->{fileno($sock)} = [ now(), $self ];
  46 }
  47
  48 sub expire_old () {
  49         my $now = now();
  50         my $exp = $EXPTIME;
  51         my $old = $now - $exp;
  52         my $nr = 0;
  53         my %new;
  54         while (my ($fd, $v) = each %$EXPMAP) {
  55                 my ($idle_time, $nntp) = @$v;
  56                 if ($idle_time < $old) {
  57                         if (!$nntp->shutdn) {
  58                                 ++$nr;
  59                                 $new{$fd} = $v;
  60                         }
  61                 } else {
  62                         ++$nr;
  63                         $new{$fd} = $v;
  64                 }
  65         }
  66         $EXPMAP = \%new;
  67         $expt = PublicInbox::EvCleanup::later(*expire_old) if $nr;
  68 }
  69
  70 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  71
  72 sub new ($$$) {
  73         my ($class, $sock, $nntpd) = @_;
  74         my $self = fields::new($class);
  75         my $ev = EPOLLIN;
  76         my $wbuf;
  77         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  78                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
  79                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  80         }
  81         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  82         $self->{nntpd} = $nntpd;
  83         if ($wbuf) {
  84                 $self->{wbuf} = $wbuf;
  85         } else {
  86                 greet($self);
  87         }
  88         update_idle_time($self);
  89         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
  90         $self;
  91 }
  92
  93 sub args_ok ($$) {
  94         my ($cb, $argc) = @_;
  95         my $tot = prototype $cb;
  96         my ($nreq, undef) = split(';', $tot);
  97         $nreq = ($nreq =~ tr/$//) - 1;
  98         $tot = ($tot =~ tr/$//) - 1;
  99         ($argc <= $tot && $argc >= $nreq);
 100 }
 101
 102 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 103 sub process_line ($$) {
 104         my ($self, $l) = @_;
 105         my ($req, @args) = split(/[ \t]/, $l);
 106         return 1 unless defined($req); # skip blank line
 107         $req = lc($req);
 108         $req = eval {
 109                 no strict 'refs';
 110                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 111         };
 112         return res($self, '500 command not recognized') unless $req;
 113         return res($self, r501) unless args_ok($req, scalar @args);
 114
 115         my $res = eval { $req->($self, @args) };
 116         my $err = $@;
 117         if ($err && $self->{sock}) {
 118                 local $/ = "\n";
 119                 chomp($l);
 120                 err($self, 'error from: %s (%s)', $l, $err);
 121                 $res = '503 program fault - command not performed';
 122         }
 123         return 0 unless defined $res;
 124         res($self, $res);
 125 }
 126
 127 sub cmd_mode ($$) {
 128         my ($self, $arg) = @_;
 129         $arg = uc $arg;
 130         return r501 unless $arg eq 'READER';
 131         '201 Posting prohibited';
 132 }
 133
 134 sub cmd_slave ($) { '202 slave status noted' }
 135
 136 sub cmd_xgtitle ($;$) {
 137         my ($self, $wildmat) = @_;
 138         more($self, '282 list of groups and descriptions follows');
 139         list_newsgroups($self, $wildmat);
 140         '.'
 141 }
 142
 143 sub list_overview_fmt ($) {
 144         my ($self) = @_;
 145         msg_more($self, $OVERVIEW_FMT);
 146 }
 147
 148 sub list_headers ($;$) {
 149         my ($self) = @_;
 150         msg_more($self, $LIST_HEADERS);
 151 }
 152
 153 sub list_active ($;$) {
 154         my ($self, $wildmat) = @_;
 155         wildmat2re($wildmat);
 156         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 157                 $ng->{newsgroup} =~ $wildmat or next;
 158                 group_line($self, $ng);
 159         }
 160 }
 161
 162 sub list_active_times ($;$) {
 163         my ($self, $wildmat) = @_;
 164         wildmat2re($wildmat);
 165         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 166                 $ng->{newsgroup} =~ $wildmat or next;
 167                 my $c = eval { $ng->mm->created_at } || time;
 168                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 169         }
 170 }
 171
 172 sub list_newsgroups ($;$) {
 173         my ($self, $wildmat) = @_;
 174         wildmat2re($wildmat);
 175         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 176                 $ng->{newsgroup} =~ $wildmat or next;
 177                 my $d = $ng->description;
 178                 more($self, "$ng->{newsgroup} $d");
 179         }
 180 }
 181
 182 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 183 sub cmd_list ($;$$) {
 184         my ($self, @args) = @_;
 185         if (scalar @args) {
 186                 my $arg = shift @args;
 187                 $arg =~ tr/A-Z./a-z_/;
 188                 $arg = "list_$arg";
 189                 return r501 if $DISABLED{$arg};
 190
 191                 $arg = eval {
 192                         no strict 'refs';
 193                         *{$arg}{CODE};
 194                 };
 195                 return r501 unless $arg && args_ok($arg, scalar @args);
 196                 more($self, '215 information follows');
 197                 $arg->($self, @args);
 198         } else {
 199                 more($self, '215 list of newsgroups follows');
 200                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 201                         group_line($self, $ng);
 202                 }
 203         }
 204         '.'
 205 }
 206
 207 sub cmd_listgroup ($;$) {
 208         my ($self, $group) = @_;
 209         if (defined $group) {
 210                 my $res = cmd_group($self, $group);
 211                 return $res if ($res !~ /\A211 /);
 212                 more($self, $res);
 213         }
 214
 215         $self->{ng} or return '412 no newsgroup selected';
 216         my $n = 0;
 217         long_response($self, sub {
 218                 my $ary = $self->{ng}->mm->ids_after(\$n);
 219                 scalar @$ary or return;
 220                 more($self, join("\r\n", @$ary));
 221                 1;
 222         });
 223 }
 224
 225 sub parse_time ($$;$) {
 226         my ($date, $time, $gmt) = @_;
 227         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 228         if (defined $gmt) {
 229                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 230                 $gmt = 1;
 231         }
 232         my @now = $gmt ? gmtime : localtime;
 233         my ($YYYY, $MM, $DD);
 234         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 235                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 236         } else { # legacy clients send YYMMDD
 237                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 238                 my $cur_year = $now[5] + 1900;
 239                 if ($YYYY > $cur_year) {
 240                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 241                 }
 242         }
 243         if ($gmt) {
 244                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 245         } else {
 246                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 247         }
 248 }
 249
 250 sub group_line ($$) {
 251         my ($self, $ng) = @_;
 252         my ($min, $max) = $ng->mm->minmax;
 253         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 254 }
 255
 256 sub cmd_newgroups ($$$;$$) {
 257         my ($self, $date, $time, $gmt, $dists) = @_;
 258         my $ts = eval { parse_time($date, $time, $gmt) };
 259         return r501 if $@;
 260
 261         # TODO dists
 262         more($self, '231 list of new newsgroups follows');
 263         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 264                 my $c = eval { $ng->mm->created_at } || 0;
 265                 next unless $c > $ts;
 266                 group_line($self, $ng);
 267         }
 268         '.'
 269 }
 270
 271 sub wildmat2re (;$) {
 272         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 273         my %keep;
 274         my $salt = rand;
 275         my $tmp = $_[0];
 276
 277         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 278                 my $orig = $1;
 279                 my $key = sha1_hex($orig . $salt);
 280                 $orig =~ s/([^\w\-])+/\Q$1/g;
 281                 $keep{$key} = $orig;
 282                 $key
 283                 #gex;
 284         my %map = ('*' => '.*', '?' => '.' );
 285         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 286         if (scalar %keep) {
 287                 $tmp =~ s#([a-f0-9]{40})#
 288                         my $orig = $keep{$1};
 289                         defined $orig ? $orig : $1;
 290                         #ge;
 291         }
 292         $_[0] = qr/\A$tmp\z/;
 293 }
 294
 295 sub ngpat2re (;$) {
 296         return $_[0] = qr/\A\z/ unless defined $_[0];
 297         my %map = ('*' => '.*', ',' => '|');
 298         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 299         $_[0] = qr/\A(?:$_[0])\z/;
 300 }
 301
 302 sub cmd_newnews ($$$$;$$) {
 303         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 304         my $ts = eval { parse_time($date, $time, $gmt) };
 305         return r501 if $@;
 306         more($self, '230 list of new articles by message-id follows');
 307         my ($keep, $skip) = split('!', $newsgroups, 2);
 308         ngpat2re($keep);
 309         ngpat2re($skip);
 310         my @over;
 311         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 312                 $ng->{newsgroup} =~ $keep or next;
 313                 $ng->{newsgroup} =~ $skip and next;
 314                 my $over = $ng->over or next;
 315                 push @over, $over;
 316         };
 317         return '.' unless @over;
 318
 319         my $prev = 0;
 320         long_response($self, sub {
 321                 my $over = $over[0];
 322                 my $msgs = $over->query_ts($ts, $prev);
 323                 if (scalar @$msgs) {
 324                         more($self, '<' .
 325                                 join(">\r\n<", map { $_->mid } @$msgs ).
 326                                 '>');
 327                         $prev = $msgs->[-1]->{num};
 328                 } else {
 329                         shift @over;
 330                         if (@over) { # continue onto next newsgroup
 331                                 $prev = 0;
 332                                 return 1;
 333                         } else { # break out of the long response.
 334                                 return;
 335                         }
 336                 }
 337         });
 338 }
 339
 340 sub cmd_group ($$) {
 341         my ($self, $group) = @_;
 342         my $no_such = '411 no such news group';
 343         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 344
 345         $self->{ng} = $ng;
 346         my ($min, $max) = $ng->mm->minmax;
 347         $min ||= 0;
 348         $max ||= 0;
 349         $self->{article} = $min;
 350         my $est_size = $max - $min;
 351         "211 $est_size $min $max $group";
 352 }
 353
 354 sub article_adj ($$) {
 355         my ($self, $off) = @_;
 356         my $ng = $self->{ng} or return '412 no newsgroup selected';
 357
 358         my $n = $self->{article};
 359         defined $n or return '420 no current article has been selected';
 360
 361         $n += $off;
 362         my $mid = $ng->mm->mid_for($n);
 363         unless ($mid) {
 364                 $n = $off > 0 ? 'next' : 'previous';
 365                 return "421 no $n article in this group";
 366         }
 367         $self->{article} = $n;
 368         "223 $n <$mid> article retrieved - request text separately";
 369 }
 370
 371 sub cmd_next ($) { article_adj($_[0], 1) }
 372 sub cmd_last ($) { article_adj($_[0], -1) }
 373
 374 # We want to encourage using email and CC-ing everybody involved to avoid
 375 # the single-point-of-failure a single server provides.
 376 sub cmd_post ($) {
 377         my ($self) = @_;
 378         my $ng = $self->{ng};
 379         $ng ? "440 mailto:$ng->{-primary_address} to post"
 380                 : '440 posting not allowed'
 381 }
 382
 383 sub cmd_quit ($) {
 384         my ($self) = @_;
 385         res($self, '205 closing connection - goodbye!');
 386         $self->shutdn;
 387         undef;
 388 }
 389
 390 sub header_append ($$$) {
 391         my ($hdr, $k, $v) = @_;
 392         my @v = $hdr->header($k);
 393         foreach (@v) {
 394                 return if $v eq $_;
 395         }
 396         $hdr->header_set($k, @v, $v);
 397 }
 398
 399 sub xref ($$$$) {
 400         my ($self, $ng, $n, $mid) = @_;
 401         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 402
 403         # num_for is pretty cheap and sometimes we'll lookup the existence
 404         # of an article without getting even the OVER info.  In other words,
 405         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 406         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 407         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 408                 next if $ng eq $other;
 409                 my $num = eval { $other->mm->num_for($mid) } or next;
 410                 $ret .= " $other->{newsgroup}:$num";
 411         }
 412         $ret;
 413 }
 414
 415 sub set_nntp_headers ($$$$$) {
 416         my ($self, $hdr, $ng, $n, $mid) = @_;
 417
 418         # why? leafnode requires a Path: header for some inexplicable
 419         # reason.  We'll fake the shortest one possible.
 420         $hdr->header_set('Path', 'y');
 421
 422         # leafnode (and maybe other NNTP clients) have trouble dealing
 423         # with v2 messages which have multiple Message-IDs (either due
 424         # to our own content-based dedupe or buggy git-send-email versions).
 425         my @mids = $hdr->header('Message-ID');
 426         if (scalar(@mids) > 1) {
 427                 my $mid0 = "<$mid>";
 428                 $hdr->header_set('Message-ID', $mid0);
 429                 my @alt = $hdr->header('X-Alt-Message-ID');
 430                 my %seen = map { $_ => 1 } (@alt, $mid0);
 431                 foreach my $m (@mids) {
 432                         next if $seen{$m}++;
 433                         push @alt, $m;
 434                 }
 435                 $hdr->header_set('X-Alt-Message-ID', @alt);
 436         }
 437
 438         # clobber some
 439         my $xref = xref($self, $ng, $n, $mid);
 440         $hdr->header_set('Xref', $xref);
 441         $xref =~ s/:[0-9]+//g;
 442         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 443         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 444         if (my $url = $ng->base_url) {
 445                 $mid = mid_escape($mid);
 446                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 447                 header_append($hdr, 'List-Archive', "<$url>");
 448         }
 449 }
 450
 451 sub art_lookup ($$$) {
 452         my ($self, $art, $set_headers) = @_;
 453         my $ng = $self->{ng};
 454         my ($n, $mid);
 455         my $err;
 456         if (defined $art) {
 457                 if ($art =~ /\A[0-9]+\z/) {
 458                         $err = '423 no such article number in this group';
 459                         $n = int($art);
 460                         goto find_mid;
 461                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 462                         $mid = $1;
 463                         $err = r430;
 464                         $n = $ng->mm->num_for($mid) if $ng;
 465                         goto found if defined $n;
 466                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 467                                 $n = $g->mm->num_for($mid);
 468                                 if (defined $n) {
 469                                         $ng = $g;
 470                                         goto found;
 471                                 }
 472                         }
 473                         return $err;
 474                 } else {
 475                         return r501;
 476                 }
 477         } else {
 478                 $err = '420 no current article has been selected';
 479                 $n = $self->{article};
 480                 defined $n or return $err;
 481 find_mid:
 482                 $ng or return '412 no newsgroup has been selected';
 483                 $mid = $ng->mm->mid_for($n);
 484                 defined $mid or return $err;
 485         }
 486 found:
 487         my $smsg = $ng->over->get_art($n) or return $err;
 488         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 489         my $s = Email::Simple->new($msg);
 490         if ($set_headers) {
 491                 set_nntp_headers($self, $s->header_obj, $ng, $n, $mid);
 492
 493                 # must be last
 494                 $s->body_set('') if ($set_headers == 2);
 495         }
 496         [ $n, $mid, $s, $smsg->bytes, $smsg->lines, $ng ];
 497 }
 498
 499 sub simple_body_write ($$) {
 500         my ($self, $s) = @_;
 501         my $body = $s->body;
 502         $s->body_set('');
 503         $body =~ s/^\./../smg;
 504         $body =~ s/(?<!\r)\n/\r\n/sg;
 505         msg_more($self, $body);
 506         msg_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 507         '.'
 508 }
 509
 510 sub set_art {
 511         my ($self, $art) = @_;
 512         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 513 }
 514
 515 sub _header ($) {
 516         my $hdr = $_[0]->header_obj->as_string;
 517         utf8::encode($hdr);
 518         $hdr =~ s/(?<!\r)\n/\r\n/sg;
 519
 520         # for leafnode compatibility, we need to ensure Message-ID headers
 521         # are only a single line.  We can't subclass Email::Simple::Header
 522         # and override _default_fold_at in here, either; since that won't
 523         # affect messages already in the archive.
 524         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 525
 526         $hdr
 527 }
 528
 529 sub cmd_article ($;$) {
 530         my ($self, $art) = @_;
 531         my $r = art_lookup($self, $art, 1);
 532         return $r unless ref $r;
 533         my ($n, $mid, $s) = @$r;
 534         set_art($self, $art);
 535         more($self, "220 $n <$mid> article retrieved - head and body follow");
 536         msg_more($self, _header($s));
 537         msg_more($self, "\r\n");
 538         simple_body_write($self, $s);
 539 }
 540
 541 sub cmd_head ($;$) {
 542         my ($self, $art) = @_;
 543         my $r = art_lookup($self, $art, 2);
 544         return $r unless ref $r;
 545         my ($n, $mid, $s) = @$r;
 546         set_art($self, $art);
 547         more($self, "221 $n <$mid> article retrieved - head follows");
 548         msg_more($self, _header($s));
 549         '.'
 550 }
 551
 552 sub cmd_body ($;$) {
 553         my ($self, $art) = @_;
 554         my $r = art_lookup($self, $art, 0);
 555         return $r unless ref $r;
 556         my ($n, $mid, $s) = @$r;
 557         set_art($self, $art);
 558         more($self, "222 $n <$mid> article retrieved - body follows");
 559         simple_body_write($self, $s);
 560 }
 561
 562 sub cmd_stat ($;$) {
 563         my ($self, $art) = @_;
 564         my $r = art_lookup($self, $art, 0);
 565         return $r unless ref $r;
 566         my ($n, $mid, undef) = @$r;
 567         set_art($self, $art);
 568         "223 $n <$mid> article retrieved - request text separately";
 569 }
 570
 571 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 572
 573 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 574
 575 sub cmd_help ($) {
 576         my ($self) = @_;
 577         more($self, '100 help text follows');
 578         '.'
 579 }
 580
 581 sub get_range ($$) {
 582         my ($self, $range) = @_;
 583         my $ng = $self->{ng} or return '412 no news group has been selected';
 584         defined $range or return '420 No article(s) selected';
 585         my ($beg, $end);
 586         my ($min, $max) = $ng->mm->minmax;
 587         if ($range =~ /\A([0-9]+)\z/) {
 588                 $beg = $end = $1;
 589         } elsif ($range =~ /\A([0-9]+)-\z/) {
 590                 ($beg, $end) = ($1, $max);
 591         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 592                 ($beg, $end) = ($1, $2);
 593         } else {
 594                 return r501;
 595         }
 596         $beg = $min if ($beg < $min);
 597         $end = $max if ($end > $max);
 598         return '420 No article(s) selected' if ($beg > $end);
 599         [ $beg, $end ];
 600 }
 601
 602 sub long_response ($$) {
 603         my ($self, $cb) = @_; # cb returns true if more, false if done
 604
 605         my $fd = fileno($self->{sock});
 606         defined $fd or return;
 607         # make sure we disable reading during a long response,
 608         # clients should not be sending us stuff and making us do more
 609         # work while we are stream a response to them
 610         my $t0 = now();
 611         my $long_cb; # DANGER: self-referential
 612         $long_cb = sub {
 613                 # wbuf is unset or empty, here; $cb may add to it
 614                 my $more = eval { $cb->() };
 615                 if ($@ || !$self->{sock}) { # something bad happened...
 616                         $long_cb = undef;
 617                         my $diff = now() - $t0;
 618                         if ($@) {
 619                                 err($self,
 620                                     "%s during long response[$fd] - %0.6f",
 621                                     $@, $diff);
 622                         }
 623                         out($self, " deferred[$fd] aborted - %0.6f", $diff);
 624                         $self->close;
 625                 } elsif ($more) { # $self->{wbuf}:
 626                         update_idle_time($self);
 627
 628                         # no recursion, schedule another call ASAP
 629                         # but only after all pending writes are done
 630                         my $wbuf = $self->{wbuf} ||= [];
 631                         push @$wbuf, $long_cb;
 632
 633                         # wbuf may be populated by $cb, no need to rearm if so:
 634                         $self->requeue if scalar(@$wbuf) == 1;
 635                 } else { # all done!
 636                         $long_cb = undef;
 637                         res($self, '.');
 638                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 639                         $self->requeue unless $self->{wbuf};
 640                 }
 641         };
 642         $self->write($long_cb); # kick off!
 643         undef;
 644 }
 645
 646 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 647         my ($self, $xhdr, $range) = @_;
 648
 649         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 650                 my ($ng, $n) = mid_lookup($self, $1);
 651                 return r430 unless $n;
 652                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 653         } else { # numeric range
 654                 $range = $self->{article} unless defined $range;
 655                 my $r = get_range($self, $range);
 656                 return $r unless ref $r;
 657                 my $mm = $self->{ng}->mm;
 658                 my ($beg, $end) = @$r;
 659                 more($self, $xhdr ? r221 : r225);
 660                 long_response($self, sub {
 661                         my $r = $mm->msg_range(\$beg, $end);
 662                         @$r or return;
 663                         more($self, join("\r\n", map {
 664                                 "$_->[0] <$_->[1]>"
 665                         } @$r));
 666                         1;
 667                 });
 668         }
 669 }
 670
 671 sub mid_lookup ($$) {
 672         my ($self, $mid) = @_;
 673         my $self_ng = $self->{ng};
 674         if ($self_ng) {
 675                 my $n = $self_ng->mm->num_for($mid);
 676                 return ($self_ng, $n) if defined $n;
 677         }
 678         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 679                 next if defined $self_ng && $ng eq $self_ng;
 680                 my $n = $ng->mm->num_for($mid);
 681                 return ($ng, $n) if defined $n;
 682         }
 683         (undef, undef);
 684 }
 685
 686 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 687         my ($self, $xhdr, $range) = @_;
 688
 689         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 690                 my $mid = $1;
 691                 my ($ng, $n) = mid_lookup($self, $mid);
 692                 return r430 unless $n;
 693                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 694                                 xref($self, $ng, $n, $mid));
 695         } else { # numeric range
 696                 $range = $self->{article} unless defined $range;
 697                 my $r = get_range($self, $range);
 698                 return $r unless ref $r;
 699                 my $ng = $self->{ng};
 700                 my $mm = $ng->mm;
 701                 my ($beg, $end) = @$r;
 702                 more($self, $xhdr ? r221 : r225);
 703                 long_response($self, sub {
 704                         my $r = $mm->msg_range(\$beg, $end);
 705                         @$r or return;
 706                         more($self, join("\r\n", map {
 707                                 my $num = $_->[0];
 708                                 "$num ".xref($self, $ng, $num, $_->[1]);
 709                         } @$r));
 710                         1;
 711                 });
 712         }
 713 }
 714
 715 sub over_header_for {
 716         my ($over, $num, $field) = @_;
 717         my $smsg = $over->get_art($num) or return;
 718         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 719         $smsg->{$field};
 720 }
 721
 722 sub hdr_searchmsg ($$$$) {
 723         my ($self, $xhdr, $field, $range) = @_;
 724         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 725                 my ($ng, $n) = mid_lookup($self, $1);
 726                 return r430 unless defined $n;
 727                 my $v = over_header_for($ng->over, $n, $field);
 728                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 729         } else { # numeric range
 730                 $range = $self->{article} unless defined $range;
 731                 my $over = $self->{ng}->over;
 732                 my $mm = $self->{ng}->mm;
 733                 my $r = get_range($self, $range);
 734                 return $r unless ref $r;
 735                 my ($beg, $end) = @$r;
 736                 more($self, $xhdr ? r221 : r225);
 737                 my $cur = $beg;
 738                 long_response($self, sub {
 739                         my $msgs = $over->query_xover($cur, $end);
 740                         my $nr = scalar @$msgs or return;
 741                         my $tmp = '';
 742                         foreach my $s (@$msgs) {
 743                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 744                         }
 745                         utf8::encode($tmp);
 746                         msg_more($self, $tmp);
 747                         $cur = $msgs->[-1]->{num} + 1;
 748                 });
 749         }
 750 }
 751
 752 sub do_hdr ($$$;$) {
 753         my ($self, $xhdr, $header, $range) = @_;
 754         my $sub = lc $header;
 755         if ($sub eq 'message-id') {
 756                 hdr_message_id($self, $xhdr, $range);
 757         } elsif ($sub eq 'xref') {
 758                 hdr_xref($self, $xhdr, $range);
 759         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 760                                 bytes|lines)\z/x) {
 761                 hdr_searchmsg($self, $xhdr, $sub, $range);
 762         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 763                 hdr_searchmsg($self, $xhdr, $1, $range);
 764         } else {
 765                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 766         }
 767 }
 768
 769 # RFC 3977
 770 sub cmd_hdr ($$;$) {
 771         my ($self, $header, $range) = @_;
 772         do_hdr($self, 0, $header, $range);
 773 }
 774
 775 # RFC 2980
 776 sub cmd_xhdr ($$;$) {
 777         my ($self, $header, $range) = @_;
 778         do_hdr($self, 1, $header, $range);
 779 }
 780
 781 sub hdr_mid_prefix ($$$$$) {
 782         my ($self, $xhdr, $ng, $n, $mid) = @_;
 783         return $mid if $xhdr;
 784
 785         # HDR for RFC 3977 users
 786         if (my $self_ng = $self->{ng}) {
 787                 ($self_ng eq $ng) ? $n : '0';
 788         } else {
 789                 '0';
 790         }
 791 }
 792
 793 sub hdr_mid_response ($$$$$$) {
 794         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 795         my $res = '';
 796         if ($xhdr) {
 797                 $res .= r221 . "\r\n";
 798                 $res .= "$mid $v\r\n";
 799         } else {
 800                 $res .= r225 . "\r\n";
 801                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 802                 $res .= "$pfx $v\r\n";
 803         }
 804         res($self, $res .= '.');
 805         undef;
 806 }
 807
 808 sub cmd_xrover ($;$) {
 809         my ($self, $range) = @_;
 810         my $ng = $self->{ng} or return '412 no newsgroup selected';
 811         (defined $range && $range =~ /[<>]/) and
 812                 return '420 No article(s) selected'; # no message IDs
 813
 814         $range = $self->{article} unless defined $range;
 815         my $r = get_range($self, $range);
 816         return $r unless ref $r;
 817         my ($beg, $end) = @$r;
 818         my $mm = $ng->mm;
 819         my $over = $ng->over;
 820         more($self, '224 Overview information follows');
 821
 822         long_response($self, sub {
 823                 my $h = over_header_for($over, $beg, 'references');
 824                 more($self, "$beg $h") if defined($h);
 825                 $beg++ < $end;
 826         });
 827 }
 828
 829 sub over_line ($$$$) {
 830         my ($self, $ng, $num, $smsg) = @_;
 831         # n.b. field access and procedural calls can be
 832         # 10%-15% faster than OO method calls:
 833         my $s = join("\t", $num,
 834                 $smsg->{subject},
 835                 $smsg->{from},
 836                 PublicInbox::SearchMsg::date($smsg),
 837                 "<$smsg->{mid}>",
 838                 $smsg->{references},
 839                 $smsg->{bytes},
 840                 $smsg->{lines},
 841                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 842         utf8::encode($s);
 843         $s
 844 }
 845
 846 sub cmd_over ($;$) {
 847         my ($self, $range) = @_;
 848         if ($range && $range =~ /\A<(.+)>\z/) {
 849                 my ($ng, $n) = mid_lookup($self, $1);
 850                 defined $n or return r430;
 851                 my $smsg = $ng->over->get_art($n) or return r430;
 852                 more($self, '224 Overview information follows (multi-line)');
 853
 854                 # Only set article number column if it's the current group
 855                 my $self_ng = $self->{ng};
 856                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 857                 more($self, over_line($self, $ng, $n, $smsg));
 858                 '.';
 859         } else {
 860                 cmd_xover($self, $range);
 861         }
 862 }
 863
 864 sub cmd_xover ($;$) {
 865         my ($self, $range) = @_;
 866         $range = $self->{article} unless defined $range;
 867         my $r = get_range($self, $range);
 868         return $r unless ref $r;
 869         my ($beg, $end) = @$r;
 870         more($self, "224 Overview information follows for $beg to $end");
 871         my $over = $self->{ng}->over;
 872         my $cur = $beg;
 873         long_response($self, sub {
 874                 my $msgs = $over->query_xover($cur, $end);
 875                 my $nr = scalar @$msgs or return;
 876
 877                 # OVERVIEW.FMT
 878                 more($self, join("\r\n", map {
 879                         over_line($self, $self->{ng}, $_->{num}, $_);
 880                         } @$msgs));
 881                 $cur = $msgs->[-1]->{num} + 1;
 882         });
 883 }
 884
 885 sub cmd_starttls ($) {
 886         my ($self) = @_;
 887         my $sock = $self->{sock} or return;
 888         # RFC 4642 2.2.1
 889         (ref($sock) eq 'IO::Socket::SSL') and return '502 Command unavailable';
 890         my $opt = $self->{nntpd}->{accept_tls} or
 891                 return '580 can not initiate TLS negotiation';
 892         res($self, '382 Continue with TLS negotiation');
 893         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 894         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 895         undef;
 896 }
 897
 898 sub cmd_xpath ($$) {
 899         my ($self, $mid) = @_;
 900         return r501 unless $mid =~ /\A<(.+)>\z/;
 901         $mid = $1;
 902         my @paths;
 903         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 904                 my $n = $ng->mm->num_for($mid);
 905                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 906         }
 907         return '430 no such article on server' unless @paths;
 908         '223 '.join(' ', @paths);
 909 }
 910
 911 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 912
 913 sub more ($$) { msg_more($_[0], $_[1] . "\r\n") }
 914
 915 sub do_write ($$) {
 916         my $self = $_[0];
 917         my $done = $self->write(\($_[1]));
 918         return 0 unless $self->{sock};
 919
 920         $done;
 921 }
 922
 923 sub err ($$;@) {
 924         my ($self, $fmt, @args) = @_;
 925         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 926 }
 927
 928 sub out ($$;@) {
 929         my ($self, $fmt, @args) = @_;
 930         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 931 }
 932
 933 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 934 sub event_step {
 935         my ($self) = @_;
 936
 937         return unless $self->flush_write && $self->{sock};
 938
 939         update_idle_time($self);
 940         # only read more requests if we've drained the write buffer,
 941         # otherwise we can be buffering infinitely w/o backpressure
 942
 943         use constant LINE_MAX => 512; # RFC 977 section 2.3
 944         my $rbuf = $self->{rbuf} // (\(my $x = ''));
 945         my $r = 1;
 946
 947         if (index($$rbuf, "\n") < 0) {
 948                 my $off = bytes::length($$rbuf);
 949                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 950         }
 951         while ($r > 0 && $$rbuf =~ s/\A[ \t\r\n]*([^\r\n]*)\r?\n//) {
 952                 my $line = $1;
 953                 return $self->close if $line =~ /[[:cntrl:]]/s;
 954                 my $t0 = now();
 955                 my $fd = fileno($self->{sock});
 956                 $r = eval { process_line($self, $line) };
 957                 my $pending = $self->{wbuf} ? ' pending' : '';
 958                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
 959         }
 960
 961         return $self->close if $r < 0;
 962         my $len = bytes::length($$rbuf);
 963         return $self->close if ($len >= LINE_MAX);
 964         $self->rbuf_idle($rbuf);
 965         update_idle_time($self);
 966
 967         # maybe there's more pipelined data, or we'll have
 968         # to register it for socket-readiness notifications
 969         $self->requeue unless $self->{wbuf};
 970 }
 971
 972 sub not_idle_long ($$) {
 973         my ($self, $now) = @_;
 974         my $sock = $self->{sock} or return;
 975         my $ary = $EXPMAP->{fileno($sock)} or return;
 976         my $exp_at = $ary->[0] + $EXPTIME;
 977         $exp_at > $now;
 978 }
 979
 980 # for graceful shutdown in PublicInbox::Daemon:
 981 sub busy {
 982         my ($self, $now) = @_;
 983         ($self->{rbuf} || $self->{wbuf} || not_idle_long($self, $now));
 984 }
 985
 986 1;