lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article ng);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 PublicInbox::DS->import(qw(now msg_more));
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26 };
  27 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  28 use Errno qw(EAGAIN);
  29
  30 my @OVERVIEW = qw(Subject From Date Message-ID References Xref);
  31 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  32 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  33                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  34
  35 # disable commands with easy DoS potential:
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $expt;
  40 our $EXPTIME = 180; # 3 minutes
  41
  42 sub update_idle_time ($) {
  43         my ($self) = @_;
  44         my $sock = $self->{sock} or return;
  45         $EXPMAP->{fileno($sock)} = [ now(), $self ];
  46 }
  47
  48 sub expire_old () {
  49         my $now = now();
  50         my $exp = $EXPTIME;
  51         my $old = $now - $exp;
  52         my $nr = 0;
  53         my %new;
  54         while (my ($fd, $v) = each %$EXPMAP) {
  55                 my ($idle_time, $nntp) = @$v;
  56                 if ($idle_time < $old) {
  57                         if (!$nntp->shutdn) {
  58                                 ++$nr;
  59                                 $new{$fd} = $v;
  60                         }
  61                 } else {
  62                         ++$nr;
  63                         $new{$fd} = $v;
  64                 }
  65         }
  66         $EXPMAP = \%new;
  67         $expt = PublicInbox::EvCleanup::later(*expire_old) if $nr;
  68 }
  69
  70 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  71
  72 sub new ($$$) {
  73         my ($class, $sock, $nntpd) = @_;
  74         my $self = fields::new($class);
  75         my $ev = EPOLLIN;
  76         my $wbuf;
  77         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  78                 return CORE::close($sock) if $! != EAGAIN;
  79                 $ev = PublicInbox::TLS::epollbit();
  80                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  81         }
  82         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  83         $self->{nntpd} = $nntpd;
  84         if ($wbuf) {
  85                 $self->{wbuf} = $wbuf;
  86         } else {
  87                 greet($self);
  88         }
  89         update_idle_time($self);
  90         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
  91         $self;
  92 }
  93
  94 sub args_ok ($$) {
  95         my ($cb, $argc) = @_;
  96         my $tot = prototype $cb;
  97         my ($nreq, undef) = split(';', $tot);
  98         $nreq = ($nreq =~ tr/$//) - 1;
  99         $tot = ($tot =~ tr/$//) - 1;
 100         ($argc <= $tot && $argc >= $nreq);
 101 }
 102
 103 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 104 sub process_line ($$) {
 105         my ($self, $l) = @_;
 106         my ($req, @args) = split(/[ \t]/, $l);
 107         return 1 unless defined($req); # skip blank line
 108         $req = lc($req);
 109         $req = eval {
 110                 no strict 'refs';
 111                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 112         };
 113         return res($self, '500 command not recognized') unless $req;
 114         return res($self, r501) unless args_ok($req, scalar @args);
 115
 116         my $res = eval { $req->($self, @args) };
 117         my $err = $@;
 118         if ($err && $self->{sock}) {
 119                 local $/ = "\n";
 120                 chomp($l);
 121                 err($self, 'error from: %s (%s)', $l, $err);
 122                 $res = '503 program fault - command not performed';
 123         }
 124         return 0 unless defined $res;
 125         res($self, $res);
 126 }
 127
 128 sub cmd_mode ($$) {
 129         my ($self, $arg) = @_;
 130         $arg = uc $arg;
 131         return r501 unless $arg eq 'READER';
 132         '201 Posting prohibited';
 133 }
 134
 135 sub cmd_slave ($) { '202 slave status noted' }
 136
 137 sub cmd_xgtitle ($;$) {
 138         my ($self, $wildmat) = @_;
 139         more($self, '282 list of groups and descriptions follows');
 140         list_newsgroups($self, $wildmat);
 141         '.'
 142 }
 143
 144 sub list_overview_fmt ($) {
 145         my ($self) = @_;
 146         msg_more($self, $OVERVIEW_FMT);
 147 }
 148
 149 sub list_headers ($;$) {
 150         my ($self) = @_;
 151         msg_more($self, $LIST_HEADERS);
 152 }
 153
 154 sub list_active ($;$) {
 155         my ($self, $wildmat) = @_;
 156         wildmat2re($wildmat);
 157         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 158                 $ng->{newsgroup} =~ $wildmat or next;
 159                 group_line($self, $ng);
 160         }
 161 }
 162
 163 sub list_active_times ($;$) {
 164         my ($self, $wildmat) = @_;
 165         wildmat2re($wildmat);
 166         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 167                 $ng->{newsgroup} =~ $wildmat or next;
 168                 my $c = eval { $ng->mm->created_at } || time;
 169                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 170         }
 171 }
 172
 173 sub list_newsgroups ($;$) {
 174         my ($self, $wildmat) = @_;
 175         wildmat2re($wildmat);
 176         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 177                 $ng->{newsgroup} =~ $wildmat or next;
 178                 my $d = $ng->description;
 179                 more($self, "$ng->{newsgroup} $d");
 180         }
 181 }
 182
 183 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 184 sub cmd_list ($;$$) {
 185         my ($self, @args) = @_;
 186         if (scalar @args) {
 187                 my $arg = shift @args;
 188                 $arg =~ tr/A-Z./a-z_/;
 189                 $arg = "list_$arg";
 190                 return r501 if $DISABLED{$arg};
 191
 192                 $arg = eval {
 193                         no strict 'refs';
 194                         *{$arg}{CODE};
 195                 };
 196                 return r501 unless $arg && args_ok($arg, scalar @args);
 197                 more($self, '215 information follows');
 198                 $arg->($self, @args);
 199         } else {
 200                 more($self, '215 list of newsgroups follows');
 201                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 202                         group_line($self, $ng);
 203                 }
 204         }
 205         '.'
 206 }
 207
 208 sub cmd_listgroup ($;$) {
 209         my ($self, $group) = @_;
 210         if (defined $group) {
 211                 my $res = cmd_group($self, $group);
 212                 return $res if ($res !~ /\A211 /);
 213                 more($self, $res);
 214         }
 215
 216         $self->{ng} or return '412 no newsgroup selected';
 217         my $n = 0;
 218         long_response($self, sub {
 219                 my $ary = $self->{ng}->mm->ids_after(\$n);
 220                 scalar @$ary or return;
 221                 more($self, join("\r\n", @$ary));
 222                 1;
 223         });
 224 }
 225
 226 sub parse_time ($$;$) {
 227         my ($date, $time, $gmt) = @_;
 228         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 229         if (defined $gmt) {
 230                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 231                 $gmt = 1;
 232         }
 233         my @now = $gmt ? gmtime : localtime;
 234         my ($YYYY, $MM, $DD);
 235         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 236                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 237         } else { # legacy clients send YYMMDD
 238                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 239                 my $cur_year = $now[5] + 1900;
 240                 if ($YYYY > $cur_year) {
 241                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 242                 }
 243         }
 244         if ($gmt) {
 245                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 246         } else {
 247                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 248         }
 249 }
 250
 251 sub group_line ($$) {
 252         my ($self, $ng) = @_;
 253         my ($min, $max) = $ng->mm->minmax;
 254         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 255 }
 256
 257 sub cmd_newgroups ($$$;$$) {
 258         my ($self, $date, $time, $gmt, $dists) = @_;
 259         my $ts = eval { parse_time($date, $time, $gmt) };
 260         return r501 if $@;
 261
 262         # TODO dists
 263         more($self, '231 list of new newsgroups follows');
 264         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 265                 my $c = eval { $ng->mm->created_at } || 0;
 266                 next unless $c > $ts;
 267                 group_line($self, $ng);
 268         }
 269         '.'
 270 }
 271
 272 sub wildmat2re (;$) {
 273         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 274         my %keep;
 275         my $salt = rand;
 276         my $tmp = $_[0];
 277
 278         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 279                 my $orig = $1;
 280                 my $key = sha1_hex($orig . $salt);
 281                 $orig =~ s/([^\w\-])+/\Q$1/g;
 282                 $keep{$key} = $orig;
 283                 $key
 284                 #gex;
 285         my %map = ('*' => '.*', '?' => '.' );
 286         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 287         if (scalar %keep) {
 288                 $tmp =~ s#([a-f0-9]{40})#
 289                         my $orig = $keep{$1};
 290                         defined $orig ? $orig : $1;
 291                         #ge;
 292         }
 293         $_[0] = qr/\A$tmp\z/;
 294 }
 295
 296 sub ngpat2re (;$) {
 297         return $_[0] = qr/\A\z/ unless defined $_[0];
 298         my %map = ('*' => '.*', ',' => '|');
 299         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 300         $_[0] = qr/\A(?:$_[0])\z/;
 301 }
 302
 303 sub cmd_newnews ($$$$;$$) {
 304         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 305         my $ts = eval { parse_time($date, $time, $gmt) };
 306         return r501 if $@;
 307         more($self, '230 list of new articles by message-id follows');
 308         my ($keep, $skip) = split('!', $newsgroups, 2);
 309         ngpat2re($keep);
 310         ngpat2re($skip);
 311         my @over;
 312         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 313                 $ng->{newsgroup} =~ $keep or next;
 314                 $ng->{newsgroup} =~ $skip and next;
 315                 my $over = $ng->over or next;
 316                 push @over, $over;
 317         };
 318         return '.' unless @over;
 319
 320         my $prev = 0;
 321         long_response($self, sub {
 322                 my $over = $over[0];
 323                 my $msgs = $over->query_ts($ts, $prev);
 324                 if (scalar @$msgs) {
 325                         more($self, '<' .
 326                                 join(">\r\n<", map { $_->mid } @$msgs ).
 327                                 '>');
 328                         $prev = $msgs->[-1]->{num};
 329                 } else {
 330                         shift @over;
 331                         if (@over) { # continue onto next newsgroup
 332                                 $prev = 0;
 333                                 return 1;
 334                         } else { # break out of the long response.
 335                                 return;
 336                         }
 337                 }
 338         });
 339 }
 340
 341 sub cmd_group ($$) {
 342         my ($self, $group) = @_;
 343         my $no_such = '411 no such news group';
 344         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 345
 346         $self->{ng} = $ng;
 347         my ($min, $max) = $ng->mm->minmax;
 348         $min ||= 0;
 349         $max ||= 0;
 350         $self->{article} = $min;
 351         my $est_size = $max - $min;
 352         "211 $est_size $min $max $group";
 353 }
 354
 355 sub article_adj ($$) {
 356         my ($self, $off) = @_;
 357         my $ng = $self->{ng} or return '412 no newsgroup selected';
 358
 359         my $n = $self->{article};
 360         defined $n or return '420 no current article has been selected';
 361
 362         $n += $off;
 363         my $mid = $ng->mm->mid_for($n);
 364         unless ($mid) {
 365                 $n = $off > 0 ? 'next' : 'previous';
 366                 return "421 no $n article in this group";
 367         }
 368         $self->{article} = $n;
 369         "223 $n <$mid> article retrieved - request text separately";
 370 }
 371
 372 sub cmd_next ($) { article_adj($_[0], 1) }
 373 sub cmd_last ($) { article_adj($_[0], -1) }
 374
 375 # We want to encourage using email and CC-ing everybody involved to avoid
 376 # the single-point-of-failure a single server provides.
 377 sub cmd_post ($) {
 378         my ($self) = @_;
 379         my $ng = $self->{ng};
 380         $ng ? "440 mailto:$ng->{-primary_address} to post"
 381                 : '440 posting not allowed'
 382 }
 383
 384 sub cmd_quit ($) {
 385         my ($self) = @_;
 386         res($self, '205 closing connection - goodbye!');
 387         $self->shutdn;
 388         undef;
 389 }
 390
 391 sub header_append ($$$) {
 392         my ($hdr, $k, $v) = @_;
 393         my @v = $hdr->header($k);
 394         foreach (@v) {
 395                 return if $v eq $_;
 396         }
 397         $hdr->header_set($k, @v, $v);
 398 }
 399
 400 sub xref ($$$$) {
 401         my ($self, $ng, $n, $mid) = @_;
 402         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 403
 404         # num_for is pretty cheap and sometimes we'll lookup the existence
 405         # of an article without getting even the OVER info.  In other words,
 406         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 407         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 408         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 409                 next if $ng eq $other;
 410                 my $num = eval { $other->mm->num_for($mid) } or next;
 411                 $ret .= " $other->{newsgroup}:$num";
 412         }
 413         $ret;
 414 }
 415
 416 sub set_nntp_headers ($$$$$) {
 417         my ($self, $hdr, $ng, $n, $mid) = @_;
 418
 419         # why? leafnode requires a Path: header for some inexplicable
 420         # reason.  We'll fake the shortest one possible.
 421         $hdr->header_set('Path', 'y');
 422
 423         # leafnode (and maybe other NNTP clients) have trouble dealing
 424         # with v2 messages which have multiple Message-IDs (either due
 425         # to our own content-based dedupe or buggy git-send-email versions).
 426         my @mids = $hdr->header('Message-ID');
 427         if (scalar(@mids) > 1) {
 428                 my $mid0 = "<$mid>";
 429                 $hdr->header_set('Message-ID', $mid0);
 430                 my @alt = $hdr->header('X-Alt-Message-ID');
 431                 my %seen = map { $_ => 1 } (@alt, $mid0);
 432                 foreach my $m (@mids) {
 433                         next if $seen{$m}++;
 434                         push @alt, $m;
 435                 }
 436                 $hdr->header_set('X-Alt-Message-ID', @alt);
 437         }
 438
 439         # clobber some
 440         my $xref = xref($self, $ng, $n, $mid);
 441         $hdr->header_set('Xref', $xref);
 442         $xref =~ s/:[0-9]+//g;
 443         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 444         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 445         if (my $url = $ng->base_url) {
 446                 $mid = mid_escape($mid);
 447                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 448                 header_append($hdr, 'List-Archive', "<$url>");
 449         }
 450 }
 451
 452 sub art_lookup ($$$) {
 453         my ($self, $art, $set_headers) = @_;
 454         my $ng = $self->{ng};
 455         my ($n, $mid);
 456         my $err;
 457         if (defined $art) {
 458                 if ($art =~ /\A[0-9]+\z/) {
 459                         $err = '423 no such article number in this group';
 460                         $n = int($art);
 461                         goto find_mid;
 462                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 463                         $mid = $1;
 464                         $err = r430;
 465                         $n = $ng->mm->num_for($mid) if $ng;
 466                         goto found if defined $n;
 467                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 468                                 $n = $g->mm->num_for($mid);
 469                                 if (defined $n) {
 470                                         $ng = $g;
 471                                         goto found;
 472                                 }
 473                         }
 474                         return $err;
 475                 } else {
 476                         return r501;
 477                 }
 478         } else {
 479                 $err = '420 no current article has been selected';
 480                 $n = $self->{article};
 481                 defined $n or return $err;
 482 find_mid:
 483                 $ng or return '412 no newsgroup has been selected';
 484                 $mid = $ng->mm->mid_for($n);
 485                 defined $mid or return $err;
 486         }
 487 found:
 488         my $smsg = $ng->over->get_art($n) or return $err;
 489         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 490         my $s = Email::Simple->new($msg);
 491         if ($set_headers) {
 492                 set_nntp_headers($self, $s->header_obj, $ng, $n, $mid);
 493
 494                 # must be last
 495                 $s->body_set('') if ($set_headers == 2);
 496         }
 497         [ $n, $mid, $s, $smsg->bytes, $smsg->lines, $ng ];
 498 }
 499
 500 sub simple_body_write ($$) {
 501         my ($self, $s) = @_;
 502         my $body = $s->body;
 503         $s->body_set('');
 504         $body =~ s/^\./../smg;
 505         $body =~ s/(?<!\r)\n/\r\n/sg;
 506         msg_more($self, $body);
 507         msg_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 508         '.'
 509 }
 510
 511 sub set_art {
 512         my ($self, $art) = @_;
 513         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 514 }
 515
 516 sub _header ($) {
 517         my $hdr = $_[0]->header_obj->as_string;
 518         utf8::encode($hdr);
 519         $hdr =~ s/(?<!\r)\n/\r\n/sg;
 520
 521         # for leafnode compatibility, we need to ensure Message-ID headers
 522         # are only a single line.  We can't subclass Email::Simple::Header
 523         # and override _default_fold_at in here, either; since that won't
 524         # affect messages already in the archive.
 525         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 526
 527         $hdr
 528 }
 529
 530 sub cmd_article ($;$) {
 531         my ($self, $art) = @_;
 532         my $r = art_lookup($self, $art, 1);
 533         return $r unless ref $r;
 534         my ($n, $mid, $s) = @$r;
 535         set_art($self, $art);
 536         more($self, "220 $n <$mid> article retrieved - head and body follow");
 537         msg_more($self, _header($s));
 538         msg_more($self, "\r\n");
 539         simple_body_write($self, $s);
 540 }
 541
 542 sub cmd_head ($;$) {
 543         my ($self, $art) = @_;
 544         my $r = art_lookup($self, $art, 2);
 545         return $r unless ref $r;
 546         my ($n, $mid, $s) = @$r;
 547         set_art($self, $art);
 548         more($self, "221 $n <$mid> article retrieved - head follows");
 549         msg_more($self, _header($s));
 550         '.'
 551 }
 552
 553 sub cmd_body ($;$) {
 554         my ($self, $art) = @_;
 555         my $r = art_lookup($self, $art, 0);
 556         return $r unless ref $r;
 557         my ($n, $mid, $s) = @$r;
 558         set_art($self, $art);
 559         more($self, "222 $n <$mid> article retrieved - body follows");
 560         simple_body_write($self, $s);
 561 }
 562
 563 sub cmd_stat ($;$) {
 564         my ($self, $art) = @_;
 565         my $r = art_lookup($self, $art, 0);
 566         return $r unless ref $r;
 567         my ($n, $mid, undef) = @$r;
 568         set_art($self, $art);
 569         "223 $n <$mid> article retrieved - request text separately";
 570 }
 571
 572 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 573
 574 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 575
 576 sub cmd_help ($) {
 577         my ($self) = @_;
 578         more($self, '100 help text follows');
 579         '.'
 580 }
 581
 582 sub get_range ($$) {
 583         my ($self, $range) = @_;
 584         my $ng = $self->{ng} or return '412 no news group has been selected';
 585         defined $range or return '420 No article(s) selected';
 586         my ($beg, $end);
 587         my ($min, $max) = $ng->mm->minmax;
 588         if ($range =~ /\A([0-9]+)\z/) {
 589                 $beg = $end = $1;
 590         } elsif ($range =~ /\A([0-9]+)-\z/) {
 591                 ($beg, $end) = ($1, $max);
 592         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 593                 ($beg, $end) = ($1, $2);
 594         } else {
 595                 return r501;
 596         }
 597         $beg = $min if ($beg < $min);
 598         $end = $max if ($end > $max);
 599         return '420 No article(s) selected' if ($beg > $end);
 600         [ $beg, $end ];
 601 }
 602
 603 sub long_response ($$) {
 604         my ($self, $cb) = @_; # cb returns true if more, false if done
 605
 606         my $fd = fileno($self->{sock});
 607         defined $fd or return;
 608         # make sure we disable reading during a long response,
 609         # clients should not be sending us stuff and making us do more
 610         # work while we are stream a response to them
 611         my $t0 = now();
 612         my $long_cb; # DANGER: self-referential
 613         $long_cb = sub {
 614                 # wbuf is unset or empty, here; $cb may add to it
 615                 my $more = eval { $cb->() };
 616                 if ($@ || !$self->{sock}) { # something bad happened...
 617                         $long_cb = undef;
 618                         my $diff = now() - $t0;
 619                         if ($@) {
 620                                 err($self,
 621                                     "%s during long response[$fd] - %0.6f",
 622                                     $@, $diff);
 623                         }
 624                         out($self, " deferred[$fd] aborted - %0.6f", $diff);
 625                         $self->close;
 626                 } elsif ($more) { # $self->{wbuf}:
 627                         update_idle_time($self);
 628
 629                         # no recursion, schedule another call ASAP
 630                         # but only after all pending writes are done
 631                         my $wbuf = $self->{wbuf} ||= [];
 632                         push @$wbuf, $long_cb;
 633
 634                         # wbuf may be populated by $cb, no need to rearm if so:
 635                         $self->requeue if scalar(@$wbuf) == 1;
 636                 } else { # all done!
 637                         $long_cb = undef;
 638                         res($self, '.');
 639                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 640                         $self->requeue unless $self->{wbuf};
 641                 }
 642         };
 643         $self->write($long_cb); # kick off!
 644         undef;
 645 }
 646
 647 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 648         my ($self, $xhdr, $range) = @_;
 649
 650         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 651                 my ($ng, $n) = mid_lookup($self, $1);
 652                 return r430 unless $n;
 653                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 654         } else { # numeric range
 655                 $range = $self->{article} unless defined $range;
 656                 my $r = get_range($self, $range);
 657                 return $r unless ref $r;
 658                 my $mm = $self->{ng}->mm;
 659                 my ($beg, $end) = @$r;
 660                 more($self, $xhdr ? r221 : r225);
 661                 long_response($self, sub {
 662                         my $r = $mm->msg_range(\$beg, $end);
 663                         @$r or return;
 664                         more($self, join("\r\n", map {
 665                                 "$_->[0] <$_->[1]>"
 666                         } @$r));
 667                         1;
 668                 });
 669         }
 670 }
 671
 672 sub mid_lookup ($$) {
 673         my ($self, $mid) = @_;
 674         my $self_ng = $self->{ng};
 675         if ($self_ng) {
 676                 my $n = $self_ng->mm->num_for($mid);
 677                 return ($self_ng, $n) if defined $n;
 678         }
 679         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 680                 next if defined $self_ng && $ng eq $self_ng;
 681                 my $n = $ng->mm->num_for($mid);
 682                 return ($ng, $n) if defined $n;
 683         }
 684         (undef, undef);
 685 }
 686
 687 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 688         my ($self, $xhdr, $range) = @_;
 689
 690         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 691                 my $mid = $1;
 692                 my ($ng, $n) = mid_lookup($self, $mid);
 693                 return r430 unless $n;
 694                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 695                                 xref($self, $ng, $n, $mid));
 696         } else { # numeric range
 697                 $range = $self->{article} unless defined $range;
 698                 my $r = get_range($self, $range);
 699                 return $r unless ref $r;
 700                 my $ng = $self->{ng};
 701                 my $mm = $ng->mm;
 702                 my ($beg, $end) = @$r;
 703                 more($self, $xhdr ? r221 : r225);
 704                 long_response($self, sub {
 705                         my $r = $mm->msg_range(\$beg, $end);
 706                         @$r or return;
 707                         more($self, join("\r\n", map {
 708                                 my $num = $_->[0];
 709                                 "$num ".xref($self, $ng, $num, $_->[1]);
 710                         } @$r));
 711                         1;
 712                 });
 713         }
 714 }
 715
 716 sub over_header_for {
 717         my ($over, $num, $field) = @_;
 718         my $smsg = $over->get_art($num) or return;
 719         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 720         $smsg->{$field};
 721 }
 722
 723 sub hdr_searchmsg ($$$$) {
 724         my ($self, $xhdr, $field, $range) = @_;
 725         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 726                 my ($ng, $n) = mid_lookup($self, $1);
 727                 return r430 unless defined $n;
 728                 my $v = over_header_for($ng->over, $n, $field);
 729                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 730         } else { # numeric range
 731                 $range = $self->{article} unless defined $range;
 732                 my $over = $self->{ng}->over;
 733                 my $mm = $self->{ng}->mm;
 734                 my $r = get_range($self, $range);
 735                 return $r unless ref $r;
 736                 my ($beg, $end) = @$r;
 737                 more($self, $xhdr ? r221 : r225);
 738                 my $cur = $beg;
 739                 long_response($self, sub {
 740                         my $msgs = $over->query_xover($cur, $end);
 741                         my $nr = scalar @$msgs or return;
 742                         my $tmp = '';
 743                         foreach my $s (@$msgs) {
 744                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 745                         }
 746                         utf8::encode($tmp);
 747                         msg_more($self, $tmp);
 748                         $cur = $msgs->[-1]->{num} + 1;
 749                 });
 750         }
 751 }
 752
 753 sub do_hdr ($$$;$) {
 754         my ($self, $xhdr, $header, $range) = @_;
 755         my $sub = lc $header;
 756         if ($sub eq 'message-id') {
 757                 hdr_message_id($self, $xhdr, $range);
 758         } elsif ($sub eq 'xref') {
 759                 hdr_xref($self, $xhdr, $range);
 760         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 761                                 bytes|lines)\z/x) {
 762                 hdr_searchmsg($self, $xhdr, $sub, $range);
 763         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 764                 hdr_searchmsg($self, $xhdr, $1, $range);
 765         } else {
 766                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 767         }
 768 }
 769
 770 # RFC 3977
 771 sub cmd_hdr ($$;$) {
 772         my ($self, $header, $range) = @_;
 773         do_hdr($self, 0, $header, $range);
 774 }
 775
 776 # RFC 2980
 777 sub cmd_xhdr ($$;$) {
 778         my ($self, $header, $range) = @_;
 779         do_hdr($self, 1, $header, $range);
 780 }
 781
 782 sub hdr_mid_prefix ($$$$$) {
 783         my ($self, $xhdr, $ng, $n, $mid) = @_;
 784         return $mid if $xhdr;
 785
 786         # HDR for RFC 3977 users
 787         if (my $self_ng = $self->{ng}) {
 788                 ($self_ng eq $ng) ? $n : '0';
 789         } else {
 790                 '0';
 791         }
 792 }
 793
 794 sub hdr_mid_response ($$$$$$) {
 795         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 796         my $res = '';
 797         if ($xhdr) {
 798                 $res .= r221 . "\r\n";
 799                 $res .= "$mid $v\r\n";
 800         } else {
 801                 $res .= r225 . "\r\n";
 802                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 803                 $res .= "$pfx $v\r\n";
 804         }
 805         res($self, $res .= '.');
 806         undef;
 807 }
 808
 809 sub cmd_xrover ($;$) {
 810         my ($self, $range) = @_;
 811         my $ng = $self->{ng} or return '412 no newsgroup selected';
 812         (defined $range && $range =~ /[<>]/) and
 813                 return '420 No article(s) selected'; # no message IDs
 814
 815         $range = $self->{article} unless defined $range;
 816         my $r = get_range($self, $range);
 817         return $r unless ref $r;
 818         my ($beg, $end) = @$r;
 819         my $mm = $ng->mm;
 820         my $over = $ng->over;
 821         more($self, '224 Overview information follows');
 822
 823         long_response($self, sub {
 824                 my $h = over_header_for($over, $beg, 'references');
 825                 more($self, "$beg $h") if defined($h);
 826                 $beg++ < $end;
 827         });
 828 }
 829
 830 sub over_line ($$$$) {
 831         my ($self, $ng, $num, $smsg) = @_;
 832         # n.b. field access and procedural calls can be
 833         # 10%-15% faster than OO method calls:
 834         my $s = join("\t", $num,
 835                 $smsg->{subject},
 836                 $smsg->{from},
 837                 PublicInbox::SearchMsg::date($smsg),
 838                 "<$smsg->{mid}>",
 839                 $smsg->{references},
 840                 $smsg->{bytes},
 841                 $smsg->{lines},
 842                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 843         utf8::encode($s);
 844         $s
 845 }
 846
 847 sub cmd_over ($;$) {
 848         my ($self, $range) = @_;
 849         if ($range && $range =~ /\A<(.+)>\z/) {
 850                 my ($ng, $n) = mid_lookup($self, $1);
 851                 defined $n or return r430;
 852                 my $smsg = $ng->over->get_art($n) or return r430;
 853                 more($self, '224 Overview information follows (multi-line)');
 854
 855                 # Only set article number column if it's the current group
 856                 my $self_ng = $self->{ng};
 857                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 858                 more($self, over_line($self, $ng, $n, $smsg));
 859                 '.';
 860         } else {
 861                 cmd_xover($self, $range);
 862         }
 863 }
 864
 865 sub cmd_xover ($;$) {
 866         my ($self, $range) = @_;
 867         $range = $self->{article} unless defined $range;
 868         my $r = get_range($self, $range);
 869         return $r unless ref $r;
 870         my ($beg, $end) = @$r;
 871         more($self, "224 Overview information follows for $beg to $end");
 872         my $over = $self->{ng}->over;
 873         my $cur = $beg;
 874         long_response($self, sub {
 875                 my $msgs = $over->query_xover($cur, $end);
 876                 my $nr = scalar @$msgs or return;
 877
 878                 # OVERVIEW.FMT
 879                 more($self, join("\r\n", map {
 880                         over_line($self, $self->{ng}, $_->{num}, $_);
 881                         } @$msgs));
 882                 $cur = $msgs->[-1]->{num} + 1;
 883         });
 884 }
 885
 886 sub cmd_starttls ($) {
 887         my ($self) = @_;
 888         my $sock = $self->{sock} or return;
 889         # RFC 4642 2.2.1
 890         (ref($sock) eq 'IO::Socket::SSL') and return '502 Command unavailable';
 891         my $opt = $self->{nntpd}->{accept_tls} or
 892                 return '580 can not initiate TLS negotiation';
 893         res($self, '382 Continue with TLS negotiation');
 894         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 895         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 896         undef;
 897 }
 898
 899 sub cmd_xpath ($$) {
 900         my ($self, $mid) = @_;
 901         return r501 unless $mid =~ /\A<(.+)>\z/;
 902         $mid = $1;
 903         my @paths;
 904         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 905                 my $n = $ng->mm->num_for($mid);
 906                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 907         }
 908         return '430 no such article on server' unless @paths;
 909         '223 '.join(' ', @paths);
 910 }
 911
 912 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 913
 914 sub more ($$) { msg_more($_[0], $_[1] . "\r\n") }
 915
 916 sub do_write ($$) {
 917         my $self = $_[0];
 918         my $done = $self->write(\($_[1]));
 919         return 0 unless $self->{sock};
 920
 921         $done;
 922 }
 923
 924 sub err ($$;@) {
 925         my ($self, $fmt, @args) = @_;
 926         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 927 }
 928
 929 sub out ($$;@) {
 930         my ($self, $fmt, @args) = @_;
 931         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 932 }
 933
 934 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 935 sub event_step {
 936         my ($self) = @_;
 937
 938         return unless $self->flush_write && $self->{sock};
 939
 940         update_idle_time($self);
 941         # only read more requests if we've drained the write buffer,
 942         # otherwise we can be buffering infinitely w/o backpressure
 943
 944         use constant LINE_MAX => 512; # RFC 977 section 2.3
 945         my $rbuf = $self->{rbuf} // (\(my $x = ''));
 946         my $r = 1;
 947
 948         if (index($$rbuf, "\n") < 0) {
 949                 my $off = bytes::length($$rbuf);
 950                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 951         }
 952         while ($r > 0 && $$rbuf =~ s/\A[ \t\r\n]*([^\r\n]*)\r?\n//) {
 953                 my $line = $1;
 954                 return $self->close if $line =~ /[[:cntrl:]]/s;
 955                 my $t0 = now();
 956                 my $fd = fileno($self->{sock});
 957                 $r = eval { process_line($self, $line) };
 958                 my $pending = $self->{wbuf} ? ' pending' : '';
 959                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
 960         }
 961
 962         return $self->close if $r < 0;
 963         my $len = bytes::length($$rbuf);
 964         return $self->close if ($len >= LINE_MAX);
 965         $self->rbuf_idle($rbuf);
 966         update_idle_time($self);
 967
 968         # maybe there's more pipelined data, or we'll have
 969         # to register it for socket-readiness notifications
 970         $self->requeue unless $self->{wbuf};
 971 }
 972
 973 sub not_idle_long ($$) {
 974         my ($self, $now) = @_;
 975         my $sock = $self->{sock} or return;
 976         my $ary = $EXPMAP->{fileno($sock)} or return;
 977         my $exp_at = $ary->[0] + $EXPTIME;
 978         $exp_at > $now;
 979 }
 980
 981 # for graceful shutdown in PublicInbox::Daemon:
 982 sub busy {
 983         my ($self, $now) = @_;
 984         ($self->{rbuf} || $self->{wbuf} || not_idle_long($self, $now));
 985 }
 986
 987 1;