lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 # fields:
   6 # nntpd: PublicInbox::NNTPD ref
   7 # article: per-session current article number
   8 # ibx: PublicInbox::Inbox ref
   9 # long_cb: long_response private data
  10 package PublicInbox::NNTP;
  11 use strict;
  12 use parent qw(PublicInbox::DS);
  13 use PublicInbox::MID qw(mid_escape $MID_EXTRACT);
  14 use PublicInbox::Eml;
  15 use POSIX qw(strftime);
  16 use PublicInbox::DS qw(now);
  17 use Digest::SHA qw(sha1_hex);
  18 use Time::Local qw(timegm timelocal);
  19 use PublicInbox::GitAsyncCat;
  20 use PublicInbox::Address;
  21
  22 use constant {
  23         LINE_MAX => 512, # RFC 977 section 2.3
  24         r501 => '501 command syntax error',
  25         r502 => '502 Command unavailable',
  26         r221 => '221 Header follows',
  27         r224 => '224 Overview information follows (multi-line)',
  28         r225 => '225 Headers follow (multi-line)',
  29         r430 => '430 No article with that message-id',
  30 };
  31 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  32 use Errno qw(EAGAIN);
  33 my $ONE_MSGID = qr/\A$MID_EXTRACT\z/;
  34 my @OVERVIEW = qw(Subject From Date Message-ID References);
  35 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  36                 "Xref:full\r\n.";
  37 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  38                         qw(:bytes :lines Xref To Cc)) . "\r\n.";
  39 my $CAPABILITIES = <<"";
  40 101 Capability list:\r
  41 VERSION 2\r
  42 READER\r
  43 NEWNEWS\r
  44 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  45 HDR\r
  46 OVER\r
  47 COMPRESS DEFLATE\r
  48
  49 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  50
  51 sub new ($$$) {
  52         my ($class, $sock, $nntpd) = @_;
  53         my $self = bless { nntpd => $nntpd }, $class;
  54         my $ev = EPOLLIN;
  55         my $wbuf;
  56         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
  57                 return CORE::close($sock) if $! != EAGAIN;
  58                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
  59                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  60         }
  61         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  62         if ($wbuf) {
  63                 $self->{wbuf} = $wbuf;
  64         } else {
  65                 greet($self);
  66         }
  67         $self->update_idle_time;
  68         $self;
  69 }
  70
  71 sub args_ok ($$) {
  72         my ($cb, $argc) = @_;
  73         my $tot = prototype $cb;
  74         my ($nreq, undef) = split(';', $tot);
  75         $nreq = ($nreq =~ tr/$//) - 1;
  76         $tot = ($tot =~ tr/$//) - 1;
  77         ($argc <= $tot && $argc >= $nreq);
  78 }
  79
  80 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  81 sub process_line ($$) {
  82         my ($self, $l) = @_;
  83         my ($req, @args) = split(/[ \t]+/, $l);
  84         return 1 unless defined($req); # skip blank line
  85         $req = $self->can('cmd_'.lc($req));
  86         return res($self, '500 command not recognized') unless $req;
  87         return res($self, r501) unless args_ok($req, scalar @args);
  88
  89         my $res = eval { $req->($self, @args) };
  90         my $err = $@;
  91         if ($err && $self->{sock}) {
  92                 local $/ = "\n";
  93                 chomp($l);
  94                 err($self, 'error from: %s (%s)', $l, $err);
  95                 $res = '503 program fault - command not performed';
  96         }
  97         defined($res) ? res($self, $res) : 0;
  98 }
  99
 100 # The keyword argument is not used (rfc3977 5.2.2)
 101 sub cmd_capabilities ($;$) {
 102         my ($self, undef) = @_;
 103         my $res = $CAPABILITIES;
 104         if (!$self->{sock}->can('accept_SSL') &&
 105                         $self->{nntpd}->{accept_tls}) {
 106                 $res .= "STARTTLS\r\n";
 107         }
 108         $res .= '.';
 109 }
 110
 111 sub cmd_mode ($$) {
 112         my ($self, $arg) = @_;
 113         uc($arg) eq 'READER' ? '201 Posting prohibited' : r501;
 114 }
 115
 116 sub cmd_slave ($) { '202 slave status noted' }
 117
 118 sub cmd_xgtitle ($;$) {
 119         my ($self, $wildmat) = @_;
 120         more($self, '282 list of groups and descriptions follows');
 121         list_newsgroups($self, $wildmat);
 122 }
 123
 124 sub list_overview_fmt ($) { $OVERVIEW_FMT }
 125
 126 sub list_headers ($;$) { $LIST_HEADERS }
 127
 128 sub list_active_i { # "LIST ACTIVE" and also just "LIST" (no args)
 129         my ($self, $groupnames) = @_;
 130         my @window = splice(@$groupnames, 0, 100) or return 0;
 131         my $ibx;
 132         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 133         for my $ngname (@window) {
 134                 $ibx = $groups->{$ngname} and group_line($self, $ibx);
 135         }
 136         scalar(@$groupnames); # continue if there's more
 137 }
 138
 139 sub list_active ($;$) { # called by cmd_list
 140         my ($self, $wildmat) = @_;
 141         wildmat2re($wildmat);
 142         long_response($self, \&list_active_i, [
 143                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 144 }
 145
 146 sub list_active_times_i {
 147         my ($self, $groupnames) = @_;
 148         my @window = splice(@$groupnames, 0, 100) or return 0;
 149         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 150         for my $ngname (@window) {
 151                 my $ibx = $groups->{$ngname} or next;
 152                 my $c = eval { $ibx->uidvalidity } // time;
 153                 more($self, "$ngname $c <$ibx->{-primary_address}>");
 154         }
 155         scalar(@$groupnames); # continue if there's more
 156 }
 157
 158 sub list_active_times ($;$) { # called by cmd_list
 159         my ($self, $wildmat) = @_;
 160         wildmat2re($wildmat);
 161         long_response($self, \&list_active_times_i, [
 162                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 163 }
 164
 165 sub list_newsgroups_i {
 166         my ($self, $groupnames) = @_;
 167         my @window = splice(@$groupnames, 0, 100) or return 0;
 168         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 169         my $ibx;
 170         for my $ngname (@window) {
 171                 $ibx = $groups->{$ngname} and
 172                         more($self, "$ngname ".$ibx->description);
 173         }
 174         scalar(@$groupnames); # continue if there's more
 175 }
 176
 177 sub list_newsgroups ($;$) { # called by cmd_list
 178         my ($self, $wildmat) = @_;
 179         wildmat2re($wildmat);
 180         long_response($self, \&list_newsgroups_i, [
 181                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 182 }
 183
 184 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 185 sub cmd_list ($;$$) {
 186         my ($self, @args) = @_;
 187         if (scalar @args) {
 188                 my $arg = shift @args;
 189                 $arg =~ tr/A-Z./a-z_/;
 190                 my $ret = $arg eq 'active';
 191                 $arg = "list_$arg";
 192                 $arg = $self->can($arg);
 193                 return r501 unless $arg && args_ok($arg, scalar @args);
 194                 more($self, '215 information follows');
 195                 $arg->($self, @args);
 196         } else {
 197                 more($self, '215 list of newsgroups follows');
 198                 long_response($self, \&list_active_i, [ # copy array
 199                         @{$self->{nntpd}->{groupnames}} ]);
 200         }
 201 }
 202
 203 sub listgroup_range_i {
 204         my ($self, $beg, $end) = @_;
 205         my $r = $self->{ibx}->mm->msg_range($beg, $end, 'num');
 206         scalar(@$r) or return;
 207         $self->msg_more(join('', map { "$_->[0]\r\n" } @$r));
 208         1;
 209 }
 210
 211 sub listgroup_all_i {
 212         my ($self, $num) = @_;
 213         my $ary = $self->{ibx}->mm->ids_after($num);
 214         scalar(@$ary) or return;
 215         more($self, join("\r\n", @$ary));
 216         1;
 217 }
 218
 219 sub cmd_listgroup ($;$$) {
 220         my ($self, $group, $range) = @_;
 221         if (defined $group) {
 222                 my $res = cmd_group($self, $group);
 223                 return $res if ($res !~ /\A211 /);
 224                 more($self, $res);
 225         }
 226         $self->{ibx} or return '412 no newsgroup selected';
 227         if (defined $range) {
 228                 my $r = get_range($self, $range);
 229                 return $r unless ref $r;
 230                 long_response($self, \&listgroup_range_i, @$r);
 231         } else { # grab every article number
 232                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 233         }
 234 }
 235
 236 sub parse_time ($$;$) {
 237         my ($date, $time, $gmt) = @_;
 238         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 239         if (defined $gmt) {
 240                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 241                 $gmt = 1;
 242         }
 243         my ($YYYY, $MM, $DD);
 244         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 245                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 246         } else { # legacy clients send YYMMDD
 247                 my $YY;
 248                 ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 249                 my @now = $gmt ? gmtime : localtime;
 250                 my $cur_year = $now[5] + 1900;
 251                 my $cur_cent = int($cur_year / 100) * 100;
 252                 $YYYY = (($YY + $cur_cent) > $cur_year) ?
 253                         ($YY + 1900) : ($YY + $cur_cent);
 254         }
 255         if ($gmt) {
 256                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 257         } else {
 258                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 259         }
 260 }
 261
 262 sub group_line ($$) {
 263         my ($self, $ibx) = @_;
 264         my ($min, $max) = $ibx->mm->minmax;
 265         more($self, "$ibx->{newsgroup} $max $min n");
 266 }
 267
 268 sub newgroups_i {
 269         my ($self, $ts, $i, $groupnames) = @_;
 270         my $end = $$i + 100;
 271         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 272         while ($$i < $end) {
 273                 my $ngname = $groupnames->[$$i++] // return;
 274                 my $ibx = $groups->{$ngname} or next; # expired on reload
 275                 next unless (eval { $ibx->uidvalidity } // 0) > $ts;
 276                 group_line($self, $ibx);
 277         }
 278         1;
 279 }
 280
 281 sub cmd_newgroups ($$$;$$) {
 282         my ($self, $date, $time, $gmt, $dists) = @_;
 283         my $ts = eval { parse_time($date, $time, $gmt) };
 284         return r501 if $@;
 285
 286         # TODO dists
 287         more($self, '231 list of new newsgroups follows');
 288         long_response($self, \&newgroups_i, $ts, \(my $i = 0),
 289                                 $self->{nntpd}->{groupnames});
 290 }
 291
 292 sub wildmat2re (;$) {
 293         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 294         my %keep;
 295         my $salt = rand;
 296         my $tmp = $_[0];
 297
 298         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 299                 my $orig = $1;
 300                 my $key = sha1_hex($orig . $salt);
 301                 $orig =~ s/([^\w\-])+/\Q$1/g;
 302                 $keep{$key} = $orig;
 303                 $key
 304                 #gex;
 305         my %map = ('*' => '.*', '?' => '.' );
 306         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 307         if (scalar %keep) {
 308                 $tmp =~ s#([a-f0-9]{40})#
 309                         my $orig = $keep{$1};
 310                         defined $orig ? $orig : $1;
 311                         #ge;
 312         }
 313         $_[0] = qr/\A$tmp\z/;
 314 }
 315
 316 sub ngpat2re (;$) {
 317         return $_[0] = qr/\A\z/ unless defined $_[0];
 318         my %map = ('*' => '.*', ',' => '|');
 319         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 320         $_[0] = qr/\A(?:$_[0])\z/;
 321 }
 322
 323 sub newnews_i {
 324         my ($self, $names, $ts, $prev) = @_;
 325         my $ngname = $names->[0];
 326         if (my $ibx = $self->{nntpd}->{pi_cfg}->{-by_newsgroup}->{$ngname}) {
 327                 if (my $over = $ibx->over) {
 328                         my $msgs = $over->query_ts($ts, $$prev);
 329                         if (scalar @$msgs) {
 330                                 $self->msg_more(join('', map {
 331                                                         "<$_->{mid}>\r\n";
 332                                                 } @$msgs));
 333                                 $$prev = $msgs->[-1]->{num};
 334                                 return 1; # continue on current group
 335                         }
 336                 }
 337         }
 338         shift @$names;
 339         if (@$names) { # continue onto next newsgroup
 340                 $$prev = 0;
 341                 1;
 342         } else { # all done, break out of the long_response
 343                 undef;
 344         }
 345 }
 346
 347 sub cmd_newnews ($$$$;$$) {
 348         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 349         my $ts = eval { parse_time($date, $time, $gmt) };
 350         return r501 if $@;
 351         more($self, '230 list of new articles by message-id follows');
 352         my ($keep, $skip) = split('!', $newsgroups, 2);
 353         ngpat2re($keep);
 354         ngpat2re($skip);
 355         my @names = grep(!/$skip/, grep(/$keep/,
 356                                 @{$self->{nntpd}->{groupnames}}));
 357         return '.' unless scalar(@names);
 358         my $prev = 0;
 359         long_response($self, \&newnews_i, \@names, $ts, \$prev);
 360 }
 361
 362 sub cmd_group ($$) {
 363         my ($self, $group) = @_;
 364         my $nntpd = $self->{nntpd};
 365         my $ibx = $nntpd->{pi_cfg}->{-by_newsgroup}->{$group} or
 366                 return '411 no such news group';
 367         $nntpd->idler_start;
 368
 369         $self->{ibx} = $ibx;
 370         my ($min, $max) = $ibx->mm->minmax;
 371         $self->{article} = $min;
 372         my $est_size = $max - $min;
 373         "211 $est_size $min $max $group";
 374 }
 375
 376 sub article_adj ($$) {
 377         my ($self, $off) = @_;
 378         my $ibx = $self->{ibx} or return '412 no newsgroup selected';
 379
 380         my $n = $self->{article};
 381         defined $n or return '420 no current article has been selected';
 382
 383         $n += $off;
 384         my $mid = $ibx->mm->mid_for($n);
 385         unless ($mid) {
 386                 $n = $off > 0 ? 'next' : 'previous';
 387                 return "421 no $n article in this group";
 388         }
 389         $self->{article} = $n;
 390         "223 $n <$mid> article retrieved - request text separately";
 391 }
 392
 393 sub cmd_next ($) { article_adj($_[0], 1) }
 394 sub cmd_last ($) { article_adj($_[0], -1) }
 395
 396 # We want to encourage using email and CC-ing everybody involved to avoid
 397 # the single-point-of-failure a single server provides.
 398 sub cmd_post ($) {
 399         my ($self) = @_;
 400         my $ibx = $self->{ibx};
 401         $ibx ? "440 mailto:$ibx->{-primary_address} to post"
 402                 : '440 posting not allowed'
 403 }
 404
 405 sub cmd_quit ($) {
 406         my ($self) = @_;
 407         res($self, '205 closing connection - goodbye!');
 408         $self->shutdn;
 409         undef;
 410 }
 411
 412 sub xref_by_tc ($$$) {
 413         my ($xref, $pi_cfg, $smsg) = @_;
 414         my $by_addr = $pi_cfg->{-by_addr};
 415         my $mid = $smsg->{mid};
 416         for my $f (qw(to cc)) {
 417                 my @ibxs = map {
 418                         $by_addr->{lc($_)} // ()
 419                 } (PublicInbox::Address::emails($smsg->{$f} // ''));
 420                 for my $ibx (@ibxs) {
 421                         my $ngname = $ibx->{newsgroup} // next;
 422                         next if defined $xref->{$ngname};
 423                         $xref->{$ngname} = eval { $ibx->mm->num_for($mid) };
 424                 }
 425         }
 426 }
 427
 428 sub xref ($$$) {
 429         my ($self, $cur_ibx, $smsg) = @_;
 430         my $nntpd = $self->{nntpd};
 431         my $cur_ng = $cur_ibx->{newsgroup};
 432         my $xref;
 433         if (my $ALL = $nntpd->{pi_cfg}->ALL) {
 434                 $xref = $ALL->nntp_xref_for($cur_ibx, $smsg);
 435                 xref_by_tc($xref, $nntpd->{pi_cfg}, $smsg);
 436         } else { # slow path
 437                 $xref = { $cur_ng => $smsg->{num} };
 438                 my $mid = $smsg->{mid};
 439                 for my $ibx (values %{$nntpd->{pi_cfg}->{-by_newsgroup}}) {
 440                         next if defined($xref->{$ibx->{newsgroup}});
 441                         my $num = eval { $ibx->mm->num_for($mid) } // next;
 442                         $xref->{$ibx->{newsgroup}} = $num;
 443                 }
 444         }
 445         my $ret = "$nntpd->{servername} $cur_ng:".delete($xref->{$cur_ng});
 446         $ret .= " $_:$xref->{$_}" for (sort keys %$xref);
 447         $ret;
 448 }
 449
 450 sub set_nntp_headers ($$) {
 451         my ($hdr, $smsg) = @_;
 452         my ($mid) = $smsg->{mid};
 453
 454         # leafnode (and maybe other NNTP clients) have trouble dealing
 455         # with v2 messages which have multiple Message-IDs (either due
 456         # to our own content-based dedupe or buggy git-send-email versions).
 457         my @mids = $hdr->header_raw('Message-ID');
 458         if (scalar(@mids) > 1) {
 459                 my $mid0 = "<$mid>";
 460                 $hdr->header_set('Message-ID', $mid0);
 461                 my @alt = $hdr->header_raw('X-Alt-Message-ID');
 462                 my %seen = map { $_ => 1 } (@alt, $mid0);
 463                 push(@alt, grep { !$seen{$_}++ } @mids);
 464                 $hdr->header_set('X-Alt-Message-ID', @alt);
 465         }
 466
 467         # clobber some existing headers
 468         my $ibx = $smsg->{-ibx};
 469         my $xref = xref($smsg->{nntp}, $ibx, $smsg);
 470         $hdr->header_set('Xref', $xref);
 471
 472         # RFC 5536 3.1.4
 473         my ($server_name, $newsgroups) = split(/ /, $xref, 2);
 474         $newsgroups =~ s/:[0-9]+\b//g; # drop NNTP article numbers
 475         $newsgroups =~ tr/ /,/;
 476         $hdr->header_set('Newsgroups', $newsgroups);
 477
 478         # *something* here is required for leafnode, try to follow
 479         # RFC 5536 3.1.5...
 480         $hdr->header_set('Path', $server_name . '!not-for-mail');
 481 }
 482
 483 sub art_lookup ($$$) {
 484         my ($self, $art, $code) = @_;
 485         my ($ibx, $n);
 486         my $err;
 487         if (defined $art) {
 488                 if ($art =~ /\A[0-9]+\z/) {
 489                         $err = '423 no such article number in this group';
 490                         $n = int($art);
 491                         goto find_ibx;
 492                 } elsif ($art =~ $ONE_MSGID) {
 493                         ($ibx, $n) = mid_lookup($self, $1);
 494                         goto found if $ibx;
 495                         return r430;
 496                 } else {
 497                         return r501;
 498                 }
 499         } else {
 500                 $err = '420 no current article has been selected';
 501                 $n = $self->{article} // return $err;
 502 find_ibx:
 503                 $ibx = $self->{ibx} or
 504                                 return '412 no newsgroup has been selected';
 505         }
 506 found:
 507         my $smsg = $ibx->over->get_art($n) or return $err;
 508         $smsg->{-ibx} = $ibx;
 509         if ($code == 223) { # STAT
 510                 set_art($self, $n);
 511                 "223 $n <$smsg->{mid}> article retrieved - " .
 512                         "request text separately";
 513         } else { # HEAD | BODY | ARTICLE
 514                 $smsg->{nntp} = $self;
 515                 $smsg->{nntp_code} = $code;
 516                 set_art($self, $art);
 517                 # this dereferences to `undef'
 518                 ${ibx_async_cat($ibx, $smsg->{blob}, \&blob_cb, $smsg)};
 519         }
 520 }
 521
 522 sub msg_body_write ($$) {
 523         my ($self, $msg) = @_;
 524
 525         # these can momentarily double the memory consumption :<
 526         $$msg =~ s/^\./../smg;
 527         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 528         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 529         $self->msg_more($$msg);
 530 }
 531
 532 sub set_art {
 533         my ($self, $art) = @_;
 534         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 535 }
 536
 537 sub msg_hdr_write ($$) {
 538         my ($eml, $smsg) = @_;
 539         set_nntp_headers($eml, $smsg);
 540
 541         my $hdr = $eml->{hdr} // \(my $x = '');
 542         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 543         $$hdr =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 544         $$hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 545
 546         # for leafnode compatibility, we need to ensure Message-ID headers
 547         # are only a single line.
 548         $$hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 549         $smsg->{nntp}->msg_more($$hdr);
 550 }
 551
 552 sub blob_cb { # called by git->cat_async via ibx_async_cat
 553         my ($bref, $oid, $type, $size, $smsg) = @_;
 554         my $self = $smsg->{nntp};
 555         my $code = $smsg->{nntp_code};
 556         if (!defined($oid)) {
 557                 # it's possible to have TOCTOU if an admin runs
 558                 # public-inbox-(edit|purge), just move onto the next message
 559                 warn "E: $smsg->{blob} missing in $smsg->{-ibx}->{inboxdir}\n";
 560                 return $self->requeue;
 561         } elsif ($smsg->{blob} ne $oid) {
 562                 $self->close;
 563                 die "BUG: $smsg->{blob} != $oid";
 564         }
 565         my $r = "$code $smsg->{num} <$smsg->{mid}> article retrieved - ";
 566         my $eml = PublicInbox::Eml->new($bref);
 567         if ($code == 220) {
 568                 more($self, $r .= 'head and body follow');
 569                 msg_hdr_write($eml, $smsg);
 570                 $self->msg_more("\r\n");
 571                 msg_body_write($self, $bref);
 572         } elsif ($code == 221) {
 573                 more($self, $r .= 'head follows');
 574                 msg_hdr_write($eml, $smsg);
 575         } elsif ($code == 222) {
 576                 more($self, $r .= 'body follows');
 577                 msg_body_write($self, $bref);
 578         } else {
 579                 $self->close;
 580                 die "BUG: bad code: $r";
 581         }
 582         $self->write(\".\r\n"); # flushes (includes ->zflush)
 583         $self->requeue;
 584 }
 585
 586 sub cmd_article ($;$) {
 587         my ($self, $art) = @_;
 588         art_lookup($self, $art, 220);
 589 }
 590
 591 sub cmd_head ($;$) {
 592         my ($self, $art) = @_;
 593         art_lookup($self, $art, 221);
 594 }
 595
 596 sub cmd_body ($;$) {
 597         my ($self, $art) = @_;
 598         art_lookup($self, $art, 222);
 599 }
 600
 601 sub cmd_stat ($;$) {
 602         my ($self, $art) = @_;
 603         art_lookup($self, $art, 223); # art may be msgid
 604 }
 605
 606 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 607
 608 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 609
 610 sub cmd_help ($) {
 611         my ($self) = @_;
 612         more($self, '100 help text follows');
 613         '.'
 614 }
 615
 616 sub get_range ($$) {
 617         my ($self, $range) = @_;
 618         my $ibx = $self->{ibx} or return '412 no news group has been selected';
 619         defined $range or return '420 No article(s) selected';
 620         my ($beg, $end);
 621         my ($min, $max) = $ibx->mm->minmax;
 622         if ($range =~ /\A([0-9]+)\z/) {
 623                 $beg = $end = $1;
 624         } elsif ($range =~ /\A([0-9]+)-\z/) {
 625                 ($beg, $end) = ($1, $max);
 626         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 627                 ($beg, $end) = ($1, $2);
 628         } else {
 629                 return r501;
 630         }
 631         $beg = $min if ($beg < $min);
 632         $end = $max if ($end > $max);
 633         return '420 No article(s) selected' if ($beg > $end);
 634         [ \$beg, $end ];
 635 }
 636
 637 sub long_step {
 638         my ($self) = @_;
 639         # wbuf is unset or empty, here; {long} may add to it
 640         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
 641         my $more = eval { $cb->($self, @args) };
 642         if ($@ || !$self->{sock}) { # something bad happened...
 643                 delete $self->{long_cb};
 644                 my $elapsed = now() - $t0;
 645                 if ($@) {
 646                         err($self,
 647                             "%s during long response[$fd] - %0.6f",
 648                             $@, $elapsed);
 649                 }
 650                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 651                 $self->close;
 652         } elsif ($more) { # $self->{wbuf}:
 653                 $self->update_idle_time;
 654
 655                 # COMPRESS users all share the same DEFLATE context.
 656                 # Flush it here to ensure clients don't see
 657                 # each other's data
 658                 $self->zflush;
 659
 660                 # no recursion, schedule another call ASAP, but only after
 661                 # all pending writes are done.  autovivify wbuf:
 662                 my $new_size = push(@{$self->{wbuf}}, \&long_step);
 663
 664                 # wbuf may be populated by $cb, no need to rearm if so:
 665                 $self->requeue if $new_size == 1;
 666         } else { # all done!
 667                 delete $self->{long_cb};
 668                 res($self, '.');
 669                 my $elapsed = now() - $t0;
 670                 my $fd = fileno($self->{sock});
 671                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 672                 my $wbuf = $self->{wbuf}; # do NOT autovivify
 673                 $self->requeue unless $wbuf && @$wbuf;
 674         }
 675 }
 676
 677 sub long_response ($$;@) {
 678         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 679
 680         my $sock = $self->{sock} or return;
 681         # make sure we disable reading during a long response,
 682         # clients should not be sending us stuff and making us do more
 683         # work while we are stream a response to them
 684         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
 685         long_step($self); # kick off!
 686         undef;
 687 }
 688
 689 sub hdr_msgid_range_i {
 690         my ($self, $beg, $end) = @_;
 691         my $r = $self->{ibx}->mm->msg_range($beg, $end);
 692         @$r or return;
 693         $self->msg_more(join('', map { "$_->[0] <$_->[1]>\r\n" } @$r));
 694         1;
 695 }
 696
 697 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 698         my ($self, $xhdr, $range) = @_;
 699
 700         if (defined $range && $range =~ $ONE_MSGID) {
 701                 my ($ibx, $n) = mid_lookup($self, $1);
 702                 return r430 unless $n;
 703                 hdr_mid_response($self, $xhdr, $ibx, $n, $range, $range);
 704         } else { # numeric range
 705                 $range = $self->{article} unless defined $range;
 706                 my $r = get_range($self, $range);
 707                 return $r unless ref $r;
 708                 more($self, $xhdr ? r221 : r225);
 709                 long_response($self, \&hdr_msgid_range_i, @$r);
 710         }
 711 }
 712
 713 sub mid_lookup ($$) {
 714         my ($self, $mid) = @_;
 715         my $cur_ibx = $self->{ibx};
 716         if ($cur_ibx) {
 717                 my $n = $cur_ibx->mm->num_for($mid);
 718                 return ($cur_ibx, $n) if defined $n;
 719         }
 720         my $pi_cfg = $self->{nntpd}->{pi_cfg};
 721         if (my $ALL = $pi_cfg->ALL) {
 722                 my ($id, $prev);
 723                 while (my $smsg = $ALL->over->next_by_mid($mid, \$id, \$prev)) {
 724                         my $xr3 = $ALL->over->get_xref3($smsg->{num});
 725                         if (my @x = grep(/:$smsg->{blob}\z/, @$xr3)) {
 726                                 my ($ngname, $xnum) = split(/:/, $x[0]);
 727                                 my $ibx = $pi_cfg->{-by_newsgroup}->{$ngname};
 728                                 return ($ibx, $xnum) if $ibx;
 729                                 # fall through to trying all xref3s
 730                         } else {
 731                                 warn <<EOF;
 732 W: xref3 missing for <$mid> ($smsg->{blob}) in $ALL->{topdir}, -extindex bug?
 733 EOF
 734                         }
 735                         # try all xref3s
 736                         for my $x (@$xr3) {
 737                                 my ($ngname, $xnum) = split(/:/, $x);
 738                                 my $ibx = $pi_cfg->{-by_newsgroup}->{$ngname};
 739                                 return ($ibx, $xnum) if $ibx;
 740                                 warn "W: `$ngname' does not exist for #$xnum\n";
 741                         }
 742                 }
 743                 # no warning here, $mid is just invalid
 744         } else { # slow path for non-ALL users
 745                 for my $ibx (values %{$pi_cfg->{-by_newsgroup}}) {
 746                         next if defined $cur_ibx && $ibx eq $cur_ibx;
 747                         my $n = $ibx->mm->num_for($mid);
 748                         return ($ibx, $n) if defined $n;
 749                 }
 750         }
 751         (undef, undef);
 752 }
 753
 754 sub xref_range_i {
 755         my ($self, $beg, $end) = @_;
 756         my $ibx = $self->{ibx};
 757         my $msgs = $ibx->over->query_xover($$beg, $end);
 758         scalar(@$msgs) or return;
 759         $$beg = $msgs->[-1]->{num} + 1;
 760         $self->msg_more(join('', map {
 761                 "$_->{num} ".xref($self, $ibx, $_) . "\r\n";
 762         } @$msgs));
 763         1;
 764 }
 765
 766 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 767         my ($self, $xhdr, $range) = @_;
 768
 769         if (defined $range && $range =~ $ONE_MSGID) {
 770                 my $mid = $1;
 771                 my ($ibx, $n) = mid_lookup($self, $mid);
 772                 return r430 unless $n;
 773                 my $smsg = $ibx->over->get_art($n) or return;
 774                 hdr_mid_response($self, $xhdr, $ibx, $n, $range,
 775                                 xref($self, $ibx, $smsg));
 776         } else { # numeric range
 777                 $range = $self->{article} unless defined $range;
 778                 my $r = get_range($self, $range);
 779                 return $r unless ref $r;
 780                 more($self, $xhdr ? r221 : r225);
 781                 long_response($self, \&xref_range_i, @$r);
 782         }
 783 }
 784
 785 sub over_header_for {
 786         my ($over, $num, $field) = @_;
 787         my $smsg = $over->get_art($num) or return;
 788         return PublicInbox::Smsg::date($smsg) if $field eq 'date';
 789         $smsg->{$field};
 790 }
 791
 792 sub smsg_range_i {
 793         my ($self, $beg, $end, $field) = @_;
 794         my $over = $self->{ibx}->over;
 795         my $msgs = $over->query_xover($$beg, $end);
 796         scalar(@$msgs) or return;
 797         my $tmp = '';
 798
 799         # ->{$field} is faster than ->$field invocations, so favor that.
 800         if ($field eq 'date') {
 801                 for my $s (@$msgs) {
 802                         $tmp .= "$s->{num} ".PublicInbox::Smsg::date($s)."\r\n"
 803                 }
 804         } else {
 805                 for my $s (@$msgs) {
 806                         $tmp .= "$s->{num} $s->{$field}\r\n";
 807                 }
 808         }
 809         utf8::encode($tmp);
 810         $self->msg_more($tmp);
 811         $$beg = $msgs->[-1]->{num} + 1;
 812 }
 813
 814 sub hdr_smsg ($$$$) {
 815         my ($self, $xhdr, $field, $range) = @_;
 816         if (defined $range && $range =~ $ONE_MSGID) {
 817                 my ($ibx, $n) = mid_lookup($self, $1);
 818                 return r430 unless defined $n;
 819                 my $v = over_header_for($ibx->over, $n, $field);
 820                 hdr_mid_response($self, $xhdr, $ibx, $n, $range, $v);
 821         } else { # numeric range
 822                 $range = $self->{article} unless defined $range;
 823                 my $r = get_range($self, $range);
 824                 return $r unless ref $r;
 825                 more($self, $xhdr ? r221 : r225);
 826                 long_response($self, \&smsg_range_i, @$r, $field);
 827         }
 828 }
 829
 830 sub do_hdr ($$$;$) {
 831         my ($self, $xhdr, $header, $range) = @_;
 832         my $sub = lc $header;
 833         if ($sub eq 'message-id') {
 834                 hdr_message_id($self, $xhdr, $range);
 835         } elsif ($sub eq 'xref') {
 836                 hdr_xref($self, $xhdr, $range);
 837         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 838                                 bytes|lines)\z/x) {
 839                 hdr_smsg($self, $xhdr, $sub, $range);
 840         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 841                 hdr_smsg($self, $xhdr, $1, $range);
 842         } else {
 843                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 844         }
 845 }
 846
 847 # RFC 3977
 848 sub cmd_hdr ($$;$) {
 849         my ($self, $header, $range) = @_;
 850         do_hdr($self, 0, $header, $range);
 851 }
 852
 853 # RFC 2980
 854 sub cmd_xhdr ($$;$) {
 855         my ($self, $header, $range) = @_;
 856         do_hdr($self, 1, $header, $range);
 857 }
 858
 859 sub hdr_mid_prefix ($$$$$) {
 860         my ($self, $xhdr, $ibx, $n, $mid) = @_;
 861         return $mid if $xhdr;
 862
 863         # HDR for RFC 3977 users
 864         if (my $cur_ibx = $self->{ibx}) {
 865                 ($cur_ibx eq $ibx) ? $n : '0';
 866         } else {
 867                 '0';
 868         }
 869 }
 870
 871 sub hdr_mid_response ($$$$$$) {
 872         my ($self, $xhdr, $ibx, $n, $mid, $v) = @_;
 873         my $res = '';
 874         if ($xhdr) {
 875                 $res .= r221 . "\r\n";
 876                 $res .= "$mid $v\r\n";
 877         } else {
 878                 $res .= r225 . "\r\n";
 879                 my $pfx = hdr_mid_prefix($self, $xhdr, $ibx, $n, $mid);
 880                 $res .= "$pfx $v\r\n";
 881         }
 882         res($self, $res .= '.');
 883         undef;
 884 }
 885
 886 sub xrover_i {
 887         my ($self, $beg, $end) = @_;
 888         my $h = over_header_for($self->{ibx}->over, $$beg, 'references');
 889         more($self, "$$beg $h") if defined($h);
 890         $$beg++ < $end;
 891 }
 892
 893 sub cmd_xrover ($;$) {
 894         my ($self, $range) = @_;
 895         my $ibx = $self->{ibx} or return '412 no newsgroup selected';
 896         (defined $range && $range =~ /[<>]/) and
 897                 return '420 No article(s) selected'; # no message IDs
 898
 899         $range = $self->{article} unless defined $range;
 900         my $r = get_range($self, $range);
 901         return $r unless ref $r;
 902         more($self, '224 Overview information follows');
 903         long_response($self, \&xrover_i, @$r);
 904 }
 905
 906 sub over_line ($$$) {
 907         my ($self, $ibx, $smsg) = @_;
 908         # n.b. field access and procedural calls can be
 909         # 10%-15% faster than OO method calls:
 910         my $s = join("\t", $smsg->{num},
 911                 $smsg->{subject},
 912                 $smsg->{from},
 913                 PublicInbox::Smsg::date($smsg),
 914                 "<$smsg->{mid}>",
 915                 $smsg->{references},
 916                 $smsg->{bytes},
 917                 $smsg->{lines},
 918                 "Xref: " . xref($self, $ibx, $smsg));
 919         utf8::encode($s);
 920         $s .= "\r\n";
 921 }
 922
 923 sub cmd_over ($;$) {
 924         my ($self, $range) = @_;
 925         if ($range && $range =~ $ONE_MSGID) {
 926                 my ($ibx, $n) = mid_lookup($self, $1);
 927                 defined $n or return r430;
 928                 my $smsg = $ibx->over->get_art($n) or return r430;
 929                 more($self, '224 Overview information follows (multi-line)');
 930
 931                 # Only set article number column if it's the current group
 932                 # (RFC 3977 8.3.2)
 933                 my $cur_ibx = $self->{ibx};
 934                 if (!$cur_ibx || $cur_ibx ne $ibx) {
 935                         # set {-orig_num} for nntp_xref_for
 936                         $smsg->{-orig_num} = $smsg->{num};
 937                         $smsg->{num} = 0;
 938                 }
 939                 $self->msg_more(over_line($self, $ibx, $smsg));
 940                 '.';
 941         } else {
 942                 cmd_xover($self, $range);
 943         }
 944 }
 945
 946 sub xover_i {
 947         my ($self, $beg, $end) = @_;
 948         my $ibx = $self->{ibx};
 949         my $msgs = $ibx->over->query_xover($$beg, $end);
 950         my $nr = scalar @$msgs or return;
 951
 952         # OVERVIEW.FMT
 953         $self->msg_more(join('', map {
 954                 over_line($self, $ibx, $_);
 955                 } @$msgs));
 956         $$beg = $msgs->[-1]->{num} + 1;
 957 }
 958
 959 sub cmd_xover ($;$) {
 960         my ($self, $range) = @_;
 961         $range = $self->{article} unless defined $range;
 962         my $r = get_range($self, $range);
 963         return $r unless ref $r;
 964         my ($beg, $end) = @$r;
 965         more($self, "224 Overview information follows for $$beg to $end");
 966         long_response($self, \&xover_i, @$r);
 967 }
 968
 969 sub compressed { undef }
 970
 971 sub cmd_starttls ($) {
 972         my ($self) = @_;
 973         my $sock = $self->{sock} or return;
 974         # RFC 4642 2.2.1
 975         return r502 if ($sock->can('accept_SSL') || $self->compressed);
 976         my $opt = $self->{nntpd}->{accept_tls} or
 977                 return '580 can not initiate TLS negotiation';
 978         res($self, '382 Continue with TLS negotiation');
 979         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 980         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 981         undef;
 982 }
 983
 984 # RFC 8054
 985 sub cmd_compress ($$) {
 986         my ($self, $alg) = @_;
 987         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 988         return r502 if $self->compressed;
 989         PublicInbox::NNTPdeflate->enable($self);
 990         $self->requeue;
 991         undef
 992 }
 993
 994 sub zflush {} # overridden by NNTPdeflate
 995
 996 sub cmd_xpath ($$) {
 997         my ($self, $mid) = @_;
 998         return r501 unless $mid =~ $ONE_MSGID;
 999         $mid = $1;
1000         my @paths;
1001         my $pi_cfg = $self->{nntpd}->{pi_cfg};
1002         my $groups = $pi_cfg->{-by_newsgroup};
1003         if (my $ALL = $pi_cfg->ALL) {
1004                 my ($id, $prev, %seen);
1005                 while (my $smsg = $ALL->over->next_by_mid($mid, \$id, \$prev)) {
1006                         my $xr3 = $ALL->over->get_xref3($smsg->{num});
1007                         for my $x (@$xr3) {
1008                                 my ($ngname, $n) = split(/:/, $x);
1009                                 $x = "$ngname/$n";
1010                                 if ($groups->{$ngname} && !$seen{$x}++) {
1011                                         push(@paths, $x);
1012                                 }
1013                         }
1014                 }
1015         } else { # slow path, no point in using long_response
1016                 for my $ibx (values %$groups) {
1017                         my $n = $ibx->mm->num_for($mid) // next;
1018                         push @paths, "$ibx->{newsgroup}/$n";
1019                 }
1020         }
1021         return '430 no such article on server' unless @paths;
1022         '223 '.join(' ', sort(@paths));
1023 }
1024
1025 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
1026
1027 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
1028
1029 sub do_write ($$) {
1030         my $self = $_[0];
1031         my $done = $self->write(\($_[1]));
1032         return 0 unless $self->{sock};
1033
1034         $done;
1035 }
1036
1037 sub err ($$;@) {
1038         my ($self, $fmt, @args) = @_;
1039         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
1040 }
1041
1042 sub out ($$;@) {
1043         my ($self, $fmt, @args) = @_;
1044         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
1045 }
1046
1047 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
1048 sub event_step {
1049         my ($self) = @_;
1050
1051         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
1052
1053         $self->update_idle_time;
1054         # only read more requests if we've drained the write buffer,
1055         # otherwise we can be buffering infinitely w/o backpressure
1056
1057         my $rbuf = $self->{rbuf} // \(my $x = '');
1058         my $line = index($$rbuf, "\n");
1059         while ($line < 0) {
1060                 return $self->close if length($$rbuf) >= LINE_MAX;
1061                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
1062                 $line = index($$rbuf, "\n");
1063         }
1064         $line = substr($$rbuf, 0, $line + 1, '');
1065         $line =~ s/\r?\n\z//s;
1066         return $self->close if $line =~ /[[:cntrl:]]/s;
1067
1068         my $t0 = now();
1069         my $fd = fileno($self->{sock});
1070         my $r = eval { process_line($self, $line) };
1071         my $pending = $self->{wbuf} ? ' pending' : '';
1072         out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
1073         return $self->close if $r < 0;
1074         $self->rbuf_idle($rbuf);
1075         $self->update_idle_time;
1076
1077         # maybe there's more pipelined data, or we'll have
1078         # to register it for socket-readiness notifications
1079         $self->requeue unless $pending;
1080 }
1081
1082 # for graceful shutdown in PublicInbox::Daemon:
1083 sub busy {
1084         my ($self, $now) = @_;
1085         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1086 }
1087
1088 1;