lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 # fields:
   6 # nntpd: PublicInbox::NNTPD ref
   7 # article: per-session current article number
   8 # ng: PublicInbox::Inbox ref
   9 # long_cb: long_response private data
  10 package PublicInbox::NNTP;
  11 use strict;
  12 use parent qw(PublicInbox::DS);
  13 use PublicInbox::MID qw(mid_escape $MID_EXTRACT);
  14 use PublicInbox::Eml;
  15 use POSIX qw(strftime);
  16 use PublicInbox::DS qw(now);
  17 use Digest::SHA qw(sha1_hex);
  18 use Time::Local qw(timegm timelocal);
  19 use PublicInbox::GitAsyncCat;
  20 use PublicInbox::Address;
  21
  22 use constant {
  23         LINE_MAX => 512, # RFC 977 section 2.3
  24         r501 => '501 command syntax error',
  25         r502 => '502 Command unavailable',
  26         r221 => '221 Header follows',
  27         r224 => '224 Overview information follows (multi-line)',
  28         r225 => '225 Headers follow (multi-line)',
  29         r430 => '430 No article with that message-id',
  30 };
  31 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  32 use Errno qw(EAGAIN);
  33 my $ONE_MSGID = qr/\A$MID_EXTRACT\z/;
  34 my @OVERVIEW = qw(Subject From Date Message-ID References);
  35 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  36                 "Xref:full\r\n.";
  37 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  38                         qw(:bytes :lines Xref To Cc)) . "\r\n.";
  39 my $CAPABILITIES = <<"";
  40 101 Capability list:\r
  41 VERSION 2\r
  42 READER\r
  43 NEWNEWS\r
  44 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  45 HDR\r
  46 OVER\r
  47 COMPRESS DEFLATE\r
  48
  49 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  50
  51 sub new ($$$) {
  52         my ($class, $sock, $nntpd) = @_;
  53         my $self = bless { nntpd => $nntpd }, $class;
  54         my $ev = EPOLLIN;
  55         my $wbuf;
  56         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
  57                 return CORE::close($sock) if $! != EAGAIN;
  58                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
  59                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  60         }
  61         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  62         if ($wbuf) {
  63                 $self->{wbuf} = $wbuf;
  64         } else {
  65                 greet($self);
  66         }
  67         $self->update_idle_time;
  68         $self;
  69 }
  70
  71 sub args_ok ($$) {
  72         my ($cb, $argc) = @_;
  73         my $tot = prototype $cb;
  74         my ($nreq, undef) = split(';', $tot);
  75         $nreq = ($nreq =~ tr/$//) - 1;
  76         $tot = ($tot =~ tr/$//) - 1;
  77         ($argc <= $tot && $argc >= $nreq);
  78 }
  79
  80 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  81 sub process_line ($$) {
  82         my ($self, $l) = @_;
  83         my ($req, @args) = split(/[ \t]+/, $l);
  84         return 1 unless defined($req); # skip blank line
  85         $req = $self->can('cmd_'.lc($req));
  86         return res($self, '500 command not recognized') unless $req;
  87         return res($self, r501) unless args_ok($req, scalar @args);
  88
  89         my $res = eval { $req->($self, @args) };
  90         my $err = $@;
  91         if ($err && $self->{sock}) {
  92                 local $/ = "\n";
  93                 chomp($l);
  94                 err($self, 'error from: %s (%s)', $l, $err);
  95                 $res = '503 program fault - command not performed';
  96         }
  97         defined($res) ? res($self, $res) : 0;
  98 }
  99
 100 # The keyword argument is not used (rfc3977 5.2.2)
 101 sub cmd_capabilities ($;$) {
 102         my ($self, undef) = @_;
 103         my $res = $CAPABILITIES;
 104         if (!$self->{sock}->can('accept_SSL') &&
 105                         $self->{nntpd}->{accept_tls}) {
 106                 $res .= "STARTTLS\r\n";
 107         }
 108         $res .= '.';
 109 }
 110
 111 sub cmd_mode ($$) {
 112         my ($self, $arg) = @_;
 113         uc($arg) eq 'READER' ? '201 Posting prohibited' : r501;
 114 }
 115
 116 sub cmd_slave ($) { '202 slave status noted' }
 117
 118 sub cmd_xgtitle ($;$) {
 119         my ($self, $wildmat) = @_;
 120         more($self, '282 list of groups and descriptions follows');
 121         list_newsgroups($self, $wildmat);
 122 }
 123
 124 sub list_overview_fmt ($) { $OVERVIEW_FMT }
 125
 126 sub list_headers ($;$) { $LIST_HEADERS }
 127
 128 sub list_active_i { # "LIST ACTIVE" and also just "LIST" (no args)
 129         my ($self, $groupnames) = @_;
 130         my @window = splice(@$groupnames, 0, 100) or return 0;
 131         my $ibx;
 132         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 133         for my $ngname (@window) {
 134                 $ibx = $groups->{$ngname} and group_line($self, $ibx);
 135         }
 136         scalar(@$groupnames); # continue if there's more
 137 }
 138
 139 sub list_active ($;$) { # called by cmd_list
 140         my ($self, $wildmat) = @_;
 141         wildmat2re($wildmat);
 142         long_response($self, \&list_active_i, [
 143                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 144 }
 145
 146 sub list_active_times_i {
 147         my ($self, $groupnames) = @_;
 148         my @window = splice(@$groupnames, 0, 100) or return 0;
 149         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 150         for my $ngname (@window) {
 151                 my $ibx = $groups->{$ngname} or next;
 152                 my $c = eval { $ibx->uidvalidity } // time;
 153                 more($self, "$ngname $c <$ibx->{-primary_address}>");
 154         }
 155         scalar(@$groupnames); # continue if there's more
 156 }
 157
 158 sub list_active_times ($;$) { # called by cmd_list
 159         my ($self, $wildmat) = @_;
 160         wildmat2re($wildmat);
 161         long_response($self, \&list_active_times_i, [
 162                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 163 }
 164
 165 sub list_newsgroups_i {
 166         my ($self, $groupnames) = @_;
 167         my @window = splice(@$groupnames, 0, 100) or return 0;
 168         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 169         my $ibx;
 170         for my $ngname (@window) {
 171                 $ibx = $groups->{$ngname} and
 172                         more($self, "$ngname ".$ibx->description);
 173         }
 174         scalar(@$groupnames); # continue if there's more
 175 }
 176
 177 sub list_newsgroups ($;$) { # called by cmd_list
 178         my ($self, $wildmat) = @_;
 179         wildmat2re($wildmat);
 180         long_response($self, \&list_newsgroups_i, [
 181                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 182 }
 183
 184 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 185 sub cmd_list ($;$$) {
 186         my ($self, @args) = @_;
 187         if (scalar @args) {
 188                 my $arg = shift @args;
 189                 $arg =~ tr/A-Z./a-z_/;
 190                 my $ret = $arg eq 'active';
 191                 $arg = "list_$arg";
 192                 $arg = $self->can($arg);
 193                 return r501 unless $arg && args_ok($arg, scalar @args);
 194                 more($self, '215 information follows');
 195                 $arg->($self, @args);
 196         } else {
 197                 more($self, '215 list of newsgroups follows');
 198                 long_response($self, \&list_active_i, [ # copy array
 199                         @{$self->{nntpd}->{groupnames}} ]);
 200         }
 201 }
 202
 203 sub listgroup_range_i {
 204         my ($self, $beg, $end) = @_;
 205         my $r = $self->{ng}->mm->msg_range($beg, $end, 'num');
 206         scalar(@$r) or return;
 207         more($self, join("\r\n", map { $_->[0] } @$r));
 208         1;
 209 }
 210
 211 sub listgroup_all_i {
 212         my ($self, $num) = @_;
 213         my $ary = $self->{ng}->mm->ids_after($num);
 214         scalar(@$ary) or return;
 215         more($self, join("\r\n", @$ary));
 216         1;
 217 }
 218
 219 sub cmd_listgroup ($;$$) {
 220         my ($self, $group, $range) = @_;
 221         if (defined $group) {
 222                 my $res = cmd_group($self, $group);
 223                 return $res if ($res !~ /\A211 /);
 224                 more($self, $res);
 225         }
 226         $self->{ng} or return '412 no newsgroup selected';
 227         if (defined $range) {
 228                 my $r = get_range($self, $range);
 229                 return $r unless ref $r;
 230                 long_response($self, \&listgroup_range_i, @$r);
 231         } else { # grab every article number
 232                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 233         }
 234 }
 235
 236 sub parse_time ($$;$) {
 237         my ($date, $time, $gmt) = @_;
 238         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 239         if (defined $gmt) {
 240                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 241                 $gmt = 1;
 242         }
 243         my ($YYYY, $MM, $DD);
 244         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 245                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 246         } else { # legacy clients send YYMMDD
 247                 my $YY;
 248                 ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 249                 my @now = $gmt ? gmtime : localtime;
 250                 my $cur_year = $now[5] + 1900;
 251                 my $cur_cent = int($cur_year / 100) * 100;
 252                 $YYYY = (($YY + $cur_cent) > $cur_year) ?
 253                         ($YY + 1900) : ($YY + $cur_cent);
 254         }
 255         if ($gmt) {
 256                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 257         } else {
 258                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 259         }
 260 }
 261
 262 sub group_line ($$) {
 263         my ($self, $ng) = @_;
 264         my ($min, $max) = $ng->mm->minmax;
 265         more($self, "$ng->{newsgroup} $max $min n");
 266 }
 267
 268 sub newgroups_i {
 269         my ($self, $ts, $i, $groupnames) = @_;
 270         my $end = $$i + 100;
 271         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 272         while ($$i < $end) {
 273                 my $ngname = $groupnames->[$$i++] // return;
 274                 my $ibx = $groups->{$ngname} or next; # expired on reload
 275                 next unless (eval { $ibx->uidvalidity } // 0) > $ts;
 276                 group_line($self, $ibx);
 277         }
 278         1;
 279 }
 280
 281 sub cmd_newgroups ($$$;$$) {
 282         my ($self, $date, $time, $gmt, $dists) = @_;
 283         my $ts = eval { parse_time($date, $time, $gmt) };
 284         return r501 if $@;
 285
 286         # TODO dists
 287         more($self, '231 list of new newsgroups follows');
 288         long_response($self, \&newgroups_i, $ts, \(my $i = 0),
 289                                 $self->{nntpd}->{groupnames});
 290 }
 291
 292 sub wildmat2re (;$) {
 293         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 294         my %keep;
 295         my $salt = rand;
 296         my $tmp = $_[0];
 297
 298         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 299                 my $orig = $1;
 300                 my $key = sha1_hex($orig . $salt);
 301                 $orig =~ s/([^\w\-])+/\Q$1/g;
 302                 $keep{$key} = $orig;
 303                 $key
 304                 #gex;
 305         my %map = ('*' => '.*', '?' => '.' );
 306         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 307         if (scalar %keep) {
 308                 $tmp =~ s#([a-f0-9]{40})#
 309                         my $orig = $keep{$1};
 310                         defined $orig ? $orig : $1;
 311                         #ge;
 312         }
 313         $_[0] = qr/\A$tmp\z/;
 314 }
 315
 316 sub ngpat2re (;$) {
 317         return $_[0] = qr/\A\z/ unless defined $_[0];
 318         my %map = ('*' => '.*', ',' => '|');
 319         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 320         $_[0] = qr/\A(?:$_[0])\z/;
 321 }
 322
 323 sub newnews_i {
 324         my ($self, $names, $ts, $prev) = @_;
 325         my $ngname = $names->[0];
 326         if (my $ibx = $self->{nntpd}->{pi_config}->{-by_newsgroup}->{$ngname}) {
 327                 if (my $over = $ibx->over) {
 328                         my $msgs = $over->query_ts($ts, $$prev);
 329                         if (scalar @$msgs) {
 330                                 more($self, '<' .
 331                                         join(">\r\n<",
 332                                                 map { $_->{mid} } @$msgs ) .
 333                                         '>');
 334                                 $$prev = $msgs->[-1]->{num};
 335                                 return 1; # continue on current group
 336                         }
 337                 }
 338         }
 339         shift @$names;
 340         if (@$names) { # continue onto next newsgroup
 341                 $$prev = 0;
 342                 1;
 343         } else { # all done, break out of the long_response
 344                 undef;
 345         }
 346 }
 347
 348 sub cmd_newnews ($$$$;$$) {
 349         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 350         my $ts = eval { parse_time($date, $time, $gmt) };
 351         return r501 if $@;
 352         more($self, '230 list of new articles by message-id follows');
 353         my ($keep, $skip) = split('!', $newsgroups, 2);
 354         ngpat2re($keep);
 355         ngpat2re($skip);
 356         my @names = grep(!/$skip/, grep(/$keep/,
 357                                 @{$self->{nntpd}->{groupnames}}));
 358         return '.' unless scalar(@names);
 359         my $prev = 0;
 360         long_response($self, \&newnews_i, \@names, $ts, \$prev);
 361 }
 362
 363 sub cmd_group ($$) {
 364         my ($self, $group) = @_;
 365         my $nntpd = $self->{nntpd};
 366         my $ibx = $nntpd->{pi_config}->{-by_newsgroup}->{$group} or
 367                 return '411 no such news group';
 368         $nntpd->idler_start;
 369
 370         $self->{ng} = $ibx;
 371         my ($min, $max) = $ibx->mm->minmax;
 372         $self->{article} = $min;
 373         my $est_size = $max - $min;
 374         "211 $est_size $min $max $group";
 375 }
 376
 377 sub article_adj ($$) {
 378         my ($self, $off) = @_;
 379         my $ng = $self->{ng} or return '412 no newsgroup selected';
 380
 381         my $n = $self->{article};
 382         defined $n or return '420 no current article has been selected';
 383
 384         $n += $off;
 385         my $mid = $ng->mm->mid_for($n);
 386         unless ($mid) {
 387                 $n = $off > 0 ? 'next' : 'previous';
 388                 return "421 no $n article in this group";
 389         }
 390         $self->{article} = $n;
 391         "223 $n <$mid> article retrieved - request text separately";
 392 }
 393
 394 sub cmd_next ($) { article_adj($_[0], 1) }
 395 sub cmd_last ($) { article_adj($_[0], -1) }
 396
 397 # We want to encourage using email and CC-ing everybody involved to avoid
 398 # the single-point-of-failure a single server provides.
 399 sub cmd_post ($) {
 400         my ($self) = @_;
 401         my $ng = $self->{ng};
 402         $ng ? "440 mailto:$ng->{-primary_address} to post"
 403                 : '440 posting not allowed'
 404 }
 405
 406 sub cmd_quit ($) {
 407         my ($self) = @_;
 408         res($self, '205 closing connection - goodbye!');
 409         $self->shutdn;
 410         undef;
 411 }
 412
 413 sub header_append ($$$) {
 414         my ($hdr, $k, $v) = @_;
 415         my @v = $hdr->header_raw($k);
 416         foreach (@v) {
 417                 return if $v eq $_;
 418         }
 419         $hdr->header_set($k, @v, $v);
 420 }
 421
 422 sub xref_by_tc ($$$) {
 423         my ($xref, $pi_cfg, $smsg) = @_;
 424         my $by_addr = $pi_cfg->{-by_addr};
 425         my $groups = $pi_cfg->{-by_newsgroup};
 426         my $mid = $smsg->{mid};
 427         for my $f (qw(to cc)) {
 428                 my @ibxs = map {
 429                         $by_addr->{lc($_)} // ()
 430                 } (PublicInbox::Address::emails($smsg->{$f} // ''));
 431                 for my $ibx (@ibxs) {
 432                         $groups->{my $ngname = $ibx->{newsgroup}} or next;
 433                         next if defined $xref->{$ngname};
 434                         $xref->{$ngname} = eval { $ibx->mm->num_for($mid) };
 435                 }
 436         }
 437 }
 438
 439 sub xref ($$$) {
 440         my ($self, $cur_ibx, $smsg) = @_;
 441         my $nntpd = $self->{nntpd};
 442         my $cur_ng = $cur_ibx->{newsgroup};
 443         my $xref;
 444         if (my $ALL = $nntpd->{pi_config}->ALL) {
 445                 $xref = $ALL->nntp_xref_for($cur_ibx, $smsg);
 446                 xref_by_tc($xref, $nntpd->{pi_config}, $smsg);
 447         } else { # slow path
 448                 $xref = { $cur_ng => $smsg->{num} };
 449                 my $mid = $smsg->{mid};
 450                 for my $ibx (values %{$nntpd->{pi_config}->{-by_newsgroup}}) {
 451                         next if defined($xref->{$ibx->{newsgroup}});
 452                         my $num = eval { $ibx->mm->num_for($mid) } // next;
 453                         $xref->{$ibx->{newsgroup}} = $num;
 454                 }
 455         }
 456         my $ret = "$nntpd->{servername} $cur_ng:".delete($xref->{$cur_ng});
 457         $ret .= " $_:$xref->{$_}" for (sort keys %$xref);
 458         $ret;
 459 }
 460
 461 sub set_nntp_headers ($$) {
 462         my ($hdr, $smsg) = @_;
 463         my ($mid) = $smsg->{mid};
 464
 465         # leafnode (and maybe other NNTP clients) have trouble dealing
 466         # with v2 messages which have multiple Message-IDs (either due
 467         # to our own content-based dedupe or buggy git-send-email versions).
 468         my @mids = $hdr->header_raw('Message-ID');
 469         if (scalar(@mids) > 1) {
 470                 my $mid0 = "<$mid>";
 471                 $hdr->header_set('Message-ID', $mid0);
 472                 my @alt = $hdr->header_raw('X-Alt-Message-ID');
 473                 my %seen = map { $_ => 1 } (@alt, $mid0);
 474                 push(@alt, grep { !$seen{$_}++ } @mids);
 475                 $hdr->header_set('X-Alt-Message-ID', @alt);
 476         }
 477
 478         # clobber some existing headers
 479         my $ibx = $smsg->{-ibx};
 480         my $xref = xref($smsg->{nntp}, $ibx, $smsg);
 481         $hdr->header_set('Xref', $xref);
 482
 483         # RFC 5536 3.1.4
 484         my ($server_name, $newsgroups) = split(/ /, $xref, 2);
 485         $newsgroups =~ s/:[0-9]+\b//g; # drop NNTP article numbers
 486         $newsgroups =~ tr/ /,/;
 487         $hdr->header_set('Newsgroups', $newsgroups);
 488
 489         # *something* here is required for leafnode, try to follow
 490         # RFC 5536 3.1.5...
 491         $hdr->header_set('Path', $server_name . '!not-for-mail');
 492
 493         header_append($hdr, 'List-Post', "<mailto:$ibx->{-primary_address}>");
 494         if (my $url = $ibx->base_url) {
 495                 $mid = mid_escape($mid);
 496                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 497                 header_append($hdr, 'List-Archive', "<$url>");
 498         }
 499 }
 500
 501 sub art_lookup ($$$) {
 502         my ($self, $art, $code) = @_;
 503         my ($ibx, $n);
 504         my $err;
 505         if (defined $art) {
 506                 if ($art =~ /\A[0-9]+\z/) {
 507                         $err = '423 no such article number in this group';
 508                         $n = int($art);
 509                         goto find_ibx;
 510                 } elsif ($art =~ $ONE_MSGID) {
 511                         ($ibx, $n) = mid_lookup($self, $1);
 512                         goto found if $ibx;
 513                         return r430;
 514                 } else {
 515                         return r501;
 516                 }
 517         } else {
 518                 $err = '420 no current article has been selected';
 519                 $n = $self->{article} // return $err;
 520 find_ibx:
 521                 $ibx = $self->{ng} or
 522                                 return '412 no newsgroup has been selected';
 523         }
 524 found:
 525         my $smsg = $ibx->over->get_art($n) or return $err;
 526         $smsg->{-ibx} = $ibx;
 527         if ($code == 223) { # STAT
 528                 set_art($self, $n);
 529                 "223 $n <$smsg->{mid}> article retrieved - " .
 530                         "request text separately";
 531         } else { # HEAD | BODY | ARTICLE
 532                 $smsg->{nntp} = $self;
 533                 $smsg->{nntp_code} = $code;
 534                 set_art($self, $art);
 535                 # this dereferences to `undef'
 536                 ${git_async_cat($ibx->git, $smsg->{blob}, \&blob_cb, $smsg)};
 537         }
 538 }
 539
 540 sub msg_body_write ($$) {
 541         my ($self, $msg) = @_;
 542
 543         # these can momentarily double the memory consumption :<
 544         $$msg =~ s/^\./../smg;
 545         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 546         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 547         $self->msg_more($$msg);
 548 }
 549
 550 sub set_art {
 551         my ($self, $art) = @_;
 552         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 553 }
 554
 555 sub msg_hdr_write ($$) {
 556         my ($eml, $smsg) = @_;
 557         set_nntp_headers($eml, $smsg);
 558
 559         my $hdr = $eml->{hdr} // \(my $x = '');
 560         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 561         $$hdr =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 562         $$hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 563
 564         # for leafnode compatibility, we need to ensure Message-ID headers
 565         # are only a single line.
 566         $$hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 567         $smsg->{nntp}->msg_more($$hdr);
 568 }
 569
 570 sub blob_cb { # called by git->cat_async via git_async_cat
 571         my ($bref, $oid, $type, $size, $smsg) = @_;
 572         my $self = $smsg->{nntp};
 573         my $code = $smsg->{nntp_code};
 574         if (!defined($oid)) {
 575                 # it's possible to have TOCTOU if an admin runs
 576                 # public-inbox-(edit|purge), just move onto the next message
 577                 warn "E: $smsg->{blob} missing in $smsg->{-ibx}->{inboxdir}\n";
 578                 return $self->requeue;
 579         } elsif ($smsg->{blob} ne $oid) {
 580                 $self->close;
 581                 die "BUG: $smsg->{blob} != $oid";
 582         }
 583         my $r = "$code $smsg->{num} <$smsg->{mid}> article retrieved - ";
 584         my $eml = PublicInbox::Eml->new($bref);
 585         if ($code == 220) {
 586                 more($self, $r .= 'head and body follow');
 587                 msg_hdr_write($eml, $smsg);
 588                 $self->msg_more("\r\n");
 589                 msg_body_write($self, $bref);
 590         } elsif ($code == 221) {
 591                 more($self, $r .= 'head follows');
 592                 msg_hdr_write($eml, $smsg);
 593         } elsif ($code == 222) {
 594                 more($self, $r .= 'body follows');
 595                 msg_body_write($self, $bref);
 596         } else {
 597                 $self->close;
 598                 die "BUG: bad code: $r";
 599         }
 600         $self->write(\".\r\n"); # flushes (includes ->zflush)
 601         $self->requeue;
 602 }
 603
 604 sub cmd_article ($;$) {
 605         my ($self, $art) = @_;
 606         art_lookup($self, $art, 220);
 607 }
 608
 609 sub cmd_head ($;$) {
 610         my ($self, $art) = @_;
 611         art_lookup($self, $art, 221);
 612 }
 613
 614 sub cmd_body ($;$) {
 615         my ($self, $art) = @_;
 616         art_lookup($self, $art, 222);
 617 }
 618
 619 sub cmd_stat ($;$) {
 620         my ($self, $art) = @_;
 621         art_lookup($self, $art, 223); # art may be msgid
 622 }
 623
 624 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 625
 626 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 627
 628 sub cmd_help ($) {
 629         my ($self) = @_;
 630         more($self, '100 help text follows');
 631         '.'
 632 }
 633
 634 sub get_range ($$) {
 635         my ($self, $range) = @_;
 636         my $ng = $self->{ng} or return '412 no news group has been selected';
 637         defined $range or return '420 No article(s) selected';
 638         my ($beg, $end);
 639         my ($min, $max) = $ng->mm->minmax;
 640         if ($range =~ /\A([0-9]+)\z/) {
 641                 $beg = $end = $1;
 642         } elsif ($range =~ /\A([0-9]+)-\z/) {
 643                 ($beg, $end) = ($1, $max);
 644         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 645                 ($beg, $end) = ($1, $2);
 646         } else {
 647                 return r501;
 648         }
 649         $beg = $min if ($beg < $min);
 650         $end = $max if ($end > $max);
 651         return '420 No article(s) selected' if ($beg > $end);
 652         [ \$beg, $end ];
 653 }
 654
 655 sub long_step {
 656         my ($self) = @_;
 657         # wbuf is unset or empty, here; {long} may add to it
 658         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
 659         my $more = eval { $cb->($self, @args) };
 660         if ($@ || !$self->{sock}) { # something bad happened...
 661                 delete $self->{long_cb};
 662                 my $elapsed = now() - $t0;
 663                 if ($@) {
 664                         err($self,
 665                             "%s during long response[$fd] - %0.6f",
 666                             $@, $elapsed);
 667                 }
 668                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 669                 $self->close;
 670         } elsif ($more) { # $self->{wbuf}:
 671                 $self->update_idle_time;
 672
 673                 # COMPRESS users all share the same DEFLATE context.
 674                 # Flush it here to ensure clients don't see
 675                 # each other's data
 676                 $self->zflush;
 677
 678                 # no recursion, schedule another call ASAP, but only after
 679                 # all pending writes are done.  autovivify wbuf:
 680                 my $new_size = push(@{$self->{wbuf}}, \&long_step);
 681
 682                 # wbuf may be populated by $cb, no need to rearm if so:
 683                 $self->requeue if $new_size == 1;
 684         } else { # all done!
 685                 delete $self->{long_cb};
 686                 res($self, '.');
 687                 my $elapsed = now() - $t0;
 688                 my $fd = fileno($self->{sock});
 689                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 690                 my $wbuf = $self->{wbuf}; # do NOT autovivify
 691                 $self->requeue unless $wbuf && @$wbuf;
 692         }
 693 }
 694
 695 sub long_response ($$;@) {
 696         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 697
 698         my $sock = $self->{sock} or return;
 699         # make sure we disable reading during a long response,
 700         # clients should not be sending us stuff and making us do more
 701         # work while we are stream a response to them
 702         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
 703         long_step($self); # kick off!
 704         undef;
 705 }
 706
 707 sub hdr_msgid_range_i {
 708         my ($self, $beg, $end) = @_;
 709         my $r = $self->{ng}->mm->msg_range($beg, $end);
 710         @$r or return;
 711         more($self, join("\r\n", map { "$_->[0] <$_->[1]>" } @$r));
 712         1;
 713 }
 714
 715 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 716         my ($self, $xhdr, $range) = @_;
 717
 718         if (defined $range && $range =~ $ONE_MSGID) {
 719                 my ($ng, $n) = mid_lookup($self, $1);
 720                 return r430 unless $n;
 721                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 722         } else { # numeric range
 723                 $range = $self->{article} unless defined $range;
 724                 my $r = get_range($self, $range);
 725                 return $r unless ref $r;
 726                 more($self, $xhdr ? r221 : r225);
 727                 long_response($self, \&hdr_msgid_range_i, @$r);
 728         }
 729 }
 730
 731 sub mid_lookup ($$) {
 732         my ($self, $mid) = @_;
 733         my $self_ng = $self->{ng};
 734         if ($self_ng) {
 735                 my $n = $self_ng->mm->num_for($mid);
 736                 return ($self_ng, $n) if defined $n;
 737         }
 738         my $pi_cfg = $self->{nntpd}->{pi_config};
 739         if (my $ALL = $pi_cfg->ALL) {
 740                 my ($id, $prev);
 741                 while (my $smsg = $ALL->over->next_by_mid($mid, \$id, \$prev)) {
 742                         my $xr3 = $ALL->over->get_xref3($smsg->{num});
 743                         if (my @x = grep(/:$smsg->{blob}\z/, @$xr3)) {
 744                                 my ($ngname, $xnum) = split(/:/, $x[0]);
 745                                 my $ibx = $pi_cfg->{-by_newsgroup}->{$ngname};
 746                                 return ($ibx, $xnum) if $ibx;
 747                                 # fall through to trying all xref3s
 748                         } else {
 749                                 warn <<EOF;
 750 W: xref3 missing for <$mid> ($smsg->{blob}) in $ALL->{topdir}, -extindex bug?
 751 EOF
 752                         }
 753                         # try all xref3s
 754                         for my $x (@$xr3) {
 755                                 my ($ngname, $xnum) = split(/:/, $x);
 756                                 my $ibx = $pi_cfg->{-by_newsgroup}->{$ngname};
 757                                 return ($ibx, $xnum) if $ibx;
 758                                 warn "W: `$ngname' does not exist for #$xnum\n";
 759                         }
 760                 }
 761                 # no warning here, $mid is just invalid
 762         } else { # slow path for non-ALL users
 763                 for my $ibx (values %{$pi_cfg->{-by_newsgroup}}) {
 764                         next if defined $self_ng && $ibx eq $self_ng;
 765                         my $n = $ibx->mm->num_for($mid);
 766                         return ($ibx, $n) if defined $n;
 767                 }
 768         }
 769         (undef, undef);
 770 }
 771
 772 sub xref_range_i {
 773         my ($self, $beg, $end) = @_;
 774         my $ng = $self->{ng};
 775         my $msgs = $ng->over->query_xover($$beg, $end);
 776         scalar(@$msgs) or return;
 777         $$beg = $msgs->[-1]->{num} + 1;
 778         more($self, join("\r\n", map {
 779                 "$_->{num} ".xref($self, $ng, $_);
 780         } @$msgs));
 781         1;
 782 }
 783
 784 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 785         my ($self, $xhdr, $range) = @_;
 786
 787         if (defined $range && $range =~ $ONE_MSGID) {
 788                 my $mid = $1;
 789                 my ($ng, $n) = mid_lookup($self, $mid);
 790                 return r430 unless $n;
 791                 my $smsg = $ng->over->get_art($n) or return;
 792                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 793                                 xref($self, $ng, $smsg));
 794         } else { # numeric range
 795                 $range = $self->{article} unless defined $range;
 796                 my $r = get_range($self, $range);
 797                 return $r unless ref $r;
 798                 more($self, $xhdr ? r221 : r225);
 799                 long_response($self, \&xref_range_i, @$r);
 800         }
 801 }
 802
 803 sub over_header_for {
 804         my ($over, $num, $field) = @_;
 805         my $smsg = $over->get_art($num) or return;
 806         return PublicInbox::Smsg::date($smsg) if $field eq 'date';
 807         $smsg->{$field};
 808 }
 809
 810 sub smsg_range_i {
 811         my ($self, $beg, $end, $field) = @_;
 812         my $over = $self->{ng}->over;
 813         my $msgs = $over->query_xover($$beg, $end);
 814         scalar(@$msgs) or return;
 815         my $tmp = '';
 816
 817         # ->{$field} is faster than ->$field invocations, so favor that.
 818         if ($field eq 'date') {
 819                 for my $s (@$msgs) {
 820                         $tmp .= "$s->{num} ".PublicInbox::Smsg::date($s)."\r\n"
 821                 }
 822         } else {
 823                 for my $s (@$msgs) {
 824                         $tmp .= "$s->{num} $s->{$field}\r\n";
 825                 }
 826         }
 827         utf8::encode($tmp);
 828         $self->msg_more($tmp);
 829         $$beg = $msgs->[-1]->{num} + 1;
 830 }
 831
 832 sub hdr_smsg ($$$$) {
 833         my ($self, $xhdr, $field, $range) = @_;
 834         if (defined $range && $range =~ $ONE_MSGID) {
 835                 my ($ng, $n) = mid_lookup($self, $1);
 836                 return r430 unless defined $n;
 837                 my $v = over_header_for($ng->over, $n, $field);
 838                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 839         } else { # numeric range
 840                 $range = $self->{article} unless defined $range;
 841                 my $r = get_range($self, $range);
 842                 return $r unless ref $r;
 843                 more($self, $xhdr ? r221 : r225);
 844                 long_response($self, \&smsg_range_i, @$r, $field);
 845         }
 846 }
 847
 848 sub do_hdr ($$$;$) {
 849         my ($self, $xhdr, $header, $range) = @_;
 850         my $sub = lc $header;
 851         if ($sub eq 'message-id') {
 852                 hdr_message_id($self, $xhdr, $range);
 853         } elsif ($sub eq 'xref') {
 854                 hdr_xref($self, $xhdr, $range);
 855         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 856                                 bytes|lines)\z/x) {
 857                 hdr_smsg($self, $xhdr, $sub, $range);
 858         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 859                 hdr_smsg($self, $xhdr, $1, $range);
 860         } else {
 861                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 862         }
 863 }
 864
 865 # RFC 3977
 866 sub cmd_hdr ($$;$) {
 867         my ($self, $header, $range) = @_;
 868         do_hdr($self, 0, $header, $range);
 869 }
 870
 871 # RFC 2980
 872 sub cmd_xhdr ($$;$) {
 873         my ($self, $header, $range) = @_;
 874         do_hdr($self, 1, $header, $range);
 875 }
 876
 877 sub hdr_mid_prefix ($$$$$) {
 878         my ($self, $xhdr, $ng, $n, $mid) = @_;
 879         return $mid if $xhdr;
 880
 881         # HDR for RFC 3977 users
 882         if (my $self_ng = $self->{ng}) {
 883                 ($self_ng eq $ng) ? $n : '0';
 884         } else {
 885                 '0';
 886         }
 887 }
 888
 889 sub hdr_mid_response ($$$$$$) {
 890         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 891         my $res = '';
 892         if ($xhdr) {
 893                 $res .= r221 . "\r\n";
 894                 $res .= "$mid $v\r\n";
 895         } else {
 896                 $res .= r225 . "\r\n";
 897                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 898                 $res .= "$pfx $v\r\n";
 899         }
 900         res($self, $res .= '.');
 901         undef;
 902 }
 903
 904 sub xrover_i {
 905         my ($self, $beg, $end) = @_;
 906         my $h = over_header_for($self->{ng}->over, $$beg, 'references');
 907         more($self, "$$beg $h") if defined($h);
 908         $$beg++ < $end;
 909 }
 910
 911 sub cmd_xrover ($;$) {
 912         my ($self, $range) = @_;
 913         my $ng = $self->{ng} or return '412 no newsgroup selected';
 914         (defined $range && $range =~ /[<>]/) and
 915                 return '420 No article(s) selected'; # no message IDs
 916
 917         $range = $self->{article} unless defined $range;
 918         my $r = get_range($self, $range);
 919         return $r unless ref $r;
 920         more($self, '224 Overview information follows');
 921         long_response($self, \&xrover_i, @$r);
 922 }
 923
 924 sub over_line ($$$) {
 925         my ($self, $ng, $smsg) = @_;
 926         # n.b. field access and procedural calls can be
 927         # 10%-15% faster than OO method calls:
 928         my $s = join("\t", $smsg->{num},
 929                 $smsg->{subject},
 930                 $smsg->{from},
 931                 PublicInbox::Smsg::date($smsg),
 932                 "<$smsg->{mid}>",
 933                 $smsg->{references},
 934                 $smsg->{bytes},
 935                 $smsg->{lines},
 936                 "Xref: " . xref($self, $ng, $smsg));
 937         utf8::encode($s);
 938         $s
 939 }
 940
 941 sub cmd_over ($;$) {
 942         my ($self, $range) = @_;
 943         if ($range && $range =~ $ONE_MSGID) {
 944                 my ($ng, $n) = mid_lookup($self, $1);
 945                 defined $n or return r430;
 946                 my $smsg = $ng->over->get_art($n) or return r430;
 947                 more($self, '224 Overview information follows (multi-line)');
 948
 949                 # Only set article number column if it's the current group
 950                 # (RFC 3977 8.3.2)
 951                 my $self_ng = $self->{ng};
 952                 if (!$self_ng || $self_ng ne $ng) {
 953                         # set {-orig_num} for nntp_xref_for
 954                         $smsg->{-orig_num} = $smsg->{num};
 955                         $smsg->{num} = 0;
 956                 }
 957                 more($self, over_line($self, $ng, $smsg));
 958                 '.';
 959         } else {
 960                 cmd_xover($self, $range);
 961         }
 962 }
 963
 964 sub xover_i {
 965         my ($self, $beg, $end) = @_;
 966         my $ng = $self->{ng};
 967         my $msgs = $ng->over->query_xover($$beg, $end);
 968         my $nr = scalar @$msgs or return;
 969
 970         # OVERVIEW.FMT
 971         more($self, join("\r\n", map {
 972                 over_line($self, $ng, $_);
 973                 } @$msgs));
 974         $$beg = $msgs->[-1]->{num} + 1;
 975 }
 976
 977 sub cmd_xover ($;$) {
 978         my ($self, $range) = @_;
 979         $range = $self->{article} unless defined $range;
 980         my $r = get_range($self, $range);
 981         return $r unless ref $r;
 982         my ($beg, $end) = @$r;
 983         more($self, "224 Overview information follows for $$beg to $end");
 984         long_response($self, \&xover_i, @$r);
 985 }
 986
 987 sub compressed { undef }
 988
 989 sub cmd_starttls ($) {
 990         my ($self) = @_;
 991         my $sock = $self->{sock} or return;
 992         # RFC 4642 2.2.1
 993         return r502 if ($sock->can('accept_SSL') || $self->compressed);
 994         my $opt = $self->{nntpd}->{accept_tls} or
 995                 return '580 can not initiate TLS negotiation';
 996         res($self, '382 Continue with TLS negotiation');
 997         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 998         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 999         undef;
1000 }
1001
1002 # RFC 8054
1003 sub cmd_compress ($$) {
1004         my ($self, $alg) = @_;
1005         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
1006         return r502 if $self->compressed;
1007         PublicInbox::NNTPdeflate->enable($self);
1008         $self->requeue;
1009         undef
1010 }
1011
1012 sub zflush {} # overridden by NNTPdeflate
1013
1014 sub cmd_xpath ($$) {
1015         my ($self, $mid) = @_;
1016         return r501 unless $mid =~ $ONE_MSGID;
1017         $mid = $1;
1018         my @paths;
1019         my $pi_cfg = $self->{nntpd}->{pi_config};
1020         my $groups = $pi_cfg->{-by_newsgroup};
1021         if (my $ALL = $pi_cfg->ALL) {
1022                 my ($id, $prev, %seen);
1023                 while (my $smsg = $ALL->over->next_by_mid($mid, \$id, \$prev)) {
1024                         my $xr3 = $ALL->over->get_xref3($smsg->{num});
1025                         for my $x (@$xr3) {
1026                                 my ($ngname, $n) = split(/:/, $x);
1027                                 $x = "$ngname/$n";
1028                                 if ($groups->{$ngname} && !$seen{$x}++) {
1029                                         push(@paths, $x);
1030                                 }
1031                         }
1032                 }
1033         } else { # slow path, no point in using long_response
1034                 for my $ibx (values %$groups) {
1035                         my $n = $ibx->mm->num_for($mid) // next;
1036                         push @paths, "$ibx->{newsgroup}/$n";
1037                 }
1038         }
1039         return '430 no such article on server' unless @paths;
1040         '223 '.join(' ', sort(@paths));
1041 }
1042
1043 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
1044
1045 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
1046
1047 sub do_write ($$) {
1048         my $self = $_[0];
1049         my $done = $self->write(\($_[1]));
1050         return 0 unless $self->{sock};
1051
1052         $done;
1053 }
1054
1055 sub err ($$;@) {
1056         my ($self, $fmt, @args) = @_;
1057         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
1058 }
1059
1060 sub out ($$;@) {
1061         my ($self, $fmt, @args) = @_;
1062         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
1063 }
1064
1065 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
1066 sub event_step {
1067         my ($self) = @_;
1068
1069         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
1070
1071         $self->update_idle_time;
1072         # only read more requests if we've drained the write buffer,
1073         # otherwise we can be buffering infinitely w/o backpressure
1074
1075         my $rbuf = $self->{rbuf} // \(my $x = '');
1076         my $line = index($$rbuf, "\n");
1077         while ($line < 0) {
1078                 return $self->close if length($$rbuf) >= LINE_MAX;
1079                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
1080                 $line = index($$rbuf, "\n");
1081         }
1082         $line = substr($$rbuf, 0, $line + 1, '');
1083         $line =~ s/\r?\n\z//s;
1084         return $self->close if $line =~ /[[:cntrl:]]/s;
1085
1086         my $t0 = now();
1087         my $fd = fileno($self->{sock});
1088         my $r = eval { process_line($self, $line) };
1089         my $pending = $self->{wbuf} ? ' pending' : '';
1090         out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
1091         return $self->close if $r < 0;
1092         $self->rbuf_idle($rbuf);
1093         $self->update_idle_time;
1094
1095         # maybe there's more pipelined data, or we'll have
1096         # to register it for socket-readiness notifications
1097         $self->requeue unless $pending;
1098 }
1099
1100 # for graceful shutdown in PublicInbox::Daemon:
1101 sub busy {
1102         my ($self, $now) = @_;
1103         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1104 }
1105
1106 1;