lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article ng);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 use PublicInbox::DS qw(now);
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         LINE_MAX => 512, # RFC 977 section 2.3
  22         r501 => '501 command syntax error',
  23         r502 => '502 Command unavailable',
  24         r221 => '221 Header follows',
  25         r224 => '224 Overview information follows (multi-line)',
  26         r225 => '225 Headers follow (multi-line)',
  27         r430 => '430 No article with that message-id',
  28 };
  29 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  30 use Errno qw(EAGAIN);
  31
  32 my @OVERVIEW = qw(Subject From Date Message-ID References Xref);
  33 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  34 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  35                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  36 my $CAPABILITIES = <<"";
  37 101 Capability list:\r
  38 VERSION 2\r
  39 READER\r
  40 NEWNEWS\r
  41 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  42 HDR\r
  43 OVER\r
  44
  45 my $have_deflate;
  46 my $EXPMAP; # fd -> [ idle_time, $self ]
  47 my $expt;
  48 our $EXPTIME = 180; # 3 minutes
  49
  50 sub update_idle_time ($) {
  51         my ($self) = @_;
  52         my $sock = $self->{sock} or return;
  53         $EXPMAP->{fileno($sock)} = [ now(), $self ];
  54 }
  55
  56 sub expire_old () {
  57         my $now = now();
  58         my $exp = $EXPTIME;
  59         my $old = $now - $exp;
  60         my %new;
  61         while (my ($fd, $v) = each %$EXPMAP) {
  62                 my ($idle_time, $nntp) = @$v;
  63                 if ($idle_time < $old) {
  64                         if (!$nntp->shutdn) {
  65                                 $new{$fd} = $v;
  66                         }
  67                 } else {
  68                         $new{$fd} = $v;
  69                 }
  70         }
  71         $EXPMAP = \%new;
  72         $expt = scalar(keys %new) ? PublicInbox::EvCleanup::later(*expire_old)
  73                                   : undef;
  74 }
  75
  76 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  77
  78 sub new ($$$) {
  79         my ($class, $sock, $nntpd) = @_;
  80         my $self = fields::new($class);
  81         my $ev = EPOLLIN;
  82         my $wbuf;
  83         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  84                 return CORE::close($sock) if $! != EAGAIN;
  85                 $ev = PublicInbox::TLS::epollbit();
  86                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  87         }
  88         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  89         $self->{nntpd} = $nntpd;
  90         if ($wbuf) {
  91                 $self->{wbuf} = $wbuf;
  92         } else {
  93                 greet($self);
  94         }
  95         update_idle_time($self);
  96         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
  97         $self;
  98 }
  99
 100 sub args_ok ($$) {
 101         my ($cb, $argc) = @_;
 102         my $tot = prototype $cb;
 103         my ($nreq, undef) = split(';', $tot);
 104         $nreq = ($nreq =~ tr/$//) - 1;
 105         $tot = ($tot =~ tr/$//) - 1;
 106         ($argc <= $tot && $argc >= $nreq);
 107 }
 108
 109 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 110 sub process_line ($$) {
 111         my ($self, $l) = @_;
 112         my ($req, @args) = split(/[ \t]/, $l);
 113         return 1 unless defined($req); # skip blank line
 114         $req = eval {
 115                 no strict 'refs';
 116                 *{'cmd_'.lc($req)}{CODE};
 117         };
 118         return res($self, '500 command not recognized') unless $req;
 119         return res($self, r501) unless args_ok($req, scalar @args);
 120
 121         my $res = eval { $req->($self, @args) };
 122         my $err = $@;
 123         if ($err && $self->{sock}) {
 124                 local $/ = "\n";
 125                 chomp($l);
 126                 err($self, 'error from: %s (%s)', $l, $err);
 127                 $res = '503 program fault - command not performed';
 128         }
 129         return 0 unless defined $res;
 130         res($self, $res);
 131 }
 132
 133 # The keyword argument is not used (rfc3977 5.2.2)
 134 sub cmd_capabilities ($;$) {
 135         my ($self, undef) = @_;
 136         my $res = $CAPABILITIES;
 137         if (ref($self->{sock}) ne 'IO::Socket::SSL' &&
 138                         $self->{nntpd}->{accept_tls}) {
 139                 $res .= "STARTTLS\r\n";
 140         }
 141         $res .= '.';
 142 }
 143
 144 sub cmd_mode ($$) {
 145         my ($self, $arg) = @_;
 146         $arg = uc $arg;
 147         return r501 unless $arg eq 'READER';
 148         '201 Posting prohibited';
 149 }
 150
 151 sub cmd_slave ($) { '202 slave status noted' }
 152
 153 sub cmd_xgtitle ($;$) {
 154         my ($self, $wildmat) = @_;
 155         more($self, '282 list of groups and descriptions follows');
 156         list_newsgroups($self, $wildmat);
 157         '.'
 158 }
 159
 160 sub list_overview_fmt ($) {
 161         my ($self) = @_;
 162         $self->msg_more($OVERVIEW_FMT);
 163 }
 164
 165 sub list_headers ($;$) {
 166         my ($self) = @_;
 167         $self->msg_more($LIST_HEADERS);
 168 }
 169
 170 sub list_active ($;$) {
 171         my ($self, $wildmat) = @_;
 172         wildmat2re($wildmat);
 173         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 174                 $ng->{newsgroup} =~ $wildmat or next;
 175                 group_line($self, $ng);
 176         }
 177 }
 178
 179 sub list_active_times ($;$) {
 180         my ($self, $wildmat) = @_;
 181         wildmat2re($wildmat);
 182         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 183                 $ng->{newsgroup} =~ $wildmat or next;
 184                 my $c = eval { $ng->mm->created_at } || time;
 185                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 186         }
 187 }
 188
 189 sub list_newsgroups ($;$) {
 190         my ($self, $wildmat) = @_;
 191         wildmat2re($wildmat);
 192         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 193                 $ng->{newsgroup} =~ $wildmat or next;
 194                 my $d = $ng->description;
 195                 more($self, "$ng->{newsgroup} $d");
 196         }
 197 }
 198
 199 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 200 sub cmd_list ($;$$) {
 201         my ($self, @args) = @_;
 202         if (scalar @args) {
 203                 my $arg = shift @args;
 204                 $arg =~ tr/A-Z./a-z_/;
 205                 $arg = "list_$arg";
 206
 207                 $arg = eval {
 208                         no strict 'refs';
 209                         *{$arg}{CODE};
 210                 };
 211                 return r501 unless $arg && args_ok($arg, scalar @args);
 212                 more($self, '215 information follows');
 213                 $arg->($self, @args);
 214         } else {
 215                 more($self, '215 list of newsgroups follows');
 216                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 217                         group_line($self, $ng);
 218                 }
 219         }
 220         '.'
 221 }
 222
 223 sub cmd_listgroup ($;$) {
 224         my ($self, $group) = @_;
 225         if (defined $group) {
 226                 my $res = cmd_group($self, $group);
 227                 return $res if ($res !~ /\A211 /);
 228                 more($self, $res);
 229         }
 230
 231         $self->{ng} or return '412 no newsgroup selected';
 232         my $n = 0;
 233         long_response($self, sub {
 234                 my $ary = $self->{ng}->mm->ids_after(\$n);
 235                 scalar @$ary or return;
 236                 more($self, join("\r\n", @$ary));
 237                 1;
 238         });
 239 }
 240
 241 sub parse_time ($$;$) {
 242         my ($date, $time, $gmt) = @_;
 243         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 244         if (defined $gmt) {
 245                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 246                 $gmt = 1;
 247         }
 248         my @now = $gmt ? gmtime : localtime;
 249         my ($YYYY, $MM, $DD);
 250         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 251                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 252         } else { # legacy clients send YYMMDD
 253                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 254                 my $cur_year = $now[5] + 1900;
 255                 if ($YYYY > $cur_year) {
 256                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 257                 }
 258         }
 259         if ($gmt) {
 260                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 261         } else {
 262                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 263         }
 264 }
 265
 266 sub group_line ($$) {
 267         my ($self, $ng) = @_;
 268         my ($min, $max) = $ng->mm->minmax;
 269         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 270 }
 271
 272 sub cmd_newgroups ($$$;$$) {
 273         my ($self, $date, $time, $gmt, $dists) = @_;
 274         my $ts = eval { parse_time($date, $time, $gmt) };
 275         return r501 if $@;
 276
 277         # TODO dists
 278         more($self, '231 list of new newsgroups follows');
 279         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 280                 my $c = eval { $ng->mm->created_at } || 0;
 281                 next unless $c > $ts;
 282                 group_line($self, $ng);
 283         }
 284         '.'
 285 }
 286
 287 sub wildmat2re (;$) {
 288         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 289         my %keep;
 290         my $salt = rand;
 291         my $tmp = $_[0];
 292
 293         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 294                 my $orig = $1;
 295                 my $key = sha1_hex($orig . $salt);
 296                 $orig =~ s/([^\w\-])+/\Q$1/g;
 297                 $keep{$key} = $orig;
 298                 $key
 299                 #gex;
 300         my %map = ('*' => '.*', '?' => '.' );
 301         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 302         if (scalar %keep) {
 303                 $tmp =~ s#([a-f0-9]{40})#
 304                         my $orig = $keep{$1};
 305                         defined $orig ? $orig : $1;
 306                         #ge;
 307         }
 308         $_[0] = qr/\A$tmp\z/;
 309 }
 310
 311 sub ngpat2re (;$) {
 312         return $_[0] = qr/\A\z/ unless defined $_[0];
 313         my %map = ('*' => '.*', ',' => '|');
 314         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 315         $_[0] = qr/\A(?:$_[0])\z/;
 316 }
 317
 318 sub cmd_newnews ($$$$;$$) {
 319         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 320         my $ts = eval { parse_time($date, $time, $gmt) };
 321         return r501 if $@;
 322         more($self, '230 list of new articles by message-id follows');
 323         my ($keep, $skip) = split('!', $newsgroups, 2);
 324         ngpat2re($keep);
 325         ngpat2re($skip);
 326         my @over;
 327         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 328                 $ng->{newsgroup} =~ $keep or next;
 329                 $ng->{newsgroup} =~ $skip and next;
 330                 my $over = $ng->over or next;
 331                 push @over, $over;
 332         };
 333         return '.' unless @over;
 334
 335         my $prev = 0;
 336         long_response($self, sub {
 337                 my $over = $over[0];
 338                 my $msgs = $over->query_ts($ts, $prev);
 339                 if (scalar @$msgs) {
 340                         more($self, '<' .
 341                                 join(">\r\n<", map { $_->mid } @$msgs ).
 342                                 '>');
 343                         $prev = $msgs->[-1]->{num};
 344                 } else {
 345                         shift @over;
 346                         if (@over) { # continue onto next newsgroup
 347                                 $prev = 0;
 348                                 return 1;
 349                         } else { # break out of the long response.
 350                                 return;
 351                         }
 352                 }
 353         });
 354 }
 355
 356 sub cmd_group ($$) {
 357         my ($self, $group) = @_;
 358         my $no_such = '411 no such news group';
 359         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 360
 361         $self->{ng} = $ng;
 362         my ($min, $max) = $ng->mm->minmax;
 363         $min ||= 0;
 364         $max ||= 0;
 365         $self->{article} = $min;
 366         my $est_size = $max - $min;
 367         "211 $est_size $min $max $group";
 368 }
 369
 370 sub article_adj ($$) {
 371         my ($self, $off) = @_;
 372         my $ng = $self->{ng} or return '412 no newsgroup selected';
 373
 374         my $n = $self->{article};
 375         defined $n or return '420 no current article has been selected';
 376
 377         $n += $off;
 378         my $mid = $ng->mm->mid_for($n);
 379         unless ($mid) {
 380                 $n = $off > 0 ? 'next' : 'previous';
 381                 return "421 no $n article in this group";
 382         }
 383         $self->{article} = $n;
 384         "223 $n <$mid> article retrieved - request text separately";
 385 }
 386
 387 sub cmd_next ($) { article_adj($_[0], 1) }
 388 sub cmd_last ($) { article_adj($_[0], -1) }
 389
 390 # We want to encourage using email and CC-ing everybody involved to avoid
 391 # the single-point-of-failure a single server provides.
 392 sub cmd_post ($) {
 393         my ($self) = @_;
 394         my $ng = $self->{ng};
 395         $ng ? "440 mailto:$ng->{-primary_address} to post"
 396                 : '440 posting not allowed'
 397 }
 398
 399 sub cmd_quit ($) {
 400         my ($self) = @_;
 401         res($self, '205 closing connection - goodbye!');
 402         $self->shutdn;
 403         undef;
 404 }
 405
 406 sub header_append ($$$) {
 407         my ($hdr, $k, $v) = @_;
 408         my @v = $hdr->header($k);
 409         foreach (@v) {
 410                 return if $v eq $_;
 411         }
 412         $hdr->header_set($k, @v, $v);
 413 }
 414
 415 sub xref ($$$$) {
 416         my ($self, $ng, $n, $mid) = @_;
 417         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 418
 419         # num_for is pretty cheap and sometimes we'll lookup the existence
 420         # of an article without getting even the OVER info.  In other words,
 421         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 422         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 423         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 424                 next if $ng eq $other;
 425                 my $num = eval { $other->mm->num_for($mid) } or next;
 426                 $ret .= " $other->{newsgroup}:$num";
 427         }
 428         $ret;
 429 }
 430
 431 sub set_nntp_headers ($$$$$) {
 432         my ($self, $hdr, $ng, $n, $mid) = @_;
 433
 434         # why? leafnode requires a Path: header for some inexplicable
 435         # reason.  We'll fake the shortest one possible.
 436         $hdr->header_set('Path', 'y');
 437
 438         # leafnode (and maybe other NNTP clients) have trouble dealing
 439         # with v2 messages which have multiple Message-IDs (either due
 440         # to our own content-based dedupe or buggy git-send-email versions).
 441         my @mids = $hdr->header('Message-ID');
 442         if (scalar(@mids) > 1) {
 443                 my $mid0 = "<$mid>";
 444                 $hdr->header_set('Message-ID', $mid0);
 445                 my @alt = $hdr->header('X-Alt-Message-ID');
 446                 my %seen = map { $_ => 1 } (@alt, $mid0);
 447                 foreach my $m (@mids) {
 448                         next if $seen{$m}++;
 449                         push @alt, $m;
 450                 }
 451                 $hdr->header_set('X-Alt-Message-ID', @alt);
 452         }
 453
 454         # clobber some
 455         my $xref = xref($self, $ng, $n, $mid);
 456         $hdr->header_set('Xref', $xref);
 457         $xref =~ s/:[0-9]+//g;
 458         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 459         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 460         if (my $url = $ng->base_url) {
 461                 $mid = mid_escape($mid);
 462                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 463                 header_append($hdr, 'List-Archive', "<$url>");
 464         }
 465 }
 466
 467 sub art_lookup ($$$) {
 468         my ($self, $art, $set_headers) = @_;
 469         my $ng = $self->{ng};
 470         my ($n, $mid);
 471         my $err;
 472         if (defined $art) {
 473                 if ($art =~ /\A[0-9]+\z/) {
 474                         $err = '423 no such article number in this group';
 475                         $n = int($art);
 476                         goto find_mid;
 477                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 478                         $mid = $1;
 479                         $err = r430;
 480                         $n = $ng->mm->num_for($mid) if $ng;
 481                         goto found if defined $n;
 482                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 483                                 $n = $g->mm->num_for($mid);
 484                                 if (defined $n) {
 485                                         $ng = $g;
 486                                         goto found;
 487                                 }
 488                         }
 489                         return $err;
 490                 } else {
 491                         return r501;
 492                 }
 493         } else {
 494                 $err = '420 no current article has been selected';
 495                 $n = $self->{article};
 496                 defined $n or return $err;
 497 find_mid:
 498                 $ng or return '412 no newsgroup has been selected';
 499                 $mid = $ng->mm->mid_for($n);
 500                 defined $mid or return $err;
 501         }
 502 found:
 503         my $smsg = $ng->over->get_art($n) or return $err;
 504         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 505
 506         # Email::Simple->new will modify $msg in-place as documented
 507         # in its manpage, so what's left is the body and we won't need
 508         # to call Email::Simple::body(), later
 509         my $hdr = Email::Simple->new($msg)->header_obj;
 510         set_nntp_headers($self, $hdr, $ng, $n, $mid) if $set_headers;
 511         [ $n, $mid, $msg, $hdr ];
 512 }
 513
 514 sub msg_body_write ($$) {
 515         my ($self, $msg) = @_;
 516
 517         # these can momentarily double the memory consumption :<
 518         $$msg =~ s/^\./../smg;
 519         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 520         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 521         $self->msg_more($$msg);
 522         '.'
 523 }
 524
 525 sub set_art {
 526         my ($self, $art) = @_;
 527         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 528 }
 529
 530 sub msg_hdr_write ($$$) {
 531         my ($self, $hdr, $body_follows) = @_;
 532         $hdr = $hdr->as_string;
 533         utf8::encode($hdr);
 534         $hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 535
 536         # for leafnode compatibility, we need to ensure Message-ID headers
 537         # are only a single line.  We can't subclass Email::Simple::Header
 538         # and override _default_fold_at in here, either; since that won't
 539         # affect messages already in the archive.
 540         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 541         $hdr .= "\r\n" if $body_follows;
 542         $self->msg_more($hdr);
 543 }
 544
 545 sub cmd_article ($;$) {
 546         my ($self, $art) = @_;
 547         my $r = art_lookup($self, $art, 1);
 548         return $r unless ref $r;
 549         my ($n, $mid, $msg, $hdr) = @$r;
 550         set_art($self, $art);
 551         more($self, "220 $n <$mid> article retrieved - head and body follow");
 552         msg_hdr_write($self, $hdr, 1);
 553         msg_body_write($self, $msg);
 554 }
 555
 556 sub cmd_head ($;$) {
 557         my ($self, $art) = @_;
 558         my $r = art_lookup($self, $art, 2);
 559         return $r unless ref $r;
 560         my ($n, $mid, undef, $hdr) = @$r;
 561         set_art($self, $art);
 562         more($self, "221 $n <$mid> article retrieved - head follows");
 563         msg_hdr_write($self, $hdr, 0);
 564         '.'
 565 }
 566
 567 sub cmd_body ($;$) {
 568         my ($self, $art) = @_;
 569         my $r = art_lookup($self, $art, 0);
 570         return $r unless ref $r;
 571         my ($n, $mid, $msg) = @$r;
 572         set_art($self, $art);
 573         more($self, "222 $n <$mid> article retrieved - body follows");
 574         msg_body_write($self, $msg);
 575 }
 576
 577 sub cmd_stat ($;$) {
 578         my ($self, $art) = @_;
 579         my $r = art_lookup($self, $art, 0);
 580         return $r unless ref $r;
 581         my ($n, $mid) = @$r;
 582         set_art($self, $art);
 583         "223 $n <$mid> article retrieved - request text separately";
 584 }
 585
 586 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 587
 588 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 589
 590 sub cmd_help ($) {
 591         my ($self) = @_;
 592         more($self, '100 help text follows');
 593         '.'
 594 }
 595
 596 sub get_range ($$) {
 597         my ($self, $range) = @_;
 598         my $ng = $self->{ng} or return '412 no news group has been selected';
 599         defined $range or return '420 No article(s) selected';
 600         my ($beg, $end);
 601         my ($min, $max) = $ng->mm->minmax;
 602         if ($range =~ /\A([0-9]+)\z/) {
 603                 $beg = $end = $1;
 604         } elsif ($range =~ /\A([0-9]+)-\z/) {
 605                 ($beg, $end) = ($1, $max);
 606         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 607                 ($beg, $end) = ($1, $2);
 608         } else {
 609                 return r501;
 610         }
 611         $beg = $min if ($beg < $min);
 612         $end = $max if ($end > $max);
 613         return '420 No article(s) selected' if ($beg > $end);
 614         [ $beg, $end ];
 615 }
 616
 617 sub long_response ($$) {
 618         my ($self, $cb) = @_; # cb returns true if more, false if done
 619
 620         my $fd = fileno($self->{sock});
 621         defined $fd or return;
 622         # make sure we disable reading during a long response,
 623         # clients should not be sending us stuff and making us do more
 624         # work while we are stream a response to them
 625         my $t0 = now();
 626         my $long_cb; # DANGER: self-referential
 627         $long_cb = sub {
 628                 # wbuf is unset or empty, here; $cb may add to it
 629                 my $more = eval { $cb->() };
 630                 if ($@ || !$self->{sock}) { # something bad happened...
 631                         $long_cb = undef;
 632                         my $diff = now() - $t0;
 633                         if ($@) {
 634                                 err($self,
 635                                     "%s during long response[$fd] - %0.6f",
 636                                     $@, $diff);
 637                         }
 638                         out($self, " deferred[$fd] aborted - %0.6f", $diff);
 639                         $self->close;
 640                 } elsif ($more) { # $self->{wbuf}:
 641                         update_idle_time($self);
 642
 643                         # COMPRESS users all share the same DEFLATE context.
 644                         # Flush it here to ensure clients don't see
 645                         # each other's data
 646                         $self->zflush;
 647
 648                         # no recursion, schedule another call ASAP
 649                         # but only after all pending writes are done
 650                         my $wbuf = $self->{wbuf} ||= [];
 651                         push @$wbuf, $long_cb;
 652
 653                         # wbuf may be populated by $cb, no need to rearm if so:
 654                         $self->requeue if scalar(@$wbuf) == 1;
 655                 } else { # all done!
 656                         $long_cb = undef;
 657                         res($self, '.');
 658                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 659                         my $wbuf = $self->{wbuf};
 660                         $self->requeue unless $wbuf && @$wbuf;
 661                 }
 662         };
 663         $self->write($long_cb); # kick off!
 664         undef;
 665 }
 666
 667 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 668         my ($self, $xhdr, $range) = @_;
 669
 670         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 671                 my ($ng, $n) = mid_lookup($self, $1);
 672                 return r430 unless $n;
 673                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 674         } else { # numeric range
 675                 $range = $self->{article} unless defined $range;
 676                 my $r = get_range($self, $range);
 677                 return $r unless ref $r;
 678                 my $mm = $self->{ng}->mm;
 679                 my ($beg, $end) = @$r;
 680                 more($self, $xhdr ? r221 : r225);
 681                 long_response($self, sub {
 682                         my $r = $mm->msg_range(\$beg, $end);
 683                         @$r or return;
 684                         more($self, join("\r\n", map {
 685                                 "$_->[0] <$_->[1]>"
 686                         } @$r));
 687                         1;
 688                 });
 689         }
 690 }
 691
 692 sub mid_lookup ($$) {
 693         my ($self, $mid) = @_;
 694         my $self_ng = $self->{ng};
 695         if ($self_ng) {
 696                 my $n = $self_ng->mm->num_for($mid);
 697                 return ($self_ng, $n) if defined $n;
 698         }
 699         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 700                 next if defined $self_ng && $ng eq $self_ng;
 701                 my $n = $ng->mm->num_for($mid);
 702                 return ($ng, $n) if defined $n;
 703         }
 704         (undef, undef);
 705 }
 706
 707 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 708         my ($self, $xhdr, $range) = @_;
 709
 710         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 711                 my $mid = $1;
 712                 my ($ng, $n) = mid_lookup($self, $mid);
 713                 return r430 unless $n;
 714                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 715                                 xref($self, $ng, $n, $mid));
 716         } else { # numeric range
 717                 $range = $self->{article} unless defined $range;
 718                 my $r = get_range($self, $range);
 719                 return $r unless ref $r;
 720                 my $ng = $self->{ng};
 721                 my $mm = $ng->mm;
 722                 my ($beg, $end) = @$r;
 723                 more($self, $xhdr ? r221 : r225);
 724                 long_response($self, sub {
 725                         my $r = $mm->msg_range(\$beg, $end);
 726                         @$r or return;
 727                         more($self, join("\r\n", map {
 728                                 my $num = $_->[0];
 729                                 "$num ".xref($self, $ng, $num, $_->[1]);
 730                         } @$r));
 731                         1;
 732                 });
 733         }
 734 }
 735
 736 sub over_header_for {
 737         my ($over, $num, $field) = @_;
 738         my $smsg = $over->get_art($num) or return;
 739         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 740         $smsg->{$field};
 741 }
 742
 743 sub hdr_searchmsg ($$$$) {
 744         my ($self, $xhdr, $field, $range) = @_;
 745         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 746                 my ($ng, $n) = mid_lookup($self, $1);
 747                 return r430 unless defined $n;
 748                 my $v = over_header_for($ng->over, $n, $field);
 749                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 750         } else { # numeric range
 751                 $range = $self->{article} unless defined $range;
 752                 my $over = $self->{ng}->over;
 753                 my $mm = $self->{ng}->mm;
 754                 my $r = get_range($self, $range);
 755                 return $r unless ref $r;
 756                 my ($beg, $end) = @$r;
 757                 more($self, $xhdr ? r221 : r225);
 758                 my $cur = $beg;
 759                 long_response($self, sub {
 760                         my $msgs = $over->query_xover($cur, $end);
 761                         my $nr = scalar @$msgs or return;
 762                         my $tmp = '';
 763                         foreach my $s (@$msgs) {
 764                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 765                         }
 766                         utf8::encode($tmp);
 767                         $self->msg_more($tmp);
 768                         $cur = $msgs->[-1]->{num} + 1;
 769                 });
 770         }
 771 }
 772
 773 sub do_hdr ($$$;$) {
 774         my ($self, $xhdr, $header, $range) = @_;
 775         my $sub = lc $header;
 776         if ($sub eq 'message-id') {
 777                 hdr_message_id($self, $xhdr, $range);
 778         } elsif ($sub eq 'xref') {
 779                 hdr_xref($self, $xhdr, $range);
 780         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 781                                 bytes|lines)\z/x) {
 782                 hdr_searchmsg($self, $xhdr, $sub, $range);
 783         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 784                 hdr_searchmsg($self, $xhdr, $1, $range);
 785         } else {
 786                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 787         }
 788 }
 789
 790 # RFC 3977
 791 sub cmd_hdr ($$;$) {
 792         my ($self, $header, $range) = @_;
 793         do_hdr($self, 0, $header, $range);
 794 }
 795
 796 # RFC 2980
 797 sub cmd_xhdr ($$;$) {
 798         my ($self, $header, $range) = @_;
 799         do_hdr($self, 1, $header, $range);
 800 }
 801
 802 sub hdr_mid_prefix ($$$$$) {
 803         my ($self, $xhdr, $ng, $n, $mid) = @_;
 804         return $mid if $xhdr;
 805
 806         # HDR for RFC 3977 users
 807         if (my $self_ng = $self->{ng}) {
 808                 ($self_ng eq $ng) ? $n : '0';
 809         } else {
 810                 '0';
 811         }
 812 }
 813
 814 sub hdr_mid_response ($$$$$$) {
 815         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 816         my $res = '';
 817         if ($xhdr) {
 818                 $res .= r221 . "\r\n";
 819                 $res .= "$mid $v\r\n";
 820         } else {
 821                 $res .= r225 . "\r\n";
 822                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 823                 $res .= "$pfx $v\r\n";
 824         }
 825         res($self, $res .= '.');
 826         undef;
 827 }
 828
 829 sub cmd_xrover ($;$) {
 830         my ($self, $range) = @_;
 831         my $ng = $self->{ng} or return '412 no newsgroup selected';
 832         (defined $range && $range =~ /[<>]/) and
 833                 return '420 No article(s) selected'; # no message IDs
 834
 835         $range = $self->{article} unless defined $range;
 836         my $r = get_range($self, $range);
 837         return $r unless ref $r;
 838         my ($beg, $end) = @$r;
 839         my $mm = $ng->mm;
 840         my $over = $ng->over;
 841         more($self, '224 Overview information follows');
 842
 843         long_response($self, sub {
 844                 my $h = over_header_for($over, $beg, 'references');
 845                 more($self, "$beg $h") if defined($h);
 846                 $beg++ < $end;
 847         });
 848 }
 849
 850 sub over_line ($$$$) {
 851         my ($self, $ng, $num, $smsg) = @_;
 852         # n.b. field access and procedural calls can be
 853         # 10%-15% faster than OO method calls:
 854         my $s = join("\t", $num,
 855                 $smsg->{subject},
 856                 $smsg->{from},
 857                 PublicInbox::SearchMsg::date($smsg),
 858                 "<$smsg->{mid}>",
 859                 $smsg->{references},
 860                 $smsg->{bytes},
 861                 $smsg->{lines},
 862                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 863         utf8::encode($s);
 864         $s
 865 }
 866
 867 sub cmd_over ($;$) {
 868         my ($self, $range) = @_;
 869         if ($range && $range =~ /\A<(.+)>\z/) {
 870                 my ($ng, $n) = mid_lookup($self, $1);
 871                 defined $n or return r430;
 872                 my $smsg = $ng->over->get_art($n) or return r430;
 873                 more($self, '224 Overview information follows (multi-line)');
 874
 875                 # Only set article number column if it's the current group
 876                 my $self_ng = $self->{ng};
 877                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 878                 more($self, over_line($self, $ng, $n, $smsg));
 879                 '.';
 880         } else {
 881                 cmd_xover($self, $range);
 882         }
 883 }
 884
 885 sub cmd_xover ($;$) {
 886         my ($self, $range) = @_;
 887         $range = $self->{article} unless defined $range;
 888         my $r = get_range($self, $range);
 889         return $r unless ref $r;
 890         my ($beg, $end) = @$r;
 891         more($self, "224 Overview information follows for $beg to $end");
 892         my $over = $self->{ng}->over;
 893         my $cur = $beg;
 894         long_response($self, sub {
 895                 my $msgs = $over->query_xover($cur, $end);
 896                 my $nr = scalar @$msgs or return;
 897
 898                 # OVERVIEW.FMT
 899                 more($self, join("\r\n", map {
 900                         over_line($self, $self->{ng}, $_->{num}, $_);
 901                         } @$msgs));
 902                 $cur = $msgs->[-1]->{num} + 1;
 903         });
 904 }
 905
 906 sub compressed { undef }
 907
 908 sub cmd_starttls ($) {
 909         my ($self) = @_;
 910         my $sock = $self->{sock} or return;
 911         # RFC 4642 2.2.1
 912         return r502 if (ref($sock) eq 'IO::Socket::SSL' || $self->compressed);
 913         my $opt = $self->{nntpd}->{accept_tls} or
 914                 return '580 can not initiate TLS negotiation';
 915         res($self, '382 Continue with TLS negotiation');
 916         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 917         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 918         undef;
 919 }
 920
 921 # RFC 8054
 922 sub cmd_compress ($$) {
 923         my ($self, $alg) = @_;
 924         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 925         return r502 if $self->compressed || !$have_deflate;
 926         PublicInbox::NNTPdeflate->enable($self);
 927         $self->requeue;
 928         undef
 929 }
 930
 931 sub zflush {} # overridden by NNTPdeflate
 932
 933 sub cmd_xpath ($$) {
 934         my ($self, $mid) = @_;
 935         return r501 unless $mid =~ /\A<(.+)>\z/;
 936         $mid = $1;
 937         my @paths;
 938         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 939                 my $n = $ng->mm->num_for($mid);
 940                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 941         }
 942         return '430 no such article on server' unless @paths;
 943         '223 '.join(' ', @paths);
 944 }
 945
 946 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 947
 948 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 949
 950 sub do_write ($$) {
 951         my $self = $_[0];
 952         my $done = $self->write(\($_[1]));
 953         return 0 unless $self->{sock};
 954
 955         $done;
 956 }
 957
 958 sub err ($$;@) {
 959         my ($self, $fmt, @args) = @_;
 960         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 961 }
 962
 963 sub out ($$;@) {
 964         my ($self, $fmt, @args) = @_;
 965         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 966 }
 967
 968 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 969 sub event_step {
 970         my ($self) = @_;
 971
 972         return unless $self->flush_write && $self->{sock};
 973
 974         update_idle_time($self);
 975         # only read more requests if we've drained the write buffer,
 976         # otherwise we can be buffering infinitely w/o backpressure
 977
 978         my $rbuf = $self->{rbuf} // (\(my $x = ''));
 979         my $r = 1;
 980
 981         if (index($$rbuf, "\n") < 0) {
 982                 my $off = bytes::length($$rbuf);
 983                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 984         }
 985         while ($r > 0 && $$rbuf =~ s/\A[ \t\r\n]*([^\r\n]*)\r?\n//) {
 986                 my $line = $1;
 987                 return $self->close if $line =~ /[[:cntrl:]]/s;
 988                 my $t0 = now();
 989                 my $fd = fileno($self->{sock});
 990                 $r = eval { process_line($self, $line) };
 991                 my $pending = $self->{wbuf} ? ' pending' : '';
 992                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
 993         }
 994
 995         return $self->close if $r < 0;
 996         my $len = bytes::length($$rbuf);
 997         return $self->close if ($len >= LINE_MAX);
 998         $self->rbuf_idle($rbuf);
 999         update_idle_time($self);
1000
1001         # maybe there's more pipelined data, or we'll have
1002         # to register it for socket-readiness notifications
1003         $self->requeue unless $self->{wbuf};
1004 }
1005
1006 sub not_idle_long ($$) {
1007         my ($self, $now) = @_;
1008         my $sock = $self->{sock} or return;
1009         my $ary = $EXPMAP->{fileno($sock)} or return;
1010         my $exp_at = $ary->[0] + $EXPTIME;
1011         $exp_at > $now;
1012 }
1013
1014 # for graceful shutdown in PublicInbox::Daemon:
1015 sub busy {
1016         my ($self, $now) = @_;
1017         ($self->{rbuf} || $self->{wbuf} || not_idle_long($self, $now));
1018 }
1019
1020 # this is an import to prevent "perl -c" from complaining about fields
1021 sub import {
1022         $have_deflate = eval { require PublicInbox::NNTPdeflate } and
1023                 $CAPABILITIES .= "COMPRESS DEFLATE\r\n";
1024 }
1025
1026 1;