lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 # fields:
   6 # nntpd: PublicInbox::NNTPD ref
   7 # article: per-session current article number
   8 # ng: PublicInbox::Inbox ref
   9 # long_cb: long_response private data
  10 package PublicInbox::NNTP;
  11 use strict;
  12 use parent qw(PublicInbox::DS);
  13 use PublicInbox::MID qw(mid_escape $MID_EXTRACT);
  14 use PublicInbox::Eml;
  15 use POSIX qw(strftime);
  16 use PublicInbox::DS qw(now);
  17 use Digest::SHA qw(sha1_hex);
  18 use Time::Local qw(timegm timelocal);
  19 use PublicInbox::GitAsyncCat;
  20 use constant {
  21         LINE_MAX => 512, # RFC 977 section 2.3
  22         r501 => '501 command syntax error',
  23         r502 => '502 Command unavailable',
  24         r221 => '221 Header follows',
  25         r224 => '224 Overview information follows (multi-line)',
  26         r225 => '225 Headers follow (multi-line)',
  27         r430 => '430 No article with that message-id',
  28 };
  29 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  30 use Errno qw(EAGAIN);
  31 my $ONE_MSGID = qr/\A$MID_EXTRACT\z/;
  32 my @OVERVIEW = qw(Subject From Date Message-ID References);
  33 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  34                 "Xref:full\r\n";
  35 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  36                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  37 my $CAPABILITIES = <<"";
  38 101 Capability list:\r
  39 VERSION 2\r
  40 READER\r
  41 NEWNEWS\r
  42 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  43 HDR\r
  44 OVER\r
  45 COMPRESS DEFLATE\r
  46
  47 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  48
  49 sub new ($$$) {
  50         my ($class, $sock, $nntpd) = @_;
  51         my $self = bless { nntpd => $nntpd }, $class;
  52         my $ev = EPOLLIN;
  53         my $wbuf;
  54         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
  55                 return CORE::close($sock) if $! != EAGAIN;
  56                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
  57                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  58         }
  59         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  60         if ($wbuf) {
  61                 $self->{wbuf} = $wbuf;
  62         } else {
  63                 greet($self);
  64         }
  65         $self->update_idle_time;
  66         $self;
  67 }
  68
  69 sub args_ok ($$) {
  70         my ($cb, $argc) = @_;
  71         my $tot = prototype $cb;
  72         my ($nreq, undef) = split(';', $tot);
  73         $nreq = ($nreq =~ tr/$//) - 1;
  74         $tot = ($tot =~ tr/$//) - 1;
  75         ($argc <= $tot && $argc >= $nreq);
  76 }
  77
  78 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  79 sub process_line ($$) {
  80         my ($self, $l) = @_;
  81         my ($req, @args) = split(/[ \t]+/, $l);
  82         return 1 unless defined($req); # skip blank line
  83         $req = $self->can('cmd_'.lc($req));
  84         return res($self, '500 command not recognized') unless $req;
  85         return res($self, r501) unless args_ok($req, scalar @args);
  86
  87         my $res = eval { $req->($self, @args) };
  88         my $err = $@;
  89         if ($err && $self->{sock}) {
  90                 local $/ = "\n";
  91                 chomp($l);
  92                 err($self, 'error from: %s (%s)', $l, $err);
  93                 $res = '503 program fault - command not performed';
  94         }
  95         return 0 unless defined $res;
  96         res($self, $res);
  97 }
  98
  99 # The keyword argument is not used (rfc3977 5.2.2)
 100 sub cmd_capabilities ($;$) {
 101         my ($self, undef) = @_;
 102         my $res = $CAPABILITIES;
 103         if (!$self->{sock}->can('accept_SSL') &&
 104                         $self->{nntpd}->{accept_tls}) {
 105                 $res .= "STARTTLS\r\n";
 106         }
 107         $res .= '.';
 108 }
 109
 110 sub cmd_mode ($$) {
 111         my ($self, $arg) = @_;
 112         $arg = uc $arg;
 113         return r501 unless $arg eq 'READER';
 114         '201 Posting prohibited';
 115 }
 116
 117 sub cmd_slave ($) { '202 slave status noted' }
 118
 119 sub cmd_xgtitle ($;$) {
 120         my ($self, $wildmat) = @_;
 121         more($self, '282 list of groups and descriptions follows');
 122         list_newsgroups($self, $wildmat);
 123         '.'
 124 }
 125
 126 sub list_overview_fmt ($) {
 127         my ($self) = @_;
 128         $self->msg_more($OVERVIEW_FMT);
 129 }
 130
 131 sub list_headers ($;$) {
 132         my ($self) = @_;
 133         $self->msg_more($LIST_HEADERS);
 134 }
 135
 136 sub list_active ($;$) {
 137         my ($self, $wildmat) = @_;
 138         wildmat2re($wildmat);
 139         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 140                 $ng->{newsgroup} =~ $wildmat or next;
 141                 group_line($self, $ng);
 142         }
 143 }
 144
 145 sub list_active_times ($;$) {
 146         my ($self, $wildmat) = @_;
 147         wildmat2re($wildmat);
 148         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 149                 $ng->{newsgroup} =~ $wildmat or next;
 150                 my $c = eval { $ng->mm->created_at } || time;
 151                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 152         }
 153 }
 154
 155 sub list_newsgroups ($;$) {
 156         my ($self, $wildmat) = @_;
 157         wildmat2re($wildmat);
 158         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 159                 $ng->{newsgroup} =~ $wildmat or next;
 160                 my $d = $ng->description;
 161                 more($self, "$ng->{newsgroup} $d");
 162         }
 163 }
 164
 165 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 166 sub cmd_list ($;$$) {
 167         my ($self, @args) = @_;
 168         if (scalar @args) {
 169                 my $arg = shift @args;
 170                 $arg =~ tr/A-Z./a-z_/;
 171                 $arg = "list_$arg";
 172                 $arg = $self->can($arg);
 173                 return r501 unless $arg && args_ok($arg, scalar @args);
 174                 more($self, '215 information follows');
 175                 $arg->($self, @args);
 176         } else {
 177                 more($self, '215 list of newsgroups follows');
 178                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 179                         group_line($self, $ng);
 180                 }
 181         }
 182         '.'
 183 }
 184
 185 sub listgroup_range_i {
 186         my ($self, $beg, $end) = @_;
 187         my $r = $self->{ng}->mm->msg_range($beg, $end, 'num');
 188         scalar(@$r) or return;
 189         more($self, join("\r\n", map { $_->[0] } @$r));
 190         1;
 191 }
 192
 193 sub listgroup_all_i {
 194         my ($self, $num) = @_;
 195         my $ary = $self->{ng}->mm->ids_after($num);
 196         scalar(@$ary) or return;
 197         more($self, join("\r\n", @$ary));
 198         1;
 199 }
 200
 201 sub cmd_listgroup ($;$$) {
 202         my ($self, $group, $range) = @_;
 203         if (defined $group) {
 204                 my $res = cmd_group($self, $group);
 205                 return $res if ($res !~ /\A211 /);
 206                 more($self, $res);
 207         }
 208         $self->{ng} or return '412 no newsgroup selected';
 209         if (defined $range) {
 210                 my $r = get_range($self, $range);
 211                 return $r unless ref $r;
 212                 long_response($self, \&listgroup_range_i, @$r);
 213         } else { # grab every article number
 214                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 215         }
 216 }
 217
 218 sub parse_time ($$;$) {
 219         my ($date, $time, $gmt) = @_;
 220         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 221         if (defined $gmt) {
 222                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 223                 $gmt = 1;
 224         }
 225         my ($YYYY, $MM, $DD);
 226         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 227                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 228         } else { # legacy clients send YYMMDD
 229                 my $YY;
 230                 ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 231                 my @now = $gmt ? gmtime : localtime;
 232                 my $cur_year = $now[5] + 1900;
 233                 my $cur_cent = int($cur_year / 100) * 100;
 234                 $YYYY = (($YY + $cur_cent) > $cur_year) ?
 235                         ($YY + 1900) : ($YY + $cur_cent);
 236         }
 237         if ($gmt) {
 238                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 239         } else {
 240                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 241         }
 242 }
 243
 244 sub group_line ($$) {
 245         my ($self, $ng) = @_;
 246         my ($min, $max) = $ng->mm->minmax;
 247         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 248 }
 249
 250 sub cmd_newgroups ($$$;$$) {
 251         my ($self, $date, $time, $gmt, $dists) = @_;
 252         my $ts = eval { parse_time($date, $time, $gmt) };
 253         return r501 if $@;
 254
 255         # TODO dists
 256         more($self, '231 list of new newsgroups follows');
 257         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 258                 my $c = eval { $ng->mm->created_at } || 0;
 259                 next unless $c > $ts;
 260                 group_line($self, $ng);
 261         }
 262         '.'
 263 }
 264
 265 sub wildmat2re (;$) {
 266         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 267         my %keep;
 268         my $salt = rand;
 269         my $tmp = $_[0];
 270
 271         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 272                 my $orig = $1;
 273                 my $key = sha1_hex($orig . $salt);
 274                 $orig =~ s/([^\w\-])+/\Q$1/g;
 275                 $keep{$key} = $orig;
 276                 $key
 277                 #gex;
 278         my %map = ('*' => '.*', '?' => '.' );
 279         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 280         if (scalar %keep) {
 281                 $tmp =~ s#([a-f0-9]{40})#
 282                         my $orig = $keep{$1};
 283                         defined $orig ? $orig : $1;
 284                         #ge;
 285         }
 286         $_[0] = qr/\A$tmp\z/;
 287 }
 288
 289 sub ngpat2re (;$) {
 290         return $_[0] = qr/\A\z/ unless defined $_[0];
 291         my %map = ('*' => '.*', ',' => '|');
 292         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 293         $_[0] = qr/\A(?:$_[0])\z/;
 294 }
 295
 296 sub newnews_i {
 297         my ($self, $overs, $ts, $prev) = @_;
 298         my $over = $overs->[0];
 299         my $msgs = $over->query_ts($ts, $$prev);
 300         if (scalar @$msgs) {
 301                 more($self, '<' .
 302                         join(">\r\n<", map { $_->{mid} } @$msgs ).
 303                         '>');
 304                 $$prev = $msgs->[-1]->{num};
 305         } else {
 306                 shift @$overs;
 307                 if (@$overs) { # continue onto next newsgroup
 308                         $$prev = 0;
 309                         return 1;
 310                 } else { # break out of the long response.
 311                         return;
 312                 }
 313         }
 314 }
 315
 316 sub cmd_newnews ($$$$;$$) {
 317         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 318         my $ts = eval { parse_time($date, $time, $gmt) };
 319         return r501 if $@;
 320         more($self, '230 list of new articles by message-id follows');
 321         my ($keep, $skip) = split('!', $newsgroups, 2);
 322         ngpat2re($keep);
 323         ngpat2re($skip);
 324         my @overs;
 325         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 326                 $ng->{newsgroup} =~ $keep or next;
 327                 $ng->{newsgroup} =~ $skip and next;
 328                 my $over = $ng->over or next;
 329                 push @overs, $over;
 330         };
 331         return '.' unless @overs;
 332
 333         my $prev = 0;
 334         long_response($self, \&newnews_i, \@overs, $ts, \$prev);
 335 }
 336
 337 sub cmd_group ($$) {
 338         my ($self, $group) = @_;
 339         my $no_such = '411 no such news group';
 340         my $nntpd = $self->{nntpd};
 341         my $ng = $nntpd->{groups}->{$group} or return $no_such;
 342         $nntpd->idler_start;
 343
 344         $self->{ng} = $ng;
 345         my ($min, $max) = $ng->mm->minmax;
 346         $min ||= 0;
 347         $max ||= 0;
 348         $self->{article} = $min;
 349         my $est_size = $max - $min;
 350         "211 $est_size $min $max $group";
 351 }
 352
 353 sub article_adj ($$) {
 354         my ($self, $off) = @_;
 355         my $ng = $self->{ng} or return '412 no newsgroup selected';
 356
 357         my $n = $self->{article};
 358         defined $n or return '420 no current article has been selected';
 359
 360         $n += $off;
 361         my $mid = $ng->mm->mid_for($n);
 362         unless ($mid) {
 363                 $n = $off > 0 ? 'next' : 'previous';
 364                 return "421 no $n article in this group";
 365         }
 366         $self->{article} = $n;
 367         "223 $n <$mid> article retrieved - request text separately";
 368 }
 369
 370 sub cmd_next ($) { article_adj($_[0], 1) }
 371 sub cmd_last ($) { article_adj($_[0], -1) }
 372
 373 # We want to encourage using email and CC-ing everybody involved to avoid
 374 # the single-point-of-failure a single server provides.
 375 sub cmd_post ($) {
 376         my ($self) = @_;
 377         my $ng = $self->{ng};
 378         $ng ? "440 mailto:$ng->{-primary_address} to post"
 379                 : '440 posting not allowed'
 380 }
 381
 382 sub cmd_quit ($) {
 383         my ($self) = @_;
 384         res($self, '205 closing connection - goodbye!');
 385         $self->shutdn;
 386         undef;
 387 }
 388
 389 sub header_append ($$$) {
 390         my ($hdr, $k, $v) = @_;
 391         my @v = $hdr->header_raw($k);
 392         foreach (@v) {
 393                 return if $v eq $_;
 394         }
 395         $hdr->header_set($k, @v, $v);
 396 }
 397
 398 sub xref ($$$$) {
 399         my ($self, $ng, $n, $mid) = @_;
 400         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 401
 402         # num_for is pretty cheap and sometimes we'll lookup the existence
 403         # of an article without getting even the OVER info.  In other words,
 404         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 405         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 406         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 407                 next if $ng eq $other;
 408                 my $num = eval { $other->mm->num_for($mid) } or next;
 409                 $ret .= " $other->{newsgroup}:$num";
 410         }
 411         $ret;
 412 }
 413
 414 sub set_nntp_headers ($$) {
 415         my ($hdr, $smsg) = @_;
 416         my ($mid) = $smsg->{mid};
 417
 418         # why? leafnode requires a Path: header for some inexplicable
 419         # reason.  We'll fake the shortest one possible.
 420         $hdr->header_set('Path', 'y');
 421
 422         # leafnode (and maybe other NNTP clients) have trouble dealing
 423         # with v2 messages which have multiple Message-IDs (either due
 424         # to our own content-based dedupe or buggy git-send-email versions).
 425         my @mids = $hdr->header_raw('Message-ID');
 426         if (scalar(@mids) > 1) {
 427                 my $mid0 = "<$mid>";
 428                 $hdr->header_set('Message-ID', $mid0);
 429                 my @alt = $hdr->header_raw('X-Alt-Message-ID');
 430                 my %seen = map { $_ => 1 } (@alt, $mid0);
 431                 push(@alt, grep { !$seen{$_}++ } @mids);
 432                 $hdr->header_set('X-Alt-Message-ID', @alt);
 433         }
 434
 435         # clobber some
 436         my $ibx = $smsg->{-ibx};
 437         my $xref = xref($smsg->{nntp}, $ibx, $smsg->{num}, $mid);
 438         $hdr->header_set('Xref', $xref);
 439         $xref =~ s/:[0-9]+//g;
 440         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 441         header_append($hdr, 'List-Post', "<mailto:$ibx->{-primary_address}>");
 442         if (my $url = $ibx->base_url) {
 443                 $mid = mid_escape($mid);
 444                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 445                 header_append($hdr, 'List-Archive', "<$url>");
 446         }
 447 }
 448
 449 sub art_lookup ($$$) {
 450         my ($self, $art, $code) = @_;
 451         my $ng = $self->{ng};
 452         my ($n, $mid);
 453         my $err;
 454         if (defined $art) {
 455                 if ($art =~ /\A[0-9]+\z/) {
 456                         $err = '423 no such article number in this group';
 457                         $n = int($art);
 458                         goto find_mid;
 459                 } elsif ($art =~ $ONE_MSGID) {
 460                         $mid = $1;
 461                         $err = r430;
 462                         $n = $ng->mm->num_for($mid) if $ng;
 463                         goto found if defined $n;
 464                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 465                                 $n = $g->mm->num_for($mid);
 466                                 if (defined $n) {
 467                                         $ng = $g;
 468                                         goto found;
 469                                 }
 470                         }
 471                         return $err;
 472                 } else {
 473                         return r501;
 474                 }
 475         } else {
 476                 $err = '420 no current article has been selected';
 477                 $n = $self->{article};
 478                 defined $n or return $err;
 479 find_mid:
 480                 $ng or return '412 no newsgroup has been selected';
 481                 $mid = $ng->mm->mid_for($n);
 482                 defined $mid or return $err;
 483         }
 484 found:
 485         my $smsg = $ng->over->get_art($n) or return $err;
 486         $smsg->{-ibx} = $ng;
 487         if ($code == 223) { # STAT
 488                 set_art($self, $n);
 489                 "223 $n <$smsg->{mid}> article retrieved - " .
 490                         "request text separately";
 491         } else { # HEAD | BODY | ARTICLE
 492                 $smsg->{nntp} = $self;
 493                 $smsg->{nntp_code} = $code;
 494                 set_art($self, $art);
 495                 # this dereferences to `undef'
 496                 ${git_async_cat($ng->git, $smsg->{blob}, \&blob_cb, $smsg)};
 497         }
 498 }
 499
 500 sub msg_body_write ($$) {
 501         my ($self, $msg) = @_;
 502
 503         # these can momentarily double the memory consumption :<
 504         $$msg =~ s/^\./../smg;
 505         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 506         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 507         $self->msg_more($$msg);
 508 }
 509
 510 sub set_art {
 511         my ($self, $art) = @_;
 512         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 513 }
 514
 515 sub msg_hdr_write ($$) {
 516         my ($eml, $smsg) = @_;
 517         set_nntp_headers($eml, $smsg);
 518
 519         my $hdr = $eml->{hdr} // \(my $x = '');
 520         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 521         $$hdr =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 522         $$hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 523
 524         # for leafnode compatibility, we need to ensure Message-ID headers
 525         # are only a single line.
 526         $$hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 527         $smsg->{nntp}->msg_more($$hdr);
 528 }
 529
 530 sub blob_cb { # called by git->cat_async via git_async_cat
 531         my ($bref, $oid, $type, $size, $smsg) = @_;
 532         my $self = $smsg->{nntp};
 533         my $code = $smsg->{nntp_code};
 534         if (!defined($oid)) {
 535                 # it's possible to have TOCTOU if an admin runs
 536                 # public-inbox-(edit|purge), just move onto the next message
 537                 warn "E: $smsg->{blob} missing in $smsg->{-ibx}->{inboxdir}\n";
 538                 return $self->requeue;
 539         } elsif ($smsg->{blob} ne $oid) {
 540                 $self->close;
 541                 die "BUG: $smsg->{blob} != $oid";
 542         }
 543         my $r = "$code $smsg->{num} <$smsg->{mid}> article retrieved - ";
 544         my $eml = PublicInbox::Eml->new($bref);
 545         if ($code == 220) {
 546                 more($self, $r .= 'head and body follow');
 547                 msg_hdr_write($eml, $smsg);
 548                 $self->msg_more("\r\n");
 549                 msg_body_write($self, $bref);
 550         } elsif ($code == 221) {
 551                 more($self, $r .= 'head follows');
 552                 msg_hdr_write($eml, $smsg);
 553         } elsif ($code == 222) {
 554                 more($self, $r .= 'body follows');
 555                 msg_body_write($self, $bref);
 556         } else {
 557                 $self->close;
 558                 die "BUG: bad code: $r";
 559         }
 560         $self->write(\".\r\n"); # flushes (includes ->zflush)
 561         $self->requeue;
 562 }
 563
 564 sub cmd_article ($;$) {
 565         my ($self, $art) = @_;
 566         art_lookup($self, $art, 220);
 567 }
 568
 569 sub cmd_head ($;$) {
 570         my ($self, $art) = @_;
 571         art_lookup($self, $art, 221);
 572 }
 573
 574 sub cmd_body ($;$) {
 575         my ($self, $art) = @_;
 576         art_lookup($self, $art, 222);
 577 }
 578
 579 sub cmd_stat ($;$) {
 580         my ($self, $art) = @_;
 581         art_lookup($self, $art, 223); # art may be msgid
 582 }
 583
 584 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 585
 586 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 587
 588 sub cmd_help ($) {
 589         my ($self) = @_;
 590         more($self, '100 help text follows');
 591         '.'
 592 }
 593
 594 sub get_range ($$) {
 595         my ($self, $range) = @_;
 596         my $ng = $self->{ng} or return '412 no news group has been selected';
 597         defined $range or return '420 No article(s) selected';
 598         my ($beg, $end);
 599         my ($min, $max) = $ng->mm->minmax;
 600         if ($range =~ /\A([0-9]+)\z/) {
 601                 $beg = $end = $1;
 602         } elsif ($range =~ /\A([0-9]+)-\z/) {
 603                 ($beg, $end) = ($1, $max);
 604         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 605                 ($beg, $end) = ($1, $2);
 606         } else {
 607                 return r501;
 608         }
 609         $beg = $min if ($beg < $min);
 610         $end = $max if ($end > $max);
 611         return '420 No article(s) selected' if ($beg > $end);
 612         [ \$beg, $end ];
 613 }
 614
 615 sub long_step {
 616         my ($self) = @_;
 617         # wbuf is unset or empty, here; {long} may add to it
 618         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
 619         my $more = eval { $cb->($self, @args) };
 620         if ($@ || !$self->{sock}) { # something bad happened...
 621                 delete $self->{long_cb};
 622                 my $elapsed = now() - $t0;
 623                 if ($@) {
 624                         err($self,
 625                             "%s during long response[$fd] - %0.6f",
 626                             $@, $elapsed);
 627                 }
 628                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 629                 $self->close;
 630         } elsif ($more) { # $self->{wbuf}:
 631                 $self->update_idle_time;
 632
 633                 # COMPRESS users all share the same DEFLATE context.
 634                 # Flush it here to ensure clients don't see
 635                 # each other's data
 636                 $self->zflush;
 637
 638                 # no recursion, schedule another call ASAP, but only after
 639                 # all pending writes are done.  autovivify wbuf:
 640                 my $new_size = push(@{$self->{wbuf}}, \&long_step);
 641
 642                 # wbuf may be populated by $cb, no need to rearm if so:
 643                 $self->requeue if $new_size == 1;
 644         } else { # all done!
 645                 delete $self->{long_cb};
 646                 res($self, '.');
 647                 my $elapsed = now() - $t0;
 648                 my $fd = fileno($self->{sock});
 649                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 650                 my $wbuf = $self->{wbuf}; # do NOT autovivify
 651                 $self->requeue unless $wbuf && @$wbuf;
 652         }
 653 }
 654
 655 sub long_response ($$;@) {
 656         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 657
 658         my $sock = $self->{sock} or return;
 659         # make sure we disable reading during a long response,
 660         # clients should not be sending us stuff and making us do more
 661         # work while we are stream a response to them
 662         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
 663         long_step($self); # kick off!
 664         undef;
 665 }
 666
 667 sub hdr_msgid_range_i {
 668         my ($self, $beg, $end) = @_;
 669         my $r = $self->{ng}->mm->msg_range($beg, $end);
 670         @$r or return;
 671         more($self, join("\r\n", map { "$_->[0] <$_->[1]>" } @$r));
 672         1;
 673 }
 674
 675 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 676         my ($self, $xhdr, $range) = @_;
 677
 678         if (defined $range && $range =~ $ONE_MSGID) {
 679                 my ($ng, $n) = mid_lookup($self, $1);
 680                 return r430 unless $n;
 681                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 682         } else { # numeric range
 683                 $range = $self->{article} unless defined $range;
 684                 my $r = get_range($self, $range);
 685                 return $r unless ref $r;
 686                 more($self, $xhdr ? r221 : r225);
 687                 long_response($self, \&hdr_msgid_range_i, @$r);
 688         }
 689 }
 690
 691 sub mid_lookup ($$) {
 692         my ($self, $mid) = @_;
 693         my $self_ng = $self->{ng};
 694         if ($self_ng) {
 695                 my $n = $self_ng->mm->num_for($mid);
 696                 return ($self_ng, $n) if defined $n;
 697         }
 698         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 699                 next if defined $self_ng && $ng eq $self_ng;
 700                 my $n = $ng->mm->num_for($mid);
 701                 return ($ng, $n) if defined $n;
 702         }
 703         (undef, undef);
 704 }
 705
 706 sub xref_range_i {
 707         my ($self, $beg, $end) = @_;
 708         my $ng = $self->{ng};
 709         my $r = $ng->mm->msg_range($beg, $end);
 710         @$r or return;
 711         more($self, join("\r\n", map {
 712                 my $num = $_->[0];
 713                 "$num ".xref($self, $ng, $num, $_->[1]);
 714         } @$r));
 715         1;
 716 }
 717
 718 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 719         my ($self, $xhdr, $range) = @_;
 720
 721         if (defined $range && $range =~ $ONE_MSGID) {
 722                 my $mid = $1;
 723                 my ($ng, $n) = mid_lookup($self, $mid);
 724                 return r430 unless $n;
 725                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 726                                 xref($self, $ng, $n, $mid));
 727         } else { # numeric range
 728                 $range = $self->{article} unless defined $range;
 729                 my $r = get_range($self, $range);
 730                 return $r unless ref $r;
 731                 more($self, $xhdr ? r221 : r225);
 732                 long_response($self, \&xref_range_i, @$r);
 733         }
 734 }
 735
 736 sub over_header_for {
 737         my ($over, $num, $field) = @_;
 738         my $smsg = $over->get_art($num) or return;
 739         return PublicInbox::Smsg::date($smsg) if $field eq 'date';
 740         $smsg->{$field};
 741 }
 742
 743 sub smsg_range_i {
 744         my ($self, $beg, $end, $field) = @_;
 745         my $over = $self->{ng}->over;
 746         my $msgs = $over->query_xover($$beg, $end);
 747         scalar(@$msgs) or return;
 748         my $tmp = '';
 749
 750         # ->{$field} is faster than ->$field invocations, so favor that.
 751         if ($field eq 'date') {
 752                 for my $s (@$msgs) {
 753                         $tmp .= "$s->{num} ".PublicInbox::Smsg::date($s)."\r\n"
 754                 }
 755         } else {
 756                 for my $s (@$msgs) {
 757                         $tmp .= "$s->{num} $s->{$field}\r\n";
 758                 }
 759         }
 760         utf8::encode($tmp);
 761         $self->msg_more($tmp);
 762         $$beg = $msgs->[-1]->{num} + 1;
 763 }
 764
 765 sub hdr_smsg ($$$$) {
 766         my ($self, $xhdr, $field, $range) = @_;
 767         if (defined $range && $range =~ $ONE_MSGID) {
 768                 my ($ng, $n) = mid_lookup($self, $1);
 769                 return r430 unless defined $n;
 770                 my $v = over_header_for($ng->over, $n, $field);
 771                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 772         } else { # numeric range
 773                 $range = $self->{article} unless defined $range;
 774                 my $r = get_range($self, $range);
 775                 return $r unless ref $r;
 776                 more($self, $xhdr ? r221 : r225);
 777                 long_response($self, \&smsg_range_i, @$r, $field);
 778         }
 779 }
 780
 781 sub do_hdr ($$$;$) {
 782         my ($self, $xhdr, $header, $range) = @_;
 783         my $sub = lc $header;
 784         if ($sub eq 'message-id') {
 785                 hdr_message_id($self, $xhdr, $range);
 786         } elsif ($sub eq 'xref') {
 787                 hdr_xref($self, $xhdr, $range);
 788         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 789                                 bytes|lines)\z/x) {
 790                 hdr_smsg($self, $xhdr, $sub, $range);
 791         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 792                 hdr_smsg($self, $xhdr, $1, $range);
 793         } else {
 794                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 795         }
 796 }
 797
 798 # RFC 3977
 799 sub cmd_hdr ($$;$) {
 800         my ($self, $header, $range) = @_;
 801         do_hdr($self, 0, $header, $range);
 802 }
 803
 804 # RFC 2980
 805 sub cmd_xhdr ($$;$) {
 806         my ($self, $header, $range) = @_;
 807         do_hdr($self, 1, $header, $range);
 808 }
 809
 810 sub hdr_mid_prefix ($$$$$) {
 811         my ($self, $xhdr, $ng, $n, $mid) = @_;
 812         return $mid if $xhdr;
 813
 814         # HDR for RFC 3977 users
 815         if (my $self_ng = $self->{ng}) {
 816                 ($self_ng eq $ng) ? $n : '0';
 817         } else {
 818                 '0';
 819         }
 820 }
 821
 822 sub hdr_mid_response ($$$$$$) {
 823         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 824         my $res = '';
 825         if ($xhdr) {
 826                 $res .= r221 . "\r\n";
 827                 $res .= "$mid $v\r\n";
 828         } else {
 829                 $res .= r225 . "\r\n";
 830                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 831                 $res .= "$pfx $v\r\n";
 832         }
 833         res($self, $res .= '.');
 834         undef;
 835 }
 836
 837 sub xrover_i {
 838         my ($self, $beg, $end) = @_;
 839         my $h = over_header_for($self->{ng}->over, $$beg, 'references');
 840         more($self, "$$beg $h") if defined($h);
 841         $$beg++ < $end;
 842 }
 843
 844 sub cmd_xrover ($;$) {
 845         my ($self, $range) = @_;
 846         my $ng = $self->{ng} or return '412 no newsgroup selected';
 847         (defined $range && $range =~ /[<>]/) and
 848                 return '420 No article(s) selected'; # no message IDs
 849
 850         $range = $self->{article} unless defined $range;
 851         my $r = get_range($self, $range);
 852         return $r unless ref $r;
 853         more($self, '224 Overview information follows');
 854         long_response($self, \&xrover_i, @$r);
 855 }
 856
 857 sub over_line ($$$$) {
 858         my ($self, $ng, $num, $smsg) = @_;
 859         # n.b. field access and procedural calls can be
 860         # 10%-15% faster than OO method calls:
 861         my $s = join("\t", $num,
 862                 $smsg->{subject},
 863                 $smsg->{from},
 864                 PublicInbox::Smsg::date($smsg),
 865                 "<$smsg->{mid}>",
 866                 $smsg->{references},
 867                 $smsg->{bytes},
 868                 $smsg->{lines},
 869                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 870         utf8::encode($s);
 871         $s
 872 }
 873
 874 sub cmd_over ($;$) {
 875         my ($self, $range) = @_;
 876         if ($range && $range =~ $ONE_MSGID) {
 877                 my ($ng, $n) = mid_lookup($self, $1);
 878                 defined $n or return r430;
 879                 my $smsg = $ng->over->get_art($n) or return r430;
 880                 more($self, '224 Overview information follows (multi-line)');
 881
 882                 # Only set article number column if it's the current group
 883                 my $self_ng = $self->{ng};
 884                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 885                 more($self, over_line($self, $ng, $n, $smsg));
 886                 '.';
 887         } else {
 888                 cmd_xover($self, $range);
 889         }
 890 }
 891
 892 sub xover_i {
 893         my ($self, $beg, $end) = @_;
 894         my $ng = $self->{ng};
 895         my $msgs = $ng->over->query_xover($$beg, $end);
 896         my $nr = scalar @$msgs or return;
 897
 898         # OVERVIEW.FMT
 899         more($self, join("\r\n", map {
 900                 over_line($self, $ng, $_->{num}, $_);
 901                 } @$msgs));
 902         $$beg = $msgs->[-1]->{num} + 1;
 903 }
 904
 905 sub cmd_xover ($;$) {
 906         my ($self, $range) = @_;
 907         $range = $self->{article} unless defined $range;
 908         my $r = get_range($self, $range);
 909         return $r unless ref $r;
 910         my ($beg, $end) = @$r;
 911         more($self, "224 Overview information follows for $$beg to $end");
 912         long_response($self, \&xover_i, @$r);
 913 }
 914
 915 sub compressed { undef }
 916
 917 sub cmd_starttls ($) {
 918         my ($self) = @_;
 919         my $sock = $self->{sock} or return;
 920         # RFC 4642 2.2.1
 921         return r502 if ($sock->can('accept_SSL') || $self->compressed);
 922         my $opt = $self->{nntpd}->{accept_tls} or
 923                 return '580 can not initiate TLS negotiation';
 924         res($self, '382 Continue with TLS negotiation');
 925         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 926         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 927         undef;
 928 }
 929
 930 # RFC 8054
 931 sub cmd_compress ($$) {
 932         my ($self, $alg) = @_;
 933         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 934         return r502 if $self->compressed;
 935         PublicInbox::NNTPdeflate->enable($self);
 936         $self->requeue;
 937         undef
 938 }
 939
 940 sub zflush {} # overridden by NNTPdeflate
 941
 942 sub cmd_xpath ($$) {
 943         my ($self, $mid) = @_;
 944         return r501 unless $mid =~ $ONE_MSGID;
 945         $mid = $1;
 946         my @paths;
 947         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 948                 my $n = $ng->mm->num_for($mid);
 949                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 950         }
 951         return '430 no such article on server' unless @paths;
 952         '223 '.join(' ', @paths);
 953 }
 954
 955 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 956
 957 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 958
 959 sub do_write ($$) {
 960         my $self = $_[0];
 961         my $done = $self->write(\($_[1]));
 962         return 0 unless $self->{sock};
 963
 964         $done;
 965 }
 966
 967 sub err ($$;@) {
 968         my ($self, $fmt, @args) = @_;
 969         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 970 }
 971
 972 sub out ($$;@) {
 973         my ($self, $fmt, @args) = @_;
 974         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 975 }
 976
 977 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 978 sub event_step {
 979         my ($self) = @_;
 980
 981         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
 982
 983         $self->update_idle_time;
 984         # only read more requests if we've drained the write buffer,
 985         # otherwise we can be buffering infinitely w/o backpressure
 986
 987         my $rbuf = $self->{rbuf} // \(my $x = '');
 988         my $line = index($$rbuf, "\n");
 989         while ($line < 0) {
 990                 return $self->close if length($$rbuf) >= LINE_MAX;
 991                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
 992                 $line = index($$rbuf, "\n");
 993         }
 994         $line = substr($$rbuf, 0, $line + 1, '');
 995         $line =~ s/\r?\n\z//s;
 996         return $self->close if $line =~ /[[:cntrl:]]/s;
 997
 998         my $t0 = now();
 999         my $fd = fileno($self->{sock});
1000         my $r = eval { process_line($self, $line) };
1001         my $pending = $self->{wbuf} ? ' pending' : '';
1002         out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
1003         return $self->close if $r < 0;
1004         $self->rbuf_idle($rbuf);
1005         $self->update_idle_time;
1006
1007         # maybe there's more pipelined data, or we'll have
1008         # to register it for socket-readiness notifications
1009         $self->requeue unless $pending;
1010 }
1011
1012 # for graceful shutdown in PublicInbox::Daemon:
1013 sub busy {
1014         my ($self, $now) = @_;
1015         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1016 }
1017
1018 1;