lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 PublicInbox::DS->import(qw(now msg_more));
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26 };
  27 use PublicInbox::Syscall qw(EPOLLOUT EPOLLONESHOT);
  28 use Errno qw(EAGAIN);
  29
  30 my @OVERVIEW = qw(Subject From Date Message-ID References Xref);
  31 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  32 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  33                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  34
  35 # disable commands with easy DoS potential:
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $expt;
  40 our $EXPTIME = 180; # 3 minutes
  41 my $nextt;
  42
  43 my $nextq = [];
  44 sub next_tick () {
  45         $nextt = undef;
  46         my $q = $nextq;
  47         $nextq = [];
  48         foreach my $nntp (@$q) {
  49                 # for request && response protocols, always finish writing
  50                 # before finishing reading:
  51                 if (my $long_cb = $nntp->{long_res}) {
  52                         $nntp->write($long_cb);
  53                 } else {
  54                         # pipelined request, we bypassed socket-readiness
  55                         # checks to get here:
  56                         event_step($nntp);
  57                 }
  58         }
  59 }
  60
  61 sub requeue ($) {
  62         push @$nextq, $_[0];
  63         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
  64 }
  65
  66 sub update_idle_time ($) {
  67         my ($self) = @_;
  68         my $sock = $self->{sock} or return;
  69         $EXPMAP->{fileno($sock)} = [ now(), $self ];
  70 }
  71
  72 sub expire_old () {
  73         my $now = now();
  74         my $exp = $EXPTIME;
  75         my $old = $now - $exp;
  76         my $nr = 0;
  77         my %new;
  78         while (my ($fd, $v) = each %$EXPMAP) {
  79                 my ($idle_time, $nntp) = @$v;
  80                 if ($idle_time < $old) {
  81                         $nntp->close; # idempotent
  82                 } else {
  83                         ++$nr;
  84                         $new{$fd} = $v;
  85                 }
  86         }
  87         $EXPMAP = \%new;
  88         if ($nr) {
  89                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  90         } else {
  91                 $expt = undef;
  92                 # noop to kick outselves out of the loop ASAP so descriptors
  93                 # really get closed
  94                 PublicInbox::EvCleanup::asap(sub {});
  95         }
  96 }
  97
  98 sub new ($$$) {
  99         my ($class, $sock, $nntpd) = @_;
 100         my $self = fields::new($class);
 101         $self->SUPER::new($sock, EPOLLOUT | EPOLLONESHOT);
 102         $self->{nntpd} = $nntpd;
 103         my $greet = "201 $nntpd->{servername} ready - post via email\r\n";
 104         open my $fh, '<:scalar',  \$greet or die "open :scalar: $!";
 105         $self->{wbuf} = [ $fh ];
 106         $self->{rbuf} = '';
 107         update_idle_time($self);
 108         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 109         $self;
 110 }
 111
 112 sub args_ok ($$) {
 113         my ($cb, $argc) = @_;
 114         my $tot = prototype $cb;
 115         my ($nreq, undef) = split(';', $tot);
 116         $nreq = ($nreq =~ tr/$//) - 1;
 117         $tot = ($tot =~ tr/$//) - 1;
 118         ($argc <= $tot && $argc >= $nreq);
 119 }
 120
 121 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 122 sub process_line ($$) {
 123         my ($self, $l) = @_;
 124         my ($req, @args) = split(/[ \t]/, $l);
 125         return 1 unless defined($req); # skip blank line
 126         $req = lc($req);
 127         $req = eval {
 128                 no strict 'refs';
 129                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 130         };
 131         return res($self, '500 command not recognized') unless $req;
 132         return res($self, r501) unless args_ok($req, scalar @args);
 133
 134         my $res = eval { $req->($self, @args) };
 135         my $err = $@;
 136         if ($err && $self->{sock}) {
 137                 local $/ = "\n";
 138                 chomp($l);
 139                 err($self, 'error from: %s (%s)', $l, $err);
 140                 $res = '503 program fault - command not performed';
 141         }
 142         return 0 unless defined $res;
 143         res($self, $res);
 144 }
 145
 146 sub cmd_mode ($$) {
 147         my ($self, $arg) = @_;
 148         $arg = uc $arg;
 149         return r501 unless $arg eq 'READER';
 150         '201 Posting prohibited';
 151 }
 152
 153 sub cmd_slave ($) { '202 slave status noted' }
 154
 155 sub cmd_xgtitle ($;$) {
 156         my ($self, $wildmat) = @_;
 157         more($self, '282 list of groups and descriptions follows');
 158         list_newsgroups($self, $wildmat);
 159         '.'
 160 }
 161
 162 sub list_overview_fmt ($) {
 163         my ($self) = @_;
 164         msg_more($self, $OVERVIEW_FMT);
 165 }
 166
 167 sub list_headers ($;$) {
 168         my ($self) = @_;
 169         msg_more($self, $LIST_HEADERS);
 170 }
 171
 172 sub list_active ($;$) {
 173         my ($self, $wildmat) = @_;
 174         wildmat2re($wildmat);
 175         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 176                 $ng->{newsgroup} =~ $wildmat or next;
 177                 group_line($self, $ng);
 178         }
 179 }
 180
 181 sub list_active_times ($;$) {
 182         my ($self, $wildmat) = @_;
 183         wildmat2re($wildmat);
 184         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 185                 $ng->{newsgroup} =~ $wildmat or next;
 186                 my $c = eval { $ng->mm->created_at } || time;
 187                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 188         }
 189 }
 190
 191 sub list_newsgroups ($;$) {
 192         my ($self, $wildmat) = @_;
 193         wildmat2re($wildmat);
 194         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 195                 $ng->{newsgroup} =~ $wildmat or next;
 196                 my $d = $ng->description;
 197                 more($self, "$ng->{newsgroup} $d");
 198         }
 199 }
 200
 201 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 202 sub cmd_list ($;$$) {
 203         my ($self, @args) = @_;
 204         if (scalar @args) {
 205                 my $arg = shift @args;
 206                 $arg =~ tr/A-Z./a-z_/;
 207                 $arg = "list_$arg";
 208                 return r501 if $DISABLED{$arg};
 209
 210                 $arg = eval {
 211                         no strict 'refs';
 212                         *{$arg}{CODE};
 213                 };
 214                 return r501 unless $arg && args_ok($arg, scalar @args);
 215                 more($self, '215 information follows');
 216                 $arg->($self, @args);
 217         } else {
 218                 more($self, '215 list of newsgroups follows');
 219                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 220                         group_line($self, $ng);
 221                 }
 222         }
 223         '.'
 224 }
 225
 226 sub cmd_listgroup ($;$) {
 227         my ($self, $group) = @_;
 228         if (defined $group) {
 229                 my $res = cmd_group($self, $group);
 230                 return $res if ($res !~ /\A211 /);
 231                 more($self, $res);
 232         }
 233
 234         $self->{ng} or return '412 no newsgroup selected';
 235         my $n = 0;
 236         long_response($self, sub {
 237                 my $ary = $self->{ng}->mm->ids_after(\$n);
 238                 scalar @$ary or return;
 239                 more($self, join("\r\n", @$ary));
 240                 1;
 241         });
 242 }
 243
 244 sub parse_time ($$;$) {
 245         my ($date, $time, $gmt) = @_;
 246         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 247         if (defined $gmt) {
 248                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 249                 $gmt = 1;
 250         }
 251         my @now = $gmt ? gmtime : localtime;
 252         my ($YYYY, $MM, $DD);
 253         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 254                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 255         } else { # legacy clients send YYMMDD
 256                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 257                 my $cur_year = $now[5] + 1900;
 258                 if ($YYYY > $cur_year) {
 259                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 260                 }
 261         }
 262         if ($gmt) {
 263                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 264         } else {
 265                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 266         }
 267 }
 268
 269 sub group_line ($$) {
 270         my ($self, $ng) = @_;
 271         my ($min, $max) = $ng->mm->minmax;
 272         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 273 }
 274
 275 sub cmd_newgroups ($$$;$$) {
 276         my ($self, $date, $time, $gmt, $dists) = @_;
 277         my $ts = eval { parse_time($date, $time, $gmt) };
 278         return r501 if $@;
 279
 280         # TODO dists
 281         more($self, '231 list of new newsgroups follows');
 282         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 283                 my $c = eval { $ng->mm->created_at } || 0;
 284                 next unless $c > $ts;
 285                 group_line($self, $ng);
 286         }
 287         '.'
 288 }
 289
 290 sub wildmat2re (;$) {
 291         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 292         my %keep;
 293         my $salt = rand;
 294         my $tmp = $_[0];
 295
 296         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 297                 my $orig = $1;
 298                 my $key = sha1_hex($orig . $salt);
 299                 $orig =~ s/([^\w\-])+/\Q$1/g;
 300                 $keep{$key} = $orig;
 301                 $key
 302                 #gex;
 303         my %map = ('*' => '.*', '?' => '.' );
 304         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 305         if (scalar %keep) {
 306                 $tmp =~ s#([a-f0-9]{40})#
 307                         my $orig = $keep{$1};
 308                         defined $orig ? $orig : $1;
 309                         #ge;
 310         }
 311         $_[0] = qr/\A$tmp\z/;
 312 }
 313
 314 sub ngpat2re (;$) {
 315         return $_[0] = qr/\A\z/ unless defined $_[0];
 316         my %map = ('*' => '.*', ',' => '|');
 317         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 318         $_[0] = qr/\A(?:$_[0])\z/;
 319 }
 320
 321 sub cmd_newnews ($$$$;$$) {
 322         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 323         my $ts = eval { parse_time($date, $time, $gmt) };
 324         return r501 if $@;
 325         more($self, '230 list of new articles by message-id follows');
 326         my ($keep, $skip) = split('!', $newsgroups, 2);
 327         ngpat2re($keep);
 328         ngpat2re($skip);
 329         my @over;
 330         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 331                 $ng->{newsgroup} =~ $keep or next;
 332                 $ng->{newsgroup} =~ $skip and next;
 333                 my $over = $ng->over or next;
 334                 push @over, $over;
 335         };
 336         return '.' unless @over;
 337
 338         my $prev = 0;
 339         long_response($self, sub {
 340                 my $over = $over[0];
 341                 my $msgs = $over->query_ts($ts, $prev);
 342                 if (scalar @$msgs) {
 343                         more($self, '<' .
 344                                 join(">\r\n<", map { $_->mid } @$msgs ).
 345                                 '>');
 346                         $prev = $msgs->[-1]->{num};
 347                 } else {
 348                         shift @over;
 349                         if (@over) { # continue onto next newsgroup
 350                                 $prev = 0;
 351                                 return 1;
 352                         } else { # break out of the long response.
 353                                 return;
 354                         }
 355                 }
 356         });
 357 }
 358
 359 sub cmd_group ($$) {
 360         my ($self, $group) = @_;
 361         my $no_such = '411 no such news group';
 362         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 363
 364         $self->{ng} = $ng;
 365         my ($min, $max) = $ng->mm->minmax;
 366         $min ||= 0;
 367         $max ||= 0;
 368         $self->{article} = $min;
 369         my $est_size = $max - $min;
 370         "211 $est_size $min $max $group";
 371 }
 372
 373 sub article_adj ($$) {
 374         my ($self, $off) = @_;
 375         my $ng = $self->{ng} or return '412 no newsgroup selected';
 376
 377         my $n = $self->{article};
 378         defined $n or return '420 no current article has been selected';
 379
 380         $n += $off;
 381         my $mid = $ng->mm->mid_for($n);
 382         unless ($mid) {
 383                 $n = $off > 0 ? 'next' : 'previous';
 384                 return "421 no $n article in this group";
 385         }
 386         $self->{article} = $n;
 387         "223 $n <$mid> article retrieved - request text separately";
 388 }
 389
 390 sub cmd_next ($) { article_adj($_[0], 1) }
 391 sub cmd_last ($) { article_adj($_[0], -1) }
 392
 393 # We want to encourage using email and CC-ing everybody involved to avoid
 394 # the single-point-of-failure a single server provides.
 395 sub cmd_post ($) {
 396         my ($self) = @_;
 397         my $ng = $self->{ng};
 398         $ng ? "440 mailto:$ng->{-primary_address} to post"
 399                 : '440 posting not allowed'
 400 }
 401
 402 sub cmd_quit ($) {
 403         my ($self) = @_;
 404         res($self, '205 closing connection - goodbye!');
 405         $self->close;
 406         undef;
 407 }
 408
 409 sub header_append ($$$) {
 410         my ($hdr, $k, $v) = @_;
 411         my @v = $hdr->header($k);
 412         foreach (@v) {
 413                 return if $v eq $_;
 414         }
 415         $hdr->header_set($k, @v, $v);
 416 }
 417
 418 sub xref ($$$$) {
 419         my ($self, $ng, $n, $mid) = @_;
 420         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 421
 422         # num_for is pretty cheap and sometimes we'll lookup the existence
 423         # of an article without getting even the OVER info.  In other words,
 424         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 425         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 426         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 427                 next if $ng eq $other;
 428                 my $num = eval { $other->mm->num_for($mid) } or next;
 429                 $ret .= " $other->{newsgroup}:$num";
 430         }
 431         $ret;
 432 }
 433
 434 sub set_nntp_headers ($$$$$) {
 435         my ($self, $hdr, $ng, $n, $mid) = @_;
 436
 437         # why? leafnode requires a Path: header for some inexplicable
 438         # reason.  We'll fake the shortest one possible.
 439         $hdr->header_set('Path', 'y');
 440
 441         # leafnode (and maybe other NNTP clients) have trouble dealing
 442         # with v2 messages which have multiple Message-IDs (either due
 443         # to our own content-based dedupe or buggy git-send-email versions).
 444         my @mids = $hdr->header('Message-ID');
 445         if (scalar(@mids) > 1) {
 446                 my $mid0 = "<$mid>";
 447                 $hdr->header_set('Message-ID', $mid0);
 448                 my @alt = $hdr->header('X-Alt-Message-ID');
 449                 my %seen = map { $_ => 1 } (@alt, $mid0);
 450                 foreach my $m (@mids) {
 451                         next if $seen{$m}++;
 452                         push @alt, $m;
 453                 }
 454                 $hdr->header_set('X-Alt-Message-ID', @alt);
 455         }
 456
 457         # clobber some
 458         my $xref = xref($self, $ng, $n, $mid);
 459         $hdr->header_set('Xref', $xref);
 460         $xref =~ s/:[0-9]+//g;
 461         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 462         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 463         if (my $url = $ng->base_url) {
 464                 $mid = mid_escape($mid);
 465                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 466                 header_append($hdr, 'List-Archive', "<$url>");
 467         }
 468 }
 469
 470 sub art_lookup ($$$) {
 471         my ($self, $art, $set_headers) = @_;
 472         my $ng = $self->{ng};
 473         my ($n, $mid);
 474         my $err;
 475         if (defined $art) {
 476                 if ($art =~ /\A[0-9]+\z/) {
 477                         $err = '423 no such article number in this group';
 478                         $n = int($art);
 479                         goto find_mid;
 480                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 481                         $mid = $1;
 482                         $err = r430;
 483                         $n = $ng->mm->num_for($mid) if $ng;
 484                         goto found if defined $n;
 485                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 486                                 $n = $g->mm->num_for($mid);
 487                                 if (defined $n) {
 488                                         $ng = $g;
 489                                         goto found;
 490                                 }
 491                         }
 492                         return $err;
 493                 } else {
 494                         return r501;
 495                 }
 496         } else {
 497                 $err = '420 no current article has been selected';
 498                 $n = $self->{article};
 499                 defined $n or return $err;
 500 find_mid:
 501                 $ng or return '412 no newsgroup has been selected';
 502                 $mid = $ng->mm->mid_for($n);
 503                 defined $mid or return $err;
 504         }
 505 found:
 506         my $smsg = $ng->over->get_art($n) or return $err;
 507         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 508         my $s = Email::Simple->new($msg);
 509         if ($set_headers) {
 510                 set_nntp_headers($self, $s->header_obj, $ng, $n, $mid);
 511
 512                 # must be last
 513                 $s->body_set('') if ($set_headers == 2);
 514         }
 515         [ $n, $mid, $s, $smsg->bytes, $smsg->lines, $ng ];
 516 }
 517
 518 sub simple_body_write ($$) {
 519         my ($self, $s) = @_;
 520         my $body = $s->body;
 521         $s->body_set('');
 522         $body =~ s/^\./../smg;
 523         $body =~ s/(?<!\r)\n/\r\n/sg;
 524         msg_more($self, $body);
 525         msg_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 526         '.'
 527 }
 528
 529 sub set_art {
 530         my ($self, $art) = @_;
 531         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 532 }
 533
 534 sub _header ($) {
 535         my $hdr = $_[0]->header_obj->as_string;
 536         utf8::encode($hdr);
 537         $hdr =~ s/(?<!\r)\n/\r\n/sg;
 538
 539         # for leafnode compatibility, we need to ensure Message-ID headers
 540         # are only a single line.  We can't subclass Email::Simple::Header
 541         # and override _default_fold_at in here, either; since that won't
 542         # affect messages already in the archive.
 543         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 544
 545         $hdr
 546 }
 547
 548 sub cmd_article ($;$) {
 549         my ($self, $art) = @_;
 550         my $r = art_lookup($self, $art, 1);
 551         return $r unless ref $r;
 552         my ($n, $mid, $s) = @$r;
 553         set_art($self, $art);
 554         more($self, "220 $n <$mid> article retrieved - head and body follow");
 555         msg_more($self, _header($s));
 556         msg_more($self, "\r\n");
 557         simple_body_write($self, $s);
 558 }
 559
 560 sub cmd_head ($;$) {
 561         my ($self, $art) = @_;
 562         my $r = art_lookup($self, $art, 2);
 563         return $r unless ref $r;
 564         my ($n, $mid, $s) = @$r;
 565         set_art($self, $art);
 566         more($self, "221 $n <$mid> article retrieved - head follows");
 567         msg_more($self, _header($s));
 568         '.'
 569 }
 570
 571 sub cmd_body ($;$) {
 572         my ($self, $art) = @_;
 573         my $r = art_lookup($self, $art, 0);
 574         return $r unless ref $r;
 575         my ($n, $mid, $s) = @$r;
 576         set_art($self, $art);
 577         more($self, "222 $n <$mid> article retrieved - body follows");
 578         simple_body_write($self, $s);
 579 }
 580
 581 sub cmd_stat ($;$) {
 582         my ($self, $art) = @_;
 583         my $r = art_lookup($self, $art, 0);
 584         return $r unless ref $r;
 585         my ($n, $mid, undef) = @$r;
 586         set_art($self, $art);
 587         "223 $n <$mid> article retrieved - request text separately";
 588 }
 589
 590 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 591
 592 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 593
 594 sub cmd_help ($) {
 595         my ($self) = @_;
 596         more($self, '100 help text follows');
 597         '.'
 598 }
 599
 600 sub get_range ($$) {
 601         my ($self, $range) = @_;
 602         my $ng = $self->{ng} or return '412 no news group has been selected';
 603         defined $range or return '420 No article(s) selected';
 604         my ($beg, $end);
 605         my ($min, $max) = $ng->mm->minmax;
 606         if ($range =~ /\A([0-9]+)\z/) {
 607                 $beg = $end = $1;
 608         } elsif ($range =~ /\A([0-9]+)-\z/) {
 609                 ($beg, $end) = ($1, $max);
 610         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 611                 ($beg, $end) = ($1, $2);
 612         } else {
 613                 return r501;
 614         }
 615         $beg = $min if ($beg < $min);
 616         $end = $max if ($end > $max);
 617         return '420 No article(s) selected' if ($beg > $end);
 618         [ $beg, $end ];
 619 }
 620
 621 sub long_response ($$) {
 622         my ($self, $cb) = @_;
 623         die "BUG: nested long response" if $self->{long_res};
 624
 625         my $fd = fileno($self->{sock});
 626         defined $fd or return;
 627         # make sure we disable reading during a long response,
 628         # clients should not be sending us stuff and making us do more
 629         # work while we are stream a response to them
 630         my $t0 = now();
 631         $self->{long_res} = sub {
 632                 my $more = eval { $cb->() };
 633                 if ($@ || !$self->{sock}) { # something bad happened...
 634                         delete $self->{long_res};
 635
 636                         if ($@) {
 637                                 err($self,
 638                                     "%s during long response[$fd] - %0.6f",
 639                                     $@, now() - $t0);
 640                         }
 641                         if ($self->{sock}) {
 642                                 update_idle_time($self);
 643                                 requeue($self);
 644                         } else {
 645                                 out($self, " deferred[$fd] aborted - %0.6f",
 646                                            now() - $t0);
 647                         }
 648                 } elsif ($more) { # $self->{wbuf}:
 649                         # no recursion, schedule another call ASAP
 650                         # but only after all pending writes are done
 651                         update_idle_time($self);
 652                         requeue($self);
 653                 } else { # all done!
 654                         delete $self->{long_res};
 655                         res($self, '.');
 656                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 657                         requeue($self);
 658                 }
 659         };
 660         $self->{long_res}->(); # kick off!
 661         undef;
 662 }
 663
 664 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 665         my ($self, $xhdr, $range) = @_;
 666
 667         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 668                 my ($ng, $n) = mid_lookup($self, $1);
 669                 return r430 unless $n;
 670                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 671         } else { # numeric range
 672                 $range = $self->{article} unless defined $range;
 673                 my $r = get_range($self, $range);
 674                 return $r unless ref $r;
 675                 my $mm = $self->{ng}->mm;
 676                 my ($beg, $end) = @$r;
 677                 more($self, $xhdr ? r221 : r225);
 678                 long_response($self, sub {
 679                         my $r = $mm->msg_range(\$beg, $end);
 680                         @$r or return;
 681                         more($self, join("\r\n", map {
 682                                 "$_->[0] <$_->[1]>"
 683                         } @$r));
 684                         1;
 685                 });
 686         }
 687 }
 688
 689 sub mid_lookup ($$) {
 690         my ($self, $mid) = @_;
 691         my $self_ng = $self->{ng};
 692         if ($self_ng) {
 693                 my $n = $self_ng->mm->num_for($mid);
 694                 return ($self_ng, $n) if defined $n;
 695         }
 696         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 697                 next if defined $self_ng && $ng eq $self_ng;
 698                 my $n = $ng->mm->num_for($mid);
 699                 return ($ng, $n) if defined $n;
 700         }
 701         (undef, undef);
 702 }
 703
 704 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 705         my ($self, $xhdr, $range) = @_;
 706
 707         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 708                 my $mid = $1;
 709                 my ($ng, $n) = mid_lookup($self, $mid);
 710                 return r430 unless $n;
 711                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 712                                 xref($self, $ng, $n, $mid));
 713         } else { # numeric range
 714                 $range = $self->{article} unless defined $range;
 715                 my $r = get_range($self, $range);
 716                 return $r unless ref $r;
 717                 my $ng = $self->{ng};
 718                 my $mm = $ng->mm;
 719                 my ($beg, $end) = @$r;
 720                 more($self, $xhdr ? r221 : r225);
 721                 long_response($self, sub {
 722                         my $r = $mm->msg_range(\$beg, $end);
 723                         @$r or return;
 724                         more($self, join("\r\n", map {
 725                                 my $num = $_->[0];
 726                                 "$num ".xref($self, $ng, $num, $_->[1]);
 727                         } @$r));
 728                         1;
 729                 });
 730         }
 731 }
 732
 733 sub over_header_for {
 734         my ($over, $num, $field) = @_;
 735         my $smsg = $over->get_art($num) or return;
 736         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 737         $smsg->{$field};
 738 }
 739
 740 sub hdr_searchmsg ($$$$) {
 741         my ($self, $xhdr, $field, $range) = @_;
 742         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 743                 my ($ng, $n) = mid_lookup($self, $1);
 744                 return r430 unless defined $n;
 745                 my $v = over_header_for($ng->over, $n, $field);
 746                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 747         } else { # numeric range
 748                 $range = $self->{article} unless defined $range;
 749                 my $over = $self->{ng}->over;
 750                 my $mm = $self->{ng}->mm;
 751                 my $r = get_range($self, $range);
 752                 return $r unless ref $r;
 753                 my ($beg, $end) = @$r;
 754                 more($self, $xhdr ? r221 : r225);
 755                 my $cur = $beg;
 756                 long_response($self, sub {
 757                         my $msgs = $over->query_xover($cur, $end);
 758                         my $nr = scalar @$msgs or return;
 759                         my $tmp = '';
 760                         foreach my $s (@$msgs) {
 761                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 762                         }
 763                         utf8::encode($tmp);
 764                         msg_more($self, $tmp);
 765                         $cur = $msgs->[-1]->{num} + 1;
 766                 });
 767         }
 768 }
 769
 770 sub do_hdr ($$$;$) {
 771         my ($self, $xhdr, $header, $range) = @_;
 772         my $sub = lc $header;
 773         if ($sub eq 'message-id') {
 774                 hdr_message_id($self, $xhdr, $range);
 775         } elsif ($sub eq 'xref') {
 776                 hdr_xref($self, $xhdr, $range);
 777         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 778                                 bytes|lines)\z/x) {
 779                 hdr_searchmsg($self, $xhdr, $sub, $range);
 780         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 781                 hdr_searchmsg($self, $xhdr, $1, $range);
 782         } else {
 783                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 784         }
 785 }
 786
 787 # RFC 3977
 788 sub cmd_hdr ($$;$) {
 789         my ($self, $header, $range) = @_;
 790         do_hdr($self, 0, $header, $range);
 791 }
 792
 793 # RFC 2980
 794 sub cmd_xhdr ($$;$) {
 795         my ($self, $header, $range) = @_;
 796         do_hdr($self, 1, $header, $range);
 797 }
 798
 799 sub hdr_mid_prefix ($$$$$) {
 800         my ($self, $xhdr, $ng, $n, $mid) = @_;
 801         return $mid if $xhdr;
 802
 803         # HDR for RFC 3977 users
 804         if (my $self_ng = $self->{ng}) {
 805                 ($self_ng eq $ng) ? $n : '0';
 806         } else {
 807                 '0';
 808         }
 809 }
 810
 811 sub hdr_mid_response ($$$$$$) {
 812         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 813         my $res = '';
 814         if ($xhdr) {
 815                 $res .= r221 . "\r\n";
 816                 $res .= "$mid $v\r\n";
 817         } else {
 818                 $res .= r225 . "\r\n";
 819                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 820                 $res .= "$pfx $v\r\n";
 821         }
 822         res($self, $res .= '.');
 823         undef;
 824 }
 825
 826 sub cmd_xrover ($;$) {
 827         my ($self, $range) = @_;
 828         my $ng = $self->{ng} or return '412 no newsgroup selected';
 829         (defined $range && $range =~ /[<>]/) and
 830                 return '420 No article(s) selected'; # no message IDs
 831
 832         $range = $self->{article} unless defined $range;
 833         my $r = get_range($self, $range);
 834         return $r unless ref $r;
 835         my ($beg, $end) = @$r;
 836         my $mm = $ng->mm;
 837         my $over = $ng->over;
 838         more($self, '224 Overview information follows');
 839
 840         long_response($self, sub {
 841                 my $h = over_header_for($over, $beg, 'references');
 842                 more($self, "$beg $h") if defined($h);
 843                 $beg++ < $end;
 844         });
 845 }
 846
 847 sub over_line ($$$$) {
 848         my ($self, $ng, $num, $smsg) = @_;
 849         # n.b. field access and procedural calls can be
 850         # 10%-15% faster than OO method calls:
 851         my $s = join("\t", $num,
 852                 $smsg->{subject},
 853                 $smsg->{from},
 854                 PublicInbox::SearchMsg::date($smsg),
 855                 "<$smsg->{mid}>",
 856                 $smsg->{references},
 857                 $smsg->{bytes},
 858                 $smsg->{lines},
 859                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 860         utf8::encode($s);
 861         $s
 862 }
 863
 864 sub cmd_over ($;$) {
 865         my ($self, $range) = @_;
 866         if ($range && $range =~ /\A<(.+)>\z/) {
 867                 my ($ng, $n) = mid_lookup($self, $1);
 868                 defined $n or return r430;
 869                 my $smsg = $ng->over->get_art($n) or return r430;
 870                 more($self, '224 Overview information follows (multi-line)');
 871
 872                 # Only set article number column if it's the current group
 873                 my $self_ng = $self->{ng};
 874                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 875                 more($self, over_line($self, $ng, $n, $smsg));
 876                 '.';
 877         } else {
 878                 cmd_xover($self, $range);
 879         }
 880 }
 881
 882 sub cmd_xover ($;$) {
 883         my ($self, $range) = @_;
 884         $range = $self->{article} unless defined $range;
 885         my $r = get_range($self, $range);
 886         return $r unless ref $r;
 887         my ($beg, $end) = @$r;
 888         more($self, "224 Overview information follows for $beg to $end");
 889         my $over = $self->{ng}->over;
 890         my $cur = $beg;
 891         long_response($self, sub {
 892                 my $msgs = $over->query_xover($cur, $end);
 893                 my $nr = scalar @$msgs or return;
 894
 895                 # OVERVIEW.FMT
 896                 more($self, join("\r\n", map {
 897                         over_line($self, $self->{ng}, $_->{num}, $_);
 898                         } @$msgs));
 899                 $cur = $msgs->[-1]->{num} + 1;
 900         });
 901 }
 902
 903 sub cmd_xpath ($$) {
 904         my ($self, $mid) = @_;
 905         return r501 unless $mid =~ /\A<(.+)>\z/;
 906         $mid = $1;
 907         my @paths;
 908         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 909                 my $n = $ng->mm->num_for($mid);
 910                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 911         }
 912         return '430 no such article on server' unless @paths;
 913         '223 '.join(' ', @paths);
 914 }
 915
 916 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 917
 918 sub more ($$) { msg_more($_[0], $_[1] . "\r\n") }
 919
 920 sub do_write ($$) {
 921         my $self = $_[0];
 922         my $done = $self->write(\($_[1]));
 923         return 0 unless $self->{sock};
 924
 925         $done;
 926 }
 927
 928 sub err ($$;@) {
 929         my ($self, $fmt, @args) = @_;
 930         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 931 }
 932
 933 sub out ($$;@) {
 934         my ($self, $fmt, @args) = @_;
 935         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 936 }
 937
 938 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 939 sub event_step {
 940         my ($self) = @_;
 941
 942         return unless $self->flush_write && $self->{sock};
 943
 944         update_idle_time($self);
 945         # only read more requests if we've drained the write buffer,
 946         # otherwise we can be buffering infinitely w/o backpressure
 947
 948         use constant LINE_MAX => 512; # RFC 977 section 2.3
 949         my $rbuf = \($self->{rbuf});
 950         my $r = 1;
 951
 952         if (index($$rbuf, "\n") < 0) {
 953                 my $off = bytes::length($$rbuf);
 954                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 955         }
 956         while ($r > 0 && $$rbuf =~ s/\A[ \t\r\n]*([^\r\n]*)\r?\n//) {
 957                 my $line = $1;
 958                 return $self->close if $line =~ /[[:cntrl:]]/s;
 959                 my $t0 = now();
 960                 my $fd = fileno($self->{sock});
 961                 $r = eval { process_line($self, $line) };
 962                 my $d = $self->{long_res} ?
 963                         " deferred[$fd]" : '';
 964                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 965         }
 966
 967         return $self->close if $r < 0;
 968         my $len = bytes::length($$rbuf);
 969         return $self->close if ($len >= LINE_MAX);
 970         update_idle_time($self);
 971
 972         # maybe there's more pipelined data, or we'll have
 973         # to register it for socket-readiness notifications
 974         requeue($self) unless ($self->{long_res} || $self->{wbuf});
 975 }
 976
 977 sub not_idle_long ($$) {
 978         my ($self, $now) = @_;
 979         my $sock = $self->{sock} or return;
 980         my $ary = $EXPMAP->{fileno($sock)} or return;
 981         my $exp_at = $ary->[0] + $EXPTIME;
 982         $exp_at > $now;
 983 }
 984
 985 # for graceful shutdown in PublicInbox::Daemon:
 986 sub busy {
 987         my ($self, $now) = @_;
 988         ($self->{rbuf} ne '' || $self->{long_res} ||
 989                 $self->{wbuf} || not_idle_long($self, $now));
 990 }
 991
 992 1;