lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::Git;
  13 use PublicInbox::MID qw(mid2path);
  14 use Email::Simple;
  15 use POSIX qw(strftime);
  16 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  17 use URI::Escape qw(uri_escape_utf8);
  18 use Encode qw(find_encoding);
  19 my $enc_utf8 = find_encoding('UTF-8');
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26         long_response_limit => 0xffffffff,
  27 };
  28
  29 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  30
  31 my @OVERVIEW = qw(Subject From Date Message-ID References);
  32 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  33 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  34                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  35
  36 # disable commands with easy DoS potential:
  37 # LISTGROUP could get pretty bad, too...
  38 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  39
  40 my $EXPMAP; # fd -> [ idle_time, $self ]
  41 my $EXPTIMER;
  42 our $EXPTIME = 180; # 3 minutes
  43 my $WEAKEN = {}; # string(nntpd) -> nntpd
  44 my $WEAKTIMER;
  45
  46 my $next_tick;
  47 my $nextq = [];
  48 sub next_tick () {
  49         $next_tick = undef;
  50         my $q = $nextq;
  51         $nextq = [];
  52         foreach my $nntp (@$q) {
  53                 # for request && response protocols, always finish writing
  54                 # before finishing reading:
  55                 if (my $long_cb = $nntp->{long_res}) {
  56                         $nntp->write($long_cb);
  57                 } elsif (&Danga::Socket::POLLIN & $nntp->{event_watch}) {
  58                         event_read($nntp);
  59                 }
  60         }
  61 }
  62
  63 sub update_idle_time ($) {
  64         my ($self) = @_;
  65         my $tmp = $self->{sock} or return;
  66         $tmp = fileno($tmp);
  67         defined $tmp and $EXPMAP->{$tmp} = [ now(), $self ];
  68 }
  69
  70 # reduce FD pressure by closing some "git cat-file --batch" processes
  71 # and unused FDs for msgmap and Xapian indices
  72 sub weaken_groups () {
  73         $WEAKTIMER = undef;
  74         foreach my $nntpd (values %$WEAKEN) {
  75                 $_->weaken_all foreach (@{$nntpd->{grouplist}});
  76         }
  77         $WEAKEN = {};
  78 }
  79
  80 sub expire_old () {
  81         my $now = now();
  82         my $exp = $EXPTIME;
  83         my $old = $now - $exp;
  84         my $next = $now + $exp;
  85         my $nr = 0;
  86         my %new;
  87         while (my ($fd, $v) = each %$EXPMAP) {
  88                 my ($idle_time, $nntp) = @$v;
  89                 if ($idle_time < $old) {
  90                         $nntp->close; # idempotent
  91                 } else {
  92                         my $nexp = $idle_time + $exp;
  93                         $next = $nexp if ($nexp < $next);
  94                         ++$nr;
  95                         $new{$fd} = $v;
  96                 }
  97         }
  98         $EXPMAP = \%new;
  99         if ($nr) {
 100                 $next -= $now;
 101                 $next = 0 if $next < 0;
 102                 $EXPTIMER = Danga::Socket->AddTimer($next, *expire_old);
 103                 weaken_groups();
 104         } else {
 105                 $EXPTIMER = undef;
 106                 # noop to kick outselves out of the loop ASAP so descriptors
 107                 # really get closed
 108                 Danga::Socket->AddTimer(0, sub {});
 109
 110                 # grace period for reaping resources
 111                 $WEAKTIMER ||= Danga::Socket->AddTimer(30, *weaken_groups);
 112         }
 113 }
 114
 115 sub new ($$$) {
 116         my ($class, $sock, $nntpd) = @_;
 117         my $self = fields::new($class);
 118         $self->SUPER::new($sock);
 119         $self->{nntpd} = $nntpd;
 120         res($self, '201 server ready - post via email');
 121         $self->{rbuf} = '';
 122         $self->watch_read(1);
 123         update_idle_time($self);
 124         $WEAKEN->{"$nntpd"} = $nntpd;
 125         $EXPTIMER ||= Danga::Socket->AddTimer($EXPTIME, *expire_old);
 126         $self;
 127 }
 128
 129 sub args_ok ($$) {
 130         my ($cb, $argc) = @_;
 131         my $tot = prototype $cb;
 132         my ($nreq, undef) = split(';', $tot);
 133         $nreq = ($nreq =~ tr/$//) - 1;
 134         $tot = ($tot =~ tr/$//) - 1;
 135         ($argc <= $tot && $argc >= $nreq);
 136 }
 137
 138 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 139 sub process_line ($$) {
 140         my ($self, $l) = @_;
 141         my ($req, @args) = split(/\s+/, $l);
 142         $req = lc($req);
 143         $req = eval {
 144                 no strict 'refs';
 145                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 146         };
 147         return res($self, '500 command not recognized') unless $req;
 148         return res($self, r501) unless args_ok($req, scalar @args);
 149
 150         my $res = eval { $req->($self, @args) };
 151         my $err = $@;
 152         if ($err && !$self->{closed}) {
 153                 chomp($l);
 154                 err($self, 'error from: %s (%s)', $l, $err);
 155                 $res = '503 program fault - command not performed';
 156         }
 157         return 0 unless defined $res;
 158         res($self, $res);
 159 }
 160
 161 sub cmd_mode ($$) {
 162         my ($self, $arg) = @_;
 163         $arg = uc $arg;
 164         return r501 unless $arg eq 'READER';
 165         '201 Posting prohibited';
 166 }
 167
 168 sub cmd_slave ($) { '202 slave status noted' }
 169
 170 sub cmd_xgtitle ($;$) {
 171         my ($self, $wildmat) = @_;
 172         more($self, '282 list of groups and descriptions follows');
 173         list_newsgroups($self, $wildmat);
 174         '.'
 175 }
 176
 177 sub list_overview_fmt ($) {
 178         my ($self) = @_;
 179         do_more($self, $OVERVIEW_FMT);
 180 }
 181
 182 sub list_headers ($;$) {
 183         my ($self) = @_;
 184         do_more($self, $LIST_HEADERS);
 185 }
 186
 187 sub list_active ($;$) {
 188         my ($self, $wildmat) = @_;
 189         wildmat2re($wildmat);
 190         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 191                 $ng->{newsgroup} =~ $wildmat or next;
 192                 group_line($self, $ng);
 193         }
 194 }
 195
 196 sub list_active_times ($;$) {
 197         my ($self, $wildmat) = @_;
 198         wildmat2re($wildmat);
 199         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 200                 $ng->{newsgroup} =~ $wildmat or next;
 201                 my $c = eval { $ng->mm->created_at } || time;
 202                 more($self, "$ng->{newsgroup} $c $ng->{address}");
 203         }
 204 }
 205
 206 sub list_newsgroups ($;$) {
 207         my ($self, $wildmat) = @_;
 208         wildmat2re($wildmat);
 209         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 210                 $ng->{newsgroup} =~ $wildmat or next;
 211                 my $d = $ng->description;
 212                 more($self, "$ng->{newsgroup} $d");
 213         }
 214 }
 215
 216 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 217 sub cmd_list ($;$$) {
 218         my ($self, @args) = @_;
 219         if (scalar @args) {
 220                 my $arg = shift @args;
 221                 $arg =~ tr/A-Z./a-z_/;
 222                 $arg = "list_$arg";
 223                 return r501 if $DISABLED{$arg};
 224
 225                 $arg = eval {
 226                         no strict 'refs';
 227                         *{$arg}{CODE};
 228                 };
 229                 return r501 unless $arg && args_ok($arg, scalar @args);
 230                 more($self, '215 information follows');
 231                 $arg->($self, @args);
 232         } else {
 233                 more($self, '215 list of newsgroups follows');
 234                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 235                         group_line($self, $ng);
 236                 }
 237         }
 238         '.'
 239 }
 240
 241 sub cmd_listgroup ($;$) {
 242         my ($self, $group) = @_;
 243         if (defined $group) {
 244                 my $res = cmd_group($self, $group);
 245                 return $res if ($res !~ /\A211 /);
 246                 more($self, $res);
 247         }
 248
 249         $self->{ng} or return '412 no newsgroup selected';
 250         long_response($self, 0, long_response_limit, sub {
 251                 my ($i) = @_;
 252                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 253                         my ($ary) = @_;
 254                         more($self, join("\r\n", @$ary));
 255                 });
 256
 257                 # -1 to adjust for implicit increment in long_response
 258                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 259         });
 260 }
 261
 262 sub parse_time ($$;$) {
 263         my ($date, $time, $gmt) = @_;
 264         use Time::Local qw();
 265         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 266         if (defined $gmt) {
 267                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 268                 $gmt = 1;
 269         }
 270         my @now = $gmt ? gmtime : localtime;
 271         my ($YYYY, $MM, $DD);
 272         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 273                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 274         } else { # legacy clients send YYMMDD
 275                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 276                 if ($YYYY > strftime('%y', @now)) {
 277                         my $cur_year = $now[5] + 1900;
 278                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 279                 }
 280         }
 281         if ($gmt) {
 282                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 283         } else {
 284                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 285         }
 286 }
 287
 288 sub group_line ($$) {
 289         my ($self, $ng) = @_;
 290         my ($min, $max) = $ng->mm->minmax;
 291         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 292 }
 293
 294 sub cmd_newgroups ($$$;$$) {
 295         my ($self, $date, $time, $gmt, $dists) = @_;
 296         my $ts = eval { parse_time($date, $time, $gmt) };
 297         return r501 if $@;
 298
 299         # TODO dists
 300         more($self, '231 list of new newsgroups follows');
 301         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 302                 my $c = eval { $ng->mm->created_at } || 0;
 303                 next unless $c > $ts;
 304                 group_line($self, $ng);
 305         }
 306         '.'
 307 }
 308
 309 sub wildmat2re (;$) {
 310         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 311         my %keep;
 312         my $salt = rand;
 313         use Digest::SHA qw(sha1_hex);
 314         my $tmp = $_[0];
 315
 316         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 317                 my $orig = $1;
 318                 my $key = sha1_hex($orig . $salt);
 319                 $orig =~ s/([^\w\-])+/\Q$1/g;
 320                 $keep{$key} = $orig;
 321                 $key
 322                 #gex;
 323         my %map = ('*' => '.*', '?' => '.' );
 324         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 325         if (scalar %keep) {
 326                 $tmp =~ s#([a-f0-9]{40})#
 327                         my $orig = $keep{$1};
 328                         defined $orig ? $orig : $1;
 329                         #ge;
 330         }
 331         $_[0] = qr/\A$tmp\z/;
 332 }
 333
 334 sub ngpat2re (;$) {
 335         return $_[0] = qr/\A\z/ unless defined $_[0];
 336         my %map = ('*' => '.*', ',' => '|');
 337         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 338         $_[0] = qr/\A(?:$_[0])\z/;
 339 }
 340
 341 sub cmd_newnews ($$$$;$$) {
 342         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 343         my $ts = eval { parse_time($date, $time, $gmt) };
 344         return r501 if $@;
 345         more($self, '230 list of new articles by message-id follows');
 346         my ($keep, $skip) = split('!', $newsgroups, 2);
 347         ngpat2re($keep);
 348         ngpat2re($skip);
 349         my @srch;
 350         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 351                 $ng->{newsgroup} =~ $keep or next;
 352                 $ng->{newsgroup} =~ $skip and next;
 353                 my $srch = $ng->search or next;
 354                 push @srch, $srch;
 355         };
 356         return '.' unless @srch;
 357
 358         $ts .= '..';
 359         my $opts = { asc => 1, limit => 1000, offset => 0 };
 360         long_response($self, 0, long_response_limit, sub {
 361                 my ($i) = @_;
 362                 my $srch = $srch[0];
 363                 my $res = $srch->query($ts, $opts);
 364                 my $msgs = $res->{msgs};
 365                 if (my $nr = scalar @$msgs) {
 366                         more($self, '<' .
 367                                 join(">\r\n<", map { $_->mid } @$msgs ).
 368                                 '>');
 369                         $opts->{offset} += $nr;
 370                 } else {
 371                         shift @srch;
 372                         if (@srch) { # continue onto next newsgroup
 373                                 $opts->{offset} = 0;
 374                         } else { # break out of the long response.
 375                                 $$i = long_response_limit;
 376                         }
 377                 }
 378         });
 379 }
 380
 381 sub cmd_group ($$) {
 382         my ($self, $group) = @_;
 383         my $no_such = '411 no such news group';
 384         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 385
 386         $self->{ng} = $ng;
 387         my ($min, $max) = $ng->mm->minmax;
 388         $min ||= 0;
 389         $max ||= 0;
 390         $self->{article} = $min;
 391         my $est_size = $max - $min;
 392         "211 $est_size $min $max $group";
 393 }
 394
 395 sub article_adj ($$) {
 396         my ($self, $off) = @_;
 397         my $ng = $self->{ng} or return '412 no newsgroup selected';
 398
 399         my $n = $self->{article};
 400         defined $n or return '420 no current article has been selected';
 401
 402         $n += $off;
 403         my $mid = $ng->mm->mid_for($n);
 404         unless ($mid) {
 405                 $n = $off > 0 ? 'next' : 'previous';
 406                 return "421 no $n article in this group";
 407         }
 408         $self->{article} = $n;
 409         "223 $n <$mid> article retrieved - request text separately";
 410 }
 411
 412 sub cmd_next ($) { article_adj($_[0], 1) }
 413 sub cmd_last ($) { article_adj($_[0], -1) }
 414
 415 # We want to encourage using email and CC-ing everybody involved to avoid
 416 # the single-point-of-failure a single server provides.
 417 sub cmd_post ($) {
 418         my ($self) = @_;
 419         my $ng = $self->{ng};
 420         $ng ? "440 mailto:$ng->{address} to post" : '440 posting not allowed'
 421 }
 422
 423 sub cmd_quit ($) {
 424         my ($self) = @_;
 425         res($self, '205 closing connection - goodbye!');
 426         $self->close;
 427         undef;
 428 }
 429
 430 sub header_append ($$$) {
 431         my ($hdr, $k, $v) = @_;
 432         my @v = $hdr->header($k);
 433         foreach (@v) {
 434                 return if $v eq $_;
 435         }
 436         $hdr->header_set($k, @v, $v);
 437 }
 438
 439 sub set_nntp_headers {
 440         my ($hdr, $ng, $n, $mid) = @_;
 441
 442         # clobber some
 443         $hdr->header_set('Newsgroups', $ng->{newsgroup});
 444         $hdr->header_set('Xref', xref($ng, $n));
 445         header_append($hdr, 'List-Post', "<mailto:$ng->{address}>");
 446         if (my $url = $ng->{url}) {
 447                 $mid = uri_escape_utf8($mid);
 448                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 449                 header_append($hdr, 'List-Archive', "<$url>");
 450         }
 451 }
 452
 453 sub art_lookup ($$$) {
 454         my ($self, $art, $set_headers) = @_;
 455         my $ng = $self->{ng};
 456         my ($n, $mid);
 457         my $err;
 458         if (defined $art) {
 459                 if ($art =~ /\A\d+\z/o) {
 460                         $err = '423 no such article number in this group';
 461                         $n = int($art);
 462                         goto find_mid;
 463                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 464                         $mid = $1;
 465                         $err = r430;
 466                         $n = $ng->mm->num_for($mid) if $ng;
 467                         goto found if defined $n;
 468                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 469                                 $n = $g->mm->num_for($mid);
 470                                 if (defined $n) {
 471                                         $ng = $g;
 472                                         goto found;
 473                                 }
 474                         }
 475                         return $err;
 476                 } else {
 477                         return r501;
 478                 }
 479         } else {
 480                 $err = '420 no current article has been selected';
 481                 $n = $self->{article};
 482                 defined $n or return $err;
 483 find_mid:
 484                 $ng or return '412 no newsgroup has been selected';
 485                 $mid = $ng->mm->mid_for($n);
 486                 defined $mid or return $err;
 487         }
 488 found:
 489         my $o = 'HEAD:' . mid2path($mid);
 490         my $bytes;
 491         my $s = eval { Email::Simple->new($ng->gcf->cat_file($o, \$bytes)) };
 492         return $err unless $s;
 493         my $lines;
 494         if ($set_headers) {
 495                 set_nntp_headers($s->header_obj, $ng, $n, $mid);
 496                 $lines = $s->body =~ tr!\n!\n!;
 497
 498                 # must be last
 499                 $s->body_set('') if ($set_headers == 2);
 500         }
 501         [ $n, $mid, $s, $bytes, $lines, $ng ];
 502 }
 503
 504 sub simple_body_write ($$) {
 505         my ($self, $s) = @_;
 506         my $body = $s->body;
 507         $s->body_set('');
 508         $body =~ s/^\./../smg;
 509         $body =~ s/(?<!\r)\n/\r\n/sg;
 510         do_more($self, $body);
 511         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 512         '.'
 513 }
 514
 515 sub set_art {
 516         my ($self, $art) = @_;
 517         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 518 }
 519
 520 sub cmd_article ($;$) {
 521         my ($self, $art) = @_;
 522         my $r = art_lookup($self, $art, 1);
 523         return $r unless ref $r;
 524         my ($n, $mid, $s) = @$r;
 525         set_art($self, $art);
 526         more($self, "220 $n <$mid> article retrieved - head and body follow");
 527         do_more($self, $s->header_obj->as_string);
 528         do_more($self, "\r\n");
 529         simple_body_write($self, $s);
 530 }
 531
 532 sub cmd_head ($;$) {
 533         my ($self, $art) = @_;
 534         my $r = art_lookup($self, $art, 2);
 535         return $r unless ref $r;
 536         my ($n, $mid, $s) = @$r;
 537         set_art($self, $art);
 538         more($self, "221 $n <$mid> article retrieved - head follows");
 539         do_more($self, $s->header_obj->as_string);
 540         '.'
 541 }
 542
 543 sub cmd_body ($;$) {
 544         my ($self, $art) = @_;
 545         my $r = art_lookup($self, $art, 0);
 546         return $r unless ref $r;
 547         my ($n, $mid, $s) = @$r;
 548         set_art($self, $art);
 549         more($self, "222 $n <$mid> article retrieved - body follows");
 550         simple_body_write($self, $s);
 551 }
 552
 553 sub cmd_stat ($;$) {
 554         my ($self, $art) = @_;
 555         my $r = art_lookup($self, $art, 0);
 556         return $r unless ref $r;
 557         my ($n, $mid, undef) = @$r;
 558         set_art($self, $art);
 559         "223 $n <$mid> article retrieved - request text separately";
 560 }
 561
 562 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 563
 564 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 565
 566 sub cmd_help ($) {
 567         my ($self) = @_;
 568         more($self, '100 help text follows');
 569         '.'
 570 }
 571
 572 sub get_range ($$) {
 573         my ($self, $range) = @_;
 574         my $ng = $self->{ng} or return '412 no news group has been selected';
 575         defined $range or return '420 No article(s) selected';
 576         my ($beg, $end);
 577         my ($min, $max) = $ng->mm->minmax;
 578         if ($range =~ /\A(\d+)\z/) {
 579                 $beg = $end = $1;
 580         } elsif ($range =~ /\A(\d+)-\z/) {
 581                 ($beg, $end) = ($1, $max);
 582         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 583                 ($beg, $end) = ($1, $2);
 584         } else {
 585                 return r501;
 586         }
 587         $beg = $min if ($beg < $min);
 588         $end = $max if ($end > $max);
 589         return '420 No article(s) selected' if ($beg > $end);
 590         [ $beg, $end ];
 591 }
 592
 593 sub long_response ($$$$) {
 594         my ($self, $beg, $end, $cb) = @_;
 595         die "BUG: nested long response" if $self->{long_res};
 596
 597         my $fd = $self->{fd};
 598         defined $fd or return;
 599         # make sure we disable reading during a long response,
 600         # clients should not be sending us stuff and making us do more
 601         # work while we are stream a response to them
 602         $self->watch_read(0);
 603         my $t0 = now();
 604         $self->{long_res} = sub {
 605                 # limit our own running time for fairness with other
 606                 # clients and to avoid buffering too much:
 607                 my $lim = 100;
 608
 609                 my $err;
 610                 do {
 611                         eval { $cb->(\$beg) };
 612                 } until (($err = $@) || $self->{closed} ||
 613                          ++$beg > $end || !--$lim || $self->{write_buf_size});
 614
 615                 if ($err || $self->{closed}) {
 616                         $self->{long_res} = undef;
 617
 618                         if ($err) {
 619                                 err($self,
 620                                     "%s during long response[$fd] - %0.6f",
 621                                     $err, now() - $t0);
 622                         }
 623                         if ($self->{closed}) {
 624                                 out($self, " deferred[$fd] aborted - %0.6f",
 625                                            now() - $t0);
 626                         } else {
 627                                 update_idle_time($self);
 628                                 $self->watch_read(1);
 629                         }
 630                 } elsif (!$lim || $self->{write_buf_size}) {
 631                         # no recursion, schedule another call ASAP
 632                         # but only after all pending writes are done
 633                         update_idle_time($self);
 634
 635                         push @$nextq, $self;
 636                         $next_tick ||= Danga::Socket->AddTimer(0, *next_tick);
 637                 } else { # all done!
 638                         $self->{long_res} = undef;
 639                         $self->watch_read(1);
 640                         res($self, '.');
 641                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 642                 }
 643         };
 644         $self->{long_res}->(); # kick off!
 645         undef;
 646 }
 647
 648 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 649         my ($self, $xhdr, $range) = @_;
 650
 651         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 652                 my ($ng, $n) = mid_lookup($self, $1);
 653                 return r430 unless $n;
 654                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 655         } else { # numeric range
 656                 $range = $self->{article} unless defined $range;
 657                 my $r = get_range($self, $range);
 658                 return $r unless ref $r;
 659                 my $mm = $self->{ng}->mm;
 660                 my ($beg, $end) = @$r;
 661                 more($self, $xhdr ? r221 : r225);
 662                 long_response($self, $beg, $end, sub {
 663                         my ($i) = @_;
 664                         my $mid = $mm->mid_for($$i);
 665                         more($self, "$$i <$mid>") if defined $mid;
 666                 });
 667         }
 668 }
 669
 670 sub xref ($$) {
 671         my ($ng, $n) = @_;
 672         "$ng->{domain} $ng->{newsgroup}:$n"
 673 }
 674
 675 sub mid_lookup ($$) {
 676         my ($self, $mid) = @_;
 677         my $self_ng = $self->{ng};
 678         if ($self_ng) {
 679                 my $n = $self_ng->mm->num_for($mid);
 680                 return ($self_ng, $n) if defined $n;
 681         }
 682         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 683                 next if defined $self_ng && $ng eq $self_ng;
 684                 my $n = $ng->mm->num_for($mid);
 685                 return ($ng, $n) if defined $n;
 686         }
 687         (undef, undef);
 688 }
 689
 690 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 691         my ($self, $xhdr, $range) = @_;
 692
 693         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 694                 my ($ng, $n) = mid_lookup($self, $1);
 695                 return r430 unless $n;
 696                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 697         } else { # numeric range
 698                 $range = $self->{article} unless defined $range;
 699                 my $r = get_range($self, $range);
 700                 return $r unless ref $r;
 701                 my $ng = $self->{ng};
 702                 my $mm = $ng->mm;
 703                 my ($beg, $end) = @$r;
 704                 more($self, $xhdr ? r221 : r225);
 705                 long_response($self, $beg, $end, sub {
 706                         my ($i) = @_;
 707                         my $mid = $mm->mid_for($$i);
 708                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 709                 });
 710         }
 711 }
 712
 713 sub search_header_for {
 714         my ($srch, $mid, $field) = @_;
 715         my $smsg = $srch->lookup_message($mid) or return;
 716         $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 717         $smsg->$field;
 718 }
 719
 720 sub hdr_searchmsg ($$$$) {
 721         my ($self, $xhdr, $field, $range) = @_;
 722         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 723                 my ($ng, $n) = mid_lookup($self, $1);
 724                 return r430 unless $n;
 725                 my $v = search_header_for($ng->search, $range, $field);
 726                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 727         } else { # numeric range
 728                 $range = $self->{article} unless defined $range;
 729                 my $srch = $self->{ng}->search;
 730                 my $mm = $self->{ng}->mm;
 731                 my $r = get_range($self, $range);
 732                 return $r unless ref $r;
 733                 my ($beg, $end) = @$r;
 734                 more($self, $xhdr ? r221 : r225);
 735                 my $off = 0;
 736                 long_response($self, $beg, $end, sub {
 737                         my ($i) = @_;
 738                         my $res = $srch->query_xover($beg, $end, $off);
 739                         my $msgs = $res->{msgs};
 740                         my $nr = scalar @$msgs or return;
 741                         $off += $nr;
 742                         my $tmp = '';
 743                         foreach my $s (@$msgs) {
 744                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 745                         }
 746                         do_more($self, $tmp);
 747                         # -1 to adjust for implicit increment in long_response
 748                         $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 749                 });
 750         }
 751 }
 752
 753 sub do_hdr ($$$;$) {
 754         my ($self, $xhdr, $header, $range) = @_;
 755         my $sub = lc $header;
 756         if ($sub eq 'message-id') {
 757                 hdr_message_id($self, $xhdr, $range);
 758         } elsif ($sub eq 'xref') {
 759                 hdr_xref($self, $xhdr, $range);
 760         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 761                                 bytes|lines)\z/x) {
 762                 hdr_searchmsg($self, $xhdr, $sub, $range);
 763         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 764                 hdr_searchmsg($self, $xhdr, $1, $range);
 765         } else {
 766                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 767         }
 768 }
 769
 770 # RFC 3977
 771 sub cmd_hdr ($$;$) {
 772         my ($self, $header, $range) = @_;
 773         do_hdr($self, 0, $header, $range);
 774 }
 775
 776 # RFC 2980
 777 sub cmd_xhdr ($$;$) {
 778         my ($self, $header, $range) = @_;
 779         do_hdr($self, 1, $header, $range);
 780 }
 781
 782 sub hdr_mid_prefix ($$$$$) {
 783         my ($self, $xhdr, $ng, $n, $mid) = @_;
 784         return $mid if $xhdr;
 785
 786         # HDR for RFC 3977 users
 787         if (my $self_ng = $self->{ng}) {
 788                 ($self_ng eq $ng) ? $n : '0';
 789         } else {
 790                 '0';
 791         }
 792 }
 793
 794 sub hdr_mid_response ($$$$$$) {
 795         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 796         my $res = '';
 797         if ($xhdr) {
 798                 $res .= r221 . "\r\n";
 799                 $res .= "$mid $v\r\n";
 800         } else {
 801                 $res .= r225 . "\r\n";
 802                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 803                 $res .= "$pfx $v\r\n";
 804         }
 805         res($self, $res .= '.');
 806         undef;
 807 }
 808
 809 sub cmd_xrover ($;$) {
 810         my ($self, $range) = @_;
 811         my $ng = $self->{ng} or return '412 no newsgroup selected';
 812         (defined $range && $range =~ /[<>]/) and
 813                 return '420 No article(s) selected'; # no message IDs
 814
 815         $range = $self->{article} unless defined $range;
 816         my $r = get_range($self, $range);
 817         return $r unless ref $r;
 818         my ($beg, $end) = @$r;
 819         my $mm = $ng->mm;
 820         my $srch = $ng->search;
 821         more($self, '224 Overview information follows');
 822         long_response($self, $beg, $end, sub {
 823                 my ($i) = @_;
 824                 my $mid = $mm->mid_for($$i) or return;
 825                 my $h = search_header_for($srch, $mid, 'references');
 826                 more($self, "$$i $h");
 827         });
 828 }
 829
 830 sub over_line ($$) {
 831         my ($num, $smsg) = @_;
 832         # n.b. field access and procedural calls can be
 833         # 10%-15% faster than OO method calls:
 834         join("\t", $num,
 835                 $smsg->{subject},
 836                 $smsg->{from},
 837                 PublicInbox::SearchMsg::date($smsg),
 838                 '<'.PublicInbox::SearchMsg::mid($smsg).'>',
 839                 $smsg->{references},
 840                 PublicInbox::SearchMsg::bytes($smsg),
 841                 PublicInbox::SearchMsg::lines($smsg));
 842 }
 843
 844 sub cmd_over ($;$) {
 845         my ($self, $range) = @_;
 846         if ($range && $range =~ /\A<(.+)>\z/) {
 847                 my ($ng, $n) = mid_lookup($self, $1);
 848                 my $smsg = $ng->search->lookup_message($range) or
 849                         return '430 No article with that message-id';
 850                 more($self, '224 Overview information follows (multi-line)');
 851                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 852
 853                 # Only set article number column if it's the current group
 854                 my $self_ng = $self->{ng};
 855                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 856                 more($self, over_line($n, $smsg));
 857                 '.';
 858         } else {
 859                 cmd_xover($self, $range);
 860         }
 861 }
 862
 863 sub cmd_xover ($;$) {
 864         my ($self, $range) = @_;
 865         $range = $self->{article} unless defined $range;
 866         my $r = get_range($self, $range);
 867         return $r unless ref $r;
 868         my ($beg, $end) = @$r;
 869         more($self, "224 Overview information follows for $beg to $end");
 870         my $srch = $self->{ng}->search;
 871         my $off = 0;
 872         long_response($self, $beg, $end, sub {
 873                 my ($i) = @_;
 874                 my $res = $srch->query_xover($beg, $end, $off);
 875                 my $msgs = $res->{msgs};
 876                 my $nr = scalar @$msgs or return;
 877                 $off += $nr;
 878
 879                 # OVERVIEW.FMT
 880                 more($self, join("\r\n", map {
 881                         over_line(PublicInbox::SearchMsg::num($_), $_);
 882                         } @$msgs));
 883
 884                 # -1 to adjust for implicit increment in long_response
 885                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 886         });
 887 }
 888
 889 sub cmd_xpath ($$) {
 890         my ($self, $mid) = @_;
 891         return r501 unless $mid =~ /\A<(.+)>\z/;
 892         $mid = $1;
 893         my @paths;
 894         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 895                 my $n = $ng->mm->num_for($mid);
 896                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 897         }
 898         return '430 no such article on server' unless @paths;
 899         '223 '.join(' ', @paths);
 900 }
 901
 902 sub res ($$) {
 903         my ($self, $line) = @_;
 904         $line = $enc_utf8->encode($line);
 905         do_write($self, $line . "\r\n");
 906 }
 907
 908 sub more ($$) {
 909         my ($self, $line) = @_;
 910         do_more($self, $line . "\r\n");
 911 }
 912
 913 sub do_write ($$) {
 914         my ($self, $data) = @_;
 915         my $done = $self->write($data);
 916         die if $self->{closed};
 917
 918         # Do not watch for readability if we have data in the queue,
 919         # instead re-enable watching for readability when we can
 920         $self->watch_read(0) if (!$done || $self->{long_res});
 921
 922         $done;
 923 }
 924
 925 sub err ($$;@) {
 926         my ($self, $fmt, @args) = @_;
 927         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 928 }
 929
 930 sub out ($$;@) {
 931         my ($self, $fmt, @args) = @_;
 932         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 933 }
 934
 935 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 936
 937 sub do_more ($$) {
 938         my ($self, $data) = @_;
 939         $data = $enc_utf8->encode($data);
 940         if (MSG_MORE && !$self->{write_buf_size}) {
 941                 my $n = send($self->{sock}, $data, MSG_MORE);
 942                 if (defined $n) {
 943                         my $dlen = length($data);
 944                         return 1 if $n == $dlen; # all done!
 945                         $data = substr($data, $n, $dlen - $n);
 946                 }
 947         }
 948         do_write($self, $data);
 949 }
 950
 951 # callbacks for Danga::Socket
 952
 953 sub event_hup { $_[0]->close }
 954 sub event_err { $_[0]->close }
 955
 956 sub event_write {
 957         my ($self) = @_;
 958         update_idle_time($self);
 959         # only continue watching for readability when we are done writing:
 960         if ($self->write(undef) == 1 && !$self->{long_res}) {
 961                 $self->watch_read(1);
 962         }
 963 }
 964
 965 sub event_read {
 966         my ($self) = @_;
 967         use constant LINE_MAX => 512; # RFC 977 section 2.3
 968         my $r = 1;
 969
 970         my $buf = $self->read(LINE_MAX) or return $self->close;
 971         $self->{rbuf} .= $$buf;
 972         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 973                 my $line = $1;
 974                 return $self->close if $line =~ /[[:cntrl:]]/s;
 975                 my $t0 = now();
 976                 my $fd = $self->{fd};
 977                 $r = eval { process_line($self, $line) };
 978                 my $d = $self->{long_res} ?
 979                         " deferred[$fd]" : '';
 980                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 981         }
 982
 983         return $self->close if $r < 0;
 984         my $len = length($self->{rbuf});
 985         return $self->close if ($len >= LINE_MAX);
 986         update_idle_time($self);
 987 }
 988
 989 sub watch_read {
 990         my ($self, $bool) = @_;
 991         my $rv = $self->SUPER::watch_read($bool);
 992         if ($bool && $self->{rbuf} ne '') {
 993                 # Force another read if there is a pipelined request.
 994                 # We don't know if the socket has anything for us to read,
 995                 # and we must double-check again by the time the timer fires
 996                 # in case we really did dispatch a read event and started
 997                 # another long response.
 998                 push @$nextq, $self;
 999                 $next_tick ||= Danga::Socket->AddTimer(0, *next_tick);
1000         }
1001         $rv;
1002 }
1003
1004 # for graceful shutdown in PublicInbox::Daemon:
1005 sub busy () {
1006         my ($self) = @_;
1007         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size});
1008 }
1009
1010 1;