lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 # fields:
   6 # nntpd: PublicInbox::NNTPD ref
   7 # article: per-session current article number
   8 # ng: PublicInbox::Inbox ref
   9 # long_cb: long_response private data
  10 package PublicInbox::NNTP;
  11 use strict;
  12 use parent qw(PublicInbox::DS);
  13 use PublicInbox::MID qw(mid_escape $MID_EXTRACT);
  14 use PublicInbox::Eml;
  15 use POSIX qw(strftime);
  16 use PublicInbox::DS qw(now);
  17 use Digest::SHA qw(sha1_hex);
  18 use Time::Local qw(timegm timelocal);
  19 use PublicInbox::GitAsyncCat;
  20 use constant {
  21         LINE_MAX => 512, # RFC 977 section 2.3
  22         r501 => '501 command syntax error',
  23         r502 => '502 Command unavailable',
  24         r221 => '221 Header follows',
  25         r224 => '224 Overview information follows (multi-line)',
  26         r225 => '225 Headers follow (multi-line)',
  27         r430 => '430 No article with that message-id',
  28 };
  29 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  30 use Errno qw(EAGAIN);
  31 my $ONE_MSGID = qr/\A$MID_EXTRACT\z/;
  32 my @OVERVIEW = qw(Subject From Date Message-ID References);
  33 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  34                 "Xref:full\r\n.";
  35 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  36                         qw(:bytes :lines Xref To Cc)) . "\r\n.";
  37 my $CAPABILITIES = <<"";
  38 101 Capability list:\r
  39 VERSION 2\r
  40 READER\r
  41 NEWNEWS\r
  42 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  43 HDR\r
  44 OVER\r
  45 COMPRESS DEFLATE\r
  46
  47 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  48
  49 sub new ($$$) {
  50         my ($class, $sock, $nntpd) = @_;
  51         my $self = bless { nntpd => $nntpd }, $class;
  52         my $ev = EPOLLIN;
  53         my $wbuf;
  54         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
  55                 return CORE::close($sock) if $! != EAGAIN;
  56                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
  57                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  58         }
  59         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  60         if ($wbuf) {
  61                 $self->{wbuf} = $wbuf;
  62         } else {
  63                 greet($self);
  64         }
  65         $self->update_idle_time;
  66         $self;
  67 }
  68
  69 sub args_ok ($$) {
  70         my ($cb, $argc) = @_;
  71         my $tot = prototype $cb;
  72         my ($nreq, undef) = split(';', $tot);
  73         $nreq = ($nreq =~ tr/$//) - 1;
  74         $tot = ($tot =~ tr/$//) - 1;
  75         ($argc <= $tot && $argc >= $nreq);
  76 }
  77
  78 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  79 sub process_line ($$) {
  80         my ($self, $l) = @_;
  81         my ($req, @args) = split(/[ \t]+/, $l);
  82         return 1 unless defined($req); # skip blank line
  83         $req = $self->can('cmd_'.lc($req));
  84         return res($self, '500 command not recognized') unless $req;
  85         return res($self, r501) unless args_ok($req, scalar @args);
  86
  87         my $res = eval { $req->($self, @args) };
  88         my $err = $@;
  89         if ($err && $self->{sock}) {
  90                 local $/ = "\n";
  91                 chomp($l);
  92                 err($self, 'error from: %s (%s)', $l, $err);
  93                 $res = '503 program fault - command not performed';
  94         }
  95         defined($res) ? res($self, $res) : 0;
  96 }
  97
  98 # The keyword argument is not used (rfc3977 5.2.2)
  99 sub cmd_capabilities ($;$) {
 100         my ($self, undef) = @_;
 101         my $res = $CAPABILITIES;
 102         if (!$self->{sock}->can('accept_SSL') &&
 103                         $self->{nntpd}->{accept_tls}) {
 104                 $res .= "STARTTLS\r\n";
 105         }
 106         $res .= '.';
 107 }
 108
 109 sub cmd_mode ($$) {
 110         my ($self, $arg) = @_;
 111         uc($arg) eq 'READER' ? '201 Posting prohibited' : r501;
 112 }
 113
 114 sub cmd_slave ($) { '202 slave status noted' }
 115
 116 sub cmd_xgtitle ($;$) {
 117         my ($self, $wildmat) = @_;
 118         more($self, '282 list of groups and descriptions follows');
 119         list_newsgroups($self, $wildmat);
 120 }
 121
 122 sub list_overview_fmt ($) { $OVERVIEW_FMT }
 123
 124 sub list_headers ($;$) { $LIST_HEADERS }
 125
 126 sub list_active_i { # "LIST ACTIVE" and also just "LIST" (no args)
 127         my ($self, $groupnames) = @_;
 128         my @window = splice(@$groupnames, 0, 100) or return 0;
 129         my $ibx;
 130         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 131         for my $ngname (@window) {
 132                 $ibx = $groups->{$ngname} and group_line($self, $ibx);
 133         }
 134         scalar(@$groupnames); # continue if there's more
 135 }
 136
 137 sub list_active ($;$) { # called by cmd_list
 138         my ($self, $wildmat) = @_;
 139         wildmat2re($wildmat);
 140         long_response($self, \&list_active_i, [
 141                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 142 }
 143
 144 sub list_active_times_i {
 145         my ($self, $groupnames) = @_;
 146         my @window = splice(@$groupnames, 0, 100) or return 0;
 147         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 148         for my $ngname (@window) {
 149                 my $ibx = $groups->{$ngname} or next;
 150                 my $c = eval { $ibx->uidvalidity } // time;
 151                 more($self, "$ngname $c <$ibx->{-primary_address}>");
 152         }
 153         scalar(@$groupnames); # continue if there's more
 154 }
 155
 156 sub list_active_times ($;$) { # called by cmd_list
 157         my ($self, $wildmat) = @_;
 158         wildmat2re($wildmat);
 159         long_response($self, \&list_active_times_i, [
 160                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 161 }
 162
 163 sub list_newsgroups_i {
 164         my ($self, $groupnames) = @_;
 165         my @window = splice(@$groupnames, 0, 100) or return 0;
 166         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 167         my $ibx;
 168         for my $ngname (@window) {
 169                 $ibx = $groups->{$ngname} and
 170                         more($self, "$ngname ".$ibx->description);
 171         }
 172         scalar(@$groupnames); # continue if there's more
 173 }
 174
 175 sub list_newsgroups ($;$) { # called by cmd_list
 176         my ($self, $wildmat) = @_;
 177         wildmat2re($wildmat);
 178         long_response($self, \&list_newsgroups_i, [
 179                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 180 }
 181
 182 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 183 sub cmd_list ($;$$) {
 184         my ($self, @args) = @_;
 185         if (scalar @args) {
 186                 my $arg = shift @args;
 187                 $arg =~ tr/A-Z./a-z_/;
 188                 my $ret = $arg eq 'active';
 189                 $arg = "list_$arg";
 190                 $arg = $self->can($arg);
 191                 return r501 unless $arg && args_ok($arg, scalar @args);
 192                 more($self, '215 information follows');
 193                 $arg->($self, @args);
 194         } else {
 195                 more($self, '215 list of newsgroups follows');
 196                 long_response($self, \&list_active_i, [ # copy array
 197                         @{$self->{nntpd}->{groupnames}} ]);
 198         }
 199 }
 200
 201 sub listgroup_range_i {
 202         my ($self, $beg, $end) = @_;
 203         my $r = $self->{ng}->mm->msg_range($beg, $end, 'num');
 204         scalar(@$r) or return;
 205         more($self, join("\r\n", map { $_->[0] } @$r));
 206         1;
 207 }
 208
 209 sub listgroup_all_i {
 210         my ($self, $num) = @_;
 211         my $ary = $self->{ng}->mm->ids_after($num);
 212         scalar(@$ary) or return;
 213         more($self, join("\r\n", @$ary));
 214         1;
 215 }
 216
 217 sub cmd_listgroup ($;$$) {
 218         my ($self, $group, $range) = @_;
 219         if (defined $group) {
 220                 my $res = cmd_group($self, $group);
 221                 return $res if ($res !~ /\A211 /);
 222                 more($self, $res);
 223         }
 224         $self->{ng} or return '412 no newsgroup selected';
 225         if (defined $range) {
 226                 my $r = get_range($self, $range);
 227                 return $r unless ref $r;
 228                 long_response($self, \&listgroup_range_i, @$r);
 229         } else { # grab every article number
 230                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 231         }
 232 }
 233
 234 sub parse_time ($$;$) {
 235         my ($date, $time, $gmt) = @_;
 236         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 237         if (defined $gmt) {
 238                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 239                 $gmt = 1;
 240         }
 241         my ($YYYY, $MM, $DD);
 242         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 243                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 244         } else { # legacy clients send YYMMDD
 245                 my $YY;
 246                 ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 247                 my @now = $gmt ? gmtime : localtime;
 248                 my $cur_year = $now[5] + 1900;
 249                 my $cur_cent = int($cur_year / 100) * 100;
 250                 $YYYY = (($YY + $cur_cent) > $cur_year) ?
 251                         ($YY + 1900) : ($YY + $cur_cent);
 252         }
 253         if ($gmt) {
 254                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 255         } else {
 256                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 257         }
 258 }
 259
 260 sub group_line ($$) {
 261         my ($self, $ng) = @_;
 262         my ($min, $max) = $ng->mm->minmax;
 263         more($self, "$ng->{newsgroup} $max $min n");
 264 }
 265
 266 sub cmd_newgroups ($$$;$$) {
 267         my ($self, $date, $time, $gmt, $dists) = @_;
 268         my $ts = eval { parse_time($date, $time, $gmt) };
 269         return r501 if $@;
 270
 271         # TODO dists
 272         more($self, '231 list of new newsgroups follows');
 273         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 274                 my $c = eval { $ng->uidvalidity } // 0;
 275                 next unless $c > $ts;
 276                 group_line($self, $ng);
 277         }
 278         '.'
 279 }
 280
 281 sub wildmat2re (;$) {
 282         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 283         my %keep;
 284         my $salt = rand;
 285         my $tmp = $_[0];
 286
 287         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 288                 my $orig = $1;
 289                 my $key = sha1_hex($orig . $salt);
 290                 $orig =~ s/([^\w\-])+/\Q$1/g;
 291                 $keep{$key} = $orig;
 292                 $key
 293                 #gex;
 294         my %map = ('*' => '.*', '?' => '.' );
 295         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 296         if (scalar %keep) {
 297                 $tmp =~ s#([a-f0-9]{40})#
 298                         my $orig = $keep{$1};
 299                         defined $orig ? $orig : $1;
 300                         #ge;
 301         }
 302         $_[0] = qr/\A$tmp\z/;
 303 }
 304
 305 sub ngpat2re (;$) {
 306         return $_[0] = qr/\A\z/ unless defined $_[0];
 307         my %map = ('*' => '.*', ',' => '|');
 308         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 309         $_[0] = qr/\A(?:$_[0])\z/;
 310 }
 311
 312 sub newnews_i {
 313         my ($self, $names, $ts, $prev) = @_;
 314         my $ngname = $names->[0];
 315         if (my $ibx = $self->{nntpd}->{groups}->{$ngname}) {
 316                 if (my $over = $ibx->over) {
 317                         my $msgs = $over->query_ts($ts, $$prev);
 318                         if (scalar @$msgs) {
 319                                 more($self, '<' .
 320                                         join(">\r\n<",
 321                                                 map { $_->{mid} } @$msgs ) .
 322                                         '>');
 323                                 $$prev = $msgs->[-1]->{num};
 324                                 return 1; # continue on current group
 325                         }
 326                 }
 327         }
 328         shift @$names;
 329         if (@$names) { # continue onto next newsgroup
 330                 $$prev = 0;
 331                 1;
 332         } else { # all done, break out of the long_response
 333                 undef;
 334         }
 335 }
 336
 337 sub cmd_newnews ($$$$;$$) {
 338         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 339         my $ts = eval { parse_time($date, $time, $gmt) };
 340         return r501 if $@;
 341         more($self, '230 list of new articles by message-id follows');
 342         my ($keep, $skip) = split('!', $newsgroups, 2);
 343         ngpat2re($keep);
 344         ngpat2re($skip);
 345         my @names = grep(!/$skip/, grep(/$keep/,
 346                                 @{$self->{nntpd}->{groupnames}}));
 347         return '.' unless scalar(@names);
 348         my $prev = 0;
 349         long_response($self, \&newnews_i, \@names, $ts, \$prev);
 350 }
 351
 352 sub cmd_group ($$) {
 353         my ($self, $group) = @_;
 354         my $no_such = '411 no such news group';
 355         my $nntpd = $self->{nntpd};
 356         my $ng = $nntpd->{groups}->{$group} or return $no_such;
 357         $nntpd->idler_start;
 358
 359         $self->{ng} = $ng;
 360         my ($min, $max) = $ng->mm->minmax;
 361         $self->{article} = $min;
 362         my $est_size = $max - $min;
 363         "211 $est_size $min $max $group";
 364 }
 365
 366 sub article_adj ($$) {
 367         my ($self, $off) = @_;
 368         my $ng = $self->{ng} or return '412 no newsgroup selected';
 369
 370         my $n = $self->{article};
 371         defined $n or return '420 no current article has been selected';
 372
 373         $n += $off;
 374         my $mid = $ng->mm->mid_for($n);
 375         unless ($mid) {
 376                 $n = $off > 0 ? 'next' : 'previous';
 377                 return "421 no $n article in this group";
 378         }
 379         $self->{article} = $n;
 380         "223 $n <$mid> article retrieved - request text separately";
 381 }
 382
 383 sub cmd_next ($) { article_adj($_[0], 1) }
 384 sub cmd_last ($) { article_adj($_[0], -1) }
 385
 386 # We want to encourage using email and CC-ing everybody involved to avoid
 387 # the single-point-of-failure a single server provides.
 388 sub cmd_post ($) {
 389         my ($self) = @_;
 390         my $ng = $self->{ng};
 391         $ng ? "440 mailto:$ng->{-primary_address} to post"
 392                 : '440 posting not allowed'
 393 }
 394
 395 sub cmd_quit ($) {
 396         my ($self) = @_;
 397         res($self, '205 closing connection - goodbye!');
 398         $self->shutdn;
 399         undef;
 400 }
 401
 402 sub header_append ($$$) {
 403         my ($hdr, $k, $v) = @_;
 404         my @v = $hdr->header_raw($k);
 405         foreach (@v) {
 406                 return if $v eq $_;
 407         }
 408         $hdr->header_set($k, @v, $v);
 409 }
 410
 411 sub xref ($$$) {
 412         my ($self, $cur_ibx, $smsg) = @_;
 413         my $nntpd = $self->{nntpd};
 414         my $cur_ngname = $cur_ibx->{newsgroup};
 415         my $ret = "$nntpd->{servername} $cur_ngname:$smsg->{num}";
 416
 417         my $mid = $smsg->{mid};
 418         my $groups = $nntpd->{pi_config}->{-by_newsgroup};
 419         for my $xngname (@{$nntpd->{groupnames}}) {
 420                 next if $cur_ngname eq $xngname;
 421                 my $xibx = $groups->{$xngname} or next;
 422                 my $num = eval { $xibx->mm->num_for($mid) } or next;
 423                 $ret .= " $xngname:$num";
 424         }
 425         $ret;
 426 }
 427
 428 sub set_nntp_headers ($$) {
 429         my ($hdr, $smsg) = @_;
 430         my ($mid) = $smsg->{mid};
 431
 432         # leafnode (and maybe other NNTP clients) have trouble dealing
 433         # with v2 messages which have multiple Message-IDs (either due
 434         # to our own content-based dedupe or buggy git-send-email versions).
 435         my @mids = $hdr->header_raw('Message-ID');
 436         if (scalar(@mids) > 1) {
 437                 my $mid0 = "<$mid>";
 438                 $hdr->header_set('Message-ID', $mid0);
 439                 my @alt = $hdr->header_raw('X-Alt-Message-ID');
 440                 my %seen = map { $_ => 1 } (@alt, $mid0);
 441                 push(@alt, grep { !$seen{$_}++ } @mids);
 442                 $hdr->header_set('X-Alt-Message-ID', @alt);
 443         }
 444
 445         # clobber some existing headers
 446         my $ibx = $smsg->{-ibx};
 447         my $xref = xref($smsg->{nntp}, $ibx, $smsg);
 448         $hdr->header_set('Xref', $xref);
 449
 450         # RFC 5536 3.1.4
 451         my ($server_name, $newsgroups) = split(/ /, $xref, 2);
 452         $newsgroups =~ s/:[0-9]+\b//g; # drop NNTP article numbers
 453         $newsgroups =~ tr/ /,/;
 454         $hdr->header_set('Newsgroups', $newsgroups);
 455
 456         # *something* here is required for leafnode, try to follow
 457         # RFC 5536 3.1.5...
 458         $hdr->header_set('Path', $server_name . '!not-for-mail');
 459
 460         header_append($hdr, 'List-Post', "<mailto:$ibx->{-primary_address}>");
 461         if (my $url = $ibx->base_url) {
 462                 $mid = mid_escape($mid);
 463                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 464                 header_append($hdr, 'List-Archive', "<$url>");
 465         }
 466 }
 467
 468 sub art_lookup ($$$) {
 469         my ($self, $art, $code) = @_;
 470         my $ng = $self->{ng};
 471         my ($n, $mid);
 472         my $err;
 473         if (defined $art) {
 474                 if ($art =~ /\A[0-9]+\z/) {
 475                         $err = '423 no such article number in this group';
 476                         $n = int($art);
 477                         goto find_mid;
 478                 } elsif ($art =~ $ONE_MSGID) {
 479                         $mid = $1;
 480                         $err = r430;
 481                         $n = $ng->mm->num_for($mid) if $ng;
 482                         goto found if defined $n;
 483                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 484                                 $n = $g->mm->num_for($mid);
 485                                 if (defined $n) {
 486                                         $ng = $g;
 487                                         goto found;
 488                                 }
 489                         }
 490                         return $err;
 491                 } else {
 492                         return r501;
 493                 }
 494         } else {
 495                 $err = '420 no current article has been selected';
 496                 $n = $self->{article};
 497                 defined $n or return $err;
 498 find_mid:
 499                 $ng or return '412 no newsgroup has been selected';
 500                 $mid = $ng->mm->mid_for($n);
 501                 defined $mid or return $err;
 502         }
 503 found:
 504         my $smsg = $ng->over->get_art($n) or return $err;
 505         $smsg->{-ibx} = $ng;
 506         if ($code == 223) { # STAT
 507                 set_art($self, $n);
 508                 "223 $n <$smsg->{mid}> article retrieved - " .
 509                         "request text separately";
 510         } else { # HEAD | BODY | ARTICLE
 511                 $smsg->{nntp} = $self;
 512                 $smsg->{nntp_code} = $code;
 513                 set_art($self, $art);
 514                 # this dereferences to `undef'
 515                 ${git_async_cat($ng->git, $smsg->{blob}, \&blob_cb, $smsg)};
 516         }
 517 }
 518
 519 sub msg_body_write ($$) {
 520         my ($self, $msg) = @_;
 521
 522         # these can momentarily double the memory consumption :<
 523         $$msg =~ s/^\./../smg;
 524         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 525         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 526         $self->msg_more($$msg);
 527 }
 528
 529 sub set_art {
 530         my ($self, $art) = @_;
 531         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 532 }
 533
 534 sub msg_hdr_write ($$) {
 535         my ($eml, $smsg) = @_;
 536         set_nntp_headers($eml, $smsg);
 537
 538         my $hdr = $eml->{hdr} // \(my $x = '');
 539         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 540         $$hdr =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 541         $$hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 542
 543         # for leafnode compatibility, we need to ensure Message-ID headers
 544         # are only a single line.
 545         $$hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 546         $smsg->{nntp}->msg_more($$hdr);
 547 }
 548
 549 sub blob_cb { # called by git->cat_async via git_async_cat
 550         my ($bref, $oid, $type, $size, $smsg) = @_;
 551         my $self = $smsg->{nntp};
 552         my $code = $smsg->{nntp_code};
 553         if (!defined($oid)) {
 554                 # it's possible to have TOCTOU if an admin runs
 555                 # public-inbox-(edit|purge), just move onto the next message
 556                 warn "E: $smsg->{blob} missing in $smsg->{-ibx}->{inboxdir}\n";
 557                 return $self->requeue;
 558         } elsif ($smsg->{blob} ne $oid) {
 559                 $self->close;
 560                 die "BUG: $smsg->{blob} != $oid";
 561         }
 562         my $r = "$code $smsg->{num} <$smsg->{mid}> article retrieved - ";
 563         my $eml = PublicInbox::Eml->new($bref);
 564         if ($code == 220) {
 565                 more($self, $r .= 'head and body follow');
 566                 msg_hdr_write($eml, $smsg);
 567                 $self->msg_more("\r\n");
 568                 msg_body_write($self, $bref);
 569         } elsif ($code == 221) {
 570                 more($self, $r .= 'head follows');
 571                 msg_hdr_write($eml, $smsg);
 572         } elsif ($code == 222) {
 573                 more($self, $r .= 'body follows');
 574                 msg_body_write($self, $bref);
 575         } else {
 576                 $self->close;
 577                 die "BUG: bad code: $r";
 578         }
 579         $self->write(\".\r\n"); # flushes (includes ->zflush)
 580         $self->requeue;
 581 }
 582
 583 sub cmd_article ($;$) {
 584         my ($self, $art) = @_;
 585         art_lookup($self, $art, 220);
 586 }
 587
 588 sub cmd_head ($;$) {
 589         my ($self, $art) = @_;
 590         art_lookup($self, $art, 221);
 591 }
 592
 593 sub cmd_body ($;$) {
 594         my ($self, $art) = @_;
 595         art_lookup($self, $art, 222);
 596 }
 597
 598 sub cmd_stat ($;$) {
 599         my ($self, $art) = @_;
 600         art_lookup($self, $art, 223); # art may be msgid
 601 }
 602
 603 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 604
 605 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 606
 607 sub cmd_help ($) {
 608         my ($self) = @_;
 609         more($self, '100 help text follows');
 610         '.'
 611 }
 612
 613 sub get_range ($$) {
 614         my ($self, $range) = @_;
 615         my $ng = $self->{ng} or return '412 no news group has been selected';
 616         defined $range or return '420 No article(s) selected';
 617         my ($beg, $end);
 618         my ($min, $max) = $ng->mm->minmax;
 619         if ($range =~ /\A([0-9]+)\z/) {
 620                 $beg = $end = $1;
 621         } elsif ($range =~ /\A([0-9]+)-\z/) {
 622                 ($beg, $end) = ($1, $max);
 623         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 624                 ($beg, $end) = ($1, $2);
 625         } else {
 626                 return r501;
 627         }
 628         $beg = $min if ($beg < $min);
 629         $end = $max if ($end > $max);
 630         return '420 No article(s) selected' if ($beg > $end);
 631         [ \$beg, $end ];
 632 }
 633
 634 sub long_step {
 635         my ($self) = @_;
 636         # wbuf is unset or empty, here; {long} may add to it
 637         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
 638         my $more = eval { $cb->($self, @args) };
 639         if ($@ || !$self->{sock}) { # something bad happened...
 640                 delete $self->{long_cb};
 641                 my $elapsed = now() - $t0;
 642                 if ($@) {
 643                         err($self,
 644                             "%s during long response[$fd] - %0.6f",
 645                             $@, $elapsed);
 646                 }
 647                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 648                 $self->close;
 649         } elsif ($more) { # $self->{wbuf}:
 650                 $self->update_idle_time;
 651
 652                 # COMPRESS users all share the same DEFLATE context.
 653                 # Flush it here to ensure clients don't see
 654                 # each other's data
 655                 $self->zflush;
 656
 657                 # no recursion, schedule another call ASAP, but only after
 658                 # all pending writes are done.  autovivify wbuf:
 659                 my $new_size = push(@{$self->{wbuf}}, \&long_step);
 660
 661                 # wbuf may be populated by $cb, no need to rearm if so:
 662                 $self->requeue if $new_size == 1;
 663         } else { # all done!
 664                 delete $self->{long_cb};
 665                 res($self, '.');
 666                 my $elapsed = now() - $t0;
 667                 my $fd = fileno($self->{sock});
 668                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 669                 my $wbuf = $self->{wbuf}; # do NOT autovivify
 670                 $self->requeue unless $wbuf && @$wbuf;
 671         }
 672 }
 673
 674 sub long_response ($$;@) {
 675         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 676
 677         my $sock = $self->{sock} or return;
 678         # make sure we disable reading during a long response,
 679         # clients should not be sending us stuff and making us do more
 680         # work while we are stream a response to them
 681         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
 682         long_step($self); # kick off!
 683         undef;
 684 }
 685
 686 sub hdr_msgid_range_i {
 687         my ($self, $beg, $end) = @_;
 688         my $r = $self->{ng}->mm->msg_range($beg, $end);
 689         @$r or return;
 690         more($self, join("\r\n", map { "$_->[0] <$_->[1]>" } @$r));
 691         1;
 692 }
 693
 694 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 695         my ($self, $xhdr, $range) = @_;
 696
 697         if (defined $range && $range =~ $ONE_MSGID) {
 698                 my ($ng, $n) = mid_lookup($self, $1);
 699                 return r430 unless $n;
 700                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 701         } else { # numeric range
 702                 $range = $self->{article} unless defined $range;
 703                 my $r = get_range($self, $range);
 704                 return $r unless ref $r;
 705                 more($self, $xhdr ? r221 : r225);
 706                 long_response($self, \&hdr_msgid_range_i, @$r);
 707         }
 708 }
 709
 710 sub mid_lookup ($$) {
 711         my ($self, $mid) = @_;
 712         my $self_ng = $self->{ng};
 713         if ($self_ng) {
 714                 my $n = $self_ng->mm->num_for($mid);
 715                 return ($self_ng, $n) if defined $n;
 716         }
 717         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 718                 next if defined $self_ng && $ng eq $self_ng;
 719                 my $n = $ng->mm->num_for($mid);
 720                 return ($ng, $n) if defined $n;
 721         }
 722         (undef, undef);
 723 }
 724
 725 sub xref_range_i {
 726         my ($self, $beg, $end) = @_;
 727         my $ng = $self->{ng};
 728         my $msgs = $ng->over->query_xover($$beg, $end);
 729         scalar(@$msgs) or return;
 730         $$beg = $msgs->[-1]->{num} + 1;
 731         more($self, join("\r\n", map {
 732                 "$_->{num} ".xref($self, $ng, $_);
 733         } @$msgs));
 734         1;
 735 }
 736
 737 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 738         my ($self, $xhdr, $range) = @_;
 739
 740         if (defined $range && $range =~ $ONE_MSGID) {
 741                 my $mid = $1;
 742                 my ($ng, $n) = mid_lookup($self, $mid);
 743                 return r430 unless $n;
 744                 my $smsg = $ng->over->get_art($n) or return;
 745                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 746                                 xref($self, $ng, $smsg));
 747         } else { # numeric range
 748                 $range = $self->{article} unless defined $range;
 749                 my $r = get_range($self, $range);
 750                 return $r unless ref $r;
 751                 more($self, $xhdr ? r221 : r225);
 752                 long_response($self, \&xref_range_i, @$r);
 753         }
 754 }
 755
 756 sub over_header_for {
 757         my ($over, $num, $field) = @_;
 758         my $smsg = $over->get_art($num) or return;
 759         return PublicInbox::Smsg::date($smsg) if $field eq 'date';
 760         $smsg->{$field};
 761 }
 762
 763 sub smsg_range_i {
 764         my ($self, $beg, $end, $field) = @_;
 765         my $over = $self->{ng}->over;
 766         my $msgs = $over->query_xover($$beg, $end);
 767         scalar(@$msgs) or return;
 768         my $tmp = '';
 769
 770         # ->{$field} is faster than ->$field invocations, so favor that.
 771         if ($field eq 'date') {
 772                 for my $s (@$msgs) {
 773                         $tmp .= "$s->{num} ".PublicInbox::Smsg::date($s)."\r\n"
 774                 }
 775         } else {
 776                 for my $s (@$msgs) {
 777                         $tmp .= "$s->{num} $s->{$field}\r\n";
 778                 }
 779         }
 780         utf8::encode($tmp);
 781         $self->msg_more($tmp);
 782         $$beg = $msgs->[-1]->{num} + 1;
 783 }
 784
 785 sub hdr_smsg ($$$$) {
 786         my ($self, $xhdr, $field, $range) = @_;
 787         if (defined $range && $range =~ $ONE_MSGID) {
 788                 my ($ng, $n) = mid_lookup($self, $1);
 789                 return r430 unless defined $n;
 790                 my $v = over_header_for($ng->over, $n, $field);
 791                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 792         } else { # numeric range
 793                 $range = $self->{article} unless defined $range;
 794                 my $r = get_range($self, $range);
 795                 return $r unless ref $r;
 796                 more($self, $xhdr ? r221 : r225);
 797                 long_response($self, \&smsg_range_i, @$r, $field);
 798         }
 799 }
 800
 801 sub do_hdr ($$$;$) {
 802         my ($self, $xhdr, $header, $range) = @_;
 803         my $sub = lc $header;
 804         if ($sub eq 'message-id') {
 805                 hdr_message_id($self, $xhdr, $range);
 806         } elsif ($sub eq 'xref') {
 807                 hdr_xref($self, $xhdr, $range);
 808         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 809                                 bytes|lines)\z/x) {
 810                 hdr_smsg($self, $xhdr, $sub, $range);
 811         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 812                 hdr_smsg($self, $xhdr, $1, $range);
 813         } else {
 814                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 815         }
 816 }
 817
 818 # RFC 3977
 819 sub cmd_hdr ($$;$) {
 820         my ($self, $header, $range) = @_;
 821         do_hdr($self, 0, $header, $range);
 822 }
 823
 824 # RFC 2980
 825 sub cmd_xhdr ($$;$) {
 826         my ($self, $header, $range) = @_;
 827         do_hdr($self, 1, $header, $range);
 828 }
 829
 830 sub hdr_mid_prefix ($$$$$) {
 831         my ($self, $xhdr, $ng, $n, $mid) = @_;
 832         return $mid if $xhdr;
 833
 834         # HDR for RFC 3977 users
 835         if (my $self_ng = $self->{ng}) {
 836                 ($self_ng eq $ng) ? $n : '0';
 837         } else {
 838                 '0';
 839         }
 840 }
 841
 842 sub hdr_mid_response ($$$$$$) {
 843         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 844         my $res = '';
 845         if ($xhdr) {
 846                 $res .= r221 . "\r\n";
 847                 $res .= "$mid $v\r\n";
 848         } else {
 849                 $res .= r225 . "\r\n";
 850                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 851                 $res .= "$pfx $v\r\n";
 852         }
 853         res($self, $res .= '.');
 854         undef;
 855 }
 856
 857 sub xrover_i {
 858         my ($self, $beg, $end) = @_;
 859         my $h = over_header_for($self->{ng}->over, $$beg, 'references');
 860         more($self, "$$beg $h") if defined($h);
 861         $$beg++ < $end;
 862 }
 863
 864 sub cmd_xrover ($;$) {
 865         my ($self, $range) = @_;
 866         my $ng = $self->{ng} or return '412 no newsgroup selected';
 867         (defined $range && $range =~ /[<>]/) and
 868                 return '420 No article(s) selected'; # no message IDs
 869
 870         $range = $self->{article} unless defined $range;
 871         my $r = get_range($self, $range);
 872         return $r unless ref $r;
 873         more($self, '224 Overview information follows');
 874         long_response($self, \&xrover_i, @$r);
 875 }
 876
 877 sub over_line ($$$) {
 878         my ($self, $ng, $smsg) = @_;
 879         # n.b. field access and procedural calls can be
 880         # 10%-15% faster than OO method calls:
 881         my $s = join("\t", $smsg->{num},
 882                 $smsg->{subject},
 883                 $smsg->{from},
 884                 PublicInbox::Smsg::date($smsg),
 885                 "<$smsg->{mid}>",
 886                 $smsg->{references},
 887                 $smsg->{bytes},
 888                 $smsg->{lines},
 889                 "Xref: " . xref($self, $ng, $smsg));
 890         utf8::encode($s);
 891         $s
 892 }
 893
 894 sub cmd_over ($;$) {
 895         my ($self, $range) = @_;
 896         if ($range && $range =~ $ONE_MSGID) {
 897                 my ($ng, $n) = mid_lookup($self, $1);
 898                 defined $n or return r430;
 899                 my $smsg = $ng->over->get_art($n) or return r430;
 900                 more($self, '224 Overview information follows (multi-line)');
 901
 902                 # Only set article number column if it's the current group
 903                 my $self_ng = $self->{ng};
 904                 $smsg->{num} = 0 if (!$self_ng || $self_ng ne $ng);
 905                 more($self, over_line($self, $ng, $smsg));
 906                 '.';
 907         } else {
 908                 cmd_xover($self, $range);
 909         }
 910 }
 911
 912 sub xover_i {
 913         my ($self, $beg, $end) = @_;
 914         my $ng = $self->{ng};
 915         my $msgs = $ng->over->query_xover($$beg, $end);
 916         my $nr = scalar @$msgs or return;
 917
 918         # OVERVIEW.FMT
 919         more($self, join("\r\n", map {
 920                 over_line($self, $ng, $_);
 921                 } @$msgs));
 922         $$beg = $msgs->[-1]->{num} + 1;
 923 }
 924
 925 sub cmd_xover ($;$) {
 926         my ($self, $range) = @_;
 927         $range = $self->{article} unless defined $range;
 928         my $r = get_range($self, $range);
 929         return $r unless ref $r;
 930         my ($beg, $end) = @$r;
 931         more($self, "224 Overview information follows for $$beg to $end");
 932         long_response($self, \&xover_i, @$r);
 933 }
 934
 935 sub compressed { undef }
 936
 937 sub cmd_starttls ($) {
 938         my ($self) = @_;
 939         my $sock = $self->{sock} or return;
 940         # RFC 4642 2.2.1
 941         return r502 if ($sock->can('accept_SSL') || $self->compressed);
 942         my $opt = $self->{nntpd}->{accept_tls} or
 943                 return '580 can not initiate TLS negotiation';
 944         res($self, '382 Continue with TLS negotiation');
 945         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 946         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 947         undef;
 948 }
 949
 950 # RFC 8054
 951 sub cmd_compress ($$) {
 952         my ($self, $alg) = @_;
 953         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 954         return r502 if $self->compressed;
 955         PublicInbox::NNTPdeflate->enable($self);
 956         $self->requeue;
 957         undef
 958 }
 959
 960 sub zflush {} # overridden by NNTPdeflate
 961
 962 sub cmd_xpath ($$) {
 963         my ($self, $mid) = @_;
 964         return r501 unless $mid =~ $ONE_MSGID;
 965         $mid = $1;
 966         my @paths;
 967         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 968                 my $n = $ng->mm->num_for($mid);
 969                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 970         }
 971         return '430 no such article on server' unless @paths;
 972         '223 '.join(' ', @paths);
 973 }
 974
 975 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 976
 977 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 978
 979 sub do_write ($$) {
 980         my $self = $_[0];
 981         my $done = $self->write(\($_[1]));
 982         return 0 unless $self->{sock};
 983
 984         $done;
 985 }
 986
 987 sub err ($$;@) {
 988         my ($self, $fmt, @args) = @_;
 989         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 990 }
 991
 992 sub out ($$;@) {
 993         my ($self, $fmt, @args) = @_;
 994         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 995 }
 996
 997 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 998 sub event_step {
 999         my ($self) = @_;
1000
1001         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
1002
1003         $self->update_idle_time;
1004         # only read more requests if we've drained the write buffer,
1005         # otherwise we can be buffering infinitely w/o backpressure
1006
1007         my $rbuf = $self->{rbuf} // \(my $x = '');
1008         my $line = index($$rbuf, "\n");
1009         while ($line < 0) {
1010                 return $self->close if length($$rbuf) >= LINE_MAX;
1011                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
1012                 $line = index($$rbuf, "\n");
1013         }
1014         $line = substr($$rbuf, 0, $line + 1, '');
1015         $line =~ s/\r?\n\z//s;
1016         return $self->close if $line =~ /[[:cntrl:]]/s;
1017
1018         my $t0 = now();
1019         my $fd = fileno($self->{sock});
1020         my $r = eval { process_line($self, $line) };
1021         my $pending = $self->{wbuf} ? ' pending' : '';
1022         out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
1023         return $self->close if $r < 0;
1024         $self->rbuf_idle($rbuf);
1025         $self->update_idle_time;
1026
1027         # maybe there's more pipelined data, or we'll have
1028         # to register it for socket-readiness notifications
1029         $self->requeue unless $pending;
1030 }
1031
1032 # for graceful shutdown in PublicInbox::Daemon:
1033 sub busy {
1034         my ($self, $now) = @_;
1035         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1036 }
1037
1038 1;