lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 PublicInbox::DS->import(qw(now msg_more));
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26 };
  27 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  28
  29 my @OVERVIEW = qw(Subject From Date Message-ID References Xref);
  30 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  31 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  32                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  33
  34 # disable commands with easy DoS potential:
  35 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  36
  37 my $EXPMAP; # fd -> [ idle_time, $self ]
  38 my $expt;
  39 our $EXPTIME = 180; # 3 minutes
  40 my $nextt;
  41
  42 my $nextq = [];
  43 sub next_tick () {
  44         $nextt = undef;
  45         my $q = $nextq;
  46         $nextq = [];
  47         foreach my $nntp (@$q) {
  48                 # for request && response protocols, always finish writing
  49                 # before finishing reading:
  50                 if (my $long_cb = $nntp->{long_res}) {
  51                         $nntp->write($long_cb);
  52                 } else {
  53                         # pipelined request, we bypassed socket-readiness
  54                         # checks to get here:
  55                         event_step($nntp);
  56                 }
  57         }
  58 }
  59
  60 sub update_idle_time ($) {
  61         my ($self) = @_;
  62         my $sock = $self->{sock} or return;
  63         $EXPMAP->{fileno($sock)} = [ now(), $self ];
  64 }
  65
  66 sub expire_old () {
  67         my $now = now();
  68         my $exp = $EXPTIME;
  69         my $old = $now - $exp;
  70         my $nr = 0;
  71         my %new;
  72         while (my ($fd, $v) = each %$EXPMAP) {
  73                 my ($idle_time, $nntp) = @$v;
  74                 if ($idle_time < $old) {
  75                         $nntp->close; # idempotent
  76                 } else {
  77                         ++$nr;
  78                         $new{$fd} = $v;
  79                 }
  80         }
  81         $EXPMAP = \%new;
  82         if ($nr) {
  83                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  84         } else {
  85                 $expt = undef;
  86                 # noop to kick outselves out of the loop ASAP so descriptors
  87                 # really get closed
  88                 PublicInbox::EvCleanup::asap(sub {});
  89         }
  90 }
  91
  92 sub new ($$$) {
  93         my ($class, $sock, $nntpd) = @_;
  94         my $self = fields::new($class);
  95         $self->SUPER::new($sock, EPOLLIN | EPOLLONESHOT);
  96         $self->{nntpd} = $nntpd;
  97         res($self, '201 ' . $nntpd->{servername} . ' ready - post via email');
  98         $self->{rbuf} = '';
  99         update_idle_time($self);
 100         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 101         $self;
 102 }
 103
 104 sub args_ok ($$) {
 105         my ($cb, $argc) = @_;
 106         my $tot = prototype $cb;
 107         my ($nreq, undef) = split(';', $tot);
 108         $nreq = ($nreq =~ tr/$//) - 1;
 109         $tot = ($tot =~ tr/$//) - 1;
 110         ($argc <= $tot && $argc >= $nreq);
 111 }
 112
 113 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 114 sub process_line ($$) {
 115         my ($self, $l) = @_;
 116         my ($req, @args) = split(/[ \t]/, $l);
 117         return 1 unless defined($req); # skip blank line
 118         $req = lc($req);
 119         $req = eval {
 120                 no strict 'refs';
 121                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 122         };
 123         return res($self, '500 command not recognized') unless $req;
 124         return res($self, r501) unless args_ok($req, scalar @args);
 125
 126         my $res = eval { $req->($self, @args) };
 127         my $err = $@;
 128         if ($err && $self->{sock}) {
 129                 local $/ = "\n";
 130                 chomp($l);
 131                 err($self, 'error from: %s (%s)', $l, $err);
 132                 $res = '503 program fault - command not performed';
 133         }
 134         return 0 unless defined $res;
 135         res($self, $res);
 136 }
 137
 138 sub cmd_mode ($$) {
 139         my ($self, $arg) = @_;
 140         $arg = uc $arg;
 141         return r501 unless $arg eq 'READER';
 142         '201 Posting prohibited';
 143 }
 144
 145 sub cmd_slave ($) { '202 slave status noted' }
 146
 147 sub cmd_xgtitle ($;$) {
 148         my ($self, $wildmat) = @_;
 149         more($self, '282 list of groups and descriptions follows');
 150         list_newsgroups($self, $wildmat);
 151         '.'
 152 }
 153
 154 sub list_overview_fmt ($) {
 155         my ($self) = @_;
 156         msg_more($self, $OVERVIEW_FMT);
 157 }
 158
 159 sub list_headers ($;$) {
 160         my ($self) = @_;
 161         msg_more($self, $LIST_HEADERS);
 162 }
 163
 164 sub list_active ($;$) {
 165         my ($self, $wildmat) = @_;
 166         wildmat2re($wildmat);
 167         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 168                 $ng->{newsgroup} =~ $wildmat or next;
 169                 group_line($self, $ng);
 170         }
 171 }
 172
 173 sub list_active_times ($;$) {
 174         my ($self, $wildmat) = @_;
 175         wildmat2re($wildmat);
 176         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 177                 $ng->{newsgroup} =~ $wildmat or next;
 178                 my $c = eval { $ng->mm->created_at } || time;
 179                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 180         }
 181 }
 182
 183 sub list_newsgroups ($;$) {
 184         my ($self, $wildmat) = @_;
 185         wildmat2re($wildmat);
 186         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 187                 $ng->{newsgroup} =~ $wildmat or next;
 188                 my $d = $ng->description;
 189                 more($self, "$ng->{newsgroup} $d");
 190         }
 191 }
 192
 193 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 194 sub cmd_list ($;$$) {
 195         my ($self, @args) = @_;
 196         if (scalar @args) {
 197                 my $arg = shift @args;
 198                 $arg =~ tr/A-Z./a-z_/;
 199                 $arg = "list_$arg";
 200                 return r501 if $DISABLED{$arg};
 201
 202                 $arg = eval {
 203                         no strict 'refs';
 204                         *{$arg}{CODE};
 205                 };
 206                 return r501 unless $arg && args_ok($arg, scalar @args);
 207                 more($self, '215 information follows');
 208                 $arg->($self, @args);
 209         } else {
 210                 more($self, '215 list of newsgroups follows');
 211                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 212                         group_line($self, $ng);
 213                 }
 214         }
 215         '.'
 216 }
 217
 218 sub cmd_listgroup ($;$) {
 219         my ($self, $group) = @_;
 220         if (defined $group) {
 221                 my $res = cmd_group($self, $group);
 222                 return $res if ($res !~ /\A211 /);
 223                 more($self, $res);
 224         }
 225
 226         $self->{ng} or return '412 no newsgroup selected';
 227         my $n = 0;
 228         long_response($self, sub {
 229                 my $ary = $self->{ng}->mm->ids_after(\$n);
 230                 scalar @$ary or return;
 231                 more($self, join("\r\n", @$ary));
 232                 1;
 233         });
 234 }
 235
 236 sub parse_time ($$;$) {
 237         my ($date, $time, $gmt) = @_;
 238         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 239         if (defined $gmt) {
 240                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 241                 $gmt = 1;
 242         }
 243         my @now = $gmt ? gmtime : localtime;
 244         my ($YYYY, $MM, $DD);
 245         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 246                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 247         } else { # legacy clients send YYMMDD
 248                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 249                 my $cur_year = $now[5] + 1900;
 250                 if ($YYYY > $cur_year) {
 251                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 252                 }
 253         }
 254         if ($gmt) {
 255                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 256         } else {
 257                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 258         }
 259 }
 260
 261 sub group_line ($$) {
 262         my ($self, $ng) = @_;
 263         my ($min, $max) = $ng->mm->minmax;
 264         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 265 }
 266
 267 sub cmd_newgroups ($$$;$$) {
 268         my ($self, $date, $time, $gmt, $dists) = @_;
 269         my $ts = eval { parse_time($date, $time, $gmt) };
 270         return r501 if $@;
 271
 272         # TODO dists
 273         more($self, '231 list of new newsgroups follows');
 274         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 275                 my $c = eval { $ng->mm->created_at } || 0;
 276                 next unless $c > $ts;
 277                 group_line($self, $ng);
 278         }
 279         '.'
 280 }
 281
 282 sub wildmat2re (;$) {
 283         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 284         my %keep;
 285         my $salt = rand;
 286         my $tmp = $_[0];
 287
 288         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 289                 my $orig = $1;
 290                 my $key = sha1_hex($orig . $salt);
 291                 $orig =~ s/([^\w\-])+/\Q$1/g;
 292                 $keep{$key} = $orig;
 293                 $key
 294                 #gex;
 295         my %map = ('*' => '.*', '?' => '.' );
 296         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 297         if (scalar %keep) {
 298                 $tmp =~ s#([a-f0-9]{40})#
 299                         my $orig = $keep{$1};
 300                         defined $orig ? $orig : $1;
 301                         #ge;
 302         }
 303         $_[0] = qr/\A$tmp\z/;
 304 }
 305
 306 sub ngpat2re (;$) {
 307         return $_[0] = qr/\A\z/ unless defined $_[0];
 308         my %map = ('*' => '.*', ',' => '|');
 309         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 310         $_[0] = qr/\A(?:$_[0])\z/;
 311 }
 312
 313 sub cmd_newnews ($$$$;$$) {
 314         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 315         my $ts = eval { parse_time($date, $time, $gmt) };
 316         return r501 if $@;
 317         more($self, '230 list of new articles by message-id follows');
 318         my ($keep, $skip) = split('!', $newsgroups, 2);
 319         ngpat2re($keep);
 320         ngpat2re($skip);
 321         my @over;
 322         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 323                 $ng->{newsgroup} =~ $keep or next;
 324                 $ng->{newsgroup} =~ $skip and next;
 325                 my $over = $ng->over or next;
 326                 push @over, $over;
 327         };
 328         return '.' unless @over;
 329
 330         my $prev = 0;
 331         long_response($self, sub {
 332                 my $over = $over[0];
 333                 my $msgs = $over->query_ts($ts, $prev);
 334                 if (scalar @$msgs) {
 335                         more($self, '<' .
 336                                 join(">\r\n<", map { $_->mid } @$msgs ).
 337                                 '>');
 338                         $prev = $msgs->[-1]->{num};
 339                 } else {
 340                         shift @over;
 341                         if (@over) { # continue onto next newsgroup
 342                                 $prev = 0;
 343                                 return 1;
 344                         } else { # break out of the long response.
 345                                 return;
 346                         }
 347                 }
 348         });
 349 }
 350
 351 sub cmd_group ($$) {
 352         my ($self, $group) = @_;
 353         my $no_such = '411 no such news group';
 354         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 355
 356         $self->{ng} = $ng;
 357         my ($min, $max) = $ng->mm->minmax;
 358         $min ||= 0;
 359         $max ||= 0;
 360         $self->{article} = $min;
 361         my $est_size = $max - $min;
 362         "211 $est_size $min $max $group";
 363 }
 364
 365 sub article_adj ($$) {
 366         my ($self, $off) = @_;
 367         my $ng = $self->{ng} or return '412 no newsgroup selected';
 368
 369         my $n = $self->{article};
 370         defined $n or return '420 no current article has been selected';
 371
 372         $n += $off;
 373         my $mid = $ng->mm->mid_for($n);
 374         unless ($mid) {
 375                 $n = $off > 0 ? 'next' : 'previous';
 376                 return "421 no $n article in this group";
 377         }
 378         $self->{article} = $n;
 379         "223 $n <$mid> article retrieved - request text separately";
 380 }
 381
 382 sub cmd_next ($) { article_adj($_[0], 1) }
 383 sub cmd_last ($) { article_adj($_[0], -1) }
 384
 385 # We want to encourage using email and CC-ing everybody involved to avoid
 386 # the single-point-of-failure a single server provides.
 387 sub cmd_post ($) {
 388         my ($self) = @_;
 389         my $ng = $self->{ng};
 390         $ng ? "440 mailto:$ng->{-primary_address} to post"
 391                 : '440 posting not allowed'
 392 }
 393
 394 sub cmd_quit ($) {
 395         my ($self) = @_;
 396         res($self, '205 closing connection - goodbye!');
 397         $self->close;
 398         undef;
 399 }
 400
 401 sub header_append ($$$) {
 402         my ($hdr, $k, $v) = @_;
 403         my @v = $hdr->header($k);
 404         foreach (@v) {
 405                 return if $v eq $_;
 406         }
 407         $hdr->header_set($k, @v, $v);
 408 }
 409
 410 sub xref ($$$$) {
 411         my ($self, $ng, $n, $mid) = @_;
 412         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 413
 414         # num_for is pretty cheap and sometimes we'll lookup the existence
 415         # of an article without getting even the OVER info.  In other words,
 416         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 417         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 418         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 419                 next if $ng eq $other;
 420                 my $num = eval { $other->mm->num_for($mid) } or next;
 421                 $ret .= " $other->{newsgroup}:$num";
 422         }
 423         $ret;
 424 }
 425
 426 sub set_nntp_headers ($$$$$) {
 427         my ($self, $hdr, $ng, $n, $mid) = @_;
 428
 429         # why? leafnode requires a Path: header for some inexplicable
 430         # reason.  We'll fake the shortest one possible.
 431         $hdr->header_set('Path', 'y');
 432
 433         # leafnode (and maybe other NNTP clients) have trouble dealing
 434         # with v2 messages which have multiple Message-IDs (either due
 435         # to our own content-based dedupe or buggy git-send-email versions).
 436         my @mids = $hdr->header('Message-ID');
 437         if (scalar(@mids) > 1) {
 438                 my $mid0 = "<$mid>";
 439                 $hdr->header_set('Message-ID', $mid0);
 440                 my @alt = $hdr->header('X-Alt-Message-ID');
 441                 my %seen = map { $_ => 1 } (@alt, $mid0);
 442                 foreach my $m (@mids) {
 443                         next if $seen{$m}++;
 444                         push @alt, $m;
 445                 }
 446                 $hdr->header_set('X-Alt-Message-ID', @alt);
 447         }
 448
 449         # clobber some
 450         my $xref = xref($self, $ng, $n, $mid);
 451         $hdr->header_set('Xref', $xref);
 452         $xref =~ s/:[0-9]+//g;
 453         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 454         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 455         if (my $url = $ng->base_url) {
 456                 $mid = mid_escape($mid);
 457                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 458                 header_append($hdr, 'List-Archive', "<$url>");
 459         }
 460 }
 461
 462 sub art_lookup ($$$) {
 463         my ($self, $art, $set_headers) = @_;
 464         my $ng = $self->{ng};
 465         my ($n, $mid);
 466         my $err;
 467         if (defined $art) {
 468                 if ($art =~ /\A[0-9]+\z/) {
 469                         $err = '423 no such article number in this group';
 470                         $n = int($art);
 471                         goto find_mid;
 472                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 473                         $mid = $1;
 474                         $err = r430;
 475                         $n = $ng->mm->num_for($mid) if $ng;
 476                         goto found if defined $n;
 477                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 478                                 $n = $g->mm->num_for($mid);
 479                                 if (defined $n) {
 480                                         $ng = $g;
 481                                         goto found;
 482                                 }
 483                         }
 484                         return $err;
 485                 } else {
 486                         return r501;
 487                 }
 488         } else {
 489                 $err = '420 no current article has been selected';
 490                 $n = $self->{article};
 491                 defined $n or return $err;
 492 find_mid:
 493                 $ng or return '412 no newsgroup has been selected';
 494                 $mid = $ng->mm->mid_for($n);
 495                 defined $mid or return $err;
 496         }
 497 found:
 498         my $smsg = $ng->over->get_art($n) or return $err;
 499         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 500         my $s = Email::Simple->new($msg);
 501         if ($set_headers) {
 502                 set_nntp_headers($self, $s->header_obj, $ng, $n, $mid);
 503
 504                 # must be last
 505                 $s->body_set('') if ($set_headers == 2);
 506         }
 507         [ $n, $mid, $s, $smsg->bytes, $smsg->lines, $ng ];
 508 }
 509
 510 sub simple_body_write ($$) {
 511         my ($self, $s) = @_;
 512         my $body = $s->body;
 513         $s->body_set('');
 514         $body =~ s/^\./../smg;
 515         $body =~ s/(?<!\r)\n/\r\n/sg;
 516         msg_more($self, $body);
 517         msg_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 518         '.'
 519 }
 520
 521 sub set_art {
 522         my ($self, $art) = @_;
 523         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 524 }
 525
 526 sub _header ($) {
 527         my $hdr = $_[0]->header_obj->as_string;
 528         utf8::encode($hdr);
 529         $hdr =~ s/(?<!\r)\n/\r\n/sg;
 530
 531         # for leafnode compatibility, we need to ensure Message-ID headers
 532         # are only a single line.  We can't subclass Email::Simple::Header
 533         # and override _default_fold_at in here, either; since that won't
 534         # affect messages already in the archive.
 535         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 536
 537         $hdr
 538 }
 539
 540 sub cmd_article ($;$) {
 541         my ($self, $art) = @_;
 542         my $r = art_lookup($self, $art, 1);
 543         return $r unless ref $r;
 544         my ($n, $mid, $s) = @$r;
 545         set_art($self, $art);
 546         more($self, "220 $n <$mid> article retrieved - head and body follow");
 547         msg_more($self, _header($s));
 548         msg_more($self, "\r\n");
 549         simple_body_write($self, $s);
 550 }
 551
 552 sub cmd_head ($;$) {
 553         my ($self, $art) = @_;
 554         my $r = art_lookup($self, $art, 2);
 555         return $r unless ref $r;
 556         my ($n, $mid, $s) = @$r;
 557         set_art($self, $art);
 558         more($self, "221 $n <$mid> article retrieved - head follows");
 559         msg_more($self, _header($s));
 560         '.'
 561 }
 562
 563 sub cmd_body ($;$) {
 564         my ($self, $art) = @_;
 565         my $r = art_lookup($self, $art, 0);
 566         return $r unless ref $r;
 567         my ($n, $mid, $s) = @$r;
 568         set_art($self, $art);
 569         more($self, "222 $n <$mid> article retrieved - body follows");
 570         simple_body_write($self, $s);
 571 }
 572
 573 sub cmd_stat ($;$) {
 574         my ($self, $art) = @_;
 575         my $r = art_lookup($self, $art, 0);
 576         return $r unless ref $r;
 577         my ($n, $mid, undef) = @$r;
 578         set_art($self, $art);
 579         "223 $n <$mid> article retrieved - request text separately";
 580 }
 581
 582 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 583
 584 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 585
 586 sub cmd_help ($) {
 587         my ($self) = @_;
 588         more($self, '100 help text follows');
 589         '.'
 590 }
 591
 592 sub get_range ($$) {
 593         my ($self, $range) = @_;
 594         my $ng = $self->{ng} or return '412 no news group has been selected';
 595         defined $range or return '420 No article(s) selected';
 596         my ($beg, $end);
 597         my ($min, $max) = $ng->mm->minmax;
 598         if ($range =~ /\A([0-9]+)\z/) {
 599                 $beg = $end = $1;
 600         } elsif ($range =~ /\A([0-9]+)-\z/) {
 601                 ($beg, $end) = ($1, $max);
 602         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 603                 ($beg, $end) = ($1, $2);
 604         } else {
 605                 return r501;
 606         }
 607         $beg = $min if ($beg < $min);
 608         $end = $max if ($end > $max);
 609         return '420 No article(s) selected' if ($beg > $end);
 610         [ $beg, $end ];
 611 }
 612
 613 sub long_response ($$) {
 614         my ($self, $cb) = @_;
 615         die "BUG: nested long response" if $self->{long_res};
 616
 617         my $fd = fileno($self->{sock});
 618         defined $fd or return;
 619         # make sure we disable reading during a long response,
 620         # clients should not be sending us stuff and making us do more
 621         # work while we are stream a response to them
 622         my $t0 = now();
 623         $self->{long_res} = sub {
 624                 my $more = eval { $cb->() };
 625                 if ($@ || !$self->{sock}) { # something bad happened...
 626                         $self->{long_res} = undef;
 627
 628                         if ($@) {
 629                                 err($self,
 630                                     "%s during long response[$fd] - %0.6f",
 631                                     $@, now() - $t0);
 632                         }
 633                         if ($self->{sock}) {
 634                                 update_idle_time($self);
 635                                 check_read($self);
 636                         } else {
 637                                 out($self, " deferred[$fd] aborted - %0.6f",
 638                                            now() - $t0);
 639                         }
 640                 } elsif ($more) { # $self->{wbuf}:
 641                         # no recursion, schedule another call ASAP
 642                         # but only after all pending writes are done
 643                         update_idle_time($self);
 644
 645                         push @$nextq, $self;
 646                         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 647                 } else { # all done!
 648                         $self->{long_res} = undef;
 649                         check_read($self);
 650                         res($self, '.');
 651                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 652                 }
 653         };
 654         $self->{long_res}->(); # kick off!
 655         undef;
 656 }
 657
 658 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 659         my ($self, $xhdr, $range) = @_;
 660
 661         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 662                 my ($ng, $n) = mid_lookup($self, $1);
 663                 return r430 unless $n;
 664                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 665         } else { # numeric range
 666                 $range = $self->{article} unless defined $range;
 667                 my $r = get_range($self, $range);
 668                 return $r unless ref $r;
 669                 my $mm = $self->{ng}->mm;
 670                 my ($beg, $end) = @$r;
 671                 more($self, $xhdr ? r221 : r225);
 672                 long_response($self, sub {
 673                         my $r = $mm->msg_range(\$beg, $end);
 674                         @$r or return;
 675                         more($self, join("\r\n", map {
 676                                 "$_->[0] <$_->[1]>"
 677                         } @$r));
 678                         1;
 679                 });
 680         }
 681 }
 682
 683 sub mid_lookup ($$) {
 684         my ($self, $mid) = @_;
 685         my $self_ng = $self->{ng};
 686         if ($self_ng) {
 687                 my $n = $self_ng->mm->num_for($mid);
 688                 return ($self_ng, $n) if defined $n;
 689         }
 690         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 691                 next if defined $self_ng && $ng eq $self_ng;
 692                 my $n = $ng->mm->num_for($mid);
 693                 return ($ng, $n) if defined $n;
 694         }
 695         (undef, undef);
 696 }
 697
 698 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 699         my ($self, $xhdr, $range) = @_;
 700
 701         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 702                 my $mid = $1;
 703                 my ($ng, $n) = mid_lookup($self, $mid);
 704                 return r430 unless $n;
 705                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 706                                 xref($self, $ng, $n, $mid));
 707         } else { # numeric range
 708                 $range = $self->{article} unless defined $range;
 709                 my $r = get_range($self, $range);
 710                 return $r unless ref $r;
 711                 my $ng = $self->{ng};
 712                 my $mm = $ng->mm;
 713                 my ($beg, $end) = @$r;
 714                 more($self, $xhdr ? r221 : r225);
 715                 long_response($self, sub {
 716                         my $r = $mm->msg_range(\$beg, $end);
 717                         @$r or return;
 718                         more($self, join("\r\n", map {
 719                                 my $num = $_->[0];
 720                                 "$num ".xref($self, $ng, $num, $_->[1]);
 721                         } @$r));
 722                         1;
 723                 });
 724         }
 725 }
 726
 727 sub over_header_for {
 728         my ($over, $num, $field) = @_;
 729         my $smsg = $over->get_art($num) or return;
 730         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 731         $smsg->{$field};
 732 }
 733
 734 sub hdr_searchmsg ($$$$) {
 735         my ($self, $xhdr, $field, $range) = @_;
 736         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 737                 my ($ng, $n) = mid_lookup($self, $1);
 738                 return r430 unless defined $n;
 739                 my $v = over_header_for($ng->over, $n, $field);
 740                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 741         } else { # numeric range
 742                 $range = $self->{article} unless defined $range;
 743                 my $over = $self->{ng}->over;
 744                 my $mm = $self->{ng}->mm;
 745                 my $r = get_range($self, $range);
 746                 return $r unless ref $r;
 747                 my ($beg, $end) = @$r;
 748                 more($self, $xhdr ? r221 : r225);
 749                 my $cur = $beg;
 750                 long_response($self, sub {
 751                         my $msgs = $over->query_xover($cur, $end);
 752                         my $nr = scalar @$msgs or return;
 753                         my $tmp = '';
 754                         foreach my $s (@$msgs) {
 755                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 756                         }
 757                         utf8::encode($tmp);
 758                         msg_more($self, $tmp);
 759                         $cur = $msgs->[-1]->{num} + 1;
 760                 });
 761         }
 762 }
 763
 764 sub do_hdr ($$$;$) {
 765         my ($self, $xhdr, $header, $range) = @_;
 766         my $sub = lc $header;
 767         if ($sub eq 'message-id') {
 768                 hdr_message_id($self, $xhdr, $range);
 769         } elsif ($sub eq 'xref') {
 770                 hdr_xref($self, $xhdr, $range);
 771         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 772                                 bytes|lines)\z/x) {
 773                 hdr_searchmsg($self, $xhdr, $sub, $range);
 774         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 775                 hdr_searchmsg($self, $xhdr, $1, $range);
 776         } else {
 777                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 778         }
 779 }
 780
 781 # RFC 3977
 782 sub cmd_hdr ($$;$) {
 783         my ($self, $header, $range) = @_;
 784         do_hdr($self, 0, $header, $range);
 785 }
 786
 787 # RFC 2980
 788 sub cmd_xhdr ($$;$) {
 789         my ($self, $header, $range) = @_;
 790         do_hdr($self, 1, $header, $range);
 791 }
 792
 793 sub hdr_mid_prefix ($$$$$) {
 794         my ($self, $xhdr, $ng, $n, $mid) = @_;
 795         return $mid if $xhdr;
 796
 797         # HDR for RFC 3977 users
 798         if (my $self_ng = $self->{ng}) {
 799                 ($self_ng eq $ng) ? $n : '0';
 800         } else {
 801                 '0';
 802         }
 803 }
 804
 805 sub hdr_mid_response ($$$$$$) {
 806         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 807         my $res = '';
 808         if ($xhdr) {
 809                 $res .= r221 . "\r\n";
 810                 $res .= "$mid $v\r\n";
 811         } else {
 812                 $res .= r225 . "\r\n";
 813                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 814                 $res .= "$pfx $v\r\n";
 815         }
 816         res($self, $res .= '.');
 817         undef;
 818 }
 819
 820 sub cmd_xrover ($;$) {
 821         my ($self, $range) = @_;
 822         my $ng = $self->{ng} or return '412 no newsgroup selected';
 823         (defined $range && $range =~ /[<>]/) and
 824                 return '420 No article(s) selected'; # no message IDs
 825
 826         $range = $self->{article} unless defined $range;
 827         my $r = get_range($self, $range);
 828         return $r unless ref $r;
 829         my ($beg, $end) = @$r;
 830         my $mm = $ng->mm;
 831         my $over = $ng->over;
 832         more($self, '224 Overview information follows');
 833
 834         long_response($self, sub {
 835                 my $h = over_header_for($over, $beg, 'references');
 836                 more($self, "$beg $h") if defined($h);
 837                 $beg++ < $end;
 838         });
 839 }
 840
 841 sub over_line ($$$$) {
 842         my ($self, $ng, $num, $smsg) = @_;
 843         # n.b. field access and procedural calls can be
 844         # 10%-15% faster than OO method calls:
 845         my $s = join("\t", $num,
 846                 $smsg->{subject},
 847                 $smsg->{from},
 848                 PublicInbox::SearchMsg::date($smsg),
 849                 "<$smsg->{mid}>",
 850                 $smsg->{references},
 851                 $smsg->{bytes},
 852                 $smsg->{lines},
 853                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 854         utf8::encode($s);
 855         $s
 856 }
 857
 858 sub cmd_over ($;$) {
 859         my ($self, $range) = @_;
 860         if ($range && $range =~ /\A<(.+)>\z/) {
 861                 my ($ng, $n) = mid_lookup($self, $1);
 862                 defined $n or return r430;
 863                 my $smsg = $ng->over->get_art($n) or return r430;
 864                 more($self, '224 Overview information follows (multi-line)');
 865
 866                 # Only set article number column if it's the current group
 867                 my $self_ng = $self->{ng};
 868                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 869                 more($self, over_line($self, $ng, $n, $smsg));
 870                 '.';
 871         } else {
 872                 cmd_xover($self, $range);
 873         }
 874 }
 875
 876 sub cmd_xover ($;$) {
 877         my ($self, $range) = @_;
 878         $range = $self->{article} unless defined $range;
 879         my $r = get_range($self, $range);
 880         return $r unless ref $r;
 881         my ($beg, $end) = @$r;
 882         more($self, "224 Overview information follows for $beg to $end");
 883         my $over = $self->{ng}->over;
 884         my $cur = $beg;
 885         long_response($self, sub {
 886                 my $msgs = $over->query_xover($cur, $end);
 887                 my $nr = scalar @$msgs or return;
 888
 889                 # OVERVIEW.FMT
 890                 more($self, join("\r\n", map {
 891                         over_line($self, $self->{ng}, $_->{num}, $_);
 892                         } @$msgs));
 893                 $cur = $msgs->[-1]->{num} + 1;
 894         });
 895 }
 896
 897 sub cmd_xpath ($$) {
 898         my ($self, $mid) = @_;
 899         return r501 unless $mid =~ /\A<(.+)>\z/;
 900         $mid = $1;
 901         my @paths;
 902         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 903                 my $n = $ng->mm->num_for($mid);
 904                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 905         }
 906         return '430 no such article on server' unless @paths;
 907         '223 '.join(' ', @paths);
 908 }
 909
 910 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 911
 912 sub more ($$) { msg_more($_[0], $_[1] . "\r\n") }
 913
 914 sub do_write ($$) {
 915         my $self = $_[0];
 916         my $done = $self->write(\($_[1]));
 917         return 0 unless $self->{sock};
 918
 919         $done;
 920 }
 921
 922 sub err ($$;@) {
 923         my ($self, $fmt, @args) = @_;
 924         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 925 }
 926
 927 sub out ($$;@) {
 928         my ($self, $fmt, @args) = @_;
 929         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 930 }
 931
 932 sub event_step {
 933         my ($self) = @_;
 934
 935         return unless $self->flush_write && $self->{sock};
 936
 937         update_idle_time($self);
 938         # only read more requests if we've drained the write buffer,
 939         # otherwise we can be buffering infinitely w/o backpressure
 940
 941         use constant LINE_MAX => 512; # RFC 977 section 2.3
 942         my $rbuf = \($self->{rbuf});
 943         my $r;
 944
 945         if (index($$rbuf, "\n") < 0) {
 946                 my $off = length($$rbuf);
 947                 $r = sysread($self->{sock}, $$rbuf, LINE_MAX, $off);
 948                 unless (defined $r) {
 949                         return $self->watch_in1 if $!{EAGAIN};
 950                         return $self->close;
 951                 }
 952                 return $self->close if $r == 0;
 953         }
 954         $r = 1;
 955         while ($r > 0 && $$rbuf =~ s/\A[ \t\r\n]*([^\r\n]*)\r?\n//) {
 956                 my $line = $1;
 957                 return $self->close if $line =~ /[[:cntrl:]]/s;
 958                 my $t0 = now();
 959                 my $fd = fileno($self->{sock});
 960                 $r = eval { process_line($self, $line) };
 961                 my $d = $self->{long_res} ?
 962                         " deferred[$fd]" : '';
 963                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 964         }
 965
 966         return $self->close if $r < 0;
 967         my $len = length($$rbuf);
 968         return $self->close if ($len >= LINE_MAX);
 969         update_idle_time($self);
 970
 971         # maybe there's more pipelined data, or we'll have
 972         # to register it for socket-readiness notifications
 973         check_read($self) unless ($self->{long_res} || $self->{wbuf});
 974 }
 975
 976 sub check_read {
 977         my ($self) = @_;
 978         if (index($self->{rbuf}, "\n") >= 0) {
 979                 # Force another read if there is a pipelined request.
 980                 # We don't know if the socket has anything for us to read,
 981                 # and we must double-check again by the time the timer fires
 982                 # in case we really did dispatch a read event and started
 983                 # another long response.
 984                 push @$nextq, $self;
 985                 $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 986         } else {
 987                 # no pipelined requests available, let the kernel know
 988                 # to wake us up if there's more
 989                 $self->watch_in1; # PublicInbox::DS::watch_in1
 990         }
 991 }
 992
 993 sub not_idle_long ($$) {
 994         my ($self, $now) = @_;
 995         my $sock = $self->{sock} or return;
 996         my $ary = $EXPMAP->{fileno($sock)} or return;
 997         my $exp_at = $ary->[0] + $EXPTIME;
 998         $exp_at > $now;
 999 }
1000
1001 # for graceful shutdown in PublicInbox::Daemon:
1002 sub busy {
1003         my ($self, $now) = @_;
1004         ($self->{rbuf} ne '' || $self->{long_res} ||
1005                 $self->{wbuf} || not_idle_long($self, $now));
1006 }
1007
1008 1;