lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::Git;
  13 use PublicInbox::MID qw(mid2path);
  14 use Email::Simple;
  15 use Data::Dumper qw(Dumper);
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use URI::Escape qw(uri_escape_utf8);
  19 use Encode qw(find_encoding);
  20 my $enc_utf8 = find_encoding('UTF-8');
  21 use constant {
  22         r501 => '501 command syntax error',
  23         r221 => '221 Header follows',
  24         r224 => '224 Overview information follows (multi-line)',
  25         r225 => '225 Headers follow (multi-line)',
  26         r430 => '430 No article with that message-id',
  27         long_response_limit => 0xffffffff,
  28 };
  29
  30 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  31
  32 my @OVERVIEW = qw(Subject From Date Message-ID References);
  33 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  34 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  35                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  36
  37 # disable commands with easy DoS potential:
  38 # LISTGROUP could get pretty bad, too...
  39 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  40
  41 my $EXPMAP; # fd -> [ idle_time, $self ]
  42 my $EXPTIMER;
  43 our $EXPTIME = 180; # 3 minutes
  44 my $WEAKEN = {}; # string(nntpd) -> nntpd
  45 my $WEAKTIMER;
  46
  47 my $next_tick;
  48 my $nextq = [];
  49 sub next_tick () {
  50         $next_tick = undef;
  51         my $q = $nextq;
  52         $nextq = [];
  53         foreach my $nntp (@$q) {
  54                 # for request && response protocols, always finish writing
  55                 # before finishing reading:
  56                 if (my $long_cb = $nntp->{long_res}) {
  57                         $nntp->write($long_cb);
  58                 } elsif (&Danga::Socket::POLLIN & $nntp->{event_watch}) {
  59                         event_read($nntp);
  60                 }
  61         }
  62 }
  63
  64 sub update_idle_time ($) {
  65         my ($self) = @_;
  66         my $tmp = $self->{sock} or return;
  67         $tmp = fileno($tmp);
  68         defined $tmp and $EXPMAP->{$tmp} = [ now(), $self ];
  69 }
  70
  71 # reduce FD pressure by closing some "git cat-file --batch" processes
  72 # and unused FDs for msgmap and Xapian indices
  73 sub weaken_groups () {
  74         $WEAKTIMER = undef;
  75         foreach my $nntpd (values %$WEAKEN) {
  76                 $_->weaken_all foreach (@{$nntpd->{grouplist}});
  77         }
  78         $WEAKEN = {};
  79 }
  80
  81 sub expire_old () {
  82         my $now = now();
  83         my $exp = $EXPTIME;
  84         my $old = $now - $exp;
  85         my $next = $now + $exp;
  86         my $nr = 0;
  87         my %new;
  88         while (my ($fd, $v) = each %$EXPMAP) {
  89                 my ($idle_time, $nntp) = @$v;
  90                 if ($idle_time < $old) {
  91                         $nntp->close; # idempotent
  92                 } else {
  93                         my $nexp = $idle_time + $exp;
  94                         $next = $nexp if ($nexp < $next);
  95                         ++$nr;
  96                         $new{$fd} = $v;
  97                 }
  98         }
  99         $EXPMAP = \%new;
 100         if ($nr) {
 101                 $next -= $now;
 102                 $next = 0 if $next < 0;
 103                 $EXPTIMER = Danga::Socket->AddTimer($next, *expire_old);
 104                 weaken_groups();
 105         } else {
 106                 $EXPTIMER = undef;
 107                 # noop to kick outselves out of the loop ASAP so descriptors
 108                 # really get closed
 109                 Danga::Socket->AddTimer(0, sub {});
 110
 111                 # grace period for reaping resources
 112                 $WEAKTIMER ||= Danga::Socket->AddTimer(30, *weaken_groups);
 113         }
 114 }
 115
 116 sub new ($$$) {
 117         my ($class, $sock, $nntpd) = @_;
 118         my $self = fields::new($class);
 119         $self->SUPER::new($sock);
 120         $self->{nntpd} = $nntpd;
 121         res($self, '201 server ready - post via email');
 122         $self->{rbuf} = '';
 123         $self->watch_read(1);
 124         update_idle_time($self);
 125         $WEAKEN->{"$nntpd"} = $nntpd;
 126         $EXPTIMER ||= Danga::Socket->AddTimer($EXPTIME, *expire_old);
 127         $self;
 128 }
 129
 130 sub args_ok ($$) {
 131         my ($cb, $argc) = @_;
 132         my $tot = prototype $cb;
 133         my ($nreq, undef) = split(';', $tot);
 134         $nreq = ($nreq =~ tr/$//) - 1;
 135         $tot = ($tot =~ tr/$//) - 1;
 136         ($argc <= $tot && $argc >= $nreq);
 137 }
 138
 139 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 140 sub process_line ($$) {
 141         my ($self, $l) = @_;
 142         my ($req, @args) = split(/\s+/, $l);
 143         $req = lc($req);
 144         $req = eval {
 145                 no strict 'refs';
 146                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 147         };
 148         return res($self, '500 command not recognized') unless $req;
 149         return res($self, r501) unless args_ok($req, scalar @args);
 150
 151         my $res = eval { $req->($self, @args) };
 152         my $err = $@;
 153         if ($err && !$self->{closed}) {
 154                 chomp($l = Dumper(\$l));
 155                 err($self, 'error from: %s (%s)', $l, $err);
 156                 $res = '503 program fault - command not performed';
 157         }
 158         return 0 unless defined $res;
 159         res($self, $res);
 160 }
 161
 162 sub cmd_mode ($$) {
 163         my ($self, $arg) = @_;
 164         $arg = uc $arg;
 165         return r501 unless $arg eq 'READER';
 166         '201 Posting prohibited';
 167 }
 168
 169 sub cmd_slave ($) { '202 slave status noted' }
 170
 171 sub cmd_xgtitle ($;$) {
 172         my ($self, $wildmat) = @_;
 173         more($self, '282 list of groups and descriptions follows');
 174         list_newsgroups($self, $wildmat);
 175         '.'
 176 }
 177
 178 sub list_overview_fmt ($) {
 179         my ($self) = @_;
 180         do_more($self, $OVERVIEW_FMT);
 181 }
 182
 183 sub list_headers ($;$) {
 184         my ($self) = @_;
 185         do_more($self, $LIST_HEADERS);
 186 }
 187
 188 sub list_active ($;$) {
 189         my ($self, $wildmat) = @_;
 190         wildmat2re($wildmat);
 191         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 192                 $ng->{newsgroup} =~ $wildmat or next;
 193                 group_line($self, $ng);
 194         }
 195 }
 196
 197 sub list_active_times ($;$) {
 198         my ($self, $wildmat) = @_;
 199         wildmat2re($wildmat);
 200         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 201                 $ng->{newsgroup} =~ $wildmat or next;
 202                 my $c = eval { $ng->mm->created_at } || time;
 203                 more($self, "$ng->{newsgroup} $c $ng->{address}");
 204         }
 205 }
 206
 207 sub list_newsgroups ($;$) {
 208         my ($self, $wildmat) = @_;
 209         wildmat2re($wildmat);
 210         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 211                 $ng->{newsgroup} =~ $wildmat or next;
 212                 my $d = $ng->description;
 213                 more($self, "$ng->{newsgroup} $d");
 214         }
 215 }
 216
 217 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 218 sub cmd_list ($;$$) {
 219         my ($self, @args) = @_;
 220         if (scalar @args) {
 221                 my $arg = shift @args;
 222                 $arg =~ tr/A-Z./a-z_/;
 223                 $arg = "list_$arg";
 224                 return r501 if $DISABLED{$arg};
 225
 226                 $arg = eval {
 227                         no strict 'refs';
 228                         *{$arg}{CODE};
 229                 };
 230                 return r501 unless $arg && args_ok($arg, scalar @args);
 231                 more($self, '215 information follows');
 232                 $arg->($self, @args);
 233         } else {
 234                 more($self, '215 list of newsgroups follows');
 235                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 236                         group_line($self, $ng);
 237                 }
 238         }
 239         '.'
 240 }
 241
 242 sub cmd_listgroup ($;$) {
 243         my ($self, $group) = @_;
 244         if (defined $group) {
 245                 my $res = cmd_group($self, $group);
 246                 return $res if ($res !~ /\A211 /);
 247                 more($self, $res);
 248         }
 249
 250         $self->{ng} or return '412 no newsgroup selected';
 251         long_response($self, 0, long_response_limit, sub {
 252                 my ($i) = @_;
 253                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 254                         my ($ary) = @_;
 255                         more($self, join("\r\n", @$ary));
 256                 });
 257
 258                 # -1 to adjust for implicit increment in long_response
 259                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 260         });
 261 }
 262
 263 sub parse_time ($$;$) {
 264         my ($date, $time, $gmt) = @_;
 265         use Time::Local qw();
 266         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 267         if (defined $gmt) {
 268                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 269                 $gmt = 1;
 270         }
 271         my @now = $gmt ? gmtime : localtime;
 272         my ($YYYY, $MM, $DD);
 273         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 274                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 275         } else { # legacy clients send YYMMDD
 276                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 277                 if ($YYYY > strftime('%y', @now)) {
 278                         my $cur_year = $now[5] + 1900;
 279                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 280                 }
 281         }
 282         if ($gmt) {
 283                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 284         } else {
 285                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 286         }
 287 }
 288
 289 sub group_line ($$) {
 290         my ($self, $ng) = @_;
 291         my ($min, $max) = $ng->mm->minmax;
 292         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 293 }
 294
 295 sub cmd_newgroups ($$$;$$) {
 296         my ($self, $date, $time, $gmt, $dists) = @_;
 297         my $ts = eval { parse_time($date, $time, $gmt) };
 298         return r501 if $@;
 299
 300         # TODO dists
 301         more($self, '231 list of new newsgroups follows');
 302         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 303                 my $c = eval { $ng->mm->created_at } || 0;
 304                 next unless $c > $ts;
 305                 group_line($self, $ng);
 306         }
 307         '.'
 308 }
 309
 310 sub wildmat2re (;$) {
 311         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 312         my %keep;
 313         my $salt = rand;
 314         use Digest::SHA qw(sha1_hex);
 315         my $tmp = $_[0];
 316
 317         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 318                 my $orig = $1;
 319                 my $key = sha1_hex($orig . $salt);
 320                 $orig =~ s/([^\w\-])+/\Q$1/g;
 321                 $keep{$key} = $orig;
 322                 $key
 323                 #gex;
 324         my %map = ('*' => '.*', '?' => '.' );
 325         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 326         if (scalar %keep) {
 327                 $tmp =~ s#([a-f0-9]{40})#
 328                         my $orig = $keep{$1};
 329                         defined $orig ? $orig : $1;
 330                         #ge;
 331         }
 332         $_[0] = qr/\A$tmp\z/;
 333 }
 334
 335 sub ngpat2re (;$) {
 336         return $_[0] = qr/\A\z/ unless defined $_[0];
 337         my %map = ('*' => '.*', ',' => '|');
 338         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 339         $_[0] = qr/\A(?:$_[0])\z/;
 340 }
 341
 342 sub cmd_newnews ($$$$;$$) {
 343         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 344         my $ts = eval { parse_time($date, $time, $gmt) };
 345         return r501 if $@;
 346         more($self, '230 list of new articles by message-id follows');
 347         my ($keep, $skip) = split('!', $newsgroups, 2);
 348         ngpat2re($keep);
 349         ngpat2re($skip);
 350         my @srch;
 351         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 352                 $ng->{newsgroup} =~ $keep or next;
 353                 $ng->{newsgroup} =~ $skip and next;
 354                 my $srch = $ng->search or next;
 355                 push @srch, $srch;
 356         };
 357         return '.' unless @srch;
 358
 359         $ts .= '..';
 360         my $opts = { asc => 1, limit => 1000, offset => 0 };
 361         long_response($self, 0, long_response_limit, sub {
 362                 my ($i) = @_;
 363                 my $srch = $srch[0];
 364                 my $res = $srch->query($ts, $opts);
 365                 my $msgs = $res->{msgs};
 366                 if (my $nr = scalar @$msgs) {
 367                         more($self, '<' .
 368                                 join(">\r\n<", map { $_->mid } @$msgs ).
 369                                 '>');
 370                         $opts->{offset} += $nr;
 371                 } else {
 372                         shift @srch;
 373                         if (@srch) { # continue onto next newsgroup
 374                                 $opts->{offset} = 0;
 375                         } else { # break out of the long response.
 376                                 $$i = long_response_limit;
 377                         }
 378                 }
 379         });
 380 }
 381
 382 sub cmd_group ($$) {
 383         my ($self, $group) = @_;
 384         my $no_such = '411 no such news group';
 385         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 386
 387         $self->{ng} = $ng;
 388         my ($min, $max) = $ng->mm->minmax;
 389         $min ||= 0;
 390         $max ||= 0;
 391         $self->{article} = $min;
 392         my $est_size = $max - $min;
 393         "211 $est_size $min $max $group";
 394 }
 395
 396 sub article_adj ($$) {
 397         my ($self, $off) = @_;
 398         my $ng = $self->{ng} or return '412 no newsgroup selected';
 399
 400         my $n = $self->{article};
 401         defined $n or return '420 no current article has been selected';
 402
 403         $n += $off;
 404         my $mid = $ng->mm->mid_for($n);
 405         unless ($mid) {
 406                 $n = $off > 0 ? 'next' : 'previous';
 407                 return "421 no $n article in this group";
 408         }
 409         $self->{article} = $n;
 410         "223 $n <$mid> article retrieved - request text separately";
 411 }
 412
 413 sub cmd_next ($) { article_adj($_[0], 1) }
 414 sub cmd_last ($) { article_adj($_[0], -1) }
 415
 416 # We want to encourage using email and CC-ing everybody involved to avoid
 417 # the single-point-of-failure a single server provides.
 418 sub cmd_post ($) {
 419         my ($self) = @_;
 420         my $ng = $self->{ng};
 421         $ng ? "440 mailto:$ng->{address} to post" : '440 posting not allowed'
 422 }
 423
 424 sub cmd_quit ($) {
 425         my ($self) = @_;
 426         res($self, '205 closing connection - goodbye!');
 427         $self->close;
 428         undef;
 429 }
 430
 431 sub header_append ($$$) {
 432         my ($hdr, $k, $v) = @_;
 433         my @v = $hdr->header($k);
 434         foreach (@v) {
 435                 return if $v eq $_;
 436         }
 437         $hdr->header_set($k, @v, $v);
 438 }
 439
 440 sub set_nntp_headers {
 441         my ($hdr, $ng, $n, $mid) = @_;
 442
 443         # clobber some
 444         $hdr->header_set('Newsgroups', $ng->{newsgroup});
 445         $hdr->header_set('Xref', xref($ng, $n));
 446         header_append($hdr, 'List-Post', "<mailto:$ng->{address}>");
 447         if (my $url = $ng->{url}) {
 448                 $mid = uri_escape_utf8($mid);
 449                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 450                 header_append($hdr, 'List-Archive', "<$url>");
 451         }
 452 }
 453
 454 sub art_lookup ($$$) {
 455         my ($self, $art, $set_headers) = @_;
 456         my $ng = $self->{ng};
 457         my ($n, $mid);
 458         my $err;
 459         if (defined $art) {
 460                 if ($art =~ /\A\d+\z/o) {
 461                         $err = '423 no such article number in this group';
 462                         $n = int($art);
 463                         goto find_mid;
 464                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 465                         $mid = $1;
 466                         $err = r430;
 467                         $n = $ng->mm->num_for($mid) if $ng;
 468                         goto found if defined $n;
 469                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 470                                 $n = $g->mm->num_for($mid);
 471                                 if (defined $n) {
 472                                         $ng = $g;
 473                                         goto found;
 474                                 }
 475                         }
 476                         return $err;
 477                 } else {
 478                         return r501;
 479                 }
 480         } else {
 481                 $err = '420 no current article has been selected';
 482                 $n = $self->{article};
 483                 defined $n or return $err;
 484 find_mid:
 485                 $ng or return '412 no newsgroup has been selected';
 486                 $mid = $ng->mm->mid_for($n);
 487                 defined $mid or return $err;
 488         }
 489 found:
 490         my $o = 'HEAD:' . mid2path($mid);
 491         my $bytes;
 492         my $s = eval { Email::Simple->new($ng->gcf->cat_file($o, \$bytes)) };
 493         return $err unless $s;
 494         my $lines;
 495         if ($set_headers) {
 496                 set_nntp_headers($s->header_obj, $ng, $n, $mid);
 497                 $lines = $s->body =~ tr!\n!\n!;
 498
 499                 # must be last
 500                 $s->body_set('') if ($set_headers == 2);
 501         }
 502         [ $n, $mid, $s, $bytes, $lines, $ng ];
 503 }
 504
 505 sub simple_body_write ($$) {
 506         my ($self, $s) = @_;
 507         my $body = $s->body;
 508         $s->body_set('');
 509         $body =~ s/^\./../smg;
 510         $body =~ s/(?<!\r)\n/\r\n/sg;
 511         do_more($self, $body);
 512         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 513         '.'
 514 }
 515
 516 sub set_art {
 517         my ($self, $art) = @_;
 518         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 519 }
 520
 521 sub cmd_article ($;$) {
 522         my ($self, $art) = @_;
 523         my $r = art_lookup($self, $art, 1);
 524         return $r unless ref $r;
 525         my ($n, $mid, $s) = @$r;
 526         set_art($self, $art);
 527         more($self, "220 $n <$mid> article retrieved - head and body follow");
 528         do_more($self, $s->header_obj->as_string);
 529         do_more($self, "\r\n");
 530         simple_body_write($self, $s);
 531 }
 532
 533 sub cmd_head ($;$) {
 534         my ($self, $art) = @_;
 535         my $r = art_lookup($self, $art, 2);
 536         return $r unless ref $r;
 537         my ($n, $mid, $s) = @$r;
 538         set_art($self, $art);
 539         more($self, "221 $n <$mid> article retrieved - head follows");
 540         do_more($self, $s->header_obj->as_string);
 541         '.'
 542 }
 543
 544 sub cmd_body ($;$) {
 545         my ($self, $art) = @_;
 546         my $r = art_lookup($self, $art, 0);
 547         return $r unless ref $r;
 548         my ($n, $mid, $s) = @$r;
 549         set_art($self, $art);
 550         more($self, "222 $n <$mid> article retrieved - body follows");
 551         simple_body_write($self, $s);
 552 }
 553
 554 sub cmd_stat ($;$) {
 555         my ($self, $art) = @_;
 556         my $r = art_lookup($self, $art, 0);
 557         return $r unless ref $r;
 558         my ($n, $mid, undef) = @$r;
 559         set_art($self, $art);
 560         "223 $n <$mid> article retrieved - request text separately";
 561 }
 562
 563 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 564
 565 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 566
 567 sub cmd_help ($) {
 568         my ($self) = @_;
 569         more($self, '100 help text follows');
 570         '.'
 571 }
 572
 573 sub get_range ($$) {
 574         my ($self, $range) = @_;
 575         my $ng = $self->{ng} or return '412 no news group has been selected';
 576         defined $range or return '420 No article(s) selected';
 577         my ($beg, $end);
 578         my ($min, $max) = $ng->mm->minmax;
 579         if ($range =~ /\A(\d+)\z/) {
 580                 $beg = $end = $1;
 581         } elsif ($range =~ /\A(\d+)-\z/) {
 582                 ($beg, $end) = ($1, $max);
 583         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 584                 ($beg, $end) = ($1, $2);
 585         } else {
 586                 return r501;
 587         }
 588         $beg = $min if ($beg < $min);
 589         $end = $max if ($end > $max);
 590         return '420 No article(s) selected' if ($beg > $end);
 591         [ $beg, $end ];
 592 }
 593
 594 sub long_response ($$$$) {
 595         my ($self, $beg, $end, $cb) = @_;
 596         die "BUG: nested long response" if $self->{long_res};
 597
 598         my $fd = $self->{fd};
 599         defined $fd or return;
 600         # make sure we disable reading during a long response,
 601         # clients should not be sending us stuff and making us do more
 602         # work while we are stream a response to them
 603         $self->watch_read(0);
 604         my $t0 = now();
 605         $self->{long_res} = sub {
 606                 # limit our own running time for fairness with other
 607                 # clients and to avoid buffering too much:
 608                 my $lim = 100;
 609
 610                 my $err;
 611                 do {
 612                         eval { $cb->(\$beg) };
 613                 } until (($err = $@) || $self->{closed} ||
 614                          ++$beg > $end || !--$lim || $self->{write_buf_size});
 615
 616                 if ($err || $self->{closed}) {
 617                         $self->{long_res} = undef;
 618
 619                         if ($err) {
 620                                 err($self,
 621                                     "%s during long response[$fd] - %0.6f",
 622                                     $err, now() - $t0);
 623                         }
 624                         if ($self->{closed}) {
 625                                 out($self, " deferred[$fd] aborted - %0.6f",
 626                                            now() - $t0);
 627                         } else {
 628                                 update_idle_time($self);
 629                                 $self->watch_read(1);
 630                         }
 631                 } elsif (!$lim || $self->{write_buf_size}) {
 632                         # no recursion, schedule another call ASAP
 633                         # but only after all pending writes are done
 634                         update_idle_time($self);
 635
 636                         push @$nextq, $self;
 637                         $next_tick ||= Danga::Socket->AddTimer(0, *next_tick);
 638                 } else { # all done!
 639                         $self->{long_res} = undef;
 640                         $self->watch_read(1);
 641                         res($self, '.');
 642                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 643                 }
 644         };
 645         $self->{long_res}->(); # kick off!
 646         undef;
 647 }
 648
 649 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 650         my ($self, $xhdr, $range) = @_;
 651
 652         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 653                 my ($ng, $n) = mid_lookup($self, $1);
 654                 return r430 unless $n;
 655                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 656         } else { # numeric range
 657                 $range = $self->{article} unless defined $range;
 658                 my $r = get_range($self, $range);
 659                 return $r unless ref $r;
 660                 my $mm = $self->{ng}->mm;
 661                 my ($beg, $end) = @$r;
 662                 more($self, $xhdr ? r221 : r225);
 663                 long_response($self, $beg, $end, sub {
 664                         my ($i) = @_;
 665                         my $mid = $mm->mid_for($$i);
 666                         more($self, "$$i <$mid>") if defined $mid;
 667                 });
 668         }
 669 }
 670
 671 sub xref ($$) {
 672         my ($ng, $n) = @_;
 673         "$ng->{domain} $ng->{newsgroup}:$n"
 674 }
 675
 676 sub mid_lookup ($$) {
 677         my ($self, $mid) = @_;
 678         my $self_ng = $self->{ng};
 679         if ($self_ng) {
 680                 my $n = $self_ng->mm->num_for($mid);
 681                 return ($self_ng, $n) if defined $n;
 682         }
 683         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 684                 next if defined $self_ng && $ng eq $self_ng;
 685                 my $n = $ng->mm->num_for($mid);
 686                 return ($ng, $n) if defined $n;
 687         }
 688         (undef, undef);
 689 }
 690
 691 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 692         my ($self, $xhdr, $range) = @_;
 693
 694         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 695                 my ($ng, $n) = mid_lookup($self, $1);
 696                 return r430 unless $n;
 697                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 698         } else { # numeric range
 699                 $range = $self->{article} unless defined $range;
 700                 my $r = get_range($self, $range);
 701                 return $r unless ref $r;
 702                 my $ng = $self->{ng};
 703                 my $mm = $ng->mm;
 704                 my ($beg, $end) = @$r;
 705                 more($self, $xhdr ? r221 : r225);
 706                 long_response($self, $beg, $end, sub {
 707                         my ($i) = @_;
 708                         my $mid = $mm->mid_for($$i);
 709                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 710                 });
 711         }
 712 }
 713
 714 sub search_header_for {
 715         my ($srch, $mid, $field) = @_;
 716         my $smsg = $srch->lookup_message($mid) or return;
 717         $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 718         $smsg->$field;
 719 }
 720
 721 sub hdr_searchmsg ($$$$) {
 722         my ($self, $xhdr, $field, $range) = @_;
 723         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 724                 my ($ng, $n) = mid_lookup($self, $1);
 725                 return r430 unless $n;
 726                 my $v = search_header_for($ng->search, $range, $field);
 727                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 728         } else { # numeric range
 729                 $range = $self->{article} unless defined $range;
 730                 my $srch = $self->{ng}->search;
 731                 my $mm = $self->{ng}->mm;
 732                 my $r = get_range($self, $range);
 733                 return $r unless ref $r;
 734                 my ($beg, $end) = @$r;
 735                 more($self, $xhdr ? r221 : r225);
 736                 my $off = 0;
 737                 long_response($self, $beg, $end, sub {
 738                         my ($i) = @_;
 739                         my $res = $srch->query_xover($beg, $end, $off);
 740                         my $msgs = $res->{msgs};
 741                         my $nr = scalar @$msgs or return;
 742                         $off += $nr;
 743                         my $tmp = '';
 744                         foreach my $s (@$msgs) {
 745                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 746                         }
 747                         do_more($self, $tmp);
 748                         # -1 to adjust for implicit increment in long_response
 749                         $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 750                 });
 751         }
 752 }
 753
 754 sub do_hdr ($$$;$) {
 755         my ($self, $xhdr, $header, $range) = @_;
 756         my $sub = lc $header;
 757         if ($sub eq 'message-id') {
 758                 hdr_message_id($self, $xhdr, $range);
 759         } elsif ($sub eq 'xref') {
 760                 hdr_xref($self, $xhdr, $range);
 761         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 762                                 bytes|lines)\z/x) {
 763                 hdr_searchmsg($self, $xhdr, $sub, $range);
 764         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 765                 hdr_searchmsg($self, $xhdr, $1, $range);
 766         } else {
 767                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 768         }
 769 }
 770
 771 # RFC 3977
 772 sub cmd_hdr ($$;$) {
 773         my ($self, $header, $range) = @_;
 774         do_hdr($self, 0, $header, $range);
 775 }
 776
 777 # RFC 2980
 778 sub cmd_xhdr ($$;$) {
 779         my ($self, $header, $range) = @_;
 780         do_hdr($self, 1, $header, $range);
 781 }
 782
 783 sub hdr_mid_prefix ($$$$$) {
 784         my ($self, $xhdr, $ng, $n, $mid) = @_;
 785         return $mid if $xhdr;
 786
 787         # HDR for RFC 3977 users
 788         if (my $self_ng = $self->{ng}) {
 789                 ($self_ng eq $ng) ? $n : '0';
 790         } else {
 791                 '0';
 792         }
 793 }
 794
 795 sub hdr_mid_response ($$$$$$) {
 796         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 797         my $res = '';
 798         if ($xhdr) {
 799                 $res .= r221 . "\r\n";
 800                 $res .= "$mid $v\r\n";
 801         } else {
 802                 $res .= r225 . "\r\n";
 803                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 804                 $res .= "$pfx $v\r\n";
 805         }
 806         res($self, $res .= '.');
 807         undef;
 808 }
 809
 810 sub cmd_xrover ($;$) {
 811         my ($self, $range) = @_;
 812         my $ng = $self->{ng} or return '412 no newsgroup selected';
 813         (defined $range && $range =~ /[<>]/) and
 814                 return '420 No article(s) selected'; # no message IDs
 815
 816         $range = $self->{article} unless defined $range;
 817         my $r = get_range($self, $range);
 818         return $r unless ref $r;
 819         my ($beg, $end) = @$r;
 820         my $mm = $ng->mm;
 821         my $srch = $ng->search;
 822         more($self, '224 Overview information follows');
 823         long_response($self, $beg, $end, sub {
 824                 my ($i) = @_;
 825                 my $mid = $mm->mid_for($$i) or return;
 826                 my $h = search_header_for($srch, $mid, 'references');
 827                 more($self, "$$i $h");
 828         });
 829 }
 830
 831 sub over_line ($$) {
 832         my ($num, $smsg) = @_;
 833         # n.b. field access and procedural calls can be
 834         # 10%-15% faster than OO method calls:
 835         join("\t", $num,
 836                 $smsg->{subject},
 837                 $smsg->{from},
 838                 PublicInbox::SearchMsg::date($smsg),
 839                 '<'.PublicInbox::SearchMsg::mid($smsg).'>',
 840                 $smsg->{references},
 841                 PublicInbox::SearchMsg::bytes($smsg),
 842                 PublicInbox::SearchMsg::lines($smsg));
 843 }
 844
 845 sub cmd_over ($;$) {
 846         my ($self, $range) = @_;
 847         if ($range && $range =~ /\A<(.+)>\z/) {
 848                 my ($ng, $n) = mid_lookup($self, $1);
 849                 my $smsg = $ng->search->lookup_message($range) or
 850                         return '430 No article with that message-id';
 851                 more($self, '224 Overview information follows (multi-line)');
 852                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 853
 854                 # Only set article number column if it's the current group
 855                 my $self_ng = $self->{ng};
 856                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 857                 more($self, over_line($n, $smsg));
 858                 '.';
 859         } else {
 860                 cmd_xover($self, $range);
 861         }
 862 }
 863
 864 sub cmd_xover ($;$) {
 865         my ($self, $range) = @_;
 866         $range = $self->{article} unless defined $range;
 867         my $r = get_range($self, $range);
 868         return $r unless ref $r;
 869         my ($beg, $end) = @$r;
 870         more($self, "224 Overview information follows for $beg to $end");
 871         my $srch = $self->{ng}->search;
 872         my $off = 0;
 873         long_response($self, $beg, $end, sub {
 874                 my ($i) = @_;
 875                 my $res = $srch->query_xover($beg, $end, $off);
 876                 my $msgs = $res->{msgs};
 877                 my $nr = scalar @$msgs or return;
 878                 $off += $nr;
 879
 880                 # OVERVIEW.FMT
 881                 more($self, join("\r\n", map {
 882                         over_line(PublicInbox::SearchMsg::num($_), $_);
 883                         } @$msgs));
 884
 885                 # -1 to adjust for implicit increment in long_response
 886                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 887         });
 888 }
 889
 890 sub cmd_xpath ($$) {
 891         my ($self, $mid) = @_;
 892         return r501 unless $mid =~ /\A<(.+)>\z/;
 893         $mid = $1;
 894         my @paths;
 895         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 896                 my $n = $ng->mm->num_for($mid);
 897                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 898         }
 899         return '430 no such article on server' unless @paths;
 900         '223 '.join(' ', @paths);
 901 }
 902
 903 sub res ($$) {
 904         my ($self, $line) = @_;
 905         $line = $enc_utf8->encode($line);
 906         do_write($self, $line . "\r\n");
 907 }
 908
 909 sub more ($$) {
 910         my ($self, $line) = @_;
 911         do_more($self, $line . "\r\n");
 912 }
 913
 914 sub do_write ($$) {
 915         my ($self, $data) = @_;
 916         my $done = $self->write($data);
 917         die if $self->{closed};
 918
 919         # Do not watch for readability if we have data in the queue,
 920         # instead re-enable watching for readability when we can
 921         $self->watch_read(0) if (!$done || $self->{long_res});
 922
 923         $done;
 924 }
 925
 926 sub err ($$;@) {
 927         my ($self, $fmt, @args) = @_;
 928         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 929 }
 930
 931 sub out ($$;@) {
 932         my ($self, $fmt, @args) = @_;
 933         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 934 }
 935
 936 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 937
 938 sub do_more ($$) {
 939         my ($self, $data) = @_;
 940         $data = $enc_utf8->encode($data);
 941         if (MSG_MORE && !$self->{write_buf_size}) {
 942                 my $n = send($self->{sock}, $data, MSG_MORE);
 943                 if (defined $n) {
 944                         my $dlen = length($data);
 945                         return 1 if $n == $dlen; # all done!
 946                         $data = substr($data, $n, $dlen - $n);
 947                 }
 948         }
 949         do_write($self, $data);
 950 }
 951
 952 # callbacks for Danga::Socket
 953
 954 sub event_hup { $_[0]->close }
 955 sub event_err { $_[0]->close }
 956
 957 sub event_write {
 958         my ($self) = @_;
 959         update_idle_time($self);
 960         # only continue watching for readability when we are done writing:
 961         if ($self->write(undef) == 1 && !$self->{long_res}) {
 962                 $self->watch_read(1);
 963         }
 964 }
 965
 966 sub event_read {
 967         my ($self) = @_;
 968         use constant LINE_MAX => 512; # RFC 977 section 2.3
 969         my $r = 1;
 970
 971         my $buf = $self->read(LINE_MAX) or return $self->close;
 972         $self->{rbuf} .= $$buf;
 973         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 974                 my $line = $1;
 975                 my $t0 = now();
 976                 my $fd = $self->{fd};
 977                 $r = eval { process_line($self, $line) };
 978                 my $d = $self->{long_res} ?
 979                         " deferred[$fd]" : '';
 980                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 981         }
 982
 983         return $self->close if $r < 0;
 984         my $len = length($self->{rbuf});
 985         return $self->close if ($len >= LINE_MAX);
 986         update_idle_time($self);
 987 }
 988
 989 sub watch_read {
 990         my ($self, $bool) = @_;
 991         my $rv = $self->SUPER::watch_read($bool);
 992         if ($bool && $self->{rbuf} ne '') {
 993                 # Force another read if there is a pipelined request.
 994                 # We don't know if the socket has anything for us to read,
 995                 # and we must double-check again by the time the timer fires
 996                 # in case we really did dispatch a read event and started
 997                 # another long response.
 998                 push @$nextq, $self;
 999                 $next_tick ||= Danga::Socket->AddTimer(0, *next_tick);
1000         }
1001         $rv;
1002 }
1003
1004 # for graceful shutdown in PublicInbox::Daemon:
1005 sub busy () {
1006         my ($self) = @_;
1007         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size});
1008 }
1009
1010 1;