lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26 };
  27
  28 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  29
  30 my @OVERVIEW = qw(Subject From Date Message-ID References Xref);
  31 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  32 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  33                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  34
  35 # disable commands with easy DoS potential:
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $expt;
  40 our $EXPTIME = 180; # 3 minutes
  41 my $nextt;
  42
  43 my $nextq = [];
  44 sub next_tick () {
  45         $nextt = undef;
  46         my $q = $nextq;
  47         $nextq = [];
  48         foreach my $nntp (@$q) {
  49                 # for request && response protocols, always finish writing
  50                 # before finishing reading:
  51                 if (my $long_cb = $nntp->{long_res}) {
  52                         $nntp->write($long_cb);
  53                 } else {
  54                         # pipelined request, we bypassed socket-readiness
  55                         # checks to get here:
  56                         event_read($nntp);
  57
  58                         # maybe there's more pipelined data, or we'll have
  59                         # to register it for socket-readiness notifications
  60                         if (!$nntp->{long_res} && !$nntp->{closed}) {
  61                                 check_read($nntp);
  62                         }
  63                 }
  64         }
  65 }
  66
  67 sub update_idle_time ($) {
  68         my ($self) = @_;
  69         my $fd = $self->{fd};
  70         defined $fd and $EXPMAP->{$fd} = [ now(), $self ];
  71 }
  72
  73 sub expire_old () {
  74         my $now = now();
  75         my $exp = $EXPTIME;
  76         my $old = $now - $exp;
  77         my $nr = 0;
  78         my %new;
  79         while (my ($fd, $v) = each %$EXPMAP) {
  80                 my ($idle_time, $nntp) = @$v;
  81                 if ($idle_time < $old) {
  82                         $nntp->close; # idempotent
  83                 } else {
  84                         ++$nr;
  85                         $new{$fd} = $v;
  86                 }
  87         }
  88         $EXPMAP = \%new;
  89         if ($nr) {
  90                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  91         } else {
  92                 $expt = undef;
  93                 # noop to kick outselves out of the loop ASAP so descriptors
  94                 # really get closed
  95                 PublicInbox::EvCleanup::asap(sub {});
  96         }
  97 }
  98
  99 sub new ($$$) {
 100         my ($class, $sock, $nntpd) = @_;
 101         my $self = fields::new($class);
 102         $self->SUPER::new($sock);
 103         $self->{nntpd} = $nntpd;
 104         res($self, '201 ' . $nntpd->{servername} . ' ready - post via email');
 105         $self->{rbuf} = '';
 106         $self->watch_read(1);
 107         update_idle_time($self);
 108         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 109         $self;
 110 }
 111
 112 sub args_ok ($$) {
 113         my ($cb, $argc) = @_;
 114         my $tot = prototype $cb;
 115         my ($nreq, undef) = split(';', $tot);
 116         $nreq = ($nreq =~ tr/$//) - 1;
 117         $tot = ($tot =~ tr/$//) - 1;
 118         ($argc <= $tot && $argc >= $nreq);
 119 }
 120
 121 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 122 sub process_line ($$) {
 123         my ($self, $l) = @_;
 124         my ($req, @args) = split(/[ \t]/, $l);
 125         return 1 unless defined($req); # skip blank line
 126         $req = lc($req);
 127         $req = eval {
 128                 no strict 'refs';
 129                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 130         };
 131         return res($self, '500 command not recognized') unless $req;
 132         return res($self, r501) unless args_ok($req, scalar @args);
 133
 134         my $res = eval { $req->($self, @args) };
 135         my $err = $@;
 136         if ($err && !$self->{closed}) {
 137                 local $/ = "\n";
 138                 chomp($l);
 139                 err($self, 'error from: %s (%s)', $l, $err);
 140                 $res = '503 program fault - command not performed';
 141         }
 142         return 0 unless defined $res;
 143         res($self, $res);
 144 }
 145
 146 sub cmd_mode ($$) {
 147         my ($self, $arg) = @_;
 148         $arg = uc $arg;
 149         return r501 unless $arg eq 'READER';
 150         '201 Posting prohibited';
 151 }
 152
 153 sub cmd_slave ($) { '202 slave status noted' }
 154
 155 sub cmd_xgtitle ($;$) {
 156         my ($self, $wildmat) = @_;
 157         more($self, '282 list of groups and descriptions follows');
 158         list_newsgroups($self, $wildmat);
 159         '.'
 160 }
 161
 162 sub list_overview_fmt ($) {
 163         my ($self) = @_;
 164         do_more($self, $OVERVIEW_FMT);
 165 }
 166
 167 sub list_headers ($;$) {
 168         my ($self) = @_;
 169         do_more($self, $LIST_HEADERS);
 170 }
 171
 172 sub list_active ($;$) {
 173         my ($self, $wildmat) = @_;
 174         wildmat2re($wildmat);
 175         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 176                 $ng->{newsgroup} =~ $wildmat or next;
 177                 group_line($self, $ng);
 178         }
 179 }
 180
 181 sub list_active_times ($;$) {
 182         my ($self, $wildmat) = @_;
 183         wildmat2re($wildmat);
 184         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 185                 $ng->{newsgroup} =~ $wildmat or next;
 186                 my $c = eval { $ng->mm->created_at } || time;
 187                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 188         }
 189 }
 190
 191 sub list_newsgroups ($;$) {
 192         my ($self, $wildmat) = @_;
 193         wildmat2re($wildmat);
 194         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 195                 $ng->{newsgroup} =~ $wildmat or next;
 196                 my $d = $ng->description;
 197                 more($self, "$ng->{newsgroup} $d");
 198         }
 199 }
 200
 201 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 202 sub cmd_list ($;$$) {
 203         my ($self, @args) = @_;
 204         if (scalar @args) {
 205                 my $arg = shift @args;
 206                 $arg =~ tr/A-Z./a-z_/;
 207                 $arg = "list_$arg";
 208                 return r501 if $DISABLED{$arg};
 209
 210                 $arg = eval {
 211                         no strict 'refs';
 212                         *{$arg}{CODE};
 213                 };
 214                 return r501 unless $arg && args_ok($arg, scalar @args);
 215                 more($self, '215 information follows');
 216                 $arg->($self, @args);
 217         } else {
 218                 more($self, '215 list of newsgroups follows');
 219                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 220                         group_line($self, $ng);
 221                 }
 222         }
 223         '.'
 224 }
 225
 226 sub cmd_listgroup ($;$) {
 227         my ($self, $group) = @_;
 228         if (defined $group) {
 229                 my $res = cmd_group($self, $group);
 230                 return $res if ($res !~ /\A211 /);
 231                 more($self, $res);
 232         }
 233
 234         $self->{ng} or return '412 no newsgroup selected';
 235         my $n = 0;
 236         long_response($self, sub {
 237                 my $ary = $self->{ng}->mm->ids_after(\$n);
 238                 scalar @$ary or return;
 239                 more($self, join("\r\n", @$ary));
 240                 1;
 241         });
 242 }
 243
 244 sub parse_time ($$;$) {
 245         my ($date, $time, $gmt) = @_;
 246         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 247         if (defined $gmt) {
 248                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 249                 $gmt = 1;
 250         }
 251         my @now = $gmt ? gmtime : localtime;
 252         my ($YYYY, $MM, $DD);
 253         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 254                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 255         } else { # legacy clients send YYMMDD
 256                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 257                 my $cur_year = $now[5] + 1900;
 258                 if ($YYYY > $cur_year) {
 259                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 260                 }
 261         }
 262         if ($gmt) {
 263                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 264         } else {
 265                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 266         }
 267 }
 268
 269 sub group_line ($$) {
 270         my ($self, $ng) = @_;
 271         my ($min, $max) = $ng->mm->minmax;
 272         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 273 }
 274
 275 sub cmd_newgroups ($$$;$$) {
 276         my ($self, $date, $time, $gmt, $dists) = @_;
 277         my $ts = eval { parse_time($date, $time, $gmt) };
 278         return r501 if $@;
 279
 280         # TODO dists
 281         more($self, '231 list of new newsgroups follows');
 282         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 283                 my $c = eval { $ng->mm->created_at } || 0;
 284                 next unless $c > $ts;
 285                 group_line($self, $ng);
 286         }
 287         '.'
 288 }
 289
 290 sub wildmat2re (;$) {
 291         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 292         my %keep;
 293         my $salt = rand;
 294         my $tmp = $_[0];
 295
 296         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 297                 my $orig = $1;
 298                 my $key = sha1_hex($orig . $salt);
 299                 $orig =~ s/([^\w\-])+/\Q$1/g;
 300                 $keep{$key} = $orig;
 301                 $key
 302                 #gex;
 303         my %map = ('*' => '.*', '?' => '.' );
 304         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 305         if (scalar %keep) {
 306                 $tmp =~ s#([a-f0-9]{40})#
 307                         my $orig = $keep{$1};
 308                         defined $orig ? $orig : $1;
 309                         #ge;
 310         }
 311         $_[0] = qr/\A$tmp\z/;
 312 }
 313
 314 sub ngpat2re (;$) {
 315         return $_[0] = qr/\A\z/ unless defined $_[0];
 316         my %map = ('*' => '.*', ',' => '|');
 317         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 318         $_[0] = qr/\A(?:$_[0])\z/;
 319 }
 320
 321 sub cmd_newnews ($$$$;$$) {
 322         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 323         my $ts = eval { parse_time($date, $time, $gmt) };
 324         return r501 if $@;
 325         more($self, '230 list of new articles by message-id follows');
 326         my ($keep, $skip) = split('!', $newsgroups, 2);
 327         ngpat2re($keep);
 328         ngpat2re($skip);
 329         my @over;
 330         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 331                 $ng->{newsgroup} =~ $keep or next;
 332                 $ng->{newsgroup} =~ $skip and next;
 333                 my $over = $ng->over or next;
 334                 push @over, $over;
 335         };
 336         return '.' unless @over;
 337
 338         my $prev = 0;
 339         long_response($self, sub {
 340                 my $over = $over[0];
 341                 my $msgs = $over->query_ts($ts, $prev);
 342                 if (scalar @$msgs) {
 343                         more($self, '<' .
 344                                 join(">\r\n<", map { $_->mid } @$msgs ).
 345                                 '>');
 346                         $prev = $msgs->[-1]->{num};
 347                 } else {
 348                         shift @over;
 349                         if (@over) { # continue onto next newsgroup
 350                                 $prev = 0;
 351                                 return 1;
 352                         } else { # break out of the long response.
 353                                 return;
 354                         }
 355                 }
 356         });
 357 }
 358
 359 sub cmd_group ($$) {
 360         my ($self, $group) = @_;
 361         my $no_such = '411 no such news group';
 362         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 363
 364         $self->{ng} = $ng;
 365         my ($min, $max) = $ng->mm->minmax;
 366         $min ||= 0;
 367         $max ||= 0;
 368         $self->{article} = $min;
 369         my $est_size = $max - $min;
 370         "211 $est_size $min $max $group";
 371 }
 372
 373 sub article_adj ($$) {
 374         my ($self, $off) = @_;
 375         my $ng = $self->{ng} or return '412 no newsgroup selected';
 376
 377         my $n = $self->{article};
 378         defined $n or return '420 no current article has been selected';
 379
 380         $n += $off;
 381         my $mid = $ng->mm->mid_for($n);
 382         unless ($mid) {
 383                 $n = $off > 0 ? 'next' : 'previous';
 384                 return "421 no $n article in this group";
 385         }
 386         $self->{article} = $n;
 387         "223 $n <$mid> article retrieved - request text separately";
 388 }
 389
 390 sub cmd_next ($) { article_adj($_[0], 1) }
 391 sub cmd_last ($) { article_adj($_[0], -1) }
 392
 393 # We want to encourage using email and CC-ing everybody involved to avoid
 394 # the single-point-of-failure a single server provides.
 395 sub cmd_post ($) {
 396         my ($self) = @_;
 397         my $ng = $self->{ng};
 398         $ng ? "440 mailto:$ng->{-primary_address} to post"
 399                 : '440 posting not allowed'
 400 }
 401
 402 sub cmd_quit ($) {
 403         my ($self) = @_;
 404         res($self, '205 closing connection - goodbye!');
 405         $self->close;
 406         undef;
 407 }
 408
 409 sub header_append ($$$) {
 410         my ($hdr, $k, $v) = @_;
 411         my @v = $hdr->header($k);
 412         foreach (@v) {
 413                 return if $v eq $_;
 414         }
 415         $hdr->header_set($k, @v, $v);
 416 }
 417
 418 sub xref ($$$$) {
 419         my ($self, $ng, $n, $mid) = @_;
 420         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 421
 422         # num_for is pretty cheap and sometimes we'll lookup the existence
 423         # of an article without getting even the OVER info.  In other words,
 424         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 425         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 426         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 427                 next if $ng eq $other;
 428                 my $num = eval { $other->mm->num_for($mid) } or next;
 429                 $ret .= " $other->{newsgroup}:$num";
 430         }
 431         $ret;
 432 }
 433
 434 sub set_nntp_headers ($$$$$) {
 435         my ($self, $hdr, $ng, $n, $mid) = @_;
 436
 437         # why? leafnode requires a Path: header for some inexplicable
 438         # reason.  We'll fake the shortest one possible.
 439         $hdr->header_set('Path', 'y');
 440
 441         # clobber some
 442         my $xref = xref($self, $ng, $n, $mid);
 443         $hdr->header_set('Xref', $xref);
 444         $xref =~ s/:[0-9]+//g;
 445         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 446         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 447         if (my $url = $ng->base_url) {
 448                 $mid = mid_escape($mid);
 449                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 450                 header_append($hdr, 'List-Archive', "<$url>");
 451         }
 452 }
 453
 454 sub art_lookup ($$$) {
 455         my ($self, $art, $set_headers) = @_;
 456         my $ng = $self->{ng};
 457         my ($n, $mid);
 458         my $err;
 459         if (defined $art) {
 460                 if ($art =~ /\A[0-9]+\z/) {
 461                         $err = '423 no such article number in this group';
 462                         $n = int($art);
 463                         goto find_mid;
 464                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 465                         $mid = $1;
 466                         $err = r430;
 467                         $n = $ng->mm->num_for($mid) if $ng;
 468                         goto found if defined $n;
 469                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 470                                 $n = $g->mm->num_for($mid);
 471                                 if (defined $n) {
 472                                         $ng = $g;
 473                                         goto found;
 474                                 }
 475                         }
 476                         return $err;
 477                 } else {
 478                         return r501;
 479                 }
 480         } else {
 481                 $err = '420 no current article has been selected';
 482                 $n = $self->{article};
 483                 defined $n or return $err;
 484 find_mid:
 485                 $ng or return '412 no newsgroup has been selected';
 486                 $mid = $ng->mm->mid_for($n);
 487                 defined $mid or return $err;
 488         }
 489 found:
 490         my $smsg = $ng->over->get_art($n) or return $err;
 491         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 492         my $s = Email::Simple->new($msg);
 493         if ($set_headers) {
 494                 set_nntp_headers($self, $s->header_obj, $ng, $n, $mid);
 495
 496                 # must be last
 497                 $s->body_set('') if ($set_headers == 2);
 498         }
 499         [ $n, $mid, $s, $smsg->bytes, $smsg->lines, $ng ];
 500 }
 501
 502 sub simple_body_write ($$) {
 503         my ($self, $s) = @_;
 504         my $body = $s->body;
 505         $s->body_set('');
 506         $body =~ s/^\./../smg;
 507         $body =~ s/(?<!\r)\n/\r\n/sg;
 508         do_more($self, $body);
 509         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 510         '.'
 511 }
 512
 513 sub set_art {
 514         my ($self, $art) = @_;
 515         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 516 }
 517
 518 sub _header ($) {
 519         my $hdr = $_[0]->header_obj->as_string;
 520         utf8::encode($hdr);
 521         $hdr =~ s/(?<!\r)\n/\r\n/sg;
 522         $hdr
 523 }
 524
 525 sub cmd_article ($;$) {
 526         my ($self, $art) = @_;
 527         my $r = art_lookup($self, $art, 1);
 528         return $r unless ref $r;
 529         my ($n, $mid, $s) = @$r;
 530         set_art($self, $art);
 531         more($self, "220 $n <$mid> article retrieved - head and body follow");
 532         do_more($self, _header($s));
 533         do_more($self, "\r\n");
 534         simple_body_write($self, $s);
 535 }
 536
 537 sub cmd_head ($;$) {
 538         my ($self, $art) = @_;
 539         my $r = art_lookup($self, $art, 2);
 540         return $r unless ref $r;
 541         my ($n, $mid, $s) = @$r;
 542         set_art($self, $art);
 543         more($self, "221 $n <$mid> article retrieved - head follows");
 544         do_more($self, _header($s));
 545         '.'
 546 }
 547
 548 sub cmd_body ($;$) {
 549         my ($self, $art) = @_;
 550         my $r = art_lookup($self, $art, 0);
 551         return $r unless ref $r;
 552         my ($n, $mid, $s) = @$r;
 553         set_art($self, $art);
 554         more($self, "222 $n <$mid> article retrieved - body follows");
 555         simple_body_write($self, $s);
 556 }
 557
 558 sub cmd_stat ($;$) {
 559         my ($self, $art) = @_;
 560         my $r = art_lookup($self, $art, 0);
 561         return $r unless ref $r;
 562         my ($n, $mid, undef) = @$r;
 563         set_art($self, $art);
 564         "223 $n <$mid> article retrieved - request text separately";
 565 }
 566
 567 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 568
 569 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 570
 571 sub cmd_help ($) {
 572         my ($self) = @_;
 573         more($self, '100 help text follows');
 574         '.'
 575 }
 576
 577 sub get_range ($$) {
 578         my ($self, $range) = @_;
 579         my $ng = $self->{ng} or return '412 no news group has been selected';
 580         defined $range or return '420 No article(s) selected';
 581         my ($beg, $end);
 582         my ($min, $max) = $ng->mm->minmax;
 583         if ($range =~ /\A([0-9]+)\z/) {
 584                 $beg = $end = $1;
 585         } elsif ($range =~ /\A([0-9]+)-\z/) {
 586                 ($beg, $end) = ($1, $max);
 587         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 588                 ($beg, $end) = ($1, $2);
 589         } else {
 590                 return r501;
 591         }
 592         $beg = $min if ($beg < $min);
 593         $end = $max if ($end > $max);
 594         return '420 No article(s) selected' if ($beg > $end);
 595         [ $beg, $end ];
 596 }
 597
 598 sub long_response ($$) {
 599         my ($self, $cb) = @_;
 600         die "BUG: nested long response" if $self->{long_res};
 601
 602         my $fd = $self->{fd};
 603         defined $fd or return;
 604         # make sure we disable reading during a long response,
 605         # clients should not be sending us stuff and making us do more
 606         # work while we are stream a response to them
 607         $self->watch_read(0);
 608         my $t0 = now();
 609         $self->{long_res} = sub {
 610                 my $more = eval { $cb->() };
 611                 if ($@ || $self->{closed}) {
 612                         $self->{long_res} = undef;
 613
 614                         if ($@) {
 615                                 err($self,
 616                                     "%s during long response[$fd] - %0.6f",
 617                                     $@, now() - $t0);
 618                         }
 619                         if ($self->{closed}) {
 620                                 out($self, " deferred[$fd] aborted - %0.6f",
 621                                            now() - $t0);
 622                         } else {
 623                                 update_idle_time($self);
 624                                 check_read($self);
 625                         }
 626                 } elsif ($more) { # $self->{write_buf_size}:
 627                         # no recursion, schedule another call ASAP
 628                         # but only after all pending writes are done
 629                         update_idle_time($self);
 630
 631                         push @$nextq, $self;
 632                         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 633                 } else { # all done!
 634                         $self->{long_res} = undef;
 635                         check_read($self);
 636                         res($self, '.');
 637                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 638                 }
 639         };
 640         $self->{long_res}->(); # kick off!
 641         undef;
 642 }
 643
 644 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 645         my ($self, $xhdr, $range) = @_;
 646
 647         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 648                 my ($ng, $n) = mid_lookup($self, $1);
 649                 return r430 unless $n;
 650                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 651         } else { # numeric range
 652                 $range = $self->{article} unless defined $range;
 653                 my $r = get_range($self, $range);
 654                 return $r unless ref $r;
 655                 my $mm = $self->{ng}->mm;
 656                 my ($beg, $end) = @$r;
 657                 more($self, $xhdr ? r221 : r225);
 658                 long_response($self, sub {
 659                         my $r = $mm->msg_range(\$beg, $end);
 660                         @$r or return;
 661                         more($self, join("\r\n", map {
 662                                 "$_->[0] <$_->[1]>"
 663                         } @$r));
 664                         1;
 665                 });
 666         }
 667 }
 668
 669 sub mid_lookup ($$) {
 670         my ($self, $mid) = @_;
 671         my $self_ng = $self->{ng};
 672         if ($self_ng) {
 673                 my $n = $self_ng->mm->num_for($mid);
 674                 return ($self_ng, $n) if defined $n;
 675         }
 676         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 677                 next if defined $self_ng && $ng eq $self_ng;
 678                 my $n = $ng->mm->num_for($mid);
 679                 return ($ng, $n) if defined $n;
 680         }
 681         (undef, undef);
 682 }
 683
 684 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 685         my ($self, $xhdr, $range) = @_;
 686
 687         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 688                 my $mid = $1;
 689                 my ($ng, $n) = mid_lookup($self, $mid);
 690                 return r430 unless $n;
 691                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 692                                 xref($self, $ng, $n, $mid));
 693         } else { # numeric range
 694                 $range = $self->{article} unless defined $range;
 695                 my $r = get_range($self, $range);
 696                 return $r unless ref $r;
 697                 my $ng = $self->{ng};
 698                 my $mm = $ng->mm;
 699                 my ($beg, $end) = @$r;
 700                 more($self, $xhdr ? r221 : r225);
 701                 long_response($self, sub {
 702                         my $r = $mm->msg_range(\$beg, $end);
 703                         @$r or return;
 704                         more($self, join("\r\n", map {
 705                                 my $num = $_->[0];
 706                                 "$num ".xref($self, $ng, $num, $_->[1]);
 707                         } @$r));
 708                         1;
 709                 });
 710         }
 711 }
 712
 713 sub over_header_for {
 714         my ($over, $num, $field) = @_;
 715         my $smsg = $over->get_art($num) or return;
 716         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 717         $smsg->{$field};
 718 }
 719
 720 sub hdr_searchmsg ($$$$) {
 721         my ($self, $xhdr, $field, $range) = @_;
 722         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 723                 my ($ng, $n) = mid_lookup($self, $1);
 724                 return r430 unless defined $n;
 725                 my $v = over_header_for($ng->over, $n, $field);
 726                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 727         } else { # numeric range
 728                 $range = $self->{article} unless defined $range;
 729                 my $over = $self->{ng}->over;
 730                 my $mm = $self->{ng}->mm;
 731                 my $r = get_range($self, $range);
 732                 return $r unless ref $r;
 733                 my ($beg, $end) = @$r;
 734                 more($self, $xhdr ? r221 : r225);
 735                 my $cur = $beg;
 736                 long_response($self, sub {
 737                         my $msgs = $over->query_xover($cur, $end);
 738                         my $nr = scalar @$msgs or return;
 739                         my $tmp = '';
 740                         foreach my $s (@$msgs) {
 741                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 742                         }
 743                         utf8::encode($tmp);
 744                         do_more($self, $tmp);
 745                         $cur = $msgs->[-1]->{num} + 1;
 746                 });
 747         }
 748 }
 749
 750 sub do_hdr ($$$;$) {
 751         my ($self, $xhdr, $header, $range) = @_;
 752         my $sub = lc $header;
 753         if ($sub eq 'message-id') {
 754                 hdr_message_id($self, $xhdr, $range);
 755         } elsif ($sub eq 'xref') {
 756                 hdr_xref($self, $xhdr, $range);
 757         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 758                                 bytes|lines)\z/x) {
 759                 hdr_searchmsg($self, $xhdr, $sub, $range);
 760         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 761                 hdr_searchmsg($self, $xhdr, $1, $range);
 762         } else {
 763                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 764         }
 765 }
 766
 767 # RFC 3977
 768 sub cmd_hdr ($$;$) {
 769         my ($self, $header, $range) = @_;
 770         do_hdr($self, 0, $header, $range);
 771 }
 772
 773 # RFC 2980
 774 sub cmd_xhdr ($$;$) {
 775         my ($self, $header, $range) = @_;
 776         do_hdr($self, 1, $header, $range);
 777 }
 778
 779 sub hdr_mid_prefix ($$$$$) {
 780         my ($self, $xhdr, $ng, $n, $mid) = @_;
 781         return $mid if $xhdr;
 782
 783         # HDR for RFC 3977 users
 784         if (my $self_ng = $self->{ng}) {
 785                 ($self_ng eq $ng) ? $n : '0';
 786         } else {
 787                 '0';
 788         }
 789 }
 790
 791 sub hdr_mid_response ($$$$$$) {
 792         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 793         my $res = '';
 794         if ($xhdr) {
 795                 $res .= r221 . "\r\n";
 796                 $res .= "$mid $v\r\n";
 797         } else {
 798                 $res .= r225 . "\r\n";
 799                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 800                 $res .= "$pfx $v\r\n";
 801         }
 802         res($self, $res .= '.');
 803         undef;
 804 }
 805
 806 sub cmd_xrover ($;$) {
 807         my ($self, $range) = @_;
 808         my $ng = $self->{ng} or return '412 no newsgroup selected';
 809         (defined $range && $range =~ /[<>]/) and
 810                 return '420 No article(s) selected'; # no message IDs
 811
 812         $range = $self->{article} unless defined $range;
 813         my $r = get_range($self, $range);
 814         return $r unless ref $r;
 815         my ($beg, $end) = @$r;
 816         my $mm = $ng->mm;
 817         my $over = $ng->over;
 818         more($self, '224 Overview information follows');
 819
 820         long_response($self, sub {
 821                 my $h = over_header_for($over, $beg, 'references');
 822                 more($self, "$beg $h") if defined($h);
 823                 $beg++ < $end;
 824         });
 825 }
 826
 827 sub over_line ($$$$) {
 828         my ($self, $ng, $num, $smsg) = @_;
 829         # n.b. field access and procedural calls can be
 830         # 10%-15% faster than OO method calls:
 831         my $s = join("\t", $num,
 832                 $smsg->{subject},
 833                 $smsg->{from},
 834                 PublicInbox::SearchMsg::date($smsg),
 835                 "<$smsg->{mid}>",
 836                 $smsg->{references},
 837                 $smsg->{bytes},
 838                 $smsg->{lines},
 839                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 840         utf8::encode($s);
 841         $s
 842 }
 843
 844 sub cmd_over ($;$) {
 845         my ($self, $range) = @_;
 846         if ($range && $range =~ /\A<(.+)>\z/) {
 847                 my ($ng, $n) = mid_lookup($self, $1);
 848                 defined $n or return r430;
 849                 my $smsg = $ng->over->get_art($n) or return r430;
 850                 more($self, '224 Overview information follows (multi-line)');
 851
 852                 # Only set article number column if it's the current group
 853                 my $self_ng = $self->{ng};
 854                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 855                 more($self, over_line($self, $ng, $n, $smsg));
 856                 '.';
 857         } else {
 858                 cmd_xover($self, $range);
 859         }
 860 }
 861
 862 sub cmd_xover ($;$) {
 863         my ($self, $range) = @_;
 864         $range = $self->{article} unless defined $range;
 865         my $r = get_range($self, $range);
 866         return $r unless ref $r;
 867         my ($beg, $end) = @$r;
 868         more($self, "224 Overview information follows for $beg to $end");
 869         my $over = $self->{ng}->over;
 870         my $cur = $beg;
 871         long_response($self, sub {
 872                 my $msgs = $over->query_xover($cur, $end);
 873                 my $nr = scalar @$msgs or return;
 874
 875                 # OVERVIEW.FMT
 876                 more($self, join("\r\n", map {
 877                         over_line($self, $self->{ng}, $_->{num}, $_);
 878                         } @$msgs));
 879                 $cur = $msgs->[-1]->{num} + 1;
 880         });
 881 }
 882
 883 sub cmd_xpath ($$) {
 884         my ($self, $mid) = @_;
 885         return r501 unless $mid =~ /\A<(.+)>\z/;
 886         $mid = $1;
 887         my @paths;
 888         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 889                 my $n = $ng->mm->num_for($mid);
 890                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 891         }
 892         return '430 no such article on server' unless @paths;
 893         '223 '.join(' ', @paths);
 894 }
 895
 896 sub res ($$) {
 897         my ($self, $line) = @_;
 898         do_write($self, $line . "\r\n");
 899 }
 900
 901 sub more ($$) {
 902         my ($self, $line) = @_;
 903         do_more($self, $line . "\r\n");
 904 }
 905
 906 sub do_write ($$) {
 907         my ($self, $data) = @_;
 908         my $done = $self->write($data);
 909         return 0 if $self->{closed};
 910
 911         # Do not watch for readability if we have data in the queue,
 912         # instead re-enable watching for readability when we can
 913         $self->watch_read(0) if (!$done || $self->{long_res});
 914
 915         $done;
 916 }
 917
 918 sub err ($$;@) {
 919         my ($self, $fmt, @args) = @_;
 920         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 921 }
 922
 923 sub out ($$;@) {
 924         my ($self, $fmt, @args) = @_;
 925         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 926 }
 927
 928 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 929
 930 sub do_more ($$) {
 931         my ($self, $data) = @_;
 932         if (MSG_MORE && !$self->{write_buf_size}) {
 933                 my $n = send($self->{sock}, $data, MSG_MORE);
 934                 if (defined $n) {
 935                         my $dlen = length($data);
 936                         return 1 if $n == $dlen; # all done!
 937                         $data = substr($data, $n, $dlen - $n);
 938                 }
 939         }
 940         do_write($self, $data);
 941 }
 942
 943 # callbacks for PublicInbox::DS
 944
 945 sub event_hup { $_[0]->close }
 946 sub event_err { $_[0]->close }
 947
 948 sub event_write {
 949         my ($self) = @_;
 950         update_idle_time($self);
 951         # only continue watching for readability when we are done writing:
 952         if ($self->write(undef) == 1 && !$self->{long_res}) {
 953                 $self->watch_read(1);
 954         }
 955 }
 956
 957 sub event_read {
 958         my ($self) = @_;
 959         use constant LINE_MAX => 512; # RFC 977 section 2.3
 960
 961         if (index($self->{rbuf}, "\n") < 0) {
 962                 my $buf = $self->read(LINE_MAX) or return $self->close;
 963                 $self->{rbuf} .= $$buf;
 964         }
 965         my $r = 1;
 966         while ($r > 0 && $self->{rbuf} =~ s/\A[ \t\r\n]*([^\r\n]*)\r?\n//) {
 967                 my $line = $1;
 968                 return $self->close if $line =~ /[[:cntrl:]]/s;
 969                 my $t0 = now();
 970                 my $fd = $self->{fd};
 971                 $r = eval { process_line($self, $line) };
 972                 my $d = $self->{long_res} ?
 973                         " deferred[$fd]" : '';
 974                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 975         }
 976
 977         return $self->close if $r < 0;
 978         my $len = length($self->{rbuf});
 979         return $self->close if ($len >= LINE_MAX);
 980         update_idle_time($self);
 981 }
 982
 983 sub check_read {
 984         my ($self) = @_;
 985         if (index($self->{rbuf}, "\n") >= 0) {
 986                 # Force another read if there is a pipelined request.
 987                 # We don't know if the socket has anything for us to read,
 988                 # and we must double-check again by the time the timer fires
 989                 # in case we really did dispatch a read event and started
 990                 # another long response.
 991                 push @$nextq, $self;
 992                 $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 993         } else {
 994                 # no pipelined requests available, let the kernel know
 995                 # to wake us up if there's more
 996                 $self->watch_read(1); # PublicInbox::DS::watch_read
 997         }
 998 }
 999
1000 sub not_idle_long ($$) {
1001         my ($self, $now) = @_;
1002         defined(my $fd = $self->{fd}) or return;
1003         my $ary = $EXPMAP->{$fd} or return;
1004         my $exp_at = $ary->[0] + $EXPTIME;
1005         $exp_at > $now;
1006 }
1007
1008 # for graceful shutdown in PublicInbox::Daemon:
1009 sub busy {
1010         my ($self, $now) = @_;
1011         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size} ||
1012          not_idle_long($self, $now));
1013 }
1014
1015 1;