lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 # fields:
   6 # nntpd: PublicInbox::NNTPD ref
   7 # article: per-session current article number
   8 # ng: PublicInbox::Inbox ref
   9 # long_cb: long_response private data
  10 package PublicInbox::NNTP;
  11 use strict;
  12 use parent qw(PublicInbox::DS);
  13 use PublicInbox::MID qw(mid_escape $MID_EXTRACT);
  14 use PublicInbox::Eml;
  15 use POSIX qw(strftime);
  16 use PublicInbox::DS qw(now);
  17 use Digest::SHA qw(sha1_hex);
  18 use Time::Local qw(timegm timelocal);
  19 use PublicInbox::GitAsyncCat;
  20 use constant {
  21         LINE_MAX => 512, # RFC 977 section 2.3
  22         r501 => '501 command syntax error',
  23         r502 => '502 Command unavailable',
  24         r221 => '221 Header follows',
  25         r224 => '224 Overview information follows (multi-line)',
  26         r225 => '225 Headers follow (multi-line)',
  27         r430 => '430 No article with that message-id',
  28 };
  29 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  30 use Errno qw(EAGAIN);
  31 my $ONE_MSGID = qr/\A$MID_EXTRACT\z/;
  32 my @OVERVIEW = qw(Subject From Date Message-ID References);
  33 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  34                 "Xref:full\r\n.";
  35 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  36                         qw(:bytes :lines Xref To Cc)) . "\r\n.";
  37 my $CAPABILITIES = <<"";
  38 101 Capability list:\r
  39 VERSION 2\r
  40 READER\r
  41 NEWNEWS\r
  42 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  43 HDR\r
  44 OVER\r
  45 COMPRESS DEFLATE\r
  46
  47 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  48
  49 sub new ($$$) {
  50         my ($class, $sock, $nntpd) = @_;
  51         my $self = bless { nntpd => $nntpd }, $class;
  52         my $ev = EPOLLIN;
  53         my $wbuf;
  54         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
  55                 return CORE::close($sock) if $! != EAGAIN;
  56                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
  57                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  58         }
  59         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  60         if ($wbuf) {
  61                 $self->{wbuf} = $wbuf;
  62         } else {
  63                 greet($self);
  64         }
  65         $self->update_idle_time;
  66         $self;
  67 }
  68
  69 sub args_ok ($$) {
  70         my ($cb, $argc) = @_;
  71         my $tot = prototype $cb;
  72         my ($nreq, undef) = split(';', $tot);
  73         $nreq = ($nreq =~ tr/$//) - 1;
  74         $tot = ($tot =~ tr/$//) - 1;
  75         ($argc <= $tot && $argc >= $nreq);
  76 }
  77
  78 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  79 sub process_line ($$) {
  80         my ($self, $l) = @_;
  81         my ($req, @args) = split(/[ \t]+/, $l);
  82         return 1 unless defined($req); # skip blank line
  83         $req = $self->can('cmd_'.lc($req));
  84         return res($self, '500 command not recognized') unless $req;
  85         return res($self, r501) unless args_ok($req, scalar @args);
  86
  87         my $res = eval { $req->($self, @args) };
  88         my $err = $@;
  89         if ($err && $self->{sock}) {
  90                 local $/ = "\n";
  91                 chomp($l);
  92                 err($self, 'error from: %s (%s)', $l, $err);
  93                 $res = '503 program fault - command not performed';
  94         }
  95         defined($res) ? res($self, $res) : 0;
  96 }
  97
  98 # The keyword argument is not used (rfc3977 5.2.2)
  99 sub cmd_capabilities ($;$) {
 100         my ($self, undef) = @_;
 101         my $res = $CAPABILITIES;
 102         if (!$self->{sock}->can('accept_SSL') &&
 103                         $self->{nntpd}->{accept_tls}) {
 104                 $res .= "STARTTLS\r\n";
 105         }
 106         $res .= '.';
 107 }
 108
 109 sub cmd_mode ($$) {
 110         my ($self, $arg) = @_;
 111         uc($arg) eq 'READER' ? '201 Posting prohibited' : r501;
 112 }
 113
 114 sub cmd_slave ($) { '202 slave status noted' }
 115
 116 sub cmd_xgtitle ($;$) {
 117         my ($self, $wildmat) = @_;
 118         more($self, '282 list of groups and descriptions follows');
 119         list_newsgroups($self, $wildmat);
 120 }
 121
 122 sub list_overview_fmt ($) { $OVERVIEW_FMT }
 123
 124 sub list_headers ($;$) { $LIST_HEADERS }
 125
 126 sub list_active_i { # "LIST ACTIVE" and also just "LIST" (no args)
 127         my ($self, $groupnames) = @_;
 128         my @window = splice(@$groupnames, 0, 100) or return 0;
 129         my $ibx;
 130         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 131         for my $ngname (@window) {
 132                 $ibx = $groups->{$ngname} and group_line($self, $ibx);
 133         }
 134         scalar(@$groupnames); # continue if there's more
 135 }
 136
 137 sub list_active ($;$) { # called by cmd_list
 138         my ($self, $wildmat) = @_;
 139         wildmat2re($wildmat);
 140         long_response($self, \&list_active_i, [
 141                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 142 }
 143
 144 sub list_active_times_i {
 145         my ($self, $groupnames) = @_;
 146         my @window = splice(@$groupnames, 0, 100) or return 0;
 147         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 148         for my $ngname (@window) {
 149                 my $ibx = $groups->{$ngname} or next;
 150                 my $c = eval { $ibx->uidvalidity } // time;
 151                 more($self, "$ngname $c <$ibx->{-primary_address}>");
 152         }
 153         scalar(@$groupnames); # continue if there's more
 154 }
 155
 156 sub list_active_times ($;$) { # called by cmd_list
 157         my ($self, $wildmat) = @_;
 158         wildmat2re($wildmat);
 159         long_response($self, \&list_active_times_i, [
 160                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 161 }
 162
 163 sub list_newsgroups_i {
 164         my ($self, $groupnames) = @_;
 165         my @window = splice(@$groupnames, 0, 100) or return 0;
 166         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 167         my $ibx;
 168         for my $ngname (@window) {
 169                 $ibx = $groups->{$ngname} and
 170                         more($self, "$ngname ".$ibx->description);
 171         }
 172         scalar(@$groupnames); # continue if there's more
 173 }
 174
 175 sub list_newsgroups ($;$) { # called by cmd_list
 176         my ($self, $wildmat) = @_;
 177         wildmat2re($wildmat);
 178         long_response($self, \&list_newsgroups_i, [
 179                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 180 }
 181
 182 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 183 sub cmd_list ($;$$) {
 184         my ($self, @args) = @_;
 185         if (scalar @args) {
 186                 my $arg = shift @args;
 187                 $arg =~ tr/A-Z./a-z_/;
 188                 my $ret = $arg eq 'active';
 189                 $arg = "list_$arg";
 190                 $arg = $self->can($arg);
 191                 return r501 unless $arg && args_ok($arg, scalar @args);
 192                 more($self, '215 information follows');
 193                 $arg->($self, @args);
 194         } else {
 195                 more($self, '215 list of newsgroups follows');
 196                 long_response($self, \&list_active_i, [ # copy array
 197                         @{$self->{nntpd}->{groupnames}} ]);
 198         }
 199 }
 200
 201 sub listgroup_range_i {
 202         my ($self, $beg, $end) = @_;
 203         my $r = $self->{ng}->mm->msg_range($beg, $end, 'num');
 204         scalar(@$r) or return;
 205         more($self, join("\r\n", map { $_->[0] } @$r));
 206         1;
 207 }
 208
 209 sub listgroup_all_i {
 210         my ($self, $num) = @_;
 211         my $ary = $self->{ng}->mm->ids_after($num);
 212         scalar(@$ary) or return;
 213         more($self, join("\r\n", @$ary));
 214         1;
 215 }
 216
 217 sub cmd_listgroup ($;$$) {
 218         my ($self, $group, $range) = @_;
 219         if (defined $group) {
 220                 my $res = cmd_group($self, $group);
 221                 return $res if ($res !~ /\A211 /);
 222                 more($self, $res);
 223         }
 224         $self->{ng} or return '412 no newsgroup selected';
 225         if (defined $range) {
 226                 my $r = get_range($self, $range);
 227                 return $r unless ref $r;
 228                 long_response($self, \&listgroup_range_i, @$r);
 229         } else { # grab every article number
 230                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 231         }
 232 }
 233
 234 sub parse_time ($$;$) {
 235         my ($date, $time, $gmt) = @_;
 236         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 237         if (defined $gmt) {
 238                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 239                 $gmt = 1;
 240         }
 241         my ($YYYY, $MM, $DD);
 242         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 243                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 244         } else { # legacy clients send YYMMDD
 245                 my $YY;
 246                 ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 247                 my @now = $gmt ? gmtime : localtime;
 248                 my $cur_year = $now[5] + 1900;
 249                 my $cur_cent = int($cur_year / 100) * 100;
 250                 $YYYY = (($YY + $cur_cent) > $cur_year) ?
 251                         ($YY + 1900) : ($YY + $cur_cent);
 252         }
 253         if ($gmt) {
 254                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 255         } else {
 256                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 257         }
 258 }
 259
 260 sub group_line ($$) {
 261         my ($self, $ng) = @_;
 262         my ($min, $max) = $ng->mm->minmax;
 263         more($self, "$ng->{newsgroup} $max $min n");
 264 }
 265
 266 sub newgroups_i {
 267         my ($self, $ts, $i, $groupnames) = @_;
 268         my $end = $$i + 100;
 269         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 270         while ($$i < $end) {
 271                 my $ngname = $groupnames->[$$i++] // return;
 272                 my $ibx = $groups->{$ngname} or next; # expired on reload
 273                 next unless (eval { $ibx->uidvalidity } // 0) > $ts;
 274                 group_line($self, $ibx);
 275         }
 276         1;
 277 }
 278
 279 sub cmd_newgroups ($$$;$$) {
 280         my ($self, $date, $time, $gmt, $dists) = @_;
 281         my $ts = eval { parse_time($date, $time, $gmt) };
 282         return r501 if $@;
 283
 284         # TODO dists
 285         more($self, '231 list of new newsgroups follows');
 286         long_response($self, \&newgroups_i, $ts, \(my $i = 0),
 287                                 $self->{nntpd}->{groupnames});
 288 }
 289
 290 sub wildmat2re (;$) {
 291         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 292         my %keep;
 293         my $salt = rand;
 294         my $tmp = $_[0];
 295
 296         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 297                 my $orig = $1;
 298                 my $key = sha1_hex($orig . $salt);
 299                 $orig =~ s/([^\w\-])+/\Q$1/g;
 300                 $keep{$key} = $orig;
 301                 $key
 302                 #gex;
 303         my %map = ('*' => '.*', '?' => '.' );
 304         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 305         if (scalar %keep) {
 306                 $tmp =~ s#([a-f0-9]{40})#
 307                         my $orig = $keep{$1};
 308                         defined $orig ? $orig : $1;
 309                         #ge;
 310         }
 311         $_[0] = qr/\A$tmp\z/;
 312 }
 313
 314 sub ngpat2re (;$) {
 315         return $_[0] = qr/\A\z/ unless defined $_[0];
 316         my %map = ('*' => '.*', ',' => '|');
 317         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 318         $_[0] = qr/\A(?:$_[0])\z/;
 319 }
 320
 321 sub newnews_i {
 322         my ($self, $names, $ts, $prev) = @_;
 323         my $ngname = $names->[0];
 324         if (my $ibx = $self->{nntpd}->{groups}->{$ngname}) {
 325                 if (my $over = $ibx->over) {
 326                         my $msgs = $over->query_ts($ts, $$prev);
 327                         if (scalar @$msgs) {
 328                                 more($self, '<' .
 329                                         join(">\r\n<",
 330                                                 map { $_->{mid} } @$msgs ) .
 331                                         '>');
 332                                 $$prev = $msgs->[-1]->{num};
 333                                 return 1; # continue on current group
 334                         }
 335                 }
 336         }
 337         shift @$names;
 338         if (@$names) { # continue onto next newsgroup
 339                 $$prev = 0;
 340                 1;
 341         } else { # all done, break out of the long_response
 342                 undef;
 343         }
 344 }
 345
 346 sub cmd_newnews ($$$$;$$) {
 347         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 348         my $ts = eval { parse_time($date, $time, $gmt) };
 349         return r501 if $@;
 350         more($self, '230 list of new articles by message-id follows');
 351         my ($keep, $skip) = split('!', $newsgroups, 2);
 352         ngpat2re($keep);
 353         ngpat2re($skip);
 354         my @names = grep(!/$skip/, grep(/$keep/,
 355                                 @{$self->{nntpd}->{groupnames}}));
 356         return '.' unless scalar(@names);
 357         my $prev = 0;
 358         long_response($self, \&newnews_i, \@names, $ts, \$prev);
 359 }
 360
 361 sub cmd_group ($$) {
 362         my ($self, $group) = @_;
 363         my $no_such = '411 no such news group';
 364         my $nntpd = $self->{nntpd};
 365         my $ng = $nntpd->{groups}->{$group} or return $no_such;
 366         $nntpd->idler_start;
 367
 368         $self->{ng} = $ng;
 369         my ($min, $max) = $ng->mm->minmax;
 370         $self->{article} = $min;
 371         my $est_size = $max - $min;
 372         "211 $est_size $min $max $group";
 373 }
 374
 375 sub article_adj ($$) {
 376         my ($self, $off) = @_;
 377         my $ng = $self->{ng} or return '412 no newsgroup selected';
 378
 379         my $n = $self->{article};
 380         defined $n or return '420 no current article has been selected';
 381
 382         $n += $off;
 383         my $mid = $ng->mm->mid_for($n);
 384         unless ($mid) {
 385                 $n = $off > 0 ? 'next' : 'previous';
 386                 return "421 no $n article in this group";
 387         }
 388         $self->{article} = $n;
 389         "223 $n <$mid> article retrieved - request text separately";
 390 }
 391
 392 sub cmd_next ($) { article_adj($_[0], 1) }
 393 sub cmd_last ($) { article_adj($_[0], -1) }
 394
 395 # We want to encourage using email and CC-ing everybody involved to avoid
 396 # the single-point-of-failure a single server provides.
 397 sub cmd_post ($) {
 398         my ($self) = @_;
 399         my $ng = $self->{ng};
 400         $ng ? "440 mailto:$ng->{-primary_address} to post"
 401                 : '440 posting not allowed'
 402 }
 403
 404 sub cmd_quit ($) {
 405         my ($self) = @_;
 406         res($self, '205 closing connection - goodbye!');
 407         $self->shutdn;
 408         undef;
 409 }
 410
 411 sub header_append ($$$) {
 412         my ($hdr, $k, $v) = @_;
 413         my @v = $hdr->header_raw($k);
 414         foreach (@v) {
 415                 return if $v eq $_;
 416         }
 417         $hdr->header_set($k, @v, $v);
 418 }
 419
 420 sub xref ($$$) {
 421         my ($self, $cur_ibx, $smsg) = @_;
 422         my $nntpd = $self->{nntpd};
 423         my $cur_ngname = $cur_ibx->{newsgroup};
 424         my $ret = "$nntpd->{servername} $cur_ngname:$smsg->{num}";
 425         if (my $ALL = $nntpd->{pi_config}->ALL) {
 426                 if (my $ary = $ALL->nntp_xref_for($cur_ibx, $smsg)) {
 427                         $ret .= join(' ', '', @$ary) if scalar(@$ary);
 428                 }
 429                 # better off wrong than slow if there's thousands of groups,
 430                 # so no fallback to the slow path below:
 431         } else { # slow path
 432                 my $mid = $smsg->{mid};
 433                 my $groups = $nntpd->{pi_config}->{-by_newsgroup};
 434                 for my $xngname (@{$nntpd->{groupnames}}) {
 435                         next if $cur_ngname eq $xngname;
 436                         my $xibx = $groups->{$xngname} or next;
 437                         my $num = eval { $xibx->mm->num_for($mid) } or next;
 438                         $ret .= " $xngname:$num";
 439                 }
 440         }
 441         $ret;
 442 }
 443
 444 sub set_nntp_headers ($$) {
 445         my ($hdr, $smsg) = @_;
 446         my ($mid) = $smsg->{mid};
 447
 448         # leafnode (and maybe other NNTP clients) have trouble dealing
 449         # with v2 messages which have multiple Message-IDs (either due
 450         # to our own content-based dedupe or buggy git-send-email versions).
 451         my @mids = $hdr->header_raw('Message-ID');
 452         if (scalar(@mids) > 1) {
 453                 my $mid0 = "<$mid>";
 454                 $hdr->header_set('Message-ID', $mid0);
 455                 my @alt = $hdr->header_raw('X-Alt-Message-ID');
 456                 my %seen = map { $_ => 1 } (@alt, $mid0);
 457                 push(@alt, grep { !$seen{$_}++ } @mids);
 458                 $hdr->header_set('X-Alt-Message-ID', @alt);
 459         }
 460
 461         # clobber some existing headers
 462         my $ibx = $smsg->{-ibx};
 463         my $xref = xref($smsg->{nntp}, $ibx, $smsg);
 464         $hdr->header_set('Xref', $xref);
 465
 466         # RFC 5536 3.1.4
 467         my ($server_name, $newsgroups) = split(/ /, $xref, 2);
 468         $newsgroups =~ s/:[0-9]+\b//g; # drop NNTP article numbers
 469         $newsgroups =~ tr/ /,/;
 470         $hdr->header_set('Newsgroups', $newsgroups);
 471
 472         # *something* here is required for leafnode, try to follow
 473         # RFC 5536 3.1.5...
 474         $hdr->header_set('Path', $server_name . '!not-for-mail');
 475
 476         header_append($hdr, 'List-Post', "<mailto:$ibx->{-primary_address}>");
 477         if (my $url = $ibx->base_url) {
 478                 $mid = mid_escape($mid);
 479                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 480                 header_append($hdr, 'List-Archive', "<$url>");
 481         }
 482 }
 483
 484 sub art_lookup ($$$) {
 485         my ($self, $art, $code) = @_;
 486         my $ng = $self->{ng};
 487         my ($n, $mid);
 488         my $err;
 489         if (defined $art) {
 490                 if ($art =~ /\A[0-9]+\z/) {
 491                         $err = '423 no such article number in this group';
 492                         $n = int($art);
 493                         goto find_mid;
 494                 } elsif ($art =~ $ONE_MSGID) {
 495                         $mid = $1;
 496                         $err = r430;
 497                         $n = $ng->mm->num_for($mid) if $ng;
 498                         goto found if defined $n;
 499                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 500                                 $n = $g->mm->num_for($mid);
 501                                 if (defined $n) {
 502                                         $ng = $g;
 503                                         goto found;
 504                                 }
 505                         }
 506                         return $err;
 507                 } else {
 508                         return r501;
 509                 }
 510         } else {
 511                 $err = '420 no current article has been selected';
 512                 $n = $self->{article};
 513                 defined $n or return $err;
 514 find_mid:
 515                 $ng or return '412 no newsgroup has been selected';
 516                 $mid = $ng->mm->mid_for($n);
 517                 defined $mid or return $err;
 518         }
 519 found:
 520         my $smsg = $ng->over->get_art($n) or return $err;
 521         $smsg->{-ibx} = $ng;
 522         if ($code == 223) { # STAT
 523                 set_art($self, $n);
 524                 "223 $n <$smsg->{mid}> article retrieved - " .
 525                         "request text separately";
 526         } else { # HEAD | BODY | ARTICLE
 527                 $smsg->{nntp} = $self;
 528                 $smsg->{nntp_code} = $code;
 529                 set_art($self, $art);
 530                 # this dereferences to `undef'
 531                 ${git_async_cat($ng->git, $smsg->{blob}, \&blob_cb, $smsg)};
 532         }
 533 }
 534
 535 sub msg_body_write ($$) {
 536         my ($self, $msg) = @_;
 537
 538         # these can momentarily double the memory consumption :<
 539         $$msg =~ s/^\./../smg;
 540         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 541         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 542         $self->msg_more($$msg);
 543 }
 544
 545 sub set_art {
 546         my ($self, $art) = @_;
 547         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 548 }
 549
 550 sub msg_hdr_write ($$) {
 551         my ($eml, $smsg) = @_;
 552         set_nntp_headers($eml, $smsg);
 553
 554         my $hdr = $eml->{hdr} // \(my $x = '');
 555         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 556         $$hdr =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 557         $$hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 558
 559         # for leafnode compatibility, we need to ensure Message-ID headers
 560         # are only a single line.
 561         $$hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 562         $smsg->{nntp}->msg_more($$hdr);
 563 }
 564
 565 sub blob_cb { # called by git->cat_async via git_async_cat
 566         my ($bref, $oid, $type, $size, $smsg) = @_;
 567         my $self = $smsg->{nntp};
 568         my $code = $smsg->{nntp_code};
 569         if (!defined($oid)) {
 570                 # it's possible to have TOCTOU if an admin runs
 571                 # public-inbox-(edit|purge), just move onto the next message
 572                 warn "E: $smsg->{blob} missing in $smsg->{-ibx}->{inboxdir}\n";
 573                 return $self->requeue;
 574         } elsif ($smsg->{blob} ne $oid) {
 575                 $self->close;
 576                 die "BUG: $smsg->{blob} != $oid";
 577         }
 578         my $r = "$code $smsg->{num} <$smsg->{mid}> article retrieved - ";
 579         my $eml = PublicInbox::Eml->new($bref);
 580         if ($code == 220) {
 581                 more($self, $r .= 'head and body follow');
 582                 msg_hdr_write($eml, $smsg);
 583                 $self->msg_more("\r\n");
 584                 msg_body_write($self, $bref);
 585         } elsif ($code == 221) {
 586                 more($self, $r .= 'head follows');
 587                 msg_hdr_write($eml, $smsg);
 588         } elsif ($code == 222) {
 589                 more($self, $r .= 'body follows');
 590                 msg_body_write($self, $bref);
 591         } else {
 592                 $self->close;
 593                 die "BUG: bad code: $r";
 594         }
 595         $self->write(\".\r\n"); # flushes (includes ->zflush)
 596         $self->requeue;
 597 }
 598
 599 sub cmd_article ($;$) {
 600         my ($self, $art) = @_;
 601         art_lookup($self, $art, 220);
 602 }
 603
 604 sub cmd_head ($;$) {
 605         my ($self, $art) = @_;
 606         art_lookup($self, $art, 221);
 607 }
 608
 609 sub cmd_body ($;$) {
 610         my ($self, $art) = @_;
 611         art_lookup($self, $art, 222);
 612 }
 613
 614 sub cmd_stat ($;$) {
 615         my ($self, $art) = @_;
 616         art_lookup($self, $art, 223); # art may be msgid
 617 }
 618
 619 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 620
 621 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 622
 623 sub cmd_help ($) {
 624         my ($self) = @_;
 625         more($self, '100 help text follows');
 626         '.'
 627 }
 628
 629 sub get_range ($$) {
 630         my ($self, $range) = @_;
 631         my $ng = $self->{ng} or return '412 no news group has been selected';
 632         defined $range or return '420 No article(s) selected';
 633         my ($beg, $end);
 634         my ($min, $max) = $ng->mm->minmax;
 635         if ($range =~ /\A([0-9]+)\z/) {
 636                 $beg = $end = $1;
 637         } elsif ($range =~ /\A([0-9]+)-\z/) {
 638                 ($beg, $end) = ($1, $max);
 639         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 640                 ($beg, $end) = ($1, $2);
 641         } else {
 642                 return r501;
 643         }
 644         $beg = $min if ($beg < $min);
 645         $end = $max if ($end > $max);
 646         return '420 No article(s) selected' if ($beg > $end);
 647         [ \$beg, $end ];
 648 }
 649
 650 sub long_step {
 651         my ($self) = @_;
 652         # wbuf is unset or empty, here; {long} may add to it
 653         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
 654         my $more = eval { $cb->($self, @args) };
 655         if ($@ || !$self->{sock}) { # something bad happened...
 656                 delete $self->{long_cb};
 657                 my $elapsed = now() - $t0;
 658                 if ($@) {
 659                         err($self,
 660                             "%s during long response[$fd] - %0.6f",
 661                             $@, $elapsed);
 662                 }
 663                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 664                 $self->close;
 665         } elsif ($more) { # $self->{wbuf}:
 666                 $self->update_idle_time;
 667
 668                 # COMPRESS users all share the same DEFLATE context.
 669                 # Flush it here to ensure clients don't see
 670                 # each other's data
 671                 $self->zflush;
 672
 673                 # no recursion, schedule another call ASAP, but only after
 674                 # all pending writes are done.  autovivify wbuf:
 675                 my $new_size = push(@{$self->{wbuf}}, \&long_step);
 676
 677                 # wbuf may be populated by $cb, no need to rearm if so:
 678                 $self->requeue if $new_size == 1;
 679         } else { # all done!
 680                 delete $self->{long_cb};
 681                 res($self, '.');
 682                 my $elapsed = now() - $t0;
 683                 my $fd = fileno($self->{sock});
 684                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 685                 my $wbuf = $self->{wbuf}; # do NOT autovivify
 686                 $self->requeue unless $wbuf && @$wbuf;
 687         }
 688 }
 689
 690 sub long_response ($$;@) {
 691         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 692
 693         my $sock = $self->{sock} or return;
 694         # make sure we disable reading during a long response,
 695         # clients should not be sending us stuff and making us do more
 696         # work while we are stream a response to them
 697         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
 698         long_step($self); # kick off!
 699         undef;
 700 }
 701
 702 sub hdr_msgid_range_i {
 703         my ($self, $beg, $end) = @_;
 704         my $r = $self->{ng}->mm->msg_range($beg, $end);
 705         @$r or return;
 706         more($self, join("\r\n", map { "$_->[0] <$_->[1]>" } @$r));
 707         1;
 708 }
 709
 710 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 711         my ($self, $xhdr, $range) = @_;
 712
 713         if (defined $range && $range =~ $ONE_MSGID) {
 714                 my ($ng, $n) = mid_lookup($self, $1);
 715                 return r430 unless $n;
 716                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 717         } else { # numeric range
 718                 $range = $self->{article} unless defined $range;
 719                 my $r = get_range($self, $range);
 720                 return $r unless ref $r;
 721                 more($self, $xhdr ? r221 : r225);
 722                 long_response($self, \&hdr_msgid_range_i, @$r);
 723         }
 724 }
 725
 726 sub mid_lookup ($$) {
 727         my ($self, $mid) = @_;
 728         my $self_ng = $self->{ng};
 729         if ($self_ng) {
 730                 my $n = $self_ng->mm->num_for($mid);
 731                 return ($self_ng, $n) if defined $n;
 732         }
 733         my $pi_cfg = $self->{nntpd}->{pi_config};
 734         if (my $ALL = $pi_cfg->ALL) {
 735                 my ($id, $prev);
 736                 while (my $smsg = $ALL->over->next_by_mid($mid, \$id, \$prev)) {
 737                         my $xr3 = $ALL->over->get_xref3($smsg->{num});
 738                         if (my @x = grep(/:$smsg->{blob}\z/, @$xr3)) {
 739                                 my ($ngname, $xnum) = split(/:/, $x[0]);
 740                                 my $ibx = $pi_cfg->{-by_newsgroup}->{$ngname};
 741                                 return ($ibx, $xnum) if $ibx;
 742                                 # fall through to trying all xref3s
 743                         } else {
 744                                 warn <<EOF;
 745 W: xref3 missing for <$mid> ($smsg->{blob}) in $ALL->{topdir}, -extindex bug?
 746 EOF
 747                         }
 748                         # try all xref3s
 749                         for my $x (@$xr3) {
 750                                 my ($ngname, $xnum) = split(/:/, $x);
 751                                 my $ibx = $pi_cfg->{-by_newsgroup}->{$ngname};
 752                                 return ($ibx, $xnum) if $ibx;
 753                                 warn "W: `$ngname' does not exist for #$xnum\n";
 754                         }
 755                 }
 756                 # no warning here, $mid is just invalid
 757         } else { # slow path for non-ALL users
 758                 foreach my $ibx (values %{$self->{nntpd}->{groups}}) {
 759                         next if defined $self_ng && $ibx eq $self_ng;
 760                         my $n = $ibx->mm->num_for($mid);
 761                         return ($ibx, $n) if defined $n;
 762                 }
 763         }
 764         (undef, undef);
 765 }
 766
 767 sub xref_range_i {
 768         my ($self, $beg, $end) = @_;
 769         my $ng = $self->{ng};
 770         my $msgs = $ng->over->query_xover($$beg, $end);
 771         scalar(@$msgs) or return;
 772         $$beg = $msgs->[-1]->{num} + 1;
 773         more($self, join("\r\n", map {
 774                 "$_->{num} ".xref($self, $ng, $_);
 775         } @$msgs));
 776         1;
 777 }
 778
 779 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 780         my ($self, $xhdr, $range) = @_;
 781
 782         if (defined $range && $range =~ $ONE_MSGID) {
 783                 my $mid = $1;
 784                 my ($ng, $n) = mid_lookup($self, $mid);
 785                 return r430 unless $n;
 786                 my $smsg = $ng->over->get_art($n) or return;
 787                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 788                                 xref($self, $ng, $smsg));
 789         } else { # numeric range
 790                 $range = $self->{article} unless defined $range;
 791                 my $r = get_range($self, $range);
 792                 return $r unless ref $r;
 793                 more($self, $xhdr ? r221 : r225);
 794                 long_response($self, \&xref_range_i, @$r);
 795         }
 796 }
 797
 798 sub over_header_for {
 799         my ($over, $num, $field) = @_;
 800         my $smsg = $over->get_art($num) or return;
 801         return PublicInbox::Smsg::date($smsg) if $field eq 'date';
 802         $smsg->{$field};
 803 }
 804
 805 sub smsg_range_i {
 806         my ($self, $beg, $end, $field) = @_;
 807         my $over = $self->{ng}->over;
 808         my $msgs = $over->query_xover($$beg, $end);
 809         scalar(@$msgs) or return;
 810         my $tmp = '';
 811
 812         # ->{$field} is faster than ->$field invocations, so favor that.
 813         if ($field eq 'date') {
 814                 for my $s (@$msgs) {
 815                         $tmp .= "$s->{num} ".PublicInbox::Smsg::date($s)."\r\n"
 816                 }
 817         } else {
 818                 for my $s (@$msgs) {
 819                         $tmp .= "$s->{num} $s->{$field}\r\n";
 820                 }
 821         }
 822         utf8::encode($tmp);
 823         $self->msg_more($tmp);
 824         $$beg = $msgs->[-1]->{num} + 1;
 825 }
 826
 827 sub hdr_smsg ($$$$) {
 828         my ($self, $xhdr, $field, $range) = @_;
 829         if (defined $range && $range =~ $ONE_MSGID) {
 830                 my ($ng, $n) = mid_lookup($self, $1);
 831                 return r430 unless defined $n;
 832                 my $v = over_header_for($ng->over, $n, $field);
 833                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 834         } else { # numeric range
 835                 $range = $self->{article} unless defined $range;
 836                 my $r = get_range($self, $range);
 837                 return $r unless ref $r;
 838                 more($self, $xhdr ? r221 : r225);
 839                 long_response($self, \&smsg_range_i, @$r, $field);
 840         }
 841 }
 842
 843 sub do_hdr ($$$;$) {
 844         my ($self, $xhdr, $header, $range) = @_;
 845         my $sub = lc $header;
 846         if ($sub eq 'message-id') {
 847                 hdr_message_id($self, $xhdr, $range);
 848         } elsif ($sub eq 'xref') {
 849                 hdr_xref($self, $xhdr, $range);
 850         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 851                                 bytes|lines)\z/x) {
 852                 hdr_smsg($self, $xhdr, $sub, $range);
 853         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 854                 hdr_smsg($self, $xhdr, $1, $range);
 855         } else {
 856                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 857         }
 858 }
 859
 860 # RFC 3977
 861 sub cmd_hdr ($$;$) {
 862         my ($self, $header, $range) = @_;
 863         do_hdr($self, 0, $header, $range);
 864 }
 865
 866 # RFC 2980
 867 sub cmd_xhdr ($$;$) {
 868         my ($self, $header, $range) = @_;
 869         do_hdr($self, 1, $header, $range);
 870 }
 871
 872 sub hdr_mid_prefix ($$$$$) {
 873         my ($self, $xhdr, $ng, $n, $mid) = @_;
 874         return $mid if $xhdr;
 875
 876         # HDR for RFC 3977 users
 877         if (my $self_ng = $self->{ng}) {
 878                 ($self_ng eq $ng) ? $n : '0';
 879         } else {
 880                 '0';
 881         }
 882 }
 883
 884 sub hdr_mid_response ($$$$$$) {
 885         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 886         my $res = '';
 887         if ($xhdr) {
 888                 $res .= r221 . "\r\n";
 889                 $res .= "$mid $v\r\n";
 890         } else {
 891                 $res .= r225 . "\r\n";
 892                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 893                 $res .= "$pfx $v\r\n";
 894         }
 895         res($self, $res .= '.');
 896         undef;
 897 }
 898
 899 sub xrover_i {
 900         my ($self, $beg, $end) = @_;
 901         my $h = over_header_for($self->{ng}->over, $$beg, 'references');
 902         more($self, "$$beg $h") if defined($h);
 903         $$beg++ < $end;
 904 }
 905
 906 sub cmd_xrover ($;$) {
 907         my ($self, $range) = @_;
 908         my $ng = $self->{ng} or return '412 no newsgroup selected';
 909         (defined $range && $range =~ /[<>]/) and
 910                 return '420 No article(s) selected'; # no message IDs
 911
 912         $range = $self->{article} unless defined $range;
 913         my $r = get_range($self, $range);
 914         return $r unless ref $r;
 915         more($self, '224 Overview information follows');
 916         long_response($self, \&xrover_i, @$r);
 917 }
 918
 919 sub over_line ($$$) {
 920         my ($self, $ng, $smsg) = @_;
 921         # n.b. field access and procedural calls can be
 922         # 10%-15% faster than OO method calls:
 923         my $s = join("\t", $smsg->{num},
 924                 $smsg->{subject},
 925                 $smsg->{from},
 926                 PublicInbox::Smsg::date($smsg),
 927                 "<$smsg->{mid}>",
 928                 $smsg->{references},
 929                 $smsg->{bytes},
 930                 $smsg->{lines},
 931                 "Xref: " . xref($self, $ng, $smsg));
 932         utf8::encode($s);
 933         $s
 934 }
 935
 936 sub cmd_over ($;$) {
 937         my ($self, $range) = @_;
 938         if ($range && $range =~ $ONE_MSGID) {
 939                 my ($ng, $n) = mid_lookup($self, $1);
 940                 defined $n or return r430;
 941                 my $smsg = $ng->over->get_art($n) or return r430;
 942                 more($self, '224 Overview information follows (multi-line)');
 943
 944                 # Only set article number column if it's the current group
 945                 my $self_ng = $self->{ng};
 946                 $smsg->{num} = 0 if (!$self_ng || $self_ng ne $ng);
 947                 more($self, over_line($self, $ng, $smsg));
 948                 '.';
 949         } else {
 950                 cmd_xover($self, $range);
 951         }
 952 }
 953
 954 sub xover_i {
 955         my ($self, $beg, $end) = @_;
 956         my $ng = $self->{ng};
 957         my $msgs = $ng->over->query_xover($$beg, $end);
 958         my $nr = scalar @$msgs or return;
 959
 960         # OVERVIEW.FMT
 961         more($self, join("\r\n", map {
 962                 over_line($self, $ng, $_);
 963                 } @$msgs));
 964         $$beg = $msgs->[-1]->{num} + 1;
 965 }
 966
 967 sub cmd_xover ($;$) {
 968         my ($self, $range) = @_;
 969         $range = $self->{article} unless defined $range;
 970         my $r = get_range($self, $range);
 971         return $r unless ref $r;
 972         my ($beg, $end) = @$r;
 973         more($self, "224 Overview information follows for $$beg to $end");
 974         long_response($self, \&xover_i, @$r);
 975 }
 976
 977 sub compressed { undef }
 978
 979 sub cmd_starttls ($) {
 980         my ($self) = @_;
 981         my $sock = $self->{sock} or return;
 982         # RFC 4642 2.2.1
 983         return r502 if ($sock->can('accept_SSL') || $self->compressed);
 984         my $opt = $self->{nntpd}->{accept_tls} or
 985                 return '580 can not initiate TLS negotiation';
 986         res($self, '382 Continue with TLS negotiation');
 987         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 988         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 989         undef;
 990 }
 991
 992 # RFC 8054
 993 sub cmd_compress ($$) {
 994         my ($self, $alg) = @_;
 995         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 996         return r502 if $self->compressed;
 997         PublicInbox::NNTPdeflate->enable($self);
 998         $self->requeue;
 999         undef
1000 }
1001
1002 sub zflush {} # overridden by NNTPdeflate
1003
1004 sub cmd_xpath ($$) {
1005         my ($self, $mid) = @_;
1006         return r501 unless $mid =~ $ONE_MSGID;
1007         $mid = $1;
1008         my @paths;
1009         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
1010                 my $n = $ng->mm->num_for($mid);
1011                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
1012         }
1013         return '430 no such article on server' unless @paths;
1014         '223 '.join(' ', @paths);
1015 }
1016
1017 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
1018
1019 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
1020
1021 sub do_write ($$) {
1022         my $self = $_[0];
1023         my $done = $self->write(\($_[1]));
1024         return 0 unless $self->{sock};
1025
1026         $done;
1027 }
1028
1029 sub err ($$;@) {
1030         my ($self, $fmt, @args) = @_;
1031         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
1032 }
1033
1034 sub out ($$;@) {
1035         my ($self, $fmt, @args) = @_;
1036         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
1037 }
1038
1039 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
1040 sub event_step {
1041         my ($self) = @_;
1042
1043         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
1044
1045         $self->update_idle_time;
1046         # only read more requests if we've drained the write buffer,
1047         # otherwise we can be buffering infinitely w/o backpressure
1048
1049         my $rbuf = $self->{rbuf} // \(my $x = '');
1050         my $line = index($$rbuf, "\n");
1051         while ($line < 0) {
1052                 return $self->close if length($$rbuf) >= LINE_MAX;
1053                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
1054                 $line = index($$rbuf, "\n");
1055         }
1056         $line = substr($$rbuf, 0, $line + 1, '');
1057         $line =~ s/\r?\n\z//s;
1058         return $self->close if $line =~ /[[:cntrl:]]/s;
1059
1060         my $t0 = now();
1061         my $fd = fileno($self->{sock});
1062         my $r = eval { process_line($self, $line) };
1063         my $pending = $self->{wbuf} ? ' pending' : '';
1064         out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
1065         return $self->close if $r < 0;
1066         $self->rbuf_idle($rbuf);
1067         $self->update_idle_time;
1068
1069         # maybe there's more pipelined data, or we'll have
1070         # to register it for socket-readiness notifications
1071         $self->requeue unless $pending;
1072 }
1073
1074 # for graceful shutdown in PublicInbox::Daemon:
1075 sub busy {
1076         my ($self, $now) = @_;
1077         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1078 }
1079
1080 1;