lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 # fields:
   6 # nntpd: PublicInbox::NNTPD ref
   7 # article: per-session current article number
   8 # ibx: PublicInbox::Inbox ref
   9 # long_cb: long_response private data
  10 package PublicInbox::NNTP;
  11 use strict;
  12 use parent qw(PublicInbox::DS);
  13 use PublicInbox::MID qw(mid_escape $MID_EXTRACT);
  14 use PublicInbox::Eml;
  15 use POSIX qw(strftime);
  16 use PublicInbox::DS qw(now);
  17 use Digest::SHA qw(sha1_hex);
  18 use Time::Local qw(timegm timelocal);
  19 use PublicInbox::GitAsyncCat;
  20 use PublicInbox::Address;
  21
  22 use constant {
  23         LINE_MAX => 512, # RFC 977 section 2.3
  24         r501 => '501 command syntax error',
  25         r502 => '502 Command unavailable',
  26         r221 => '221 Header follows',
  27         r224 => '224 Overview information follows (multi-line)',
  28         r225 => '225 Headers follow (multi-line)',
  29         r430 => '430 No article with that message-id',
  30 };
  31 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  32 use Errno qw(EAGAIN);
  33 my $ONE_MSGID = qr/\A$MID_EXTRACT\z/;
  34 my @OVERVIEW = qw(Subject From Date Message-ID References);
  35 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  36                 "Xref:full\r\n.";
  37 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  38                         qw(:bytes :lines Xref To Cc)) . "\r\n.";
  39 my $CAPABILITIES = <<"";
  40 101 Capability list:\r
  41 VERSION 2\r
  42 READER\r
  43 NEWNEWS\r
  44 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  45 HDR\r
  46 OVER\r
  47 COMPRESS DEFLATE\r
  48
  49 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  50
  51 sub new ($$$) {
  52         my ($class, $sock, $nntpd) = @_;
  53         my $self = bless { nntpd => $nntpd }, $class;
  54         my $ev = EPOLLIN;
  55         my $wbuf;
  56         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
  57                 return CORE::close($sock) if $! != EAGAIN;
  58                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
  59                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  60         }
  61         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  62         if ($wbuf) {
  63                 $self->{wbuf} = $wbuf;
  64         } else {
  65                 greet($self);
  66         }
  67         $self->update_idle_time;
  68         $self;
  69 }
  70
  71 sub args_ok ($$) {
  72         my ($cb, $argc) = @_;
  73         my $tot = prototype $cb;
  74         my ($nreq, undef) = split(';', $tot);
  75         $nreq = ($nreq =~ tr/$//) - 1;
  76         $tot = ($tot =~ tr/$//) - 1;
  77         ($argc <= $tot && $argc >= $nreq);
  78 }
  79
  80 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  81 sub process_line ($$) {
  82         my ($self, $l) = @_;
  83         my ($req, @args) = split(/[ \t]+/, $l);
  84         return 1 unless defined($req); # skip blank line
  85         $req = $self->can('cmd_'.lc($req));
  86         return res($self, '500 command not recognized') unless $req;
  87         return res($self, r501) unless args_ok($req, scalar @args);
  88
  89         my $res = eval { $req->($self, @args) };
  90         my $err = $@;
  91         if ($err && $self->{sock}) {
  92                 local $/ = "\n";
  93                 chomp($l);
  94                 err($self, 'error from: %s (%s)', $l, $err);
  95                 $res = '503 program fault - command not performed';
  96         }
  97         defined($res) ? res($self, $res) : 0;
  98 }
  99
 100 # The keyword argument is not used (rfc3977 5.2.2)
 101 sub cmd_capabilities ($;$) {
 102         my ($self, undef) = @_;
 103         my $res = $CAPABILITIES;
 104         if (!$self->{sock}->can('accept_SSL') &&
 105                         $self->{nntpd}->{accept_tls}) {
 106                 $res .= "STARTTLS\r\n";
 107         }
 108         $res .= '.';
 109 }
 110
 111 sub cmd_mode ($$) {
 112         my ($self, $arg) = @_;
 113         uc($arg) eq 'READER' ? '201 Posting prohibited' : r501;
 114 }
 115
 116 sub cmd_slave ($) { '202 slave status noted' }
 117
 118 sub cmd_xgtitle ($;$) {
 119         my ($self, $wildmat) = @_;
 120         more($self, '282 list of groups and descriptions follows');
 121         list_newsgroups($self, $wildmat);
 122 }
 123
 124 sub list_overview_fmt ($) { $OVERVIEW_FMT }
 125
 126 sub list_headers ($;$) { $LIST_HEADERS }
 127
 128 sub list_active_i { # "LIST ACTIVE" and also just "LIST" (no args)
 129         my ($self, $groupnames) = @_;
 130         my @window = splice(@$groupnames, 0, 100) or return 0;
 131         my $ibx;
 132         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 133         for my $ngname (@window) {
 134                 $ibx = $groups->{$ngname} and group_line($self, $ibx);
 135         }
 136         scalar(@$groupnames); # continue if there's more
 137 }
 138
 139 sub list_active ($;$) { # called by cmd_list
 140         my ($self, $wildmat) = @_;
 141         wildmat2re($wildmat);
 142         long_response($self, \&list_active_i, [
 143                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 144 }
 145
 146 sub list_active_times_i {
 147         my ($self, $groupnames) = @_;
 148         my @window = splice(@$groupnames, 0, 100) or return 0;
 149         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 150         for my $ngname (@window) {
 151                 my $ibx = $groups->{$ngname} or next;
 152                 my $c = eval { $ibx->uidvalidity } // time;
 153                 more($self, "$ngname $c <$ibx->{-primary_address}>");
 154         }
 155         scalar(@$groupnames); # continue if there's more
 156 }
 157
 158 sub list_active_times ($;$) { # called by cmd_list
 159         my ($self, $wildmat) = @_;
 160         wildmat2re($wildmat);
 161         long_response($self, \&list_active_times_i, [
 162                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 163 }
 164
 165 sub list_newsgroups_i {
 166         my ($self, $groupnames) = @_;
 167         my @window = splice(@$groupnames, 0, 100) or return 0;
 168         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 169         my $ibx;
 170         for my $ngname (@window) {
 171                 $ibx = $groups->{$ngname} and
 172                         more($self, "$ngname ".$ibx->description);
 173         }
 174         scalar(@$groupnames); # continue if there's more
 175 }
 176
 177 sub list_newsgroups ($;$) { # called by cmd_list
 178         my ($self, $wildmat) = @_;
 179         wildmat2re($wildmat);
 180         long_response($self, \&list_newsgroups_i, [
 181                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 182 }
 183
 184 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 185 sub cmd_list ($;$$) {
 186         my ($self, @args) = @_;
 187         if (scalar @args) {
 188                 my $arg = shift @args;
 189                 $arg =~ tr/A-Z./a-z_/;
 190                 my $ret = $arg eq 'active';
 191                 $arg = "list_$arg";
 192                 $arg = $self->can($arg);
 193                 return r501 unless $arg && args_ok($arg, scalar @args);
 194                 more($self, '215 information follows');
 195                 $arg->($self, @args);
 196         } else {
 197                 more($self, '215 list of newsgroups follows');
 198                 long_response($self, \&list_active_i, [ # copy array
 199                         @{$self->{nntpd}->{groupnames}} ]);
 200         }
 201 }
 202
 203 sub listgroup_range_i {
 204         my ($self, $beg, $end) = @_;
 205         my $r = $self->{ibx}->mm->msg_range($beg, $end, 'num');
 206         scalar(@$r) or return;
 207         $self->msg_more(join('', map { "$_->[0]\r\n" } @$r));
 208         1;
 209 }
 210
 211 sub listgroup_all_i {
 212         my ($self, $num) = @_;
 213         my $ary = $self->{ibx}->mm->ids_after($num);
 214         scalar(@$ary) or return;
 215         more($self, join("\r\n", @$ary));
 216         1;
 217 }
 218
 219 sub cmd_listgroup ($;$$) {
 220         my ($self, $group, $range) = @_;
 221         if (defined $group) {
 222                 my $res = cmd_group($self, $group);
 223                 return $res if ($res !~ /\A211 /);
 224                 more($self, $res);
 225         }
 226         $self->{ibx} or return '412 no newsgroup selected';
 227         if (defined $range) {
 228                 my $r = get_range($self, $range);
 229                 return $r unless ref $r;
 230                 long_response($self, \&listgroup_range_i, @$r);
 231         } else { # grab every article number
 232                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 233         }
 234 }
 235
 236 sub parse_time ($$;$) {
 237         my ($date, $time, $gmt) = @_;
 238         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 239         if (defined $gmt) {
 240                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 241                 $gmt = 1;
 242         }
 243         my ($YYYY, $MM, $DD);
 244         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 245                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 246         } else { # legacy clients send YYMMDD
 247                 my $YY;
 248                 ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 249                 my @now = $gmt ? gmtime : localtime;
 250                 my $cur_year = $now[5] + 1900;
 251                 my $cur_cent = int($cur_year / 100) * 100;
 252                 $YYYY = (($YY + $cur_cent) > $cur_year) ?
 253                         ($YY + 1900) : ($YY + $cur_cent);
 254         }
 255         if ($gmt) {
 256                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 257         } else {
 258                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 259         }
 260 }
 261
 262 sub group_line ($$) {
 263         my ($self, $ibx) = @_;
 264         my ($min, $max) = $ibx->mm->minmax;
 265         more($self, "$ibx->{newsgroup} $max $min n");
 266 }
 267
 268 sub newgroups_i {
 269         my ($self, $ts, $i, $groupnames) = @_;
 270         my $end = $$i + 100;
 271         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 272         while ($$i < $end) {
 273                 my $ngname = $groupnames->[$$i++] // return;
 274                 my $ibx = $groups->{$ngname} or next; # expired on reload
 275                 next unless (eval { $ibx->uidvalidity } // 0) > $ts;
 276                 group_line($self, $ibx);
 277         }
 278         1;
 279 }
 280
 281 sub cmd_newgroups ($$$;$$) {
 282         my ($self, $date, $time, $gmt, $dists) = @_;
 283         my $ts = eval { parse_time($date, $time, $gmt) };
 284         return r501 if $@;
 285
 286         # TODO dists
 287         more($self, '231 list of new newsgroups follows');
 288         long_response($self, \&newgroups_i, $ts, \(my $i = 0),
 289                                 $self->{nntpd}->{groupnames});
 290 }
 291
 292 sub wildmat2re (;$) {
 293         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 294         my %keep;
 295         my $salt = rand;
 296         my $tmp = $_[0];
 297
 298         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 299                 my $orig = $1;
 300                 my $key = sha1_hex($orig . $salt);
 301                 $orig =~ s/([^\w\-])+/\Q$1/g;
 302                 $keep{$key} = $orig;
 303                 $key
 304                 #gex;
 305         my %map = ('*' => '.*', '?' => '.' );
 306         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 307         if (scalar %keep) {
 308                 $tmp =~ s#([a-f0-9]{40})#
 309                         my $orig = $keep{$1};
 310                         defined $orig ? $orig : $1;
 311                         #ge;
 312         }
 313         $_[0] = qr/\A$tmp\z/;
 314 }
 315
 316 sub ngpat2re (;$) {
 317         return $_[0] = qr/\A\z/ unless defined $_[0];
 318         my %map = ('*' => '.*', ',' => '|');
 319         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 320         $_[0] = qr/\A(?:$_[0])\z/;
 321 }
 322
 323 sub newnews_i {
 324         my ($self, $names, $ts, $prev) = @_;
 325         my $ngname = $names->[0];
 326         if (my $ibx = $self->{nntpd}->{pi_cfg}->{-by_newsgroup}->{$ngname}) {
 327                 if (my $over = $ibx->over) {
 328                         my $msgs = $over->query_ts($ts, $$prev);
 329                         if (scalar @$msgs) {
 330                                 $self->msg_more(join('', map {
 331                                                         "<$_->{mid}>\r\n";
 332                                                 } @$msgs));
 333                                 $$prev = $msgs->[-1]->{num};
 334                                 return 1; # continue on current group
 335                         }
 336                 }
 337         }
 338         shift @$names;
 339         if (@$names) { # continue onto next newsgroup
 340                 $$prev = 0;
 341                 1;
 342         } else { # all done, break out of the long_response
 343                 undef;
 344         }
 345 }
 346
 347 sub cmd_newnews ($$$$;$$) {
 348         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 349         my $ts = eval { parse_time($date, $time, $gmt) };
 350         return r501 if $@;
 351         more($self, '230 list of new articles by message-id follows');
 352         my ($keep, $skip) = split('!', $newsgroups, 2);
 353         ngpat2re($keep);
 354         ngpat2re($skip);
 355         my @names = grep(!/$skip/, grep(/$keep/,
 356                                 @{$self->{nntpd}->{groupnames}}));
 357         return '.' unless scalar(@names);
 358         my $prev = 0;
 359         long_response($self, \&newnews_i, \@names, $ts, \$prev);
 360 }
 361
 362 sub cmd_group ($$) {
 363         my ($self, $group) = @_;
 364         my $nntpd = $self->{nntpd};
 365         my $ibx = $nntpd->{pi_cfg}->{-by_newsgroup}->{$group} or
 366                 return '411 no such news group';
 367         $nntpd->idler_start;
 368
 369         $self->{ibx} = $ibx;
 370         my ($min, $max) = $ibx->mm->minmax;
 371         $self->{article} = $min;
 372         my $est_size = $max - $min;
 373         "211 $est_size $min $max $group";
 374 }
 375
 376 sub article_adj ($$) {
 377         my ($self, $off) = @_;
 378         my $ibx = $self->{ibx} or return '412 no newsgroup selected';
 379
 380         my $n = $self->{article};
 381         defined $n or return '420 no current article has been selected';
 382
 383         $n += $off;
 384         my $mid = $ibx->mm->mid_for($n);
 385         unless ($mid) {
 386                 $n = $off > 0 ? 'next' : 'previous';
 387                 return "421 no $n article in this group";
 388         }
 389         $self->{article} = $n;
 390         "223 $n <$mid> article retrieved - request text separately";
 391 }
 392
 393 sub cmd_next ($) { article_adj($_[0], 1) }
 394 sub cmd_last ($) { article_adj($_[0], -1) }
 395
 396 # We want to encourage using email and CC-ing everybody involved to avoid
 397 # the single-point-of-failure a single server provides.
 398 sub cmd_post ($) {
 399         my ($self) = @_;
 400         my $ibx = $self->{ibx};
 401         $ibx ? "440 mailto:$ibx->{-primary_address} to post"
 402                 : '440 posting not allowed'
 403 }
 404
 405 sub cmd_quit ($) {
 406         my ($self) = @_;
 407         res($self, '205 closing connection - goodbye!');
 408         $self->shutdn;
 409         undef;
 410 }
 411
 412 sub header_append ($$$) {
 413         my ($hdr, $k, $v) = @_;
 414         my @v = $hdr->header_raw($k);
 415         foreach (@v) {
 416                 return if $v eq $_;
 417         }
 418         $hdr->header_set($k, @v, $v);
 419 }
 420
 421 sub xref_by_tc ($$$) {
 422         my ($xref, $pi_cfg, $smsg) = @_;
 423         my $by_addr = $pi_cfg->{-by_addr};
 424         my $mid = $smsg->{mid};
 425         for my $f (qw(to cc)) {
 426                 my @ibxs = map {
 427                         $by_addr->{lc($_)} // ()
 428                 } (PublicInbox::Address::emails($smsg->{$f} // ''));
 429                 for my $ibx (@ibxs) {
 430                         my $ngname = $ibx->{newsgroup} // next;
 431                         next if defined $xref->{$ngname};
 432                         $xref->{$ngname} = eval { $ibx->mm->num_for($mid) };
 433                 }
 434         }
 435 }
 436
 437 sub xref ($$$) {
 438         my ($self, $cur_ibx, $smsg) = @_;
 439         my $nntpd = $self->{nntpd};
 440         my $cur_ng = $cur_ibx->{newsgroup};
 441         my $xref;
 442         if (my $ALL = $nntpd->{pi_cfg}->ALL) {
 443                 $xref = $ALL->nntp_xref_for($cur_ibx, $smsg);
 444                 xref_by_tc($xref, $nntpd->{pi_cfg}, $smsg);
 445         } else { # slow path
 446                 $xref = { $cur_ng => $smsg->{num} };
 447                 my $mid = $smsg->{mid};
 448                 for my $ibx (values %{$nntpd->{pi_cfg}->{-by_newsgroup}}) {
 449                         next if defined($xref->{$ibx->{newsgroup}});
 450                         my $num = eval { $ibx->mm->num_for($mid) } // next;
 451                         $xref->{$ibx->{newsgroup}} = $num;
 452                 }
 453         }
 454         my $ret = "$nntpd->{servername} $cur_ng:".delete($xref->{$cur_ng});
 455         $ret .= " $_:$xref->{$_}" for (sort keys %$xref);
 456         $ret;
 457 }
 458
 459 sub set_nntp_headers ($$) {
 460         my ($hdr, $smsg) = @_;
 461         my ($mid) = $smsg->{mid};
 462
 463         # leafnode (and maybe other NNTP clients) have trouble dealing
 464         # with v2 messages which have multiple Message-IDs (either due
 465         # to our own content-based dedupe or buggy git-send-email versions).
 466         my @mids = $hdr->header_raw('Message-ID');
 467         if (scalar(@mids) > 1) {
 468                 my $mid0 = "<$mid>";
 469                 $hdr->header_set('Message-ID', $mid0);
 470                 my @alt = $hdr->header_raw('X-Alt-Message-ID');
 471                 my %seen = map { $_ => 1 } (@alt, $mid0);
 472                 push(@alt, grep { !$seen{$_}++ } @mids);
 473                 $hdr->header_set('X-Alt-Message-ID', @alt);
 474         }
 475
 476         # clobber some existing headers
 477         my $ibx = $smsg->{-ibx};
 478         my $xref = xref($smsg->{nntp}, $ibx, $smsg);
 479         $hdr->header_set('Xref', $xref);
 480
 481         # RFC 5536 3.1.4
 482         my ($server_name, $newsgroups) = split(/ /, $xref, 2);
 483         $newsgroups =~ s/:[0-9]+\b//g; # drop NNTP article numbers
 484         $newsgroups =~ tr/ /,/;
 485         $hdr->header_set('Newsgroups', $newsgroups);
 486
 487         # *something* here is required for leafnode, try to follow
 488         # RFC 5536 3.1.5...
 489         $hdr->header_set('Path', $server_name . '!not-for-mail');
 490         if (my $post_addr = $ibx->{-primary_address}) {
 491                 header_append($hdr, 'List-Post', "<mailto:$post_addr>");
 492         }
 493         if (my $url = $ibx->base_url) {
 494                 $mid = mid_escape($mid);
 495                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 496                 header_append($hdr, 'List-Archive', "<$url>");
 497         }
 498 }
 499
 500 sub art_lookup ($$$) {
 501         my ($self, $art, $code) = @_;
 502         my ($ibx, $n);
 503         my $err;
 504         if (defined $art) {
 505                 if ($art =~ /\A[0-9]+\z/) {
 506                         $err = '423 no such article number in this group';
 507                         $n = int($art);
 508                         goto find_ibx;
 509                 } elsif ($art =~ $ONE_MSGID) {
 510                         ($ibx, $n) = mid_lookup($self, $1);
 511                         goto found if $ibx;
 512                         return r430;
 513                 } else {
 514                         return r501;
 515                 }
 516         } else {
 517                 $err = '420 no current article has been selected';
 518                 $n = $self->{article} // return $err;
 519 find_ibx:
 520                 $ibx = $self->{ibx} or
 521                                 return '412 no newsgroup has been selected';
 522         }
 523 found:
 524         my $smsg = $ibx->over->get_art($n) or return $err;
 525         $smsg->{-ibx} = $ibx;
 526         if ($code == 223) { # STAT
 527                 set_art($self, $n);
 528                 "223 $n <$smsg->{mid}> article retrieved - " .
 529                         "request text separately";
 530         } else { # HEAD | BODY | ARTICLE
 531                 $smsg->{nntp} = $self;
 532                 $smsg->{nntp_code} = $code;
 533                 set_art($self, $art);
 534                 # this dereferences to `undef'
 535                 ${git_async_cat($ibx->git, $smsg->{blob}, \&blob_cb, $smsg)};
 536         }
 537 }
 538
 539 sub msg_body_write ($$) {
 540         my ($self, $msg) = @_;
 541
 542         # these can momentarily double the memory consumption :<
 543         $$msg =~ s/^\./../smg;
 544         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 545         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 546         $self->msg_more($$msg);
 547 }
 548
 549 sub set_art {
 550         my ($self, $art) = @_;
 551         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 552 }
 553
 554 sub msg_hdr_write ($$) {
 555         my ($eml, $smsg) = @_;
 556         set_nntp_headers($eml, $smsg);
 557
 558         my $hdr = $eml->{hdr} // \(my $x = '');
 559         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 560         $$hdr =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 561         $$hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 562
 563         # for leafnode compatibility, we need to ensure Message-ID headers
 564         # are only a single line.
 565         $$hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 566         $smsg->{nntp}->msg_more($$hdr);
 567 }
 568
 569 sub blob_cb { # called by git->cat_async via git_async_cat
 570         my ($bref, $oid, $type, $size, $smsg) = @_;
 571         my $self = $smsg->{nntp};
 572         my $code = $smsg->{nntp_code};
 573         if (!defined($oid)) {
 574                 # it's possible to have TOCTOU if an admin runs
 575                 # public-inbox-(edit|purge), just move onto the next message
 576                 warn "E: $smsg->{blob} missing in $smsg->{-ibx}->{inboxdir}\n";
 577                 return $self->requeue;
 578         } elsif ($smsg->{blob} ne $oid) {
 579                 $self->close;
 580                 die "BUG: $smsg->{blob} != $oid";
 581         }
 582         my $r = "$code $smsg->{num} <$smsg->{mid}> article retrieved - ";
 583         my $eml = PublicInbox::Eml->new($bref);
 584         if ($code == 220) {
 585                 more($self, $r .= 'head and body follow');
 586                 msg_hdr_write($eml, $smsg);
 587                 $self->msg_more("\r\n");
 588                 msg_body_write($self, $bref);
 589         } elsif ($code == 221) {
 590                 more($self, $r .= 'head follows');
 591                 msg_hdr_write($eml, $smsg);
 592         } elsif ($code == 222) {
 593                 more($self, $r .= 'body follows');
 594                 msg_body_write($self, $bref);
 595         } else {
 596                 $self->close;
 597                 die "BUG: bad code: $r";
 598         }
 599         $self->write(\".\r\n"); # flushes (includes ->zflush)
 600         $self->requeue;
 601 }
 602
 603 sub cmd_article ($;$) {
 604         my ($self, $art) = @_;
 605         art_lookup($self, $art, 220);
 606 }
 607
 608 sub cmd_head ($;$) {
 609         my ($self, $art) = @_;
 610         art_lookup($self, $art, 221);
 611 }
 612
 613 sub cmd_body ($;$) {
 614         my ($self, $art) = @_;
 615         art_lookup($self, $art, 222);
 616 }
 617
 618 sub cmd_stat ($;$) {
 619         my ($self, $art) = @_;
 620         art_lookup($self, $art, 223); # art may be msgid
 621 }
 622
 623 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 624
 625 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 626
 627 sub cmd_help ($) {
 628         my ($self) = @_;
 629         more($self, '100 help text follows');
 630         '.'
 631 }
 632
 633 sub get_range ($$) {
 634         my ($self, $range) = @_;
 635         my $ibx = $self->{ibx} or return '412 no news group has been selected';
 636         defined $range or return '420 No article(s) selected';
 637         my ($beg, $end);
 638         my ($min, $max) = $ibx->mm->minmax;
 639         if ($range =~ /\A([0-9]+)\z/) {
 640                 $beg = $end = $1;
 641         } elsif ($range =~ /\A([0-9]+)-\z/) {
 642                 ($beg, $end) = ($1, $max);
 643         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 644                 ($beg, $end) = ($1, $2);
 645         } else {
 646                 return r501;
 647         }
 648         $beg = $min if ($beg < $min);
 649         $end = $max if ($end > $max);
 650         return '420 No article(s) selected' if ($beg > $end);
 651         [ \$beg, $end ];
 652 }
 653
 654 sub long_step {
 655         my ($self) = @_;
 656         # wbuf is unset or empty, here; {long} may add to it
 657         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
 658         my $more = eval { $cb->($self, @args) };
 659         if ($@ || !$self->{sock}) { # something bad happened...
 660                 delete $self->{long_cb};
 661                 my $elapsed = now() - $t0;
 662                 if ($@) {
 663                         err($self,
 664                             "%s during long response[$fd] - %0.6f",
 665                             $@, $elapsed);
 666                 }
 667                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 668                 $self->close;
 669         } elsif ($more) { # $self->{wbuf}:
 670                 $self->update_idle_time;
 671
 672                 # COMPRESS users all share the same DEFLATE context.
 673                 # Flush it here to ensure clients don't see
 674                 # each other's data
 675                 $self->zflush;
 676
 677                 # no recursion, schedule another call ASAP, but only after
 678                 # all pending writes are done.  autovivify wbuf:
 679                 my $new_size = push(@{$self->{wbuf}}, \&long_step);
 680
 681                 # wbuf may be populated by $cb, no need to rearm if so:
 682                 $self->requeue if $new_size == 1;
 683         } else { # all done!
 684                 delete $self->{long_cb};
 685                 res($self, '.');
 686                 my $elapsed = now() - $t0;
 687                 my $fd = fileno($self->{sock});
 688                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 689                 my $wbuf = $self->{wbuf}; # do NOT autovivify
 690                 $self->requeue unless $wbuf && @$wbuf;
 691         }
 692 }
 693
 694 sub long_response ($$;@) {
 695         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 696
 697         my $sock = $self->{sock} or return;
 698         # make sure we disable reading during a long response,
 699         # clients should not be sending us stuff and making us do more
 700         # work while we are stream a response to them
 701         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
 702         long_step($self); # kick off!
 703         undef;
 704 }
 705
 706 sub hdr_msgid_range_i {
 707         my ($self, $beg, $end) = @_;
 708         my $r = $self->{ibx}->mm->msg_range($beg, $end);
 709         @$r or return;
 710         $self->msg_more(join('', map { "$_->[0] <$_->[1]>\r\n" } @$r));
 711         1;
 712 }
 713
 714 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 715         my ($self, $xhdr, $range) = @_;
 716
 717         if (defined $range && $range =~ $ONE_MSGID) {
 718                 my ($ibx, $n) = mid_lookup($self, $1);
 719                 return r430 unless $n;
 720                 hdr_mid_response($self, $xhdr, $ibx, $n, $range, $range);
 721         } else { # numeric range
 722                 $range = $self->{article} unless defined $range;
 723                 my $r = get_range($self, $range);
 724                 return $r unless ref $r;
 725                 more($self, $xhdr ? r221 : r225);
 726                 long_response($self, \&hdr_msgid_range_i, @$r);
 727         }
 728 }
 729
 730 sub mid_lookup ($$) {
 731         my ($self, $mid) = @_;
 732         my $cur_ibx = $self->{ibx};
 733         if ($cur_ibx) {
 734                 my $n = $cur_ibx->mm->num_for($mid);
 735                 return ($cur_ibx, $n) if defined $n;
 736         }
 737         my $pi_cfg = $self->{nntpd}->{pi_cfg};
 738         if (my $ALL = $pi_cfg->ALL) {
 739                 my ($id, $prev);
 740                 while (my $smsg = $ALL->over->next_by_mid($mid, \$id, \$prev)) {
 741                         my $xr3 = $ALL->over->get_xref3($smsg->{num});
 742                         if (my @x = grep(/:$smsg->{blob}\z/, @$xr3)) {
 743                                 my ($ngname, $xnum) = split(/:/, $x[0]);
 744                                 my $ibx = $pi_cfg->{-by_newsgroup}->{$ngname};
 745                                 return ($ibx, $xnum) if $ibx;
 746                                 # fall through to trying all xref3s
 747                         } else {
 748                                 warn <<EOF;
 749 W: xref3 missing for <$mid> ($smsg->{blob}) in $ALL->{topdir}, -extindex bug?
 750 EOF
 751                         }
 752                         # try all xref3s
 753                         for my $x (@$xr3) {
 754                                 my ($ngname, $xnum) = split(/:/, $x);
 755                                 my $ibx = $pi_cfg->{-by_newsgroup}->{$ngname};
 756                                 return ($ibx, $xnum) if $ibx;
 757                                 warn "W: `$ngname' does not exist for #$xnum\n";
 758                         }
 759                 }
 760                 # no warning here, $mid is just invalid
 761         } else { # slow path for non-ALL users
 762                 for my $ibx (values %{$pi_cfg->{-by_newsgroup}}) {
 763                         next if defined $cur_ibx && $ibx eq $cur_ibx;
 764                         my $n = $ibx->mm->num_for($mid);
 765                         return ($ibx, $n) if defined $n;
 766                 }
 767         }
 768         (undef, undef);
 769 }
 770
 771 sub xref_range_i {
 772         my ($self, $beg, $end) = @_;
 773         my $ibx = $self->{ibx};
 774         my $msgs = $ibx->over->query_xover($$beg, $end);
 775         scalar(@$msgs) or return;
 776         $$beg = $msgs->[-1]->{num} + 1;
 777         $self->msg_more(join('', map {
 778                 "$_->{num} ".xref($self, $ibx, $_) . "\r\n";
 779         } @$msgs));
 780         1;
 781 }
 782
 783 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 784         my ($self, $xhdr, $range) = @_;
 785
 786         if (defined $range && $range =~ $ONE_MSGID) {
 787                 my $mid = $1;
 788                 my ($ibx, $n) = mid_lookup($self, $mid);
 789                 return r430 unless $n;
 790                 my $smsg = $ibx->over->get_art($n) or return;
 791                 hdr_mid_response($self, $xhdr, $ibx, $n, $range,
 792                                 xref($self, $ibx, $smsg));
 793         } else { # numeric range
 794                 $range = $self->{article} unless defined $range;
 795                 my $r = get_range($self, $range);
 796                 return $r unless ref $r;
 797                 more($self, $xhdr ? r221 : r225);
 798                 long_response($self, \&xref_range_i, @$r);
 799         }
 800 }
 801
 802 sub over_header_for {
 803         my ($over, $num, $field) = @_;
 804         my $smsg = $over->get_art($num) or return;
 805         return PublicInbox::Smsg::date($smsg) if $field eq 'date';
 806         $smsg->{$field};
 807 }
 808
 809 sub smsg_range_i {
 810         my ($self, $beg, $end, $field) = @_;
 811         my $over = $self->{ibx}->over;
 812         my $msgs = $over->query_xover($$beg, $end);
 813         scalar(@$msgs) or return;
 814         my $tmp = '';
 815
 816         # ->{$field} is faster than ->$field invocations, so favor that.
 817         if ($field eq 'date') {
 818                 for my $s (@$msgs) {
 819                         $tmp .= "$s->{num} ".PublicInbox::Smsg::date($s)."\r\n"
 820                 }
 821         } else {
 822                 for my $s (@$msgs) {
 823                         $tmp .= "$s->{num} $s->{$field}\r\n";
 824                 }
 825         }
 826         utf8::encode($tmp);
 827         $self->msg_more($tmp);
 828         $$beg = $msgs->[-1]->{num} + 1;
 829 }
 830
 831 sub hdr_smsg ($$$$) {
 832         my ($self, $xhdr, $field, $range) = @_;
 833         if (defined $range && $range =~ $ONE_MSGID) {
 834                 my ($ibx, $n) = mid_lookup($self, $1);
 835                 return r430 unless defined $n;
 836                 my $v = over_header_for($ibx->over, $n, $field);
 837                 hdr_mid_response($self, $xhdr, $ibx, $n, $range, $v);
 838         } else { # numeric range
 839                 $range = $self->{article} unless defined $range;
 840                 my $r = get_range($self, $range);
 841                 return $r unless ref $r;
 842                 more($self, $xhdr ? r221 : r225);
 843                 long_response($self, \&smsg_range_i, @$r, $field);
 844         }
 845 }
 846
 847 sub do_hdr ($$$;$) {
 848         my ($self, $xhdr, $header, $range) = @_;
 849         my $sub = lc $header;
 850         if ($sub eq 'message-id') {
 851                 hdr_message_id($self, $xhdr, $range);
 852         } elsif ($sub eq 'xref') {
 853                 hdr_xref($self, $xhdr, $range);
 854         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 855                                 bytes|lines)\z/x) {
 856                 hdr_smsg($self, $xhdr, $sub, $range);
 857         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 858                 hdr_smsg($self, $xhdr, $1, $range);
 859         } else {
 860                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 861         }
 862 }
 863
 864 # RFC 3977
 865 sub cmd_hdr ($$;$) {
 866         my ($self, $header, $range) = @_;
 867         do_hdr($self, 0, $header, $range);
 868 }
 869
 870 # RFC 2980
 871 sub cmd_xhdr ($$;$) {
 872         my ($self, $header, $range) = @_;
 873         do_hdr($self, 1, $header, $range);
 874 }
 875
 876 sub hdr_mid_prefix ($$$$$) {
 877         my ($self, $xhdr, $ibx, $n, $mid) = @_;
 878         return $mid if $xhdr;
 879
 880         # HDR for RFC 3977 users
 881         if (my $cur_ibx = $self->{ibx}) {
 882                 ($cur_ibx eq $ibx) ? $n : '0';
 883         } else {
 884                 '0';
 885         }
 886 }
 887
 888 sub hdr_mid_response ($$$$$$) {
 889         my ($self, $xhdr, $ibx, $n, $mid, $v) = @_;
 890         my $res = '';
 891         if ($xhdr) {
 892                 $res .= r221 . "\r\n";
 893                 $res .= "$mid $v\r\n";
 894         } else {
 895                 $res .= r225 . "\r\n";
 896                 my $pfx = hdr_mid_prefix($self, $xhdr, $ibx, $n, $mid);
 897                 $res .= "$pfx $v\r\n";
 898         }
 899         res($self, $res .= '.');
 900         undef;
 901 }
 902
 903 sub xrover_i {
 904         my ($self, $beg, $end) = @_;
 905         my $h = over_header_for($self->{ibx}->over, $$beg, 'references');
 906         more($self, "$$beg $h") if defined($h);
 907         $$beg++ < $end;
 908 }
 909
 910 sub cmd_xrover ($;$) {
 911         my ($self, $range) = @_;
 912         my $ibx = $self->{ibx} or return '412 no newsgroup selected';
 913         (defined $range && $range =~ /[<>]/) and
 914                 return '420 No article(s) selected'; # no message IDs
 915
 916         $range = $self->{article} unless defined $range;
 917         my $r = get_range($self, $range);
 918         return $r unless ref $r;
 919         more($self, '224 Overview information follows');
 920         long_response($self, \&xrover_i, @$r);
 921 }
 922
 923 sub over_line ($$$) {
 924         my ($self, $ibx, $smsg) = @_;
 925         # n.b. field access and procedural calls can be
 926         # 10%-15% faster than OO method calls:
 927         my $s = join("\t", $smsg->{num},
 928                 $smsg->{subject},
 929                 $smsg->{from},
 930                 PublicInbox::Smsg::date($smsg),
 931                 "<$smsg->{mid}>",
 932                 $smsg->{references},
 933                 $smsg->{bytes},
 934                 $smsg->{lines},
 935                 "Xref: " . xref($self, $ibx, $smsg));
 936         utf8::encode($s);
 937         $s .= "\r\n";
 938 }
 939
 940 sub cmd_over ($;$) {
 941         my ($self, $range) = @_;
 942         if ($range && $range =~ $ONE_MSGID) {
 943                 my ($ibx, $n) = mid_lookup($self, $1);
 944                 defined $n or return r430;
 945                 my $smsg = $ibx->over->get_art($n) or return r430;
 946                 more($self, '224 Overview information follows (multi-line)');
 947
 948                 # Only set article number column if it's the current group
 949                 # (RFC 3977 8.3.2)
 950                 my $cur_ibx = $self->{ibx};
 951                 if (!$cur_ibx || $cur_ibx ne $ibx) {
 952                         # set {-orig_num} for nntp_xref_for
 953                         $smsg->{-orig_num} = $smsg->{num};
 954                         $smsg->{num} = 0;
 955                 }
 956                 $self->msg_more(over_line($self, $ibx, $smsg));
 957                 '.';
 958         } else {
 959                 cmd_xover($self, $range);
 960         }
 961 }
 962
 963 sub xover_i {
 964         my ($self, $beg, $end) = @_;
 965         my $ibx = $self->{ibx};
 966         my $msgs = $ibx->over->query_xover($$beg, $end);
 967         my $nr = scalar @$msgs or return;
 968
 969         # OVERVIEW.FMT
 970         $self->msg_more(join('', map {
 971                 over_line($self, $ibx, $_);
 972                 } @$msgs));
 973         $$beg = $msgs->[-1]->{num} + 1;
 974 }
 975
 976 sub cmd_xover ($;$) {
 977         my ($self, $range) = @_;
 978         $range = $self->{article} unless defined $range;
 979         my $r = get_range($self, $range);
 980         return $r unless ref $r;
 981         my ($beg, $end) = @$r;
 982         more($self, "224 Overview information follows for $$beg to $end");
 983         long_response($self, \&xover_i, @$r);
 984 }
 985
 986 sub compressed { undef }
 987
 988 sub cmd_starttls ($) {
 989         my ($self) = @_;
 990         my $sock = $self->{sock} or return;
 991         # RFC 4642 2.2.1
 992         return r502 if ($sock->can('accept_SSL') || $self->compressed);
 993         my $opt = $self->{nntpd}->{accept_tls} or
 994                 return '580 can not initiate TLS negotiation';
 995         res($self, '382 Continue with TLS negotiation');
 996         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 997         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 998         undef;
 999 }
1000
1001 # RFC 8054
1002 sub cmd_compress ($$) {
1003         my ($self, $alg) = @_;
1004         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
1005         return r502 if $self->compressed;
1006         PublicInbox::NNTPdeflate->enable($self);
1007         $self->requeue;
1008         undef
1009 }
1010
1011 sub zflush {} # overridden by NNTPdeflate
1012
1013 sub cmd_xpath ($$) {
1014         my ($self, $mid) = @_;
1015         return r501 unless $mid =~ $ONE_MSGID;
1016         $mid = $1;
1017         my @paths;
1018         my $pi_cfg = $self->{nntpd}->{pi_cfg};
1019         my $groups = $pi_cfg->{-by_newsgroup};
1020         if (my $ALL = $pi_cfg->ALL) {
1021                 my ($id, $prev, %seen);
1022                 while (my $smsg = $ALL->over->next_by_mid($mid, \$id, \$prev)) {
1023                         my $xr3 = $ALL->over->get_xref3($smsg->{num});
1024                         for my $x (@$xr3) {
1025                                 my ($ngname, $n) = split(/:/, $x);
1026                                 $x = "$ngname/$n";
1027                                 if ($groups->{$ngname} && !$seen{$x}++) {
1028                                         push(@paths, $x);
1029                                 }
1030                         }
1031                 }
1032         } else { # slow path, no point in using long_response
1033                 for my $ibx (values %$groups) {
1034                         my $n = $ibx->mm->num_for($mid) // next;
1035                         push @paths, "$ibx->{newsgroup}/$n";
1036                 }
1037         }
1038         return '430 no such article on server' unless @paths;
1039         '223 '.join(' ', sort(@paths));
1040 }
1041
1042 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
1043
1044 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
1045
1046 sub do_write ($$) {
1047         my $self = $_[0];
1048         my $done = $self->write(\($_[1]));
1049         return 0 unless $self->{sock};
1050
1051         $done;
1052 }
1053
1054 sub err ($$;@) {
1055         my ($self, $fmt, @args) = @_;
1056         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
1057 }
1058
1059 sub out ($$;@) {
1060         my ($self, $fmt, @args) = @_;
1061         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
1062 }
1063
1064 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
1065 sub event_step {
1066         my ($self) = @_;
1067
1068         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
1069
1070         $self->update_idle_time;
1071         # only read more requests if we've drained the write buffer,
1072         # otherwise we can be buffering infinitely w/o backpressure
1073
1074         my $rbuf = $self->{rbuf} // \(my $x = '');
1075         my $line = index($$rbuf, "\n");
1076         while ($line < 0) {
1077                 return $self->close if length($$rbuf) >= LINE_MAX;
1078                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
1079                 $line = index($$rbuf, "\n");
1080         }
1081         $line = substr($$rbuf, 0, $line + 1, '');
1082         $line =~ s/\r?\n\z//s;
1083         return $self->close if $line =~ /[[:cntrl:]]/s;
1084
1085         my $t0 = now();
1086         my $fd = fileno($self->{sock});
1087         my $r = eval { process_line($self, $line) };
1088         my $pending = $self->{wbuf} ? ' pending' : '';
1089         out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
1090         return $self->close if $r < 0;
1091         $self->rbuf_idle($rbuf);
1092         $self->update_idle_time;
1093
1094         # maybe there's more pipelined data, or we'll have
1095         # to register it for socket-readiness notifications
1096         $self->requeue unless $pending;
1097 }
1098
1099 # for graceful shutdown in PublicInbox::Daemon:
1100 sub busy {
1101         my ($self, $now) = @_;
1102         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1103 }
1104
1105 1;