lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article ng);
  10 use PublicInbox::MID qw(mid_escape);
  11 use Email::Simple;
  12 use POSIX qw(strftime);
  13 use PublicInbox::DS qw(now);
  14 use Digest::SHA qw(sha1_hex);
  15 use Time::Local qw(timegm timelocal);
  16 use constant {
  17         LINE_MAX => 512, # RFC 977 section 2.3
  18         r501 => '501 command syntax error',
  19         r502 => '502 Command unavailable',
  20         r221 => '221 Header follows',
  21         r224 => '224 Overview information follows (multi-line)',
  22         r225 => '225 Headers follow (multi-line)',
  23         r430 => '430 No article with that message-id',
  24 };
  25 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  26 use Errno qw(EAGAIN);
  27
  28 my @OVERVIEW = qw(Subject From Date Message-ID References);
  29 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  30                 "Xref:full\r\n";
  31 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  32                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  33 my $CAPABILITIES = <<"";
  34 101 Capability list:\r
  35 VERSION 2\r
  36 READER\r
  37 NEWNEWS\r
  38 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  39 HDR\r
  40 OVER\r
  41
  42 my $have_deflate;
  43
  44 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  45
  46 sub new ($$$) {
  47         my ($class, $sock, $nntpd) = @_;
  48         my $self = fields::new($class);
  49         my $ev = EPOLLIN;
  50         my $wbuf;
  51         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  52                 return CORE::close($sock) if $! != EAGAIN;
  53                 $ev = PublicInbox::TLS::epollbit();
  54                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  55         }
  56         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  57         $self->{nntpd} = $nntpd;
  58         if ($wbuf) {
  59                 $self->{wbuf} = $wbuf;
  60         } else {
  61                 greet($self);
  62         }
  63         $self->update_idle_time;
  64         $self;
  65 }
  66
  67 sub args_ok ($$) {
  68         my ($cb, $argc) = @_;
  69         my $tot = prototype $cb;
  70         my ($nreq, undef) = split(';', $tot);
  71         $nreq = ($nreq =~ tr/$//) - 1;
  72         $tot = ($tot =~ tr/$//) - 1;
  73         ($argc <= $tot && $argc >= $nreq);
  74 }
  75
  76 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  77 sub process_line ($$) {
  78         my ($self, $l) = @_;
  79         my ($req, @args) = split(/[ \t]/, $l);
  80         return 1 unless defined($req); # skip blank line
  81         $req = $self->can('cmd_'.lc($req));
  82         return res($self, '500 command not recognized') unless $req;
  83         return res($self, r501) unless args_ok($req, scalar @args);
  84
  85         my $res = eval { $req->($self, @args) };
  86         my $err = $@;
  87         if ($err && $self->{sock}) {
  88                 local $/ = "\n";
  89                 chomp($l);
  90                 err($self, 'error from: %s (%s)', $l, $err);
  91                 $res = '503 program fault - command not performed';
  92         }
  93         return 0 unless defined $res;
  94         res($self, $res);
  95 }
  96
  97 # The keyword argument is not used (rfc3977 5.2.2)
  98 sub cmd_capabilities ($;$) {
  99         my ($self, undef) = @_;
 100         my $res = $CAPABILITIES;
 101         if (ref($self->{sock}) ne 'IO::Socket::SSL' &&
 102                         $self->{nntpd}->{accept_tls}) {
 103                 $res .= "STARTTLS\r\n";
 104         }
 105         $res .= '.';
 106 }
 107
 108 sub cmd_mode ($$) {
 109         my ($self, $arg) = @_;
 110         $arg = uc $arg;
 111         return r501 unless $arg eq 'READER';
 112         '201 Posting prohibited';
 113 }
 114
 115 sub cmd_slave ($) { '202 slave status noted' }
 116
 117 sub cmd_xgtitle ($;$) {
 118         my ($self, $wildmat) = @_;
 119         more($self, '282 list of groups and descriptions follows');
 120         list_newsgroups($self, $wildmat);
 121         '.'
 122 }
 123
 124 sub list_overview_fmt ($) {
 125         my ($self) = @_;
 126         $self->msg_more($OVERVIEW_FMT);
 127 }
 128
 129 sub list_headers ($;$) {
 130         my ($self) = @_;
 131         $self->msg_more($LIST_HEADERS);
 132 }
 133
 134 sub list_active ($;$) {
 135         my ($self, $wildmat) = @_;
 136         wildmat2re($wildmat);
 137         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 138                 $ng->{newsgroup} =~ $wildmat or next;
 139                 group_line($self, $ng);
 140         }
 141 }
 142
 143 sub list_active_times ($;$) {
 144         my ($self, $wildmat) = @_;
 145         wildmat2re($wildmat);
 146         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 147                 $ng->{newsgroup} =~ $wildmat or next;
 148                 my $c = eval { $ng->mm->created_at } || time;
 149                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 150         }
 151 }
 152
 153 sub list_newsgroups ($;$) {
 154         my ($self, $wildmat) = @_;
 155         wildmat2re($wildmat);
 156         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 157                 $ng->{newsgroup} =~ $wildmat or next;
 158                 my $d = $ng->description;
 159                 more($self, "$ng->{newsgroup} $d");
 160         }
 161 }
 162
 163 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 164 sub cmd_list ($;$$) {
 165         my ($self, @args) = @_;
 166         if (scalar @args) {
 167                 my $arg = shift @args;
 168                 $arg =~ tr/A-Z./a-z_/;
 169                 $arg = "list_$arg";
 170                 $arg = $self->can($arg);
 171                 return r501 unless $arg && args_ok($arg, scalar @args);
 172                 more($self, '215 information follows');
 173                 $arg->($self, @args);
 174         } else {
 175                 more($self, '215 list of newsgroups follows');
 176                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 177                         group_line($self, $ng);
 178                 }
 179         }
 180         '.'
 181 }
 182
 183 sub cmd_listgroup ($;$$) {
 184         my ($self, $group, $range) = @_;
 185         if (defined $group) {
 186                 my $res = cmd_group($self, $group);
 187                 return $res if ($res !~ /\A211 /);
 188                 more($self, $res);
 189         }
 190         my $ng = $self->{ng} or return '412 no newsgroup selected';
 191         my $mm = $ng->mm;
 192         if (defined $range) {
 193                 my $r = get_range($self, $range);
 194                 return $r unless ref $r;
 195                 my ($beg, $end) = @$r;
 196                 long_response($self, sub {
 197                         $r = $mm->msg_range(\$beg, $end, 'num');
 198                         scalar(@$r) or return;
 199                         more($self, join("\r\n", map { $_->[0] } @$r));
 200                         1;
 201                 });
 202         } else { # grab every article number
 203                 my $n = 0;
 204                 long_response($self, sub {
 205                         my $ary = $mm->ids_after(\$n);
 206                         scalar(@$ary) or return;
 207                         more($self, join("\r\n", @$ary));
 208                         1;
 209                 });
 210         }
 211 }
 212
 213 sub parse_time ($$;$) {
 214         my ($date, $time, $gmt) = @_;
 215         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 216         if (defined $gmt) {
 217                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 218                 $gmt = 1;
 219         }
 220         my @now = $gmt ? gmtime : localtime;
 221         my ($YYYY, $MM, $DD);
 222         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 223                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 224         } else { # legacy clients send YYMMDD
 225                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 226                 my $cur_year = $now[5] + 1900;
 227                 if ($YYYY > $cur_year) {
 228                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 229                 }
 230         }
 231         if ($gmt) {
 232                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 233         } else {
 234                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 235         }
 236 }
 237
 238 sub group_line ($$) {
 239         my ($self, $ng) = @_;
 240         my ($min, $max) = $ng->mm->minmax;
 241         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 242 }
 243
 244 sub cmd_newgroups ($$$;$$) {
 245         my ($self, $date, $time, $gmt, $dists) = @_;
 246         my $ts = eval { parse_time($date, $time, $gmt) };
 247         return r501 if $@;
 248
 249         # TODO dists
 250         more($self, '231 list of new newsgroups follows');
 251         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 252                 my $c = eval { $ng->mm->created_at } || 0;
 253                 next unless $c > $ts;
 254                 group_line($self, $ng);
 255         }
 256         '.'
 257 }
 258
 259 sub wildmat2re (;$) {
 260         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 261         my %keep;
 262         my $salt = rand;
 263         my $tmp = $_[0];
 264
 265         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 266                 my $orig = $1;
 267                 my $key = sha1_hex($orig . $salt);
 268                 $orig =~ s/([^\w\-])+/\Q$1/g;
 269                 $keep{$key} = $orig;
 270                 $key
 271                 #gex;
 272         my %map = ('*' => '.*', '?' => '.' );
 273         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 274         if (scalar %keep) {
 275                 $tmp =~ s#([a-f0-9]{40})#
 276                         my $orig = $keep{$1};
 277                         defined $orig ? $orig : $1;
 278                         #ge;
 279         }
 280         $_[0] = qr/\A$tmp\z/;
 281 }
 282
 283 sub ngpat2re (;$) {
 284         return $_[0] = qr/\A\z/ unless defined $_[0];
 285         my %map = ('*' => '.*', ',' => '|');
 286         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 287         $_[0] = qr/\A(?:$_[0])\z/;
 288 }
 289
 290 sub cmd_newnews ($$$$;$$) {
 291         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 292         my $ts = eval { parse_time($date, $time, $gmt) };
 293         return r501 if $@;
 294         more($self, '230 list of new articles by message-id follows');
 295         my ($keep, $skip) = split('!', $newsgroups, 2);
 296         ngpat2re($keep);
 297         ngpat2re($skip);
 298         my @over;
 299         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 300                 $ng->{newsgroup} =~ $keep or next;
 301                 $ng->{newsgroup} =~ $skip and next;
 302                 my $over = $ng->over or next;
 303                 push @over, $over;
 304         };
 305         return '.' unless @over;
 306
 307         my $prev = 0;
 308         long_response($self, sub {
 309                 my $over = $over[0];
 310                 my $msgs = $over->query_ts($ts, $prev);
 311                 if (scalar @$msgs) {
 312                         more($self, '<' .
 313                                 join(">\r\n<", map { $_->mid } @$msgs ).
 314                                 '>');
 315                         $prev = $msgs->[-1]->{num};
 316                 } else {
 317                         shift @over;
 318                         if (@over) { # continue onto next newsgroup
 319                                 $prev = 0;
 320                                 return 1;
 321                         } else { # break out of the long response.
 322                                 return;
 323                         }
 324                 }
 325         });
 326 }
 327
 328 sub cmd_group ($$) {
 329         my ($self, $group) = @_;
 330         my $no_such = '411 no such news group';
 331         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 332
 333         $self->{ng} = $ng;
 334         my ($min, $max) = $ng->mm->minmax;
 335         $min ||= 0;
 336         $max ||= 0;
 337         $self->{article} = $min;
 338         my $est_size = $max - $min;
 339         "211 $est_size $min $max $group";
 340 }
 341
 342 sub article_adj ($$) {
 343         my ($self, $off) = @_;
 344         my $ng = $self->{ng} or return '412 no newsgroup selected';
 345
 346         my $n = $self->{article};
 347         defined $n or return '420 no current article has been selected';
 348
 349         $n += $off;
 350         my $mid = $ng->mm->mid_for($n);
 351         unless ($mid) {
 352                 $n = $off > 0 ? 'next' : 'previous';
 353                 return "421 no $n article in this group";
 354         }
 355         $self->{article} = $n;
 356         "223 $n <$mid> article retrieved - request text separately";
 357 }
 358
 359 sub cmd_next ($) { article_adj($_[0], 1) }
 360 sub cmd_last ($) { article_adj($_[0], -1) }
 361
 362 # We want to encourage using email and CC-ing everybody involved to avoid
 363 # the single-point-of-failure a single server provides.
 364 sub cmd_post ($) {
 365         my ($self) = @_;
 366         my $ng = $self->{ng};
 367         $ng ? "440 mailto:$ng->{-primary_address} to post"
 368                 : '440 posting not allowed'
 369 }
 370
 371 sub cmd_quit ($) {
 372         my ($self) = @_;
 373         res($self, '205 closing connection - goodbye!');
 374         $self->shutdn;
 375         undef;
 376 }
 377
 378 sub header_append ($$$) {
 379         my ($hdr, $k, $v) = @_;
 380         my @v = $hdr->header($k);
 381         foreach (@v) {
 382                 return if $v eq $_;
 383         }
 384         $hdr->header_set($k, @v, $v);
 385 }
 386
 387 sub xref ($$$$) {
 388         my ($self, $ng, $n, $mid) = @_;
 389         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 390
 391         # num_for is pretty cheap and sometimes we'll lookup the existence
 392         # of an article without getting even the OVER info.  In other words,
 393         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 394         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 395         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 396                 next if $ng eq $other;
 397                 my $num = eval { $other->mm->num_for($mid) } or next;
 398                 $ret .= " $other->{newsgroup}:$num";
 399         }
 400         $ret;
 401 }
 402
 403 sub set_nntp_headers ($$$$$) {
 404         my ($self, $hdr, $ng, $n, $mid) = @_;
 405
 406         # why? leafnode requires a Path: header for some inexplicable
 407         # reason.  We'll fake the shortest one possible.
 408         $hdr->header_set('Path', 'y');
 409
 410         # leafnode (and maybe other NNTP clients) have trouble dealing
 411         # with v2 messages which have multiple Message-IDs (either due
 412         # to our own content-based dedupe or buggy git-send-email versions).
 413         my @mids = $hdr->header('Message-ID');
 414         if (scalar(@mids) > 1) {
 415                 my $mid0 = "<$mid>";
 416                 $hdr->header_set('Message-ID', $mid0);
 417                 my @alt = $hdr->header('X-Alt-Message-ID');
 418                 my %seen = map { $_ => 1 } (@alt, $mid0);
 419                 foreach my $m (@mids) {
 420                         next if $seen{$m}++;
 421                         push @alt, $m;
 422                 }
 423                 $hdr->header_set('X-Alt-Message-ID', @alt);
 424         }
 425
 426         # clobber some
 427         my $xref = xref($self, $ng, $n, $mid);
 428         $hdr->header_set('Xref', $xref);
 429         $xref =~ s/:[0-9]+//g;
 430         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 431         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 432         if (my $url = $ng->base_url) {
 433                 $mid = mid_escape($mid);
 434                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 435                 header_append($hdr, 'List-Archive', "<$url>");
 436         }
 437 }
 438
 439 sub art_lookup ($$$) {
 440         my ($self, $art, $set_headers) = @_;
 441         my $ng = $self->{ng};
 442         my ($n, $mid);
 443         my $err;
 444         if (defined $art) {
 445                 if ($art =~ /\A[0-9]+\z/) {
 446                         $err = '423 no such article number in this group';
 447                         $n = int($art);
 448                         goto find_mid;
 449                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 450                         $mid = $1;
 451                         $err = r430;
 452                         $n = $ng->mm->num_for($mid) if $ng;
 453                         goto found if defined $n;
 454                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 455                                 $n = $g->mm->num_for($mid);
 456                                 if (defined $n) {
 457                                         $ng = $g;
 458                                         goto found;
 459                                 }
 460                         }
 461                         return $err;
 462                 } else {
 463                         return r501;
 464                 }
 465         } else {
 466                 $err = '420 no current article has been selected';
 467                 $n = $self->{article};
 468                 defined $n or return $err;
 469 find_mid:
 470                 $ng or return '412 no newsgroup has been selected';
 471                 $mid = $ng->mm->mid_for($n);
 472                 defined $mid or return $err;
 473         }
 474 found:
 475         my $smsg = $ng->over->get_art($n) or return $err;
 476         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 477
 478         # Email::Simple->new will modify $msg in-place as documented
 479         # in its manpage, so what's left is the body and we won't need
 480         # to call Email::Simple::body(), later
 481         my $hdr = Email::Simple->new($msg)->header_obj;
 482         set_nntp_headers($self, $hdr, $ng, $n, $mid) if $set_headers;
 483         [ $n, $mid, $msg, $hdr ];
 484 }
 485
 486 sub msg_body_write ($$) {
 487         my ($self, $msg) = @_;
 488
 489         # these can momentarily double the memory consumption :<
 490         $$msg =~ s/^\./../smg;
 491         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 492         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 493         $self->msg_more($$msg);
 494         '.'
 495 }
 496
 497 sub set_art {
 498         my ($self, $art) = @_;
 499         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 500 }
 501
 502 sub msg_hdr_write ($$$) {
 503         my ($self, $hdr, $body_follows) = @_;
 504         $hdr = $hdr->as_string;
 505         utf8::encode($hdr);
 506         $hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 507
 508         # for leafnode compatibility, we need to ensure Message-ID headers
 509         # are only a single line.  We can't subclass Email::Simple::Header
 510         # and override _default_fold_at in here, either; since that won't
 511         # affect messages already in the archive.
 512         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 513         $hdr .= "\r\n" if $body_follows;
 514         $self->msg_more($hdr);
 515 }
 516
 517 sub cmd_article ($;$) {
 518         my ($self, $art) = @_;
 519         my $r = art_lookup($self, $art, 1);
 520         return $r unless ref $r;
 521         my ($n, $mid, $msg, $hdr) = @$r;
 522         set_art($self, $art);
 523         more($self, "220 $n <$mid> article retrieved - head and body follow");
 524         msg_hdr_write($self, $hdr, 1);
 525         msg_body_write($self, $msg);
 526 }
 527
 528 sub cmd_head ($;$) {
 529         my ($self, $art) = @_;
 530         my $r = art_lookup($self, $art, 2);
 531         return $r unless ref $r;
 532         my ($n, $mid, undef, $hdr) = @$r;
 533         set_art($self, $art);
 534         more($self, "221 $n <$mid> article retrieved - head follows");
 535         msg_hdr_write($self, $hdr, 0);
 536         '.'
 537 }
 538
 539 sub cmd_body ($;$) {
 540         my ($self, $art) = @_;
 541         my $r = art_lookup($self, $art, 0);
 542         return $r unless ref $r;
 543         my ($n, $mid, $msg) = @$r;
 544         set_art($self, $art);
 545         more($self, "222 $n <$mid> article retrieved - body follows");
 546         msg_body_write($self, $msg);
 547 }
 548
 549 sub cmd_stat ($;$) {
 550         my ($self, $art) = @_;
 551         my $r = art_lookup($self, $art, 0);
 552         return $r unless ref $r;
 553         my ($n, $mid) = @$r;
 554         set_art($self, $art);
 555         "223 $n <$mid> article retrieved - request text separately";
 556 }
 557
 558 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 559
 560 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 561
 562 sub cmd_help ($) {
 563         my ($self) = @_;
 564         more($self, '100 help text follows');
 565         '.'
 566 }
 567
 568 sub get_range ($$) {
 569         my ($self, $range) = @_;
 570         my $ng = $self->{ng} or return '412 no news group has been selected';
 571         defined $range or return '420 No article(s) selected';
 572         my ($beg, $end);
 573         my ($min, $max) = $ng->mm->minmax;
 574         if ($range =~ /\A([0-9]+)\z/) {
 575                 $beg = $end = $1;
 576         } elsif ($range =~ /\A([0-9]+)-\z/) {
 577                 ($beg, $end) = ($1, $max);
 578         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 579                 ($beg, $end) = ($1, $2);
 580         } else {
 581                 return r501;
 582         }
 583         $beg = $min if ($beg < $min);
 584         $end = $max if ($end > $max);
 585         return '420 No article(s) selected' if ($beg > $end);
 586         [ $beg, $end ];
 587 }
 588
 589 sub long_response ($$) {
 590         my ($self, $cb) = @_; # cb returns true if more, false if done
 591
 592         my $fd = fileno($self->{sock});
 593         defined $fd or return;
 594         # make sure we disable reading during a long response,
 595         # clients should not be sending us stuff and making us do more
 596         # work while we are stream a response to them
 597         my $t0 = now();
 598         my $long_cb; # DANGER: self-referential
 599         $long_cb = sub {
 600                 # wbuf is unset or empty, here; $cb may add to it
 601                 my $more = eval { $cb->() };
 602                 if ($@ || !$self->{sock}) { # something bad happened...
 603                         $long_cb = undef;
 604                         my $diff = now() - $t0;
 605                         if ($@) {
 606                                 err($self,
 607                                     "%s during long response[$fd] - %0.6f",
 608                                     $@, $diff);
 609                         }
 610                         out($self, " deferred[$fd] aborted - %0.6f", $diff);
 611                         $self->close;
 612                 } elsif ($more) { # $self->{wbuf}:
 613                         $self->update_idle_time;
 614
 615                         # COMPRESS users all share the same DEFLATE context.
 616                         # Flush it here to ensure clients don't see
 617                         # each other's data
 618                         $self->zflush;
 619
 620                         # no recursion, schedule another call ASAP
 621                         # but only after all pending writes are done
 622                         my $wbuf = $self->{wbuf} ||= [];
 623                         push @$wbuf, $long_cb;
 624
 625                         # wbuf may be populated by $cb, no need to rearm if so:
 626                         $self->requeue if scalar(@$wbuf) == 1;
 627                 } else { # all done!
 628                         $long_cb = undef;
 629                         res($self, '.');
 630                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 631                         my $wbuf = $self->{wbuf};
 632                         $self->requeue unless $wbuf && @$wbuf;
 633                 }
 634         };
 635         $self->write($long_cb); # kick off!
 636         undef;
 637 }
 638
 639 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 640         my ($self, $xhdr, $range) = @_;
 641
 642         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 643                 my ($ng, $n) = mid_lookup($self, $1);
 644                 return r430 unless $n;
 645                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 646         } else { # numeric range
 647                 $range = $self->{article} unless defined $range;
 648                 my $r = get_range($self, $range);
 649                 return $r unless ref $r;
 650                 my $mm = $self->{ng}->mm;
 651                 my ($beg, $end) = @$r;
 652                 more($self, $xhdr ? r221 : r225);
 653                 long_response($self, sub {
 654                         my $r = $mm->msg_range(\$beg, $end);
 655                         @$r or return;
 656                         more($self, join("\r\n", map {
 657                                 "$_->[0] <$_->[1]>"
 658                         } @$r));
 659                         1;
 660                 });
 661         }
 662 }
 663
 664 sub mid_lookup ($$) {
 665         my ($self, $mid) = @_;
 666         my $self_ng = $self->{ng};
 667         if ($self_ng) {
 668                 my $n = $self_ng->mm->num_for($mid);
 669                 return ($self_ng, $n) if defined $n;
 670         }
 671         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 672                 next if defined $self_ng && $ng eq $self_ng;
 673                 my $n = $ng->mm->num_for($mid);
 674                 return ($ng, $n) if defined $n;
 675         }
 676         (undef, undef);
 677 }
 678
 679 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 680         my ($self, $xhdr, $range) = @_;
 681
 682         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 683                 my $mid = $1;
 684                 my ($ng, $n) = mid_lookup($self, $mid);
 685                 return r430 unless $n;
 686                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 687                                 xref($self, $ng, $n, $mid));
 688         } else { # numeric range
 689                 $range = $self->{article} unless defined $range;
 690                 my $r = get_range($self, $range);
 691                 return $r unless ref $r;
 692                 my $ng = $self->{ng};
 693                 my $mm = $ng->mm;
 694                 my ($beg, $end) = @$r;
 695                 more($self, $xhdr ? r221 : r225);
 696                 long_response($self, sub {
 697                         my $r = $mm->msg_range(\$beg, $end);
 698                         @$r or return;
 699                         more($self, join("\r\n", map {
 700                                 my $num = $_->[0];
 701                                 "$num ".xref($self, $ng, $num, $_->[1]);
 702                         } @$r));
 703                         1;
 704                 });
 705         }
 706 }
 707
 708 sub over_header_for {
 709         my ($over, $num, $field) = @_;
 710         my $smsg = $over->get_art($num) or return;
 711         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 712         $smsg->{$field};
 713 }
 714
 715 sub hdr_searchmsg ($$$$) {
 716         my ($self, $xhdr, $field, $range) = @_;
 717         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 718                 my ($ng, $n) = mid_lookup($self, $1);
 719                 return r430 unless defined $n;
 720                 my $v = over_header_for($ng->over, $n, $field);
 721                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 722         } else { # numeric range
 723                 $range = $self->{article} unless defined $range;
 724                 my $over = $self->{ng}->over;
 725                 my $mm = $self->{ng}->mm;
 726                 my $r = get_range($self, $range);
 727                 return $r unless ref $r;
 728                 my ($beg, $end) = @$r;
 729                 more($self, $xhdr ? r221 : r225);
 730                 my $cur = $beg;
 731                 long_response($self, sub {
 732                         my $msgs = $over->query_xover($cur, $end);
 733                         my $nr = scalar @$msgs or return;
 734                         my $tmp = '';
 735                         foreach my $s (@$msgs) {
 736                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 737                         }
 738                         utf8::encode($tmp);
 739                         $self->msg_more($tmp);
 740                         $cur = $msgs->[-1]->{num} + 1;
 741                 });
 742         }
 743 }
 744
 745 sub do_hdr ($$$;$) {
 746         my ($self, $xhdr, $header, $range) = @_;
 747         my $sub = lc $header;
 748         if ($sub eq 'message-id') {
 749                 hdr_message_id($self, $xhdr, $range);
 750         } elsif ($sub eq 'xref') {
 751                 hdr_xref($self, $xhdr, $range);
 752         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 753                                 bytes|lines)\z/x) {
 754                 hdr_searchmsg($self, $xhdr, $sub, $range);
 755         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 756                 hdr_searchmsg($self, $xhdr, $1, $range);
 757         } else {
 758                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 759         }
 760 }
 761
 762 # RFC 3977
 763 sub cmd_hdr ($$;$) {
 764         my ($self, $header, $range) = @_;
 765         do_hdr($self, 0, $header, $range);
 766 }
 767
 768 # RFC 2980
 769 sub cmd_xhdr ($$;$) {
 770         my ($self, $header, $range) = @_;
 771         do_hdr($self, 1, $header, $range);
 772 }
 773
 774 sub hdr_mid_prefix ($$$$$) {
 775         my ($self, $xhdr, $ng, $n, $mid) = @_;
 776         return $mid if $xhdr;
 777
 778         # HDR for RFC 3977 users
 779         if (my $self_ng = $self->{ng}) {
 780                 ($self_ng eq $ng) ? $n : '0';
 781         } else {
 782                 '0';
 783         }
 784 }
 785
 786 sub hdr_mid_response ($$$$$$) {
 787         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 788         my $res = '';
 789         if ($xhdr) {
 790                 $res .= r221 . "\r\n";
 791                 $res .= "$mid $v\r\n";
 792         } else {
 793                 $res .= r225 . "\r\n";
 794                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 795                 $res .= "$pfx $v\r\n";
 796         }
 797         res($self, $res .= '.');
 798         undef;
 799 }
 800
 801 sub cmd_xrover ($;$) {
 802         my ($self, $range) = @_;
 803         my $ng = $self->{ng} or return '412 no newsgroup selected';
 804         (defined $range && $range =~ /[<>]/) and
 805                 return '420 No article(s) selected'; # no message IDs
 806
 807         $range = $self->{article} unless defined $range;
 808         my $r = get_range($self, $range);
 809         return $r unless ref $r;
 810         my ($beg, $end) = @$r;
 811         my $mm = $ng->mm;
 812         my $over = $ng->over;
 813         more($self, '224 Overview information follows');
 814
 815         long_response($self, sub {
 816                 my $h = over_header_for($over, $beg, 'references');
 817                 more($self, "$beg $h") if defined($h);
 818                 $beg++ < $end;
 819         });
 820 }
 821
 822 sub over_line ($$$$) {
 823         my ($self, $ng, $num, $smsg) = @_;
 824         # n.b. field access and procedural calls can be
 825         # 10%-15% faster than OO method calls:
 826         my $s = join("\t", $num,
 827                 $smsg->{subject},
 828                 $smsg->{from},
 829                 PublicInbox::SearchMsg::date($smsg),
 830                 "<$smsg->{mid}>",
 831                 $smsg->{references},
 832                 $smsg->{bytes},
 833                 $smsg->{lines},
 834                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 835         utf8::encode($s);
 836         $s
 837 }
 838
 839 sub cmd_over ($;$) {
 840         my ($self, $range) = @_;
 841         if ($range && $range =~ /\A<(.+)>\z/) {
 842                 my ($ng, $n) = mid_lookup($self, $1);
 843                 defined $n or return r430;
 844                 my $smsg = $ng->over->get_art($n) or return r430;
 845                 more($self, '224 Overview information follows (multi-line)');
 846
 847                 # Only set article number column if it's the current group
 848                 my $self_ng = $self->{ng};
 849                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 850                 more($self, over_line($self, $ng, $n, $smsg));
 851                 '.';
 852         } else {
 853                 cmd_xover($self, $range);
 854         }
 855 }
 856
 857 sub cmd_xover ($;$) {
 858         my ($self, $range) = @_;
 859         $range = $self->{article} unless defined $range;
 860         my $r = get_range($self, $range);
 861         return $r unless ref $r;
 862         my ($beg, $end) = @$r;
 863         more($self, "224 Overview information follows for $beg to $end");
 864         my $over = $self->{ng}->over;
 865         my $cur = $beg;
 866         long_response($self, sub {
 867                 my $msgs = $over->query_xover($cur, $end);
 868                 my $nr = scalar @$msgs or return;
 869
 870                 # OVERVIEW.FMT
 871                 more($self, join("\r\n", map {
 872                         over_line($self, $self->{ng}, $_->{num}, $_);
 873                         } @$msgs));
 874                 $cur = $msgs->[-1]->{num} + 1;
 875         });
 876 }
 877
 878 sub compressed { undef }
 879
 880 sub cmd_starttls ($) {
 881         my ($self) = @_;
 882         my $sock = $self->{sock} or return;
 883         # RFC 4642 2.2.1
 884         return r502 if (ref($sock) eq 'IO::Socket::SSL' || $self->compressed);
 885         my $opt = $self->{nntpd}->{accept_tls} or
 886                 return '580 can not initiate TLS negotiation';
 887         res($self, '382 Continue with TLS negotiation');
 888         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 889         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 890         undef;
 891 }
 892
 893 # RFC 8054
 894 sub cmd_compress ($$) {
 895         my ($self, $alg) = @_;
 896         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 897         return r502 if $self->compressed || !$have_deflate;
 898         PublicInbox::NNTPdeflate->enable($self);
 899         $self->requeue;
 900         undef
 901 }
 902
 903 sub zflush {} # overridden by NNTPdeflate
 904
 905 sub cmd_xpath ($$) {
 906         my ($self, $mid) = @_;
 907         return r501 unless $mid =~ /\A<(.+)>\z/;
 908         $mid = $1;
 909         my @paths;
 910         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 911                 my $n = $ng->mm->num_for($mid);
 912                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 913         }
 914         return '430 no such article on server' unless @paths;
 915         '223 '.join(' ', @paths);
 916 }
 917
 918 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 919
 920 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 921
 922 sub do_write ($$) {
 923         my $self = $_[0];
 924         my $done = $self->write(\($_[1]));
 925         return 0 unless $self->{sock};
 926
 927         $done;
 928 }
 929
 930 sub err ($$;@) {
 931         my ($self, $fmt, @args) = @_;
 932         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 933 }
 934
 935 sub out ($$;@) {
 936         my ($self, $fmt, @args) = @_;
 937         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 938 }
 939
 940 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 941 sub event_step {
 942         my ($self) = @_;
 943
 944         return unless $self->flush_write && $self->{sock};
 945
 946         $self->update_idle_time;
 947         # only read more requests if we've drained the write buffer,
 948         # otherwise we can be buffering infinitely w/o backpressure
 949
 950         my $rbuf = $self->{rbuf} // (\(my $x = ''));
 951         my $r = 1;
 952
 953         if (index($$rbuf, "\n") < 0) {
 954                 my $off = bytes::length($$rbuf);
 955                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 956         }
 957         while ($r > 0 && $$rbuf =~ s/\A[ \t]*([^\n]*?)\r?\n//) {
 958                 my $line = $1;
 959                 return $self->close if $line =~ /[[:cntrl:]]/s;
 960                 my $t0 = now();
 961                 my $fd = fileno($self->{sock});
 962                 $r = eval { process_line($self, $line) };
 963                 my $pending = $self->{wbuf} ? ' pending' : '';
 964                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
 965         }
 966
 967         return $self->close if $r < 0;
 968         my $len = bytes::length($$rbuf);
 969         return $self->close if ($len >= LINE_MAX);
 970         $self->rbuf_idle($rbuf);
 971         $self->update_idle_time;
 972
 973         # maybe there's more pipelined data, or we'll have
 974         # to register it for socket-readiness notifications
 975         $self->requeue unless $self->{wbuf};
 976 }
 977
 978 # for graceful shutdown in PublicInbox::Daemon:
 979 sub busy {
 980         my ($self, $now) = @_;
 981         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
 982 }
 983
 984 # this is an import to prevent "perl -c" from complaining about fields
 985 sub import {
 986         $have_deflate = eval { require PublicInbox::NNTPdeflate } and
 987                 $CAPABILITIES .= "COMPRESS DEFLATE\r\n";
 988 }
 989
 990 1;