lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article ng);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 use PublicInbox::DS qw(now);
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         LINE_MAX => 512, # RFC 977 section 2.3
  22         r501 => '501 command syntax error',
  23         r502 => '502 Command unavailable',
  24         r221 => '221 Header follows',
  25         r224 => '224 Overview information follows (multi-line)',
  26         r225 => '225 Headers follow (multi-line)',
  27         r430 => '430 No article with that message-id',
  28 };
  29 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  30 use Errno qw(EAGAIN);
  31
  32 my @OVERVIEW = qw(Subject From Date Message-ID References);
  33 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  34                 "Xref:full\r\n";
  35 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  36                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  37 my $CAPABILITIES = <<"";
  38 101 Capability list:\r
  39 VERSION 2\r
  40 READER\r
  41 NEWNEWS\r
  42 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  43 HDR\r
  44 OVER\r
  45
  46 my $have_deflate;
  47 my $EXPMAP; # fd -> [ idle_time, $self ]
  48 my $expt;
  49 our $EXPTIME = 180; # 3 minutes
  50
  51 sub update_idle_time ($) {
  52         my ($self) = @_;
  53         my $sock = $self->{sock} or return;
  54         $EXPMAP->{fileno($sock)} = [ now(), $self ];
  55 }
  56
  57 sub expire_old () {
  58         my $now = now();
  59         my $exp = $EXPTIME;
  60         my $old = $now - $exp;
  61         my %new;
  62         while (my ($fd, $v) = each %$EXPMAP) {
  63                 my ($idle_time, $nntp) = @$v;
  64                 if ($idle_time < $old) {
  65                         if (!$nntp->shutdn) {
  66                                 $new{$fd} = $v;
  67                         }
  68                 } else {
  69                         $new{$fd} = $v;
  70                 }
  71         }
  72         $EXPMAP = \%new;
  73         $expt = scalar(keys %new) ? PublicInbox::EvCleanup::later(*expire_old)
  74                                   : undef;
  75 }
  76
  77 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  78
  79 sub new ($$$) {
  80         my ($class, $sock, $nntpd) = @_;
  81         my $self = fields::new($class);
  82         my $ev = EPOLLIN;
  83         my $wbuf;
  84         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  85                 return CORE::close($sock) if $! != EAGAIN;
  86                 $ev = PublicInbox::TLS::epollbit();
  87                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  88         }
  89         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  90         $self->{nntpd} = $nntpd;
  91         if ($wbuf) {
  92                 $self->{wbuf} = $wbuf;
  93         } else {
  94                 greet($self);
  95         }
  96         update_idle_time($self);
  97         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
  98         $self;
  99 }
 100
 101 sub args_ok ($$) {
 102         my ($cb, $argc) = @_;
 103         my $tot = prototype $cb;
 104         my ($nreq, undef) = split(';', $tot);
 105         $nreq = ($nreq =~ tr/$//) - 1;
 106         $tot = ($tot =~ tr/$//) - 1;
 107         ($argc <= $tot && $argc >= $nreq);
 108 }
 109
 110 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 111 sub process_line ($$) {
 112         my ($self, $l) = @_;
 113         my ($req, @args) = split(/[ \t]/, $l);
 114         return 1 unless defined($req); # skip blank line
 115         $req = eval {
 116                 no strict 'refs';
 117                 *{'cmd_'.lc($req)}{CODE};
 118         };
 119         return res($self, '500 command not recognized') unless $req;
 120         return res($self, r501) unless args_ok($req, scalar @args);
 121
 122         my $res = eval { $req->($self, @args) };
 123         my $err = $@;
 124         if ($err && $self->{sock}) {
 125                 local $/ = "\n";
 126                 chomp($l);
 127                 err($self, 'error from: %s (%s)', $l, $err);
 128                 $res = '503 program fault - command not performed';
 129         }
 130         return 0 unless defined $res;
 131         res($self, $res);
 132 }
 133
 134 # The keyword argument is not used (rfc3977 5.2.2)
 135 sub cmd_capabilities ($;$) {
 136         my ($self, undef) = @_;
 137         my $res = $CAPABILITIES;
 138         if (ref($self->{sock}) ne 'IO::Socket::SSL' &&
 139                         $self->{nntpd}->{accept_tls}) {
 140                 $res .= "STARTTLS\r\n";
 141         }
 142         $res .= '.';
 143 }
 144
 145 sub cmd_mode ($$) {
 146         my ($self, $arg) = @_;
 147         $arg = uc $arg;
 148         return r501 unless $arg eq 'READER';
 149         '201 Posting prohibited';
 150 }
 151
 152 sub cmd_slave ($) { '202 slave status noted' }
 153
 154 sub cmd_xgtitle ($;$) {
 155         my ($self, $wildmat) = @_;
 156         more($self, '282 list of groups and descriptions follows');
 157         list_newsgroups($self, $wildmat);
 158         '.'
 159 }
 160
 161 sub list_overview_fmt ($) {
 162         my ($self) = @_;
 163         $self->msg_more($OVERVIEW_FMT);
 164 }
 165
 166 sub list_headers ($;$) {
 167         my ($self) = @_;
 168         $self->msg_more($LIST_HEADERS);
 169 }
 170
 171 sub list_active ($;$) {
 172         my ($self, $wildmat) = @_;
 173         wildmat2re($wildmat);
 174         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 175                 $ng->{newsgroup} =~ $wildmat or next;
 176                 group_line($self, $ng);
 177         }
 178 }
 179
 180 sub list_active_times ($;$) {
 181         my ($self, $wildmat) = @_;
 182         wildmat2re($wildmat);
 183         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 184                 $ng->{newsgroup} =~ $wildmat or next;
 185                 my $c = eval { $ng->mm->created_at } || time;
 186                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 187         }
 188 }
 189
 190 sub list_newsgroups ($;$) {
 191         my ($self, $wildmat) = @_;
 192         wildmat2re($wildmat);
 193         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 194                 $ng->{newsgroup} =~ $wildmat or next;
 195                 my $d = $ng->description;
 196                 more($self, "$ng->{newsgroup} $d");
 197         }
 198 }
 199
 200 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 201 sub cmd_list ($;$$) {
 202         my ($self, @args) = @_;
 203         if (scalar @args) {
 204                 my $arg = shift @args;
 205                 $arg =~ tr/A-Z./a-z_/;
 206                 $arg = "list_$arg";
 207
 208                 $arg = eval {
 209                         no strict 'refs';
 210                         *{$arg}{CODE};
 211                 };
 212                 return r501 unless $arg && args_ok($arg, scalar @args);
 213                 more($self, '215 information follows');
 214                 $arg->($self, @args);
 215         } else {
 216                 more($self, '215 list of newsgroups follows');
 217                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 218                         group_line($self, $ng);
 219                 }
 220         }
 221         '.'
 222 }
 223
 224 sub cmd_listgroup ($;$) {
 225         my ($self, $group) = @_;
 226         if (defined $group) {
 227                 my $res = cmd_group($self, $group);
 228                 return $res if ($res !~ /\A211 /);
 229                 more($self, $res);
 230         }
 231
 232         $self->{ng} or return '412 no newsgroup selected';
 233         my $n = 0;
 234         long_response($self, sub {
 235                 my $ary = $self->{ng}->mm->ids_after(\$n);
 236                 scalar @$ary or return;
 237                 more($self, join("\r\n", @$ary));
 238                 1;
 239         });
 240 }
 241
 242 sub parse_time ($$;$) {
 243         my ($date, $time, $gmt) = @_;
 244         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 245         if (defined $gmt) {
 246                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 247                 $gmt = 1;
 248         }
 249         my @now = $gmt ? gmtime : localtime;
 250         my ($YYYY, $MM, $DD);
 251         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 252                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 253         } else { # legacy clients send YYMMDD
 254                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 255                 my $cur_year = $now[5] + 1900;
 256                 if ($YYYY > $cur_year) {
 257                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 258                 }
 259         }
 260         if ($gmt) {
 261                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 262         } else {
 263                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 264         }
 265 }
 266
 267 sub group_line ($$) {
 268         my ($self, $ng) = @_;
 269         my ($min, $max) = $ng->mm->minmax;
 270         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 271 }
 272
 273 sub cmd_newgroups ($$$;$$) {
 274         my ($self, $date, $time, $gmt, $dists) = @_;
 275         my $ts = eval { parse_time($date, $time, $gmt) };
 276         return r501 if $@;
 277
 278         # TODO dists
 279         more($self, '231 list of new newsgroups follows');
 280         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 281                 my $c = eval { $ng->mm->created_at } || 0;
 282                 next unless $c > $ts;
 283                 group_line($self, $ng);
 284         }
 285         '.'
 286 }
 287
 288 sub wildmat2re (;$) {
 289         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 290         my %keep;
 291         my $salt = rand;
 292         my $tmp = $_[0];
 293
 294         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 295                 my $orig = $1;
 296                 my $key = sha1_hex($orig . $salt);
 297                 $orig =~ s/([^\w\-])+/\Q$1/g;
 298                 $keep{$key} = $orig;
 299                 $key
 300                 #gex;
 301         my %map = ('*' => '.*', '?' => '.' );
 302         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 303         if (scalar %keep) {
 304                 $tmp =~ s#([a-f0-9]{40})#
 305                         my $orig = $keep{$1};
 306                         defined $orig ? $orig : $1;
 307                         #ge;
 308         }
 309         $_[0] = qr/\A$tmp\z/;
 310 }
 311
 312 sub ngpat2re (;$) {
 313         return $_[0] = qr/\A\z/ unless defined $_[0];
 314         my %map = ('*' => '.*', ',' => '|');
 315         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 316         $_[0] = qr/\A(?:$_[0])\z/;
 317 }
 318
 319 sub cmd_newnews ($$$$;$$) {
 320         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 321         my $ts = eval { parse_time($date, $time, $gmt) };
 322         return r501 if $@;
 323         more($self, '230 list of new articles by message-id follows');
 324         my ($keep, $skip) = split('!', $newsgroups, 2);
 325         ngpat2re($keep);
 326         ngpat2re($skip);
 327         my @over;
 328         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 329                 $ng->{newsgroup} =~ $keep or next;
 330                 $ng->{newsgroup} =~ $skip and next;
 331                 my $over = $ng->over or next;
 332                 push @over, $over;
 333         };
 334         return '.' unless @over;
 335
 336         my $prev = 0;
 337         long_response($self, sub {
 338                 my $over = $over[0];
 339                 my $msgs = $over->query_ts($ts, $prev);
 340                 if (scalar @$msgs) {
 341                         more($self, '<' .
 342                                 join(">\r\n<", map { $_->mid } @$msgs ).
 343                                 '>');
 344                         $prev = $msgs->[-1]->{num};
 345                 } else {
 346                         shift @over;
 347                         if (@over) { # continue onto next newsgroup
 348                                 $prev = 0;
 349                                 return 1;
 350                         } else { # break out of the long response.
 351                                 return;
 352                         }
 353                 }
 354         });
 355 }
 356
 357 sub cmd_group ($$) {
 358         my ($self, $group) = @_;
 359         my $no_such = '411 no such news group';
 360         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 361
 362         $self->{ng} = $ng;
 363         my ($min, $max) = $ng->mm->minmax;
 364         $min ||= 0;
 365         $max ||= 0;
 366         $self->{article} = $min;
 367         my $est_size = $max - $min;
 368         "211 $est_size $min $max $group";
 369 }
 370
 371 sub article_adj ($$) {
 372         my ($self, $off) = @_;
 373         my $ng = $self->{ng} or return '412 no newsgroup selected';
 374
 375         my $n = $self->{article};
 376         defined $n or return '420 no current article has been selected';
 377
 378         $n += $off;
 379         my $mid = $ng->mm->mid_for($n);
 380         unless ($mid) {
 381                 $n = $off > 0 ? 'next' : 'previous';
 382                 return "421 no $n article in this group";
 383         }
 384         $self->{article} = $n;
 385         "223 $n <$mid> article retrieved - request text separately";
 386 }
 387
 388 sub cmd_next ($) { article_adj($_[0], 1) }
 389 sub cmd_last ($) { article_adj($_[0], -1) }
 390
 391 # We want to encourage using email and CC-ing everybody involved to avoid
 392 # the single-point-of-failure a single server provides.
 393 sub cmd_post ($) {
 394         my ($self) = @_;
 395         my $ng = $self->{ng};
 396         $ng ? "440 mailto:$ng->{-primary_address} to post"
 397                 : '440 posting not allowed'
 398 }
 399
 400 sub cmd_quit ($) {
 401         my ($self) = @_;
 402         res($self, '205 closing connection - goodbye!');
 403         $self->shutdn;
 404         undef;
 405 }
 406
 407 sub header_append ($$$) {
 408         my ($hdr, $k, $v) = @_;
 409         my @v = $hdr->header($k);
 410         foreach (@v) {
 411                 return if $v eq $_;
 412         }
 413         $hdr->header_set($k, @v, $v);
 414 }
 415
 416 sub xref ($$$$) {
 417         my ($self, $ng, $n, $mid) = @_;
 418         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 419
 420         # num_for is pretty cheap and sometimes we'll lookup the existence
 421         # of an article without getting even the OVER info.  In other words,
 422         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 423         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 424         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 425                 next if $ng eq $other;
 426                 my $num = eval { $other->mm->num_for($mid) } or next;
 427                 $ret .= " $other->{newsgroup}:$num";
 428         }
 429         $ret;
 430 }
 431
 432 sub set_nntp_headers ($$$$$) {
 433         my ($self, $hdr, $ng, $n, $mid) = @_;
 434
 435         # why? leafnode requires a Path: header for some inexplicable
 436         # reason.  We'll fake the shortest one possible.
 437         $hdr->header_set('Path', 'y');
 438
 439         # leafnode (and maybe other NNTP clients) have trouble dealing
 440         # with v2 messages which have multiple Message-IDs (either due
 441         # to our own content-based dedupe or buggy git-send-email versions).
 442         my @mids = $hdr->header('Message-ID');
 443         if (scalar(@mids) > 1) {
 444                 my $mid0 = "<$mid>";
 445                 $hdr->header_set('Message-ID', $mid0);
 446                 my @alt = $hdr->header('X-Alt-Message-ID');
 447                 my %seen = map { $_ => 1 } (@alt, $mid0);
 448                 foreach my $m (@mids) {
 449                         next if $seen{$m}++;
 450                         push @alt, $m;
 451                 }
 452                 $hdr->header_set('X-Alt-Message-ID', @alt);
 453         }
 454
 455         # clobber some
 456         my $xref = xref($self, $ng, $n, $mid);
 457         $hdr->header_set('Xref', $xref);
 458         $xref =~ s/:[0-9]+//g;
 459         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 460         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 461         if (my $url = $ng->base_url) {
 462                 $mid = mid_escape($mid);
 463                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 464                 header_append($hdr, 'List-Archive', "<$url>");
 465         }
 466 }
 467
 468 sub art_lookup ($$$) {
 469         my ($self, $art, $set_headers) = @_;
 470         my $ng = $self->{ng};
 471         my ($n, $mid);
 472         my $err;
 473         if (defined $art) {
 474                 if ($art =~ /\A[0-9]+\z/) {
 475                         $err = '423 no such article number in this group';
 476                         $n = int($art);
 477                         goto find_mid;
 478                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 479                         $mid = $1;
 480                         $err = r430;
 481                         $n = $ng->mm->num_for($mid) if $ng;
 482                         goto found if defined $n;
 483                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 484                                 $n = $g->mm->num_for($mid);
 485                                 if (defined $n) {
 486                                         $ng = $g;
 487                                         goto found;
 488                                 }
 489                         }
 490                         return $err;
 491                 } else {
 492                         return r501;
 493                 }
 494         } else {
 495                 $err = '420 no current article has been selected';
 496                 $n = $self->{article};
 497                 defined $n or return $err;
 498 find_mid:
 499                 $ng or return '412 no newsgroup has been selected';
 500                 $mid = $ng->mm->mid_for($n);
 501                 defined $mid or return $err;
 502         }
 503 found:
 504         my $smsg = $ng->over->get_art($n) or return $err;
 505         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 506
 507         # Email::Simple->new will modify $msg in-place as documented
 508         # in its manpage, so what's left is the body and we won't need
 509         # to call Email::Simple::body(), later
 510         my $hdr = Email::Simple->new($msg)->header_obj;
 511         set_nntp_headers($self, $hdr, $ng, $n, $mid) if $set_headers;
 512         [ $n, $mid, $msg, $hdr ];
 513 }
 514
 515 sub msg_body_write ($$) {
 516         my ($self, $msg) = @_;
 517
 518         # these can momentarily double the memory consumption :<
 519         $$msg =~ s/^\./../smg;
 520         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 521         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 522         $self->msg_more($$msg);
 523         '.'
 524 }
 525
 526 sub set_art {
 527         my ($self, $art) = @_;
 528         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 529 }
 530
 531 sub msg_hdr_write ($$$) {
 532         my ($self, $hdr, $body_follows) = @_;
 533         $hdr = $hdr->as_string;
 534         utf8::encode($hdr);
 535         $hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 536
 537         # for leafnode compatibility, we need to ensure Message-ID headers
 538         # are only a single line.  We can't subclass Email::Simple::Header
 539         # and override _default_fold_at in here, either; since that won't
 540         # affect messages already in the archive.
 541         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 542         $hdr .= "\r\n" if $body_follows;
 543         $self->msg_more($hdr);
 544 }
 545
 546 sub cmd_article ($;$) {
 547         my ($self, $art) = @_;
 548         my $r = art_lookup($self, $art, 1);
 549         return $r unless ref $r;
 550         my ($n, $mid, $msg, $hdr) = @$r;
 551         set_art($self, $art);
 552         more($self, "220 $n <$mid> article retrieved - head and body follow");
 553         msg_hdr_write($self, $hdr, 1);
 554         msg_body_write($self, $msg);
 555 }
 556
 557 sub cmd_head ($;$) {
 558         my ($self, $art) = @_;
 559         my $r = art_lookup($self, $art, 2);
 560         return $r unless ref $r;
 561         my ($n, $mid, undef, $hdr) = @$r;
 562         set_art($self, $art);
 563         more($self, "221 $n <$mid> article retrieved - head follows");
 564         msg_hdr_write($self, $hdr, 0);
 565         '.'
 566 }
 567
 568 sub cmd_body ($;$) {
 569         my ($self, $art) = @_;
 570         my $r = art_lookup($self, $art, 0);
 571         return $r unless ref $r;
 572         my ($n, $mid, $msg) = @$r;
 573         set_art($self, $art);
 574         more($self, "222 $n <$mid> article retrieved - body follows");
 575         msg_body_write($self, $msg);
 576 }
 577
 578 sub cmd_stat ($;$) {
 579         my ($self, $art) = @_;
 580         my $r = art_lookup($self, $art, 0);
 581         return $r unless ref $r;
 582         my ($n, $mid) = @$r;
 583         set_art($self, $art);
 584         "223 $n <$mid> article retrieved - request text separately";
 585 }
 586
 587 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 588
 589 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 590
 591 sub cmd_help ($) {
 592         my ($self) = @_;
 593         more($self, '100 help text follows');
 594         '.'
 595 }
 596
 597 sub get_range ($$) {
 598         my ($self, $range) = @_;
 599         my $ng = $self->{ng} or return '412 no news group has been selected';
 600         defined $range or return '420 No article(s) selected';
 601         my ($beg, $end);
 602         my ($min, $max) = $ng->mm->minmax;
 603         if ($range =~ /\A([0-9]+)\z/) {
 604                 $beg = $end = $1;
 605         } elsif ($range =~ /\A([0-9]+)-\z/) {
 606                 ($beg, $end) = ($1, $max);
 607         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 608                 ($beg, $end) = ($1, $2);
 609         } else {
 610                 return r501;
 611         }
 612         $beg = $min if ($beg < $min);
 613         $end = $max if ($end > $max);
 614         return '420 No article(s) selected' if ($beg > $end);
 615         [ $beg, $end ];
 616 }
 617
 618 sub long_response ($$) {
 619         my ($self, $cb) = @_; # cb returns true if more, false if done
 620
 621         my $fd = fileno($self->{sock});
 622         defined $fd or return;
 623         # make sure we disable reading during a long response,
 624         # clients should not be sending us stuff and making us do more
 625         # work while we are stream a response to them
 626         my $t0 = now();
 627         my $long_cb; # DANGER: self-referential
 628         $long_cb = sub {
 629                 # wbuf is unset or empty, here; $cb may add to it
 630                 my $more = eval { $cb->() };
 631                 if ($@ || !$self->{sock}) { # something bad happened...
 632                         $long_cb = undef;
 633                         my $diff = now() - $t0;
 634                         if ($@) {
 635                                 err($self,
 636                                     "%s during long response[$fd] - %0.6f",
 637                                     $@, $diff);
 638                         }
 639                         out($self, " deferred[$fd] aborted - %0.6f", $diff);
 640                         $self->close;
 641                 } elsif ($more) { # $self->{wbuf}:
 642                         update_idle_time($self);
 643
 644                         # COMPRESS users all share the same DEFLATE context.
 645                         # Flush it here to ensure clients don't see
 646                         # each other's data
 647                         $self->zflush;
 648
 649                         # no recursion, schedule another call ASAP
 650                         # but only after all pending writes are done
 651                         my $wbuf = $self->{wbuf} ||= [];
 652                         push @$wbuf, $long_cb;
 653
 654                         # wbuf may be populated by $cb, no need to rearm if so:
 655                         $self->requeue if scalar(@$wbuf) == 1;
 656                 } else { # all done!
 657                         $long_cb = undef;
 658                         res($self, '.');
 659                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 660                         my $wbuf = $self->{wbuf};
 661                         $self->requeue unless $wbuf && @$wbuf;
 662                 }
 663         };
 664         $self->write($long_cb); # kick off!
 665         undef;
 666 }
 667
 668 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 669         my ($self, $xhdr, $range) = @_;
 670
 671         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 672                 my ($ng, $n) = mid_lookup($self, $1);
 673                 return r430 unless $n;
 674                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 675         } else { # numeric range
 676                 $range = $self->{article} unless defined $range;
 677                 my $r = get_range($self, $range);
 678                 return $r unless ref $r;
 679                 my $mm = $self->{ng}->mm;
 680                 my ($beg, $end) = @$r;
 681                 more($self, $xhdr ? r221 : r225);
 682                 long_response($self, sub {
 683                         my $r = $mm->msg_range(\$beg, $end);
 684                         @$r or return;
 685                         more($self, join("\r\n", map {
 686                                 "$_->[0] <$_->[1]>"
 687                         } @$r));
 688                         1;
 689                 });
 690         }
 691 }
 692
 693 sub mid_lookup ($$) {
 694         my ($self, $mid) = @_;
 695         my $self_ng = $self->{ng};
 696         if ($self_ng) {
 697                 my $n = $self_ng->mm->num_for($mid);
 698                 return ($self_ng, $n) if defined $n;
 699         }
 700         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 701                 next if defined $self_ng && $ng eq $self_ng;
 702                 my $n = $ng->mm->num_for($mid);
 703                 return ($ng, $n) if defined $n;
 704         }
 705         (undef, undef);
 706 }
 707
 708 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 709         my ($self, $xhdr, $range) = @_;
 710
 711         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 712                 my $mid = $1;
 713                 my ($ng, $n) = mid_lookup($self, $mid);
 714                 return r430 unless $n;
 715                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 716                                 xref($self, $ng, $n, $mid));
 717         } else { # numeric range
 718                 $range = $self->{article} unless defined $range;
 719                 my $r = get_range($self, $range);
 720                 return $r unless ref $r;
 721                 my $ng = $self->{ng};
 722                 my $mm = $ng->mm;
 723                 my ($beg, $end) = @$r;
 724                 more($self, $xhdr ? r221 : r225);
 725                 long_response($self, sub {
 726                         my $r = $mm->msg_range(\$beg, $end);
 727                         @$r or return;
 728                         more($self, join("\r\n", map {
 729                                 my $num = $_->[0];
 730                                 "$num ".xref($self, $ng, $num, $_->[1]);
 731                         } @$r));
 732                         1;
 733                 });
 734         }
 735 }
 736
 737 sub over_header_for {
 738         my ($over, $num, $field) = @_;
 739         my $smsg = $over->get_art($num) or return;
 740         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 741         $smsg->{$field};
 742 }
 743
 744 sub hdr_searchmsg ($$$$) {
 745         my ($self, $xhdr, $field, $range) = @_;
 746         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 747                 my ($ng, $n) = mid_lookup($self, $1);
 748                 return r430 unless defined $n;
 749                 my $v = over_header_for($ng->over, $n, $field);
 750                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 751         } else { # numeric range
 752                 $range = $self->{article} unless defined $range;
 753                 my $over = $self->{ng}->over;
 754                 my $mm = $self->{ng}->mm;
 755                 my $r = get_range($self, $range);
 756                 return $r unless ref $r;
 757                 my ($beg, $end) = @$r;
 758                 more($self, $xhdr ? r221 : r225);
 759                 my $cur = $beg;
 760                 long_response($self, sub {
 761                         my $msgs = $over->query_xover($cur, $end);
 762                         my $nr = scalar @$msgs or return;
 763                         my $tmp = '';
 764                         foreach my $s (@$msgs) {
 765                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 766                         }
 767                         utf8::encode($tmp);
 768                         $self->msg_more($tmp);
 769                         $cur = $msgs->[-1]->{num} + 1;
 770                 });
 771         }
 772 }
 773
 774 sub do_hdr ($$$;$) {
 775         my ($self, $xhdr, $header, $range) = @_;
 776         my $sub = lc $header;
 777         if ($sub eq 'message-id') {
 778                 hdr_message_id($self, $xhdr, $range);
 779         } elsif ($sub eq 'xref') {
 780                 hdr_xref($self, $xhdr, $range);
 781         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 782                                 bytes|lines)\z/x) {
 783                 hdr_searchmsg($self, $xhdr, $sub, $range);
 784         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 785                 hdr_searchmsg($self, $xhdr, $1, $range);
 786         } else {
 787                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 788         }
 789 }
 790
 791 # RFC 3977
 792 sub cmd_hdr ($$;$) {
 793         my ($self, $header, $range) = @_;
 794         do_hdr($self, 0, $header, $range);
 795 }
 796
 797 # RFC 2980
 798 sub cmd_xhdr ($$;$) {
 799         my ($self, $header, $range) = @_;
 800         do_hdr($self, 1, $header, $range);
 801 }
 802
 803 sub hdr_mid_prefix ($$$$$) {
 804         my ($self, $xhdr, $ng, $n, $mid) = @_;
 805         return $mid if $xhdr;
 806
 807         # HDR for RFC 3977 users
 808         if (my $self_ng = $self->{ng}) {
 809                 ($self_ng eq $ng) ? $n : '0';
 810         } else {
 811                 '0';
 812         }
 813 }
 814
 815 sub hdr_mid_response ($$$$$$) {
 816         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 817         my $res = '';
 818         if ($xhdr) {
 819                 $res .= r221 . "\r\n";
 820                 $res .= "$mid $v\r\n";
 821         } else {
 822                 $res .= r225 . "\r\n";
 823                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 824                 $res .= "$pfx $v\r\n";
 825         }
 826         res($self, $res .= '.');
 827         undef;
 828 }
 829
 830 sub cmd_xrover ($;$) {
 831         my ($self, $range) = @_;
 832         my $ng = $self->{ng} or return '412 no newsgroup selected';
 833         (defined $range && $range =~ /[<>]/) and
 834                 return '420 No article(s) selected'; # no message IDs
 835
 836         $range = $self->{article} unless defined $range;
 837         my $r = get_range($self, $range);
 838         return $r unless ref $r;
 839         my ($beg, $end) = @$r;
 840         my $mm = $ng->mm;
 841         my $over = $ng->over;
 842         more($self, '224 Overview information follows');
 843
 844         long_response($self, sub {
 845                 my $h = over_header_for($over, $beg, 'references');
 846                 more($self, "$beg $h") if defined($h);
 847                 $beg++ < $end;
 848         });
 849 }
 850
 851 sub over_line ($$$$) {
 852         my ($self, $ng, $num, $smsg) = @_;
 853         # n.b. field access and procedural calls can be
 854         # 10%-15% faster than OO method calls:
 855         my $s = join("\t", $num,
 856                 $smsg->{subject},
 857                 $smsg->{from},
 858                 PublicInbox::SearchMsg::date($smsg),
 859                 "<$smsg->{mid}>",
 860                 $smsg->{references},
 861                 $smsg->{bytes},
 862                 $smsg->{lines},
 863                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 864         utf8::encode($s);
 865         $s
 866 }
 867
 868 sub cmd_over ($;$) {
 869         my ($self, $range) = @_;
 870         if ($range && $range =~ /\A<(.+)>\z/) {
 871                 my ($ng, $n) = mid_lookup($self, $1);
 872                 defined $n or return r430;
 873                 my $smsg = $ng->over->get_art($n) or return r430;
 874                 more($self, '224 Overview information follows (multi-line)');
 875
 876                 # Only set article number column if it's the current group
 877                 my $self_ng = $self->{ng};
 878                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 879                 more($self, over_line($self, $ng, $n, $smsg));
 880                 '.';
 881         } else {
 882                 cmd_xover($self, $range);
 883         }
 884 }
 885
 886 sub cmd_xover ($;$) {
 887         my ($self, $range) = @_;
 888         $range = $self->{article} unless defined $range;
 889         my $r = get_range($self, $range);
 890         return $r unless ref $r;
 891         my ($beg, $end) = @$r;
 892         more($self, "224 Overview information follows for $beg to $end");
 893         my $over = $self->{ng}->over;
 894         my $cur = $beg;
 895         long_response($self, sub {
 896                 my $msgs = $over->query_xover($cur, $end);
 897                 my $nr = scalar @$msgs or return;
 898
 899                 # OVERVIEW.FMT
 900                 more($self, join("\r\n", map {
 901                         over_line($self, $self->{ng}, $_->{num}, $_);
 902                         } @$msgs));
 903                 $cur = $msgs->[-1]->{num} + 1;
 904         });
 905 }
 906
 907 sub compressed { undef }
 908
 909 sub cmd_starttls ($) {
 910         my ($self) = @_;
 911         my $sock = $self->{sock} or return;
 912         # RFC 4642 2.2.1
 913         return r502 if (ref($sock) eq 'IO::Socket::SSL' || $self->compressed);
 914         my $opt = $self->{nntpd}->{accept_tls} or
 915                 return '580 can not initiate TLS negotiation';
 916         res($self, '382 Continue with TLS negotiation');
 917         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 918         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 919         undef;
 920 }
 921
 922 # RFC 8054
 923 sub cmd_compress ($$) {
 924         my ($self, $alg) = @_;
 925         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 926         return r502 if $self->compressed || !$have_deflate;
 927         PublicInbox::NNTPdeflate->enable($self);
 928         $self->requeue;
 929         undef
 930 }
 931
 932 sub zflush {} # overridden by NNTPdeflate
 933
 934 sub cmd_xpath ($$) {
 935         my ($self, $mid) = @_;
 936         return r501 unless $mid =~ /\A<(.+)>\z/;
 937         $mid = $1;
 938         my @paths;
 939         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 940                 my $n = $ng->mm->num_for($mid);
 941                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 942         }
 943         return '430 no such article on server' unless @paths;
 944         '223 '.join(' ', @paths);
 945 }
 946
 947 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 948
 949 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 950
 951 sub do_write ($$) {
 952         my $self = $_[0];
 953         my $done = $self->write(\($_[1]));
 954         return 0 unless $self->{sock};
 955
 956         $done;
 957 }
 958
 959 sub err ($$;@) {
 960         my ($self, $fmt, @args) = @_;
 961         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 962 }
 963
 964 sub out ($$;@) {
 965         my ($self, $fmt, @args) = @_;
 966         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 967 }
 968
 969 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 970 sub event_step {
 971         my ($self) = @_;
 972
 973         return unless $self->flush_write && $self->{sock};
 974
 975         update_idle_time($self);
 976         # only read more requests if we've drained the write buffer,
 977         # otherwise we can be buffering infinitely w/o backpressure
 978
 979         my $rbuf = $self->{rbuf} // (\(my $x = ''));
 980         my $r = 1;
 981
 982         if (index($$rbuf, "\n") < 0) {
 983                 my $off = bytes::length($$rbuf);
 984                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 985         }
 986         while ($r > 0 && $$rbuf =~ s/\A[ \t\r\n]*([^\r\n]*)\r?\n//) {
 987                 my $line = $1;
 988                 return $self->close if $line =~ /[[:cntrl:]]/s;
 989                 my $t0 = now();
 990                 my $fd = fileno($self->{sock});
 991                 $r = eval { process_line($self, $line) };
 992                 my $pending = $self->{wbuf} ? ' pending' : '';
 993                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
 994         }
 995
 996         return $self->close if $r < 0;
 997         my $len = bytes::length($$rbuf);
 998         return $self->close if ($len >= LINE_MAX);
 999         $self->rbuf_idle($rbuf);
1000         update_idle_time($self);
1001
1002         # maybe there's more pipelined data, or we'll have
1003         # to register it for socket-readiness notifications
1004         $self->requeue unless $self->{wbuf};
1005 }
1006
1007 sub not_idle_long ($$) {
1008         my ($self, $now) = @_;
1009         my $sock = $self->{sock} or return;
1010         my $ary = $EXPMAP->{fileno($sock)} or return;
1011         my $exp_at = $ary->[0] + $EXPTIME;
1012         $exp_at > $now;
1013 }
1014
1015 # for graceful shutdown in PublicInbox::Daemon:
1016 sub busy {
1017         my ($self, $now) = @_;
1018         ($self->{rbuf} || $self->{wbuf} || not_idle_long($self, $now));
1019 }
1020
1021 # this is an import to prevent "perl -c" from complaining about fields
1022 sub import {
1023         $have_deflate = eval { require PublicInbox::NNTPdeflate } and
1024                 $CAPABILITIES .= "COMPRESS DEFLATE\r\n";
1025 }
1026
1027 1;