lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 # fields:
   6 # nntpd: PublicInbox::NNTPD ref
   7 # article: per-session current article number
   8 # ng: PublicInbox::Inbox ref
   9 # long_cb: long_response private data
  10 package PublicInbox::NNTP;
  11 use strict;
  12 use parent qw(PublicInbox::DS);
  13 use PublicInbox::MID qw(mid_escape $MID_EXTRACT);
  14 use PublicInbox::Eml;
  15 use POSIX qw(strftime);
  16 use PublicInbox::DS qw(now);
  17 use Digest::SHA qw(sha1_hex);
  18 use Time::Local qw(timegm timelocal);
  19 use PublicInbox::GitAsyncCat;
  20 use constant {
  21         LINE_MAX => 512, # RFC 977 section 2.3
  22         r501 => '501 command syntax error',
  23         r502 => '502 Command unavailable',
  24         r221 => '221 Header follows',
  25         r224 => '224 Overview information follows (multi-line)',
  26         r225 => '225 Headers follow (multi-line)',
  27         r430 => '430 No article with that message-id',
  28 };
  29 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  30 use Errno qw(EAGAIN);
  31 my $ONE_MSGID = qr/\A$MID_EXTRACT\z/;
  32 my @OVERVIEW = qw(Subject From Date Message-ID References);
  33 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  34                 "Xref:full\r\n.";
  35 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  36                         qw(:bytes :lines Xref To Cc)) . "\r\n.";
  37 my $CAPABILITIES = <<"";
  38 101 Capability list:\r
  39 VERSION 2\r
  40 READER\r
  41 NEWNEWS\r
  42 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  43 HDR\r
  44 OVER\r
  45 COMPRESS DEFLATE\r
  46
  47 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  48
  49 sub new ($$$) {
  50         my ($class, $sock, $nntpd) = @_;
  51         my $self = bless { nntpd => $nntpd }, $class;
  52         my $ev = EPOLLIN;
  53         my $wbuf;
  54         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
  55                 return CORE::close($sock) if $! != EAGAIN;
  56                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
  57                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  58         }
  59         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  60         if ($wbuf) {
  61                 $self->{wbuf} = $wbuf;
  62         } else {
  63                 greet($self);
  64         }
  65         $self->update_idle_time;
  66         $self;
  67 }
  68
  69 sub args_ok ($$) {
  70         my ($cb, $argc) = @_;
  71         my $tot = prototype $cb;
  72         my ($nreq, undef) = split(';', $tot);
  73         $nreq = ($nreq =~ tr/$//) - 1;
  74         $tot = ($tot =~ tr/$//) - 1;
  75         ($argc <= $tot && $argc >= $nreq);
  76 }
  77
  78 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  79 sub process_line ($$) {
  80         my ($self, $l) = @_;
  81         my ($req, @args) = split(/[ \t]+/, $l);
  82         return 1 unless defined($req); # skip blank line
  83         $req = $self->can('cmd_'.lc($req));
  84         return res($self, '500 command not recognized') unless $req;
  85         return res($self, r501) unless args_ok($req, scalar @args);
  86
  87         my $res = eval { $req->($self, @args) };
  88         my $err = $@;
  89         if ($err && $self->{sock}) {
  90                 local $/ = "\n";
  91                 chomp($l);
  92                 err($self, 'error from: %s (%s)', $l, $err);
  93                 $res = '503 program fault - command not performed';
  94         }
  95         defined($res) ? res($self, $res) : 0;
  96 }
  97
  98 # The keyword argument is not used (rfc3977 5.2.2)
  99 sub cmd_capabilities ($;$) {
 100         my ($self, undef) = @_;
 101         my $res = $CAPABILITIES;
 102         if (!$self->{sock}->can('accept_SSL') &&
 103                         $self->{nntpd}->{accept_tls}) {
 104                 $res .= "STARTTLS\r\n";
 105         }
 106         $res .= '.';
 107 }
 108
 109 sub cmd_mode ($$) {
 110         my ($self, $arg) = @_;
 111         uc($arg) eq 'READER' ? '201 Posting prohibited' : r501;
 112 }
 113
 114 sub cmd_slave ($) { '202 slave status noted' }
 115
 116 sub cmd_xgtitle ($;$) {
 117         my ($self, $wildmat) = @_;
 118         more($self, '282 list of groups and descriptions follows');
 119         list_newsgroups($self, $wildmat);
 120 }
 121
 122 sub list_overview_fmt ($) { $OVERVIEW_FMT }
 123
 124 sub list_headers ($;$) { $LIST_HEADERS }
 125
 126 sub list_active_i { # "LIST ACTIVE" and also just "LIST" (no args)
 127         my ($self, $groupnames) = @_;
 128         my @window = splice(@$groupnames, 0, 100) or return 0;
 129         my $ibx;
 130         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 131         for my $ngname (@window) {
 132                 $ibx = $groups->{$ngname} and group_line($self, $ibx);
 133         }
 134         scalar(@$groupnames); # continue if there's more
 135 }
 136
 137 sub list_active ($;$) { # called by cmd_list
 138         my ($self, $wildmat) = @_;
 139         wildmat2re($wildmat);
 140         long_response($self, \&list_active_i, [
 141                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 142 }
 143
 144 sub list_active_times_i {
 145         my ($self, $groupnames) = @_;
 146         my @window = splice(@$groupnames, 0, 100) or return 0;
 147         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 148         for my $ngname (@window) {
 149                 my $ibx = $groups->{$ngname} or next;
 150                 my $c = eval { $ibx->uidvalidity } // time;
 151                 more($self, "$ngname $c <$ibx->{-primary_address}>");
 152         }
 153         scalar(@$groupnames); # continue if there's more
 154 }
 155
 156 sub list_active_times ($;$) { # called by cmd_list
 157         my ($self, $wildmat) = @_;
 158         wildmat2re($wildmat);
 159         long_response($self, \&list_active_times_i, [
 160                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 161 }
 162
 163 sub list_newsgroups_i {
 164         my ($self, $groupnames) = @_;
 165         my @window = splice(@$groupnames, 0, 100) or return 0;
 166         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 167         my $ibx;
 168         for my $ngname (@window) {
 169                 $ibx = $groups->{$ngname} and
 170                         more($self, "$ngname ".$ibx->description);
 171         }
 172         scalar(@$groupnames); # continue if there's more
 173 }
 174
 175 sub list_newsgroups ($;$) { # called by cmd_list
 176         my ($self, $wildmat) = @_;
 177         wildmat2re($wildmat);
 178         long_response($self, \&list_newsgroups_i, [
 179                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 180 }
 181
 182 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 183 sub cmd_list ($;$$) {
 184         my ($self, @args) = @_;
 185         if (scalar @args) {
 186                 my $arg = shift @args;
 187                 $arg =~ tr/A-Z./a-z_/;
 188                 my $ret = $arg eq 'active';
 189                 $arg = "list_$arg";
 190                 $arg = $self->can($arg);
 191                 return r501 unless $arg && args_ok($arg, scalar @args);
 192                 more($self, '215 information follows');
 193                 $arg->($self, @args);
 194         } else {
 195                 more($self, '215 list of newsgroups follows');
 196                 long_response($self, \&list_active_i, [ # copy array
 197                         @{$self->{nntpd}->{groupnames}} ]);
 198         }
 199 }
 200
 201 sub listgroup_range_i {
 202         my ($self, $beg, $end) = @_;
 203         my $r = $self->{ng}->mm->msg_range($beg, $end, 'num');
 204         scalar(@$r) or return;
 205         more($self, join("\r\n", map { $_->[0] } @$r));
 206         1;
 207 }
 208
 209 sub listgroup_all_i {
 210         my ($self, $num) = @_;
 211         my $ary = $self->{ng}->mm->ids_after($num);
 212         scalar(@$ary) or return;
 213         more($self, join("\r\n", @$ary));
 214         1;
 215 }
 216
 217 sub cmd_listgroup ($;$$) {
 218         my ($self, $group, $range) = @_;
 219         if (defined $group) {
 220                 my $res = cmd_group($self, $group);
 221                 return $res if ($res !~ /\A211 /);
 222                 more($self, $res);
 223         }
 224         $self->{ng} or return '412 no newsgroup selected';
 225         if (defined $range) {
 226                 my $r = get_range($self, $range);
 227                 return $r unless ref $r;
 228                 long_response($self, \&listgroup_range_i, @$r);
 229         } else { # grab every article number
 230                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 231         }
 232 }
 233
 234 sub parse_time ($$;$) {
 235         my ($date, $time, $gmt) = @_;
 236         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 237         if (defined $gmt) {
 238                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 239                 $gmt = 1;
 240         }
 241         my ($YYYY, $MM, $DD);
 242         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 243                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 244         } else { # legacy clients send YYMMDD
 245                 my $YY;
 246                 ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 247                 my @now = $gmt ? gmtime : localtime;
 248                 my $cur_year = $now[5] + 1900;
 249                 my $cur_cent = int($cur_year / 100) * 100;
 250                 $YYYY = (($YY + $cur_cent) > $cur_year) ?
 251                         ($YY + 1900) : ($YY + $cur_cent);
 252         }
 253         if ($gmt) {
 254                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 255         } else {
 256                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 257         }
 258 }
 259
 260 sub group_line ($$) {
 261         my ($self, $ng) = @_;
 262         my ($min, $max) = $ng->mm->minmax;
 263         more($self, "$ng->{newsgroup} $max $min n");
 264 }
 265
 266 sub cmd_newgroups ($$$;$$) {
 267         my ($self, $date, $time, $gmt, $dists) = @_;
 268         my $ts = eval { parse_time($date, $time, $gmt) };
 269         return r501 if $@;
 270
 271         # TODO dists
 272         more($self, '231 list of new newsgroups follows');
 273         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 274                 my $c = eval { $ng->uidvalidity } // 0;
 275                 next unless $c > $ts;
 276                 group_line($self, $ng);
 277         }
 278         '.'
 279 }
 280
 281 sub wildmat2re (;$) {
 282         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 283         my %keep;
 284         my $salt = rand;
 285         my $tmp = $_[0];
 286
 287         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 288                 my $orig = $1;
 289                 my $key = sha1_hex($orig . $salt);
 290                 $orig =~ s/([^\w\-])+/\Q$1/g;
 291                 $keep{$key} = $orig;
 292                 $key
 293                 #gex;
 294         my %map = ('*' => '.*', '?' => '.' );
 295         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 296         if (scalar %keep) {
 297                 $tmp =~ s#([a-f0-9]{40})#
 298                         my $orig = $keep{$1};
 299                         defined $orig ? $orig : $1;
 300                         #ge;
 301         }
 302         $_[0] = qr/\A$tmp\z/;
 303 }
 304
 305 sub ngpat2re (;$) {
 306         return $_[0] = qr/\A\z/ unless defined $_[0];
 307         my %map = ('*' => '.*', ',' => '|');
 308         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 309         $_[0] = qr/\A(?:$_[0])\z/;
 310 }
 311
 312 sub newnews_i {
 313         my ($self, $names, $ts, $prev) = @_;
 314         my $ngname = $names->[0];
 315         if (my $ibx = $self->{nntpd}->{groups}->{$ngname}) {
 316                 if (my $over = $ibx->over) {
 317                         my $msgs = $over->query_ts($ts, $$prev);
 318                         if (scalar @$msgs) {
 319                                 more($self, '<' .
 320                                         join(">\r\n<",
 321                                                 map { $_->{mid} } @$msgs ) .
 322                                         '>');
 323                                 $$prev = $msgs->[-1]->{num};
 324                                 return 1; # continue on current group
 325                         }
 326                 }
 327         }
 328         shift @$names;
 329         if (@$names) { # continue onto next newsgroup
 330                 $$prev = 0;
 331                 1;
 332         } else { # all done, break out of the long_response
 333                 undef;
 334         }
 335 }
 336
 337 sub cmd_newnews ($$$$;$$) {
 338         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 339         my $ts = eval { parse_time($date, $time, $gmt) };
 340         return r501 if $@;
 341         more($self, '230 list of new articles by message-id follows');
 342         my ($keep, $skip) = split('!', $newsgroups, 2);
 343         ngpat2re($keep);
 344         ngpat2re($skip);
 345         my @names = grep(!/$skip/, grep(/$keep/,
 346                                 @{$self->{nntpd}->{groupnames}}));
 347         return '.' unless scalar(@names);
 348         my $prev = 0;
 349         long_response($self, \&newnews_i, \@names, $ts, \$prev);
 350 }
 351
 352 sub cmd_group ($$) {
 353         my ($self, $group) = @_;
 354         my $no_such = '411 no such news group';
 355         my $nntpd = $self->{nntpd};
 356         my $ng = $nntpd->{groups}->{$group} or return $no_such;
 357         $nntpd->idler_start;
 358
 359         $self->{ng} = $ng;
 360         my ($min, $max) = $ng->mm->minmax;
 361         $self->{article} = $min;
 362         my $est_size = $max - $min;
 363         "211 $est_size $min $max $group";
 364 }
 365
 366 sub article_adj ($$) {
 367         my ($self, $off) = @_;
 368         my $ng = $self->{ng} or return '412 no newsgroup selected';
 369
 370         my $n = $self->{article};
 371         defined $n or return '420 no current article has been selected';
 372
 373         $n += $off;
 374         my $mid = $ng->mm->mid_for($n);
 375         unless ($mid) {
 376                 $n = $off > 0 ? 'next' : 'previous';
 377                 return "421 no $n article in this group";
 378         }
 379         $self->{article} = $n;
 380         "223 $n <$mid> article retrieved - request text separately";
 381 }
 382
 383 sub cmd_next ($) { article_adj($_[0], 1) }
 384 sub cmd_last ($) { article_adj($_[0], -1) }
 385
 386 # We want to encourage using email and CC-ing everybody involved to avoid
 387 # the single-point-of-failure a single server provides.
 388 sub cmd_post ($) {
 389         my ($self) = @_;
 390         my $ng = $self->{ng};
 391         $ng ? "440 mailto:$ng->{-primary_address} to post"
 392                 : '440 posting not allowed'
 393 }
 394
 395 sub cmd_quit ($) {
 396         my ($self) = @_;
 397         res($self, '205 closing connection - goodbye!');
 398         $self->shutdn;
 399         undef;
 400 }
 401
 402 sub header_append ($$$) {
 403         my ($hdr, $k, $v) = @_;
 404         my @v = $hdr->header_raw($k);
 405         foreach (@v) {
 406                 return if $v eq $_;
 407         }
 408         $hdr->header_set($k, @v, $v);
 409 }
 410
 411 sub xref ($$$) {
 412         my ($self, $cur_ibx, $smsg) = @_;
 413         my $nntpd = $self->{nntpd};
 414         my $cur_ngname = $cur_ibx->{newsgroup};
 415         my $ret = "$nntpd->{servername} $cur_ngname:$smsg->{num}";
 416         if (my $ALL = $nntpd->{pi_config}->ALL) {
 417                 if (my $ary = $ALL->nntp_xref_for($cur_ibx, $smsg)) {
 418                         $ret .= join(' ', '', @$ary) if scalar(@$ary);
 419                 }
 420                 # better off wrong than slow if there's thousands of groups,
 421                 # so no fallback to the slow path below:
 422         } else { # slow path
 423                 my $mid = $smsg->{mid};
 424                 my $groups = $nntpd->{pi_config}->{-by_newsgroup};
 425                 for my $xngname (@{$nntpd->{groupnames}}) {
 426                         next if $cur_ngname eq $xngname;
 427                         my $xibx = $groups->{$xngname} or next;
 428                         my $num = eval { $xibx->mm->num_for($mid) } or next;
 429                         $ret .= " $xngname:$num";
 430                 }
 431         }
 432         $ret;
 433 }
 434
 435 sub set_nntp_headers ($$) {
 436         my ($hdr, $smsg) = @_;
 437         my ($mid) = $smsg->{mid};
 438
 439         # leafnode (and maybe other NNTP clients) have trouble dealing
 440         # with v2 messages which have multiple Message-IDs (either due
 441         # to our own content-based dedupe or buggy git-send-email versions).
 442         my @mids = $hdr->header_raw('Message-ID');
 443         if (scalar(@mids) > 1) {
 444                 my $mid0 = "<$mid>";
 445                 $hdr->header_set('Message-ID', $mid0);
 446                 my @alt = $hdr->header_raw('X-Alt-Message-ID');
 447                 my %seen = map { $_ => 1 } (@alt, $mid0);
 448                 push(@alt, grep { !$seen{$_}++ } @mids);
 449                 $hdr->header_set('X-Alt-Message-ID', @alt);
 450         }
 451
 452         # clobber some existing headers
 453         my $ibx = $smsg->{-ibx};
 454         my $xref = xref($smsg->{nntp}, $ibx, $smsg);
 455         $hdr->header_set('Xref', $xref);
 456
 457         # RFC 5536 3.1.4
 458         my ($server_name, $newsgroups) = split(/ /, $xref, 2);
 459         $newsgroups =~ s/:[0-9]+\b//g; # drop NNTP article numbers
 460         $newsgroups =~ tr/ /,/;
 461         $hdr->header_set('Newsgroups', $newsgroups);
 462
 463         # *something* here is required for leafnode, try to follow
 464         # RFC 5536 3.1.5...
 465         $hdr->header_set('Path', $server_name . '!not-for-mail');
 466
 467         header_append($hdr, 'List-Post', "<mailto:$ibx->{-primary_address}>");
 468         if (my $url = $ibx->base_url) {
 469                 $mid = mid_escape($mid);
 470                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 471                 header_append($hdr, 'List-Archive', "<$url>");
 472         }
 473 }
 474
 475 sub art_lookup ($$$) {
 476         my ($self, $art, $code) = @_;
 477         my $ng = $self->{ng};
 478         my ($n, $mid);
 479         my $err;
 480         if (defined $art) {
 481                 if ($art =~ /\A[0-9]+\z/) {
 482                         $err = '423 no such article number in this group';
 483                         $n = int($art);
 484                         goto find_mid;
 485                 } elsif ($art =~ $ONE_MSGID) {
 486                         $mid = $1;
 487                         $err = r430;
 488                         $n = $ng->mm->num_for($mid) if $ng;
 489                         goto found if defined $n;
 490                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 491                                 $n = $g->mm->num_for($mid);
 492                                 if (defined $n) {
 493                                         $ng = $g;
 494                                         goto found;
 495                                 }
 496                         }
 497                         return $err;
 498                 } else {
 499                         return r501;
 500                 }
 501         } else {
 502                 $err = '420 no current article has been selected';
 503                 $n = $self->{article};
 504                 defined $n or return $err;
 505 find_mid:
 506                 $ng or return '412 no newsgroup has been selected';
 507                 $mid = $ng->mm->mid_for($n);
 508                 defined $mid or return $err;
 509         }
 510 found:
 511         my $smsg = $ng->over->get_art($n) or return $err;
 512         $smsg->{-ibx} = $ng;
 513         if ($code == 223) { # STAT
 514                 set_art($self, $n);
 515                 "223 $n <$smsg->{mid}> article retrieved - " .
 516                         "request text separately";
 517         } else { # HEAD | BODY | ARTICLE
 518                 $smsg->{nntp} = $self;
 519                 $smsg->{nntp_code} = $code;
 520                 set_art($self, $art);
 521                 # this dereferences to `undef'
 522                 ${git_async_cat($ng->git, $smsg->{blob}, \&blob_cb, $smsg)};
 523         }
 524 }
 525
 526 sub msg_body_write ($$) {
 527         my ($self, $msg) = @_;
 528
 529         # these can momentarily double the memory consumption :<
 530         $$msg =~ s/^\./../smg;
 531         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 532         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 533         $self->msg_more($$msg);
 534 }
 535
 536 sub set_art {
 537         my ($self, $art) = @_;
 538         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 539 }
 540
 541 sub msg_hdr_write ($$) {
 542         my ($eml, $smsg) = @_;
 543         set_nntp_headers($eml, $smsg);
 544
 545         my $hdr = $eml->{hdr} // \(my $x = '');
 546         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 547         $$hdr =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 548         $$hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 549
 550         # for leafnode compatibility, we need to ensure Message-ID headers
 551         # are only a single line.
 552         $$hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 553         $smsg->{nntp}->msg_more($$hdr);
 554 }
 555
 556 sub blob_cb { # called by git->cat_async via git_async_cat
 557         my ($bref, $oid, $type, $size, $smsg) = @_;
 558         my $self = $smsg->{nntp};
 559         my $code = $smsg->{nntp_code};
 560         if (!defined($oid)) {
 561                 # it's possible to have TOCTOU if an admin runs
 562                 # public-inbox-(edit|purge), just move onto the next message
 563                 warn "E: $smsg->{blob} missing in $smsg->{-ibx}->{inboxdir}\n";
 564                 return $self->requeue;
 565         } elsif ($smsg->{blob} ne $oid) {
 566                 $self->close;
 567                 die "BUG: $smsg->{blob} != $oid";
 568         }
 569         my $r = "$code $smsg->{num} <$smsg->{mid}> article retrieved - ";
 570         my $eml = PublicInbox::Eml->new($bref);
 571         if ($code == 220) {
 572                 more($self, $r .= 'head and body follow');
 573                 msg_hdr_write($eml, $smsg);
 574                 $self->msg_more("\r\n");
 575                 msg_body_write($self, $bref);
 576         } elsif ($code == 221) {
 577                 more($self, $r .= 'head follows');
 578                 msg_hdr_write($eml, $smsg);
 579         } elsif ($code == 222) {
 580                 more($self, $r .= 'body follows');
 581                 msg_body_write($self, $bref);
 582         } else {
 583                 $self->close;
 584                 die "BUG: bad code: $r";
 585         }
 586         $self->write(\".\r\n"); # flushes (includes ->zflush)
 587         $self->requeue;
 588 }
 589
 590 sub cmd_article ($;$) {
 591         my ($self, $art) = @_;
 592         art_lookup($self, $art, 220);
 593 }
 594
 595 sub cmd_head ($;$) {
 596         my ($self, $art) = @_;
 597         art_lookup($self, $art, 221);
 598 }
 599
 600 sub cmd_body ($;$) {
 601         my ($self, $art) = @_;
 602         art_lookup($self, $art, 222);
 603 }
 604
 605 sub cmd_stat ($;$) {
 606         my ($self, $art) = @_;
 607         art_lookup($self, $art, 223); # art may be msgid
 608 }
 609
 610 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 611
 612 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 613
 614 sub cmd_help ($) {
 615         my ($self) = @_;
 616         more($self, '100 help text follows');
 617         '.'
 618 }
 619
 620 sub get_range ($$) {
 621         my ($self, $range) = @_;
 622         my $ng = $self->{ng} or return '412 no news group has been selected';
 623         defined $range or return '420 No article(s) selected';
 624         my ($beg, $end);
 625         my ($min, $max) = $ng->mm->minmax;
 626         if ($range =~ /\A([0-9]+)\z/) {
 627                 $beg = $end = $1;
 628         } elsif ($range =~ /\A([0-9]+)-\z/) {
 629                 ($beg, $end) = ($1, $max);
 630         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 631                 ($beg, $end) = ($1, $2);
 632         } else {
 633                 return r501;
 634         }
 635         $beg = $min if ($beg < $min);
 636         $end = $max if ($end > $max);
 637         return '420 No article(s) selected' if ($beg > $end);
 638         [ \$beg, $end ];
 639 }
 640
 641 sub long_step {
 642         my ($self) = @_;
 643         # wbuf is unset or empty, here; {long} may add to it
 644         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
 645         my $more = eval { $cb->($self, @args) };
 646         if ($@ || !$self->{sock}) { # something bad happened...
 647                 delete $self->{long_cb};
 648                 my $elapsed = now() - $t0;
 649                 if ($@) {
 650                         err($self,
 651                             "%s during long response[$fd] - %0.6f",
 652                             $@, $elapsed);
 653                 }
 654                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 655                 $self->close;
 656         } elsif ($more) { # $self->{wbuf}:
 657                 $self->update_idle_time;
 658
 659                 # COMPRESS users all share the same DEFLATE context.
 660                 # Flush it here to ensure clients don't see
 661                 # each other's data
 662                 $self->zflush;
 663
 664                 # no recursion, schedule another call ASAP, but only after
 665                 # all pending writes are done.  autovivify wbuf:
 666                 my $new_size = push(@{$self->{wbuf}}, \&long_step);
 667
 668                 # wbuf may be populated by $cb, no need to rearm if so:
 669                 $self->requeue if $new_size == 1;
 670         } else { # all done!
 671                 delete $self->{long_cb};
 672                 res($self, '.');
 673                 my $elapsed = now() - $t0;
 674                 my $fd = fileno($self->{sock});
 675                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 676                 my $wbuf = $self->{wbuf}; # do NOT autovivify
 677                 $self->requeue unless $wbuf && @$wbuf;
 678         }
 679 }
 680
 681 sub long_response ($$;@) {
 682         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 683
 684         my $sock = $self->{sock} or return;
 685         # make sure we disable reading during a long response,
 686         # clients should not be sending us stuff and making us do more
 687         # work while we are stream a response to them
 688         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
 689         long_step($self); # kick off!
 690         undef;
 691 }
 692
 693 sub hdr_msgid_range_i {
 694         my ($self, $beg, $end) = @_;
 695         my $r = $self->{ng}->mm->msg_range($beg, $end);
 696         @$r or return;
 697         more($self, join("\r\n", map { "$_->[0] <$_->[1]>" } @$r));
 698         1;
 699 }
 700
 701 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 702         my ($self, $xhdr, $range) = @_;
 703
 704         if (defined $range && $range =~ $ONE_MSGID) {
 705                 my ($ng, $n) = mid_lookup($self, $1);
 706                 return r430 unless $n;
 707                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 708         } else { # numeric range
 709                 $range = $self->{article} unless defined $range;
 710                 my $r = get_range($self, $range);
 711                 return $r unless ref $r;
 712                 more($self, $xhdr ? r221 : r225);
 713                 long_response($self, \&hdr_msgid_range_i, @$r);
 714         }
 715 }
 716
 717 sub mid_lookup ($$) {
 718         my ($self, $mid) = @_;
 719         my $self_ng = $self->{ng};
 720         if ($self_ng) {
 721                 my $n = $self_ng->mm->num_for($mid);
 722                 return ($self_ng, $n) if defined $n;
 723         }
 724         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 725                 next if defined $self_ng && $ng eq $self_ng;
 726                 my $n = $ng->mm->num_for($mid);
 727                 return ($ng, $n) if defined $n;
 728         }
 729         (undef, undef);
 730 }
 731
 732 sub xref_range_i {
 733         my ($self, $beg, $end) = @_;
 734         my $ng = $self->{ng};
 735         my $msgs = $ng->over->query_xover($$beg, $end);
 736         scalar(@$msgs) or return;
 737         $$beg = $msgs->[-1]->{num} + 1;
 738         more($self, join("\r\n", map {
 739                 "$_->{num} ".xref($self, $ng, $_);
 740         } @$msgs));
 741         1;
 742 }
 743
 744 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 745         my ($self, $xhdr, $range) = @_;
 746
 747         if (defined $range && $range =~ $ONE_MSGID) {
 748                 my $mid = $1;
 749                 my ($ng, $n) = mid_lookup($self, $mid);
 750                 return r430 unless $n;
 751                 my $smsg = $ng->over->get_art($n) or return;
 752                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 753                                 xref($self, $ng, $smsg));
 754         } else { # numeric range
 755                 $range = $self->{article} unless defined $range;
 756                 my $r = get_range($self, $range);
 757                 return $r unless ref $r;
 758                 more($self, $xhdr ? r221 : r225);
 759                 long_response($self, \&xref_range_i, @$r);
 760         }
 761 }
 762
 763 sub over_header_for {
 764         my ($over, $num, $field) = @_;
 765         my $smsg = $over->get_art($num) or return;
 766         return PublicInbox::Smsg::date($smsg) if $field eq 'date';
 767         $smsg->{$field};
 768 }
 769
 770 sub smsg_range_i {
 771         my ($self, $beg, $end, $field) = @_;
 772         my $over = $self->{ng}->over;
 773         my $msgs = $over->query_xover($$beg, $end);
 774         scalar(@$msgs) or return;
 775         my $tmp = '';
 776
 777         # ->{$field} is faster than ->$field invocations, so favor that.
 778         if ($field eq 'date') {
 779                 for my $s (@$msgs) {
 780                         $tmp .= "$s->{num} ".PublicInbox::Smsg::date($s)."\r\n"
 781                 }
 782         } else {
 783                 for my $s (@$msgs) {
 784                         $tmp .= "$s->{num} $s->{$field}\r\n";
 785                 }
 786         }
 787         utf8::encode($tmp);
 788         $self->msg_more($tmp);
 789         $$beg = $msgs->[-1]->{num} + 1;
 790 }
 791
 792 sub hdr_smsg ($$$$) {
 793         my ($self, $xhdr, $field, $range) = @_;
 794         if (defined $range && $range =~ $ONE_MSGID) {
 795                 my ($ng, $n) = mid_lookup($self, $1);
 796                 return r430 unless defined $n;
 797                 my $v = over_header_for($ng->over, $n, $field);
 798                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 799         } else { # numeric range
 800                 $range = $self->{article} unless defined $range;
 801                 my $r = get_range($self, $range);
 802                 return $r unless ref $r;
 803                 more($self, $xhdr ? r221 : r225);
 804                 long_response($self, \&smsg_range_i, @$r, $field);
 805         }
 806 }
 807
 808 sub do_hdr ($$$;$) {
 809         my ($self, $xhdr, $header, $range) = @_;
 810         my $sub = lc $header;
 811         if ($sub eq 'message-id') {
 812                 hdr_message_id($self, $xhdr, $range);
 813         } elsif ($sub eq 'xref') {
 814                 hdr_xref($self, $xhdr, $range);
 815         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 816                                 bytes|lines)\z/x) {
 817                 hdr_smsg($self, $xhdr, $sub, $range);
 818         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 819                 hdr_smsg($self, $xhdr, $1, $range);
 820         } else {
 821                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 822         }
 823 }
 824
 825 # RFC 3977
 826 sub cmd_hdr ($$;$) {
 827         my ($self, $header, $range) = @_;
 828         do_hdr($self, 0, $header, $range);
 829 }
 830
 831 # RFC 2980
 832 sub cmd_xhdr ($$;$) {
 833         my ($self, $header, $range) = @_;
 834         do_hdr($self, 1, $header, $range);
 835 }
 836
 837 sub hdr_mid_prefix ($$$$$) {
 838         my ($self, $xhdr, $ng, $n, $mid) = @_;
 839         return $mid if $xhdr;
 840
 841         # HDR for RFC 3977 users
 842         if (my $self_ng = $self->{ng}) {
 843                 ($self_ng eq $ng) ? $n : '0';
 844         } else {
 845                 '0';
 846         }
 847 }
 848
 849 sub hdr_mid_response ($$$$$$) {
 850         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 851         my $res = '';
 852         if ($xhdr) {
 853                 $res .= r221 . "\r\n";
 854                 $res .= "$mid $v\r\n";
 855         } else {
 856                 $res .= r225 . "\r\n";
 857                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 858                 $res .= "$pfx $v\r\n";
 859         }
 860         res($self, $res .= '.');
 861         undef;
 862 }
 863
 864 sub xrover_i {
 865         my ($self, $beg, $end) = @_;
 866         my $h = over_header_for($self->{ng}->over, $$beg, 'references');
 867         more($self, "$$beg $h") if defined($h);
 868         $$beg++ < $end;
 869 }
 870
 871 sub cmd_xrover ($;$) {
 872         my ($self, $range) = @_;
 873         my $ng = $self->{ng} or return '412 no newsgroup selected';
 874         (defined $range && $range =~ /[<>]/) and
 875                 return '420 No article(s) selected'; # no message IDs
 876
 877         $range = $self->{article} unless defined $range;
 878         my $r = get_range($self, $range);
 879         return $r unless ref $r;
 880         more($self, '224 Overview information follows');
 881         long_response($self, \&xrover_i, @$r);
 882 }
 883
 884 sub over_line ($$$) {
 885         my ($self, $ng, $smsg) = @_;
 886         # n.b. field access and procedural calls can be
 887         # 10%-15% faster than OO method calls:
 888         my $s = join("\t", $smsg->{num},
 889                 $smsg->{subject},
 890                 $smsg->{from},
 891                 PublicInbox::Smsg::date($smsg),
 892                 "<$smsg->{mid}>",
 893                 $smsg->{references},
 894                 $smsg->{bytes},
 895                 $smsg->{lines},
 896                 "Xref: " . xref($self, $ng, $smsg));
 897         utf8::encode($s);
 898         $s
 899 }
 900
 901 sub cmd_over ($;$) {
 902         my ($self, $range) = @_;
 903         if ($range && $range =~ $ONE_MSGID) {
 904                 my ($ng, $n) = mid_lookup($self, $1);
 905                 defined $n or return r430;
 906                 my $smsg = $ng->over->get_art($n) or return r430;
 907                 more($self, '224 Overview information follows (multi-line)');
 908
 909                 # Only set article number column if it's the current group
 910                 my $self_ng = $self->{ng};
 911                 $smsg->{num} = 0 if (!$self_ng || $self_ng ne $ng);
 912                 more($self, over_line($self, $ng, $smsg));
 913                 '.';
 914         } else {
 915                 cmd_xover($self, $range);
 916         }
 917 }
 918
 919 sub xover_i {
 920         my ($self, $beg, $end) = @_;
 921         my $ng = $self->{ng};
 922         my $msgs = $ng->over->query_xover($$beg, $end);
 923         my $nr = scalar @$msgs or return;
 924
 925         # OVERVIEW.FMT
 926         more($self, join("\r\n", map {
 927                 over_line($self, $ng, $_);
 928                 } @$msgs));
 929         $$beg = $msgs->[-1]->{num} + 1;
 930 }
 931
 932 sub cmd_xover ($;$) {
 933         my ($self, $range) = @_;
 934         $range = $self->{article} unless defined $range;
 935         my $r = get_range($self, $range);
 936         return $r unless ref $r;
 937         my ($beg, $end) = @$r;
 938         more($self, "224 Overview information follows for $$beg to $end");
 939         long_response($self, \&xover_i, @$r);
 940 }
 941
 942 sub compressed { undef }
 943
 944 sub cmd_starttls ($) {
 945         my ($self) = @_;
 946         my $sock = $self->{sock} or return;
 947         # RFC 4642 2.2.1
 948         return r502 if ($sock->can('accept_SSL') || $self->compressed);
 949         my $opt = $self->{nntpd}->{accept_tls} or
 950                 return '580 can not initiate TLS negotiation';
 951         res($self, '382 Continue with TLS negotiation');
 952         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 953         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 954         undef;
 955 }
 956
 957 # RFC 8054
 958 sub cmd_compress ($$) {
 959         my ($self, $alg) = @_;
 960         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 961         return r502 if $self->compressed;
 962         PublicInbox::NNTPdeflate->enable($self);
 963         $self->requeue;
 964         undef
 965 }
 966
 967 sub zflush {} # overridden by NNTPdeflate
 968
 969 sub cmd_xpath ($$) {
 970         my ($self, $mid) = @_;
 971         return r501 unless $mid =~ $ONE_MSGID;
 972         $mid = $1;
 973         my @paths;
 974         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 975                 my $n = $ng->mm->num_for($mid);
 976                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 977         }
 978         return '430 no such article on server' unless @paths;
 979         '223 '.join(' ', @paths);
 980 }
 981
 982 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 983
 984 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 985
 986 sub do_write ($$) {
 987         my $self = $_[0];
 988         my $done = $self->write(\($_[1]));
 989         return 0 unless $self->{sock};
 990
 991         $done;
 992 }
 993
 994 sub err ($$;@) {
 995         my ($self, $fmt, @args) = @_;
 996         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 997 }
 998
 999 sub out ($$;@) {
1000         my ($self, $fmt, @args) = @_;
1001         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
1002 }
1003
1004 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
1005 sub event_step {
1006         my ($self) = @_;
1007
1008         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
1009
1010         $self->update_idle_time;
1011         # only read more requests if we've drained the write buffer,
1012         # otherwise we can be buffering infinitely w/o backpressure
1013
1014         my $rbuf = $self->{rbuf} // \(my $x = '');
1015         my $line = index($$rbuf, "\n");
1016         while ($line < 0) {
1017                 return $self->close if length($$rbuf) >= LINE_MAX;
1018                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
1019                 $line = index($$rbuf, "\n");
1020         }
1021         $line = substr($$rbuf, 0, $line + 1, '');
1022         $line =~ s/\r?\n\z//s;
1023         return $self->close if $line =~ /[[:cntrl:]]/s;
1024
1025         my $t0 = now();
1026         my $fd = fileno($self->{sock});
1027         my $r = eval { process_line($self, $line) };
1028         my $pending = $self->{wbuf} ? ' pending' : '';
1029         out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
1030         return $self->close if $r < 0;
1031         $self->rbuf_idle($rbuf);
1032         $self->update_idle_time;
1033
1034         # maybe there's more pipelined data, or we'll have
1035         # to register it for socket-readiness notifications
1036         $self->requeue unless $pending;
1037 }
1038
1039 # for graceful shutdown in PublicInbox::Daemon:
1040 sub busy {
1041         my ($self, $now) = @_;
1042         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1043 }
1044
1045 1;