lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 PublicInbox::DS->import(qw(now msg_more));
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26 };
  27 use PublicInbox::Syscall qw(EPOLLOUT EPOLLONESHOT);
  28 use Errno qw(EAGAIN);
  29
  30 my @OVERVIEW = qw(Subject From Date Message-ID References Xref);
  31 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  32 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  33                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  34
  35 # disable commands with easy DoS potential:
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $expt;
  40 our $EXPTIME = 180; # 3 minutes
  41 my $nextt;
  42
  43 my $nextq = [];
  44 sub next_tick () {
  45         $nextt = undef;
  46         my $q = $nextq;
  47         $nextq = [];
  48         foreach my $nntp (@$q) {
  49                 # for request && response protocols, always finish writing
  50                 # before finishing reading:
  51                 if (my $long_cb = $nntp->{long_res}) {
  52                         $nntp->write($long_cb);
  53                 } else {
  54                         # pipelined request, we bypassed socket-readiness
  55                         # checks to get here:
  56                         event_step($nntp);
  57                 }
  58         }
  59 }
  60
  61 sub requeue ($) {
  62         push @$nextq, $_[0];
  63         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
  64 }
  65
  66 sub update_idle_time ($) {
  67         my ($self) = @_;
  68         my $sock = $self->{sock} or return;
  69         $EXPMAP->{fileno($sock)} = [ now(), $self ];
  70 }
  71
  72 sub expire_old () {
  73         my $now = now();
  74         my $exp = $EXPTIME;
  75         my $old = $now - $exp;
  76         my $nr = 0;
  77         my %new;
  78         while (my ($fd, $v) = each %$EXPMAP) {
  79                 my ($idle_time, $nntp) = @$v;
  80                 if ($idle_time < $old) {
  81                         $nntp->close; # idempotent
  82                 } else {
  83                         ++$nr;
  84                         $new{$fd} = $v;
  85                 }
  86         }
  87         $EXPMAP = \%new;
  88         if ($nr) {
  89                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  90         } else {
  91                 $expt = undef;
  92                 # noop to kick outselves out of the loop ASAP so descriptors
  93                 # really get closed
  94                 PublicInbox::EvCleanup::asap(sub {});
  95         }
  96 }
  97
  98 sub new ($$$) {
  99         my ($class, $sock, $nntpd) = @_;
 100         my $self = fields::new($class);
 101         my $ev = EPOLLOUT | EPOLLONESHOT;
 102         my $wbuf = [];
 103         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
 104                 $ev = PublicInbox::TLS::epollbit() or return $sock->close;
 105                 $ev |= EPOLLONESHOT;
 106                 $wbuf->[0] = \&PublicInbox::DS::accept_tls_step;
 107         }
 108         $self->SUPER::new($sock, $ev);
 109         $self->{nntpd} = $nntpd;
 110         my $greet = "201 $nntpd->{servername} ready - post via email\r\n";
 111         open my $fh, '<:scalar',  \$greet or die "open :scalar: $!";
 112         push @$wbuf, $fh;
 113         $self->{wbuf} = $wbuf;
 114         $self->{rbuf} = '';
 115         update_idle_time($self);
 116         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 117         $self;
 118 }
 119
 120 sub args_ok ($$) {
 121         my ($cb, $argc) = @_;
 122         my $tot = prototype $cb;
 123         my ($nreq, undef) = split(';', $tot);
 124         $nreq = ($nreq =~ tr/$//) - 1;
 125         $tot = ($tot =~ tr/$//) - 1;
 126         ($argc <= $tot && $argc >= $nreq);
 127 }
 128
 129 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 130 sub process_line ($$) {
 131         my ($self, $l) = @_;
 132         my ($req, @args) = split(/[ \t]/, $l);
 133         return 1 unless defined($req); # skip blank line
 134         $req = lc($req);
 135         $req = eval {
 136                 no strict 'refs';
 137                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 138         };
 139         return res($self, '500 command not recognized') unless $req;
 140         return res($self, r501) unless args_ok($req, scalar @args);
 141
 142         my $res = eval { $req->($self, @args) };
 143         my $err = $@;
 144         if ($err && $self->{sock}) {
 145                 local $/ = "\n";
 146                 chomp($l);
 147                 err($self, 'error from: %s (%s)', $l, $err);
 148                 $res = '503 program fault - command not performed';
 149         }
 150         return 0 unless defined $res;
 151         res($self, $res);
 152 }
 153
 154 sub cmd_mode ($$) {
 155         my ($self, $arg) = @_;
 156         $arg = uc $arg;
 157         return r501 unless $arg eq 'READER';
 158         '201 Posting prohibited';
 159 }
 160
 161 sub cmd_slave ($) { '202 slave status noted' }
 162
 163 sub cmd_xgtitle ($;$) {
 164         my ($self, $wildmat) = @_;
 165         more($self, '282 list of groups and descriptions follows');
 166         list_newsgroups($self, $wildmat);
 167         '.'
 168 }
 169
 170 sub list_overview_fmt ($) {
 171         my ($self) = @_;
 172         msg_more($self, $OVERVIEW_FMT);
 173 }
 174
 175 sub list_headers ($;$) {
 176         my ($self) = @_;
 177         msg_more($self, $LIST_HEADERS);
 178 }
 179
 180 sub list_active ($;$) {
 181         my ($self, $wildmat) = @_;
 182         wildmat2re($wildmat);
 183         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 184                 $ng->{newsgroup} =~ $wildmat or next;
 185                 group_line($self, $ng);
 186         }
 187 }
 188
 189 sub list_active_times ($;$) {
 190         my ($self, $wildmat) = @_;
 191         wildmat2re($wildmat);
 192         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 193                 $ng->{newsgroup} =~ $wildmat or next;
 194                 my $c = eval { $ng->mm->created_at } || time;
 195                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 196         }
 197 }
 198
 199 sub list_newsgroups ($;$) {
 200         my ($self, $wildmat) = @_;
 201         wildmat2re($wildmat);
 202         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 203                 $ng->{newsgroup} =~ $wildmat or next;
 204                 my $d = $ng->description;
 205                 more($self, "$ng->{newsgroup} $d");
 206         }
 207 }
 208
 209 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 210 sub cmd_list ($;$$) {
 211         my ($self, @args) = @_;
 212         if (scalar @args) {
 213                 my $arg = shift @args;
 214                 $arg =~ tr/A-Z./a-z_/;
 215                 $arg = "list_$arg";
 216                 return r501 if $DISABLED{$arg};
 217
 218                 $arg = eval {
 219                         no strict 'refs';
 220                         *{$arg}{CODE};
 221                 };
 222                 return r501 unless $arg && args_ok($arg, scalar @args);
 223                 more($self, '215 information follows');
 224                 $arg->($self, @args);
 225         } else {
 226                 more($self, '215 list of newsgroups follows');
 227                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 228                         group_line($self, $ng);
 229                 }
 230         }
 231         '.'
 232 }
 233
 234 sub cmd_listgroup ($;$) {
 235         my ($self, $group) = @_;
 236         if (defined $group) {
 237                 my $res = cmd_group($self, $group);
 238                 return $res if ($res !~ /\A211 /);
 239                 more($self, $res);
 240         }
 241
 242         $self->{ng} or return '412 no newsgroup selected';
 243         my $n = 0;
 244         long_response($self, sub {
 245                 my $ary = $self->{ng}->mm->ids_after(\$n);
 246                 scalar @$ary or return;
 247                 more($self, join("\r\n", @$ary));
 248                 1;
 249         });
 250 }
 251
 252 sub parse_time ($$;$) {
 253         my ($date, $time, $gmt) = @_;
 254         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 255         if (defined $gmt) {
 256                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 257                 $gmt = 1;
 258         }
 259         my @now = $gmt ? gmtime : localtime;
 260         my ($YYYY, $MM, $DD);
 261         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 262                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 263         } else { # legacy clients send YYMMDD
 264                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 265                 my $cur_year = $now[5] + 1900;
 266                 if ($YYYY > $cur_year) {
 267                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 268                 }
 269         }
 270         if ($gmt) {
 271                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 272         } else {
 273                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 274         }
 275 }
 276
 277 sub group_line ($$) {
 278         my ($self, $ng) = @_;
 279         my ($min, $max) = $ng->mm->minmax;
 280         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 281 }
 282
 283 sub cmd_newgroups ($$$;$$) {
 284         my ($self, $date, $time, $gmt, $dists) = @_;
 285         my $ts = eval { parse_time($date, $time, $gmt) };
 286         return r501 if $@;
 287
 288         # TODO dists
 289         more($self, '231 list of new newsgroups follows');
 290         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 291                 my $c = eval { $ng->mm->created_at } || 0;
 292                 next unless $c > $ts;
 293                 group_line($self, $ng);
 294         }
 295         '.'
 296 }
 297
 298 sub wildmat2re (;$) {
 299         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 300         my %keep;
 301         my $salt = rand;
 302         my $tmp = $_[0];
 303
 304         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 305                 my $orig = $1;
 306                 my $key = sha1_hex($orig . $salt);
 307                 $orig =~ s/([^\w\-])+/\Q$1/g;
 308                 $keep{$key} = $orig;
 309                 $key
 310                 #gex;
 311         my %map = ('*' => '.*', '?' => '.' );
 312         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 313         if (scalar %keep) {
 314                 $tmp =~ s#([a-f0-9]{40})#
 315                         my $orig = $keep{$1};
 316                         defined $orig ? $orig : $1;
 317                         #ge;
 318         }
 319         $_[0] = qr/\A$tmp\z/;
 320 }
 321
 322 sub ngpat2re (;$) {
 323         return $_[0] = qr/\A\z/ unless defined $_[0];
 324         my %map = ('*' => '.*', ',' => '|');
 325         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 326         $_[0] = qr/\A(?:$_[0])\z/;
 327 }
 328
 329 sub cmd_newnews ($$$$;$$) {
 330         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 331         my $ts = eval { parse_time($date, $time, $gmt) };
 332         return r501 if $@;
 333         more($self, '230 list of new articles by message-id follows');
 334         my ($keep, $skip) = split('!', $newsgroups, 2);
 335         ngpat2re($keep);
 336         ngpat2re($skip);
 337         my @over;
 338         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 339                 $ng->{newsgroup} =~ $keep or next;
 340                 $ng->{newsgroup} =~ $skip and next;
 341                 my $over = $ng->over or next;
 342                 push @over, $over;
 343         };
 344         return '.' unless @over;
 345
 346         my $prev = 0;
 347         long_response($self, sub {
 348                 my $over = $over[0];
 349                 my $msgs = $over->query_ts($ts, $prev);
 350                 if (scalar @$msgs) {
 351                         more($self, '<' .
 352                                 join(">\r\n<", map { $_->mid } @$msgs ).
 353                                 '>');
 354                         $prev = $msgs->[-1]->{num};
 355                 } else {
 356                         shift @over;
 357                         if (@over) { # continue onto next newsgroup
 358                                 $prev = 0;
 359                                 return 1;
 360                         } else { # break out of the long response.
 361                                 return;
 362                         }
 363                 }
 364         });
 365 }
 366
 367 sub cmd_group ($$) {
 368         my ($self, $group) = @_;
 369         my $no_such = '411 no such news group';
 370         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 371
 372         $self->{ng} = $ng;
 373         my ($min, $max) = $ng->mm->minmax;
 374         $min ||= 0;
 375         $max ||= 0;
 376         $self->{article} = $min;
 377         my $est_size = $max - $min;
 378         "211 $est_size $min $max $group";
 379 }
 380
 381 sub article_adj ($$) {
 382         my ($self, $off) = @_;
 383         my $ng = $self->{ng} or return '412 no newsgroup selected';
 384
 385         my $n = $self->{article};
 386         defined $n or return '420 no current article has been selected';
 387
 388         $n += $off;
 389         my $mid = $ng->mm->mid_for($n);
 390         unless ($mid) {
 391                 $n = $off > 0 ? 'next' : 'previous';
 392                 return "421 no $n article in this group";
 393         }
 394         $self->{article} = $n;
 395         "223 $n <$mid> article retrieved - request text separately";
 396 }
 397
 398 sub cmd_next ($) { article_adj($_[0], 1) }
 399 sub cmd_last ($) { article_adj($_[0], -1) }
 400
 401 # We want to encourage using email and CC-ing everybody involved to avoid
 402 # the single-point-of-failure a single server provides.
 403 sub cmd_post ($) {
 404         my ($self) = @_;
 405         my $ng = $self->{ng};
 406         $ng ? "440 mailto:$ng->{-primary_address} to post"
 407                 : '440 posting not allowed'
 408 }
 409
 410 sub cmd_quit ($) {
 411         my ($self) = @_;
 412         res($self, '205 closing connection - goodbye!');
 413         $self->close;
 414         undef;
 415 }
 416
 417 sub header_append ($$$) {
 418         my ($hdr, $k, $v) = @_;
 419         my @v = $hdr->header($k);
 420         foreach (@v) {
 421                 return if $v eq $_;
 422         }
 423         $hdr->header_set($k, @v, $v);
 424 }
 425
 426 sub xref ($$$$) {
 427         my ($self, $ng, $n, $mid) = @_;
 428         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 429
 430         # num_for is pretty cheap and sometimes we'll lookup the existence
 431         # of an article without getting even the OVER info.  In other words,
 432         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 433         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 434         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 435                 next if $ng eq $other;
 436                 my $num = eval { $other->mm->num_for($mid) } or next;
 437                 $ret .= " $other->{newsgroup}:$num";
 438         }
 439         $ret;
 440 }
 441
 442 sub set_nntp_headers ($$$$$) {
 443         my ($self, $hdr, $ng, $n, $mid) = @_;
 444
 445         # why? leafnode requires a Path: header for some inexplicable
 446         # reason.  We'll fake the shortest one possible.
 447         $hdr->header_set('Path', 'y');
 448
 449         # leafnode (and maybe other NNTP clients) have trouble dealing
 450         # with v2 messages which have multiple Message-IDs (either due
 451         # to our own content-based dedupe or buggy git-send-email versions).
 452         my @mids = $hdr->header('Message-ID');
 453         if (scalar(@mids) > 1) {
 454                 my $mid0 = "<$mid>";
 455                 $hdr->header_set('Message-ID', $mid0);
 456                 my @alt = $hdr->header('X-Alt-Message-ID');
 457                 my %seen = map { $_ => 1 } (@alt, $mid0);
 458                 foreach my $m (@mids) {
 459                         next if $seen{$m}++;
 460                         push @alt, $m;
 461                 }
 462                 $hdr->header_set('X-Alt-Message-ID', @alt);
 463         }
 464
 465         # clobber some
 466         my $xref = xref($self, $ng, $n, $mid);
 467         $hdr->header_set('Xref', $xref);
 468         $xref =~ s/:[0-9]+//g;
 469         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 470         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 471         if (my $url = $ng->base_url) {
 472                 $mid = mid_escape($mid);
 473                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 474                 header_append($hdr, 'List-Archive', "<$url>");
 475         }
 476 }
 477
 478 sub art_lookup ($$$) {
 479         my ($self, $art, $set_headers) = @_;
 480         my $ng = $self->{ng};
 481         my ($n, $mid);
 482         my $err;
 483         if (defined $art) {
 484                 if ($art =~ /\A[0-9]+\z/) {
 485                         $err = '423 no such article number in this group';
 486                         $n = int($art);
 487                         goto find_mid;
 488                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 489                         $mid = $1;
 490                         $err = r430;
 491                         $n = $ng->mm->num_for($mid) if $ng;
 492                         goto found if defined $n;
 493                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 494                                 $n = $g->mm->num_for($mid);
 495                                 if (defined $n) {
 496                                         $ng = $g;
 497                                         goto found;
 498                                 }
 499                         }
 500                         return $err;
 501                 } else {
 502                         return r501;
 503                 }
 504         } else {
 505                 $err = '420 no current article has been selected';
 506                 $n = $self->{article};
 507                 defined $n or return $err;
 508 find_mid:
 509                 $ng or return '412 no newsgroup has been selected';
 510                 $mid = $ng->mm->mid_for($n);
 511                 defined $mid or return $err;
 512         }
 513 found:
 514         my $smsg = $ng->over->get_art($n) or return $err;
 515         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 516         my $s = Email::Simple->new($msg);
 517         if ($set_headers) {
 518                 set_nntp_headers($self, $s->header_obj, $ng, $n, $mid);
 519
 520                 # must be last
 521                 $s->body_set('') if ($set_headers == 2);
 522         }
 523         [ $n, $mid, $s, $smsg->bytes, $smsg->lines, $ng ];
 524 }
 525
 526 sub simple_body_write ($$) {
 527         my ($self, $s) = @_;
 528         my $body = $s->body;
 529         $s->body_set('');
 530         $body =~ s/^\./../smg;
 531         $body =~ s/(?<!\r)\n/\r\n/sg;
 532         msg_more($self, $body);
 533         msg_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 534         '.'
 535 }
 536
 537 sub set_art {
 538         my ($self, $art) = @_;
 539         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 540 }
 541
 542 sub _header ($) {
 543         my $hdr = $_[0]->header_obj->as_string;
 544         utf8::encode($hdr);
 545         $hdr =~ s/(?<!\r)\n/\r\n/sg;
 546
 547         # for leafnode compatibility, we need to ensure Message-ID headers
 548         # are only a single line.  We can't subclass Email::Simple::Header
 549         # and override _default_fold_at in here, either; since that won't
 550         # affect messages already in the archive.
 551         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 552
 553         $hdr
 554 }
 555
 556 sub cmd_article ($;$) {
 557         my ($self, $art) = @_;
 558         my $r = art_lookup($self, $art, 1);
 559         return $r unless ref $r;
 560         my ($n, $mid, $s) = @$r;
 561         set_art($self, $art);
 562         more($self, "220 $n <$mid> article retrieved - head and body follow");
 563         msg_more($self, _header($s));
 564         msg_more($self, "\r\n");
 565         simple_body_write($self, $s);
 566 }
 567
 568 sub cmd_head ($;$) {
 569         my ($self, $art) = @_;
 570         my $r = art_lookup($self, $art, 2);
 571         return $r unless ref $r;
 572         my ($n, $mid, $s) = @$r;
 573         set_art($self, $art);
 574         more($self, "221 $n <$mid> article retrieved - head follows");
 575         msg_more($self, _header($s));
 576         '.'
 577 }
 578
 579 sub cmd_body ($;$) {
 580         my ($self, $art) = @_;
 581         my $r = art_lookup($self, $art, 0);
 582         return $r unless ref $r;
 583         my ($n, $mid, $s) = @$r;
 584         set_art($self, $art);
 585         more($self, "222 $n <$mid> article retrieved - body follows");
 586         simple_body_write($self, $s);
 587 }
 588
 589 sub cmd_stat ($;$) {
 590         my ($self, $art) = @_;
 591         my $r = art_lookup($self, $art, 0);
 592         return $r unless ref $r;
 593         my ($n, $mid, undef) = @$r;
 594         set_art($self, $art);
 595         "223 $n <$mid> article retrieved - request text separately";
 596 }
 597
 598 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 599
 600 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 601
 602 sub cmd_help ($) {
 603         my ($self) = @_;
 604         more($self, '100 help text follows');
 605         '.'
 606 }
 607
 608 sub get_range ($$) {
 609         my ($self, $range) = @_;
 610         my $ng = $self->{ng} or return '412 no news group has been selected';
 611         defined $range or return '420 No article(s) selected';
 612         my ($beg, $end);
 613         my ($min, $max) = $ng->mm->minmax;
 614         if ($range =~ /\A([0-9]+)\z/) {
 615                 $beg = $end = $1;
 616         } elsif ($range =~ /\A([0-9]+)-\z/) {
 617                 ($beg, $end) = ($1, $max);
 618         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 619                 ($beg, $end) = ($1, $2);
 620         } else {
 621                 return r501;
 622         }
 623         $beg = $min if ($beg < $min);
 624         $end = $max if ($end > $max);
 625         return '420 No article(s) selected' if ($beg > $end);
 626         [ $beg, $end ];
 627 }
 628
 629 sub long_response ($$) {
 630         my ($self, $cb) = @_;
 631         die "BUG: nested long response" if $self->{long_res};
 632
 633         my $fd = fileno($self->{sock});
 634         defined $fd or return;
 635         # make sure we disable reading during a long response,
 636         # clients should not be sending us stuff and making us do more
 637         # work while we are stream a response to them
 638         my $t0 = now();
 639         $self->{long_res} = sub {
 640                 my $more = eval { $cb->() };
 641                 if ($@ || !$self->{sock}) { # something bad happened...
 642                         delete $self->{long_res};
 643
 644                         if ($@) {
 645                                 err($self,
 646                                     "%s during long response[$fd] - %0.6f",
 647                                     $@, now() - $t0);
 648                         }
 649                         if ($self->{sock}) {
 650                                 update_idle_time($self);
 651                                 requeue($self);
 652                         } else {
 653                                 out($self, " deferred[$fd] aborted - %0.6f",
 654                                            now() - $t0);
 655                         }
 656                 } elsif ($more) { # $self->{wbuf}:
 657                         # no recursion, schedule another call ASAP
 658                         # but only after all pending writes are done
 659                         update_idle_time($self);
 660                         requeue($self);
 661                 } else { # all done!
 662                         delete $self->{long_res};
 663                         res($self, '.');
 664                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 665                         requeue($self);
 666                 }
 667         };
 668         $self->{long_res}->(); # kick off!
 669         undef;
 670 }
 671
 672 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 673         my ($self, $xhdr, $range) = @_;
 674
 675         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 676                 my ($ng, $n) = mid_lookup($self, $1);
 677                 return r430 unless $n;
 678                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 679         } else { # numeric range
 680                 $range = $self->{article} unless defined $range;
 681                 my $r = get_range($self, $range);
 682                 return $r unless ref $r;
 683                 my $mm = $self->{ng}->mm;
 684                 my ($beg, $end) = @$r;
 685                 more($self, $xhdr ? r221 : r225);
 686                 long_response($self, sub {
 687                         my $r = $mm->msg_range(\$beg, $end);
 688                         @$r or return;
 689                         more($self, join("\r\n", map {
 690                                 "$_->[0] <$_->[1]>"
 691                         } @$r));
 692                         1;
 693                 });
 694         }
 695 }
 696
 697 sub mid_lookup ($$) {
 698         my ($self, $mid) = @_;
 699         my $self_ng = $self->{ng};
 700         if ($self_ng) {
 701                 my $n = $self_ng->mm->num_for($mid);
 702                 return ($self_ng, $n) if defined $n;
 703         }
 704         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 705                 next if defined $self_ng && $ng eq $self_ng;
 706                 my $n = $ng->mm->num_for($mid);
 707                 return ($ng, $n) if defined $n;
 708         }
 709         (undef, undef);
 710 }
 711
 712 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 713         my ($self, $xhdr, $range) = @_;
 714
 715         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 716                 my $mid = $1;
 717                 my ($ng, $n) = mid_lookup($self, $mid);
 718                 return r430 unless $n;
 719                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 720                                 xref($self, $ng, $n, $mid));
 721         } else { # numeric range
 722                 $range = $self->{article} unless defined $range;
 723                 my $r = get_range($self, $range);
 724                 return $r unless ref $r;
 725                 my $ng = $self->{ng};
 726                 my $mm = $ng->mm;
 727                 my ($beg, $end) = @$r;
 728                 more($self, $xhdr ? r221 : r225);
 729                 long_response($self, sub {
 730                         my $r = $mm->msg_range(\$beg, $end);
 731                         @$r or return;
 732                         more($self, join("\r\n", map {
 733                                 my $num = $_->[0];
 734                                 "$num ".xref($self, $ng, $num, $_->[1]);
 735                         } @$r));
 736                         1;
 737                 });
 738         }
 739 }
 740
 741 sub over_header_for {
 742         my ($over, $num, $field) = @_;
 743         my $smsg = $over->get_art($num) or return;
 744         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 745         $smsg->{$field};
 746 }
 747
 748 sub hdr_searchmsg ($$$$) {
 749         my ($self, $xhdr, $field, $range) = @_;
 750         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 751                 my ($ng, $n) = mid_lookup($self, $1);
 752                 return r430 unless defined $n;
 753                 my $v = over_header_for($ng->over, $n, $field);
 754                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 755         } else { # numeric range
 756                 $range = $self->{article} unless defined $range;
 757                 my $over = $self->{ng}->over;
 758                 my $mm = $self->{ng}->mm;
 759                 my $r = get_range($self, $range);
 760                 return $r unless ref $r;
 761                 my ($beg, $end) = @$r;
 762                 more($self, $xhdr ? r221 : r225);
 763                 my $cur = $beg;
 764                 long_response($self, sub {
 765                         my $msgs = $over->query_xover($cur, $end);
 766                         my $nr = scalar @$msgs or return;
 767                         my $tmp = '';
 768                         foreach my $s (@$msgs) {
 769                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 770                         }
 771                         utf8::encode($tmp);
 772                         msg_more($self, $tmp);
 773                         $cur = $msgs->[-1]->{num} + 1;
 774                 });
 775         }
 776 }
 777
 778 sub do_hdr ($$$;$) {
 779         my ($self, $xhdr, $header, $range) = @_;
 780         my $sub = lc $header;
 781         if ($sub eq 'message-id') {
 782                 hdr_message_id($self, $xhdr, $range);
 783         } elsif ($sub eq 'xref') {
 784                 hdr_xref($self, $xhdr, $range);
 785         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 786                                 bytes|lines)\z/x) {
 787                 hdr_searchmsg($self, $xhdr, $sub, $range);
 788         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 789                 hdr_searchmsg($self, $xhdr, $1, $range);
 790         } else {
 791                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 792         }
 793 }
 794
 795 # RFC 3977
 796 sub cmd_hdr ($$;$) {
 797         my ($self, $header, $range) = @_;
 798         do_hdr($self, 0, $header, $range);
 799 }
 800
 801 # RFC 2980
 802 sub cmd_xhdr ($$;$) {
 803         my ($self, $header, $range) = @_;
 804         do_hdr($self, 1, $header, $range);
 805 }
 806
 807 sub hdr_mid_prefix ($$$$$) {
 808         my ($self, $xhdr, $ng, $n, $mid) = @_;
 809         return $mid if $xhdr;
 810
 811         # HDR for RFC 3977 users
 812         if (my $self_ng = $self->{ng}) {
 813                 ($self_ng eq $ng) ? $n : '0';
 814         } else {
 815                 '0';
 816         }
 817 }
 818
 819 sub hdr_mid_response ($$$$$$) {
 820         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 821         my $res = '';
 822         if ($xhdr) {
 823                 $res .= r221 . "\r\n";
 824                 $res .= "$mid $v\r\n";
 825         } else {
 826                 $res .= r225 . "\r\n";
 827                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 828                 $res .= "$pfx $v\r\n";
 829         }
 830         res($self, $res .= '.');
 831         undef;
 832 }
 833
 834 sub cmd_xrover ($;$) {
 835         my ($self, $range) = @_;
 836         my $ng = $self->{ng} or return '412 no newsgroup selected';
 837         (defined $range && $range =~ /[<>]/) and
 838                 return '420 No article(s) selected'; # no message IDs
 839
 840         $range = $self->{article} unless defined $range;
 841         my $r = get_range($self, $range);
 842         return $r unless ref $r;
 843         my ($beg, $end) = @$r;
 844         my $mm = $ng->mm;
 845         my $over = $ng->over;
 846         more($self, '224 Overview information follows');
 847
 848         long_response($self, sub {
 849                 my $h = over_header_for($over, $beg, 'references');
 850                 more($self, "$beg $h") if defined($h);
 851                 $beg++ < $end;
 852         });
 853 }
 854
 855 sub over_line ($$$$) {
 856         my ($self, $ng, $num, $smsg) = @_;
 857         # n.b. field access and procedural calls can be
 858         # 10%-15% faster than OO method calls:
 859         my $s = join("\t", $num,
 860                 $smsg->{subject},
 861                 $smsg->{from},
 862                 PublicInbox::SearchMsg::date($smsg),
 863                 "<$smsg->{mid}>",
 864                 $smsg->{references},
 865                 $smsg->{bytes},
 866                 $smsg->{lines},
 867                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 868         utf8::encode($s);
 869         $s
 870 }
 871
 872 sub cmd_over ($;$) {
 873         my ($self, $range) = @_;
 874         if ($range && $range =~ /\A<(.+)>\z/) {
 875                 my ($ng, $n) = mid_lookup($self, $1);
 876                 defined $n or return r430;
 877                 my $smsg = $ng->over->get_art($n) or return r430;
 878                 more($self, '224 Overview information follows (multi-line)');
 879
 880                 # Only set article number column if it's the current group
 881                 my $self_ng = $self->{ng};
 882                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 883                 more($self, over_line($self, $ng, $n, $smsg));
 884                 '.';
 885         } else {
 886                 cmd_xover($self, $range);
 887         }
 888 }
 889
 890 sub cmd_xover ($;$) {
 891         my ($self, $range) = @_;
 892         $range = $self->{article} unless defined $range;
 893         my $r = get_range($self, $range);
 894         return $r unless ref $r;
 895         my ($beg, $end) = @$r;
 896         more($self, "224 Overview information follows for $beg to $end");
 897         my $over = $self->{ng}->over;
 898         my $cur = $beg;
 899         long_response($self, sub {
 900                 my $msgs = $over->query_xover($cur, $end);
 901                 my $nr = scalar @$msgs or return;
 902
 903                 # OVERVIEW.FMT
 904                 more($self, join("\r\n", map {
 905                         over_line($self, $self->{ng}, $_->{num}, $_);
 906                         } @$msgs));
 907                 $cur = $msgs->[-1]->{num} + 1;
 908         });
 909 }
 910
 911 sub cmd_starttls ($) {
 912         my ($self) = @_;
 913         my $sock = $self->{sock} or return;
 914         # RFC 4642 2.2.1
 915         (ref($sock) eq 'IO::Socket::SSL') and return '502 Command unavailable';
 916         my $opt = $self->{nntpd}->{accept_tls} or
 917                 return '580 can not initiate TLS negotiation';
 918         res($self, '382 Continue with TLS negotiation');
 919         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 920         requeue($self) if PublicInbox::DS::accept_tls_step($self);
 921         undef;
 922 }
 923
 924 sub cmd_xpath ($$) {
 925         my ($self, $mid) = @_;
 926         return r501 unless $mid =~ /\A<(.+)>\z/;
 927         $mid = $1;
 928         my @paths;
 929         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 930                 my $n = $ng->mm->num_for($mid);
 931                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 932         }
 933         return '430 no such article on server' unless @paths;
 934         '223 '.join(' ', @paths);
 935 }
 936
 937 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 938
 939 sub more ($$) { msg_more($_[0], $_[1] . "\r\n") }
 940
 941 sub do_write ($$) {
 942         my $self = $_[0];
 943         my $done = $self->write(\($_[1]));
 944         return 0 unless $self->{sock};
 945
 946         $done;
 947 }
 948
 949 sub err ($$;@) {
 950         my ($self, $fmt, @args) = @_;
 951         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 952 }
 953
 954 sub out ($$;@) {
 955         my ($self, $fmt, @args) = @_;
 956         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 957 }
 958
 959 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 960 sub event_step {
 961         my ($self) = @_;
 962
 963         return unless $self->flush_write && $self->{sock};
 964
 965         update_idle_time($self);
 966         # only read more requests if we've drained the write buffer,
 967         # otherwise we can be buffering infinitely w/o backpressure
 968
 969         use constant LINE_MAX => 512; # RFC 977 section 2.3
 970         my $rbuf = \($self->{rbuf});
 971         my $r = 1;
 972
 973         if (index($$rbuf, "\n") < 0) {
 974                 my $off = bytes::length($$rbuf);
 975                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 976         }
 977         while ($r > 0 && $$rbuf =~ s/\A[ \t\r\n]*([^\r\n]*)\r?\n//) {
 978                 my $line = $1;
 979                 return $self->close if $line =~ /[[:cntrl:]]/s;
 980                 my $t0 = now();
 981                 my $fd = fileno($self->{sock});
 982                 $r = eval { process_line($self, $line) };
 983                 my $d = $self->{long_res} ?
 984                         " deferred[$fd]" : '';
 985                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 986         }
 987
 988         return $self->close if $r < 0;
 989         my $len = bytes::length($$rbuf);
 990         return $self->close if ($len >= LINE_MAX);
 991         update_idle_time($self);
 992
 993         # maybe there's more pipelined data, or we'll have
 994         # to register it for socket-readiness notifications
 995         requeue($self) unless ($self->{long_res} || $self->{wbuf});
 996 }
 997
 998 sub not_idle_long ($$) {
 999         my ($self, $now) = @_;
1000         my $sock = $self->{sock} or return;
1001         my $ary = $EXPMAP->{fileno($sock)} or return;
1002         my $exp_at = $ary->[0] + $EXPTIME;
1003         $exp_at > $now;
1004 }
1005
1006 # for graceful shutdown in PublicInbox::Daemon:
1007 sub busy {
1008         my ($self, $now) = @_;
1009         ($self->{rbuf} ne '' || $self->{long_res} ||
1010                 $self->{wbuf} || not_idle_long($self, $now));
1011 }
1012
1013 1;