lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article ng);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 use Email::Simple;
  15 use POSIX qw(strftime);
  16 use PublicInbox::DS qw(now);
  17 use Digest::SHA qw(sha1_hex);
  18 use Time::Local qw(timegm timelocal);
  19 use constant {
  20         LINE_MAX => 512, # RFC 977 section 2.3
  21         r501 => '501 command syntax error',
  22         r502 => '502 Command unavailable',
  23         r221 => '221 Header follows',
  24         r224 => '224 Overview information follows (multi-line)',
  25         r225 => '225 Headers follow (multi-line)',
  26         r430 => '430 No article with that message-id',
  27 };
  28 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  29 use Errno qw(EAGAIN);
  30
  31 my @OVERVIEW = qw(Subject From Date Message-ID References);
  32 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  33                 "Xref:full\r\n";
  34 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  35                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  36 my $CAPABILITIES = <<"";
  37 101 Capability list:\r
  38 VERSION 2\r
  39 READER\r
  40 NEWNEWS\r
  41 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  42 HDR\r
  43 OVER\r
  44
  45 my $have_deflate;
  46
  47 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  48
  49 sub new ($$$) {
  50         my ($class, $sock, $nntpd) = @_;
  51         my $self = fields::new($class);
  52         my $ev = EPOLLIN;
  53         my $wbuf;
  54         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  55                 return CORE::close($sock) if $! != EAGAIN;
  56                 $ev = PublicInbox::TLS::epollbit();
  57                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  58         }
  59         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  60         $self->{nntpd} = $nntpd;
  61         if ($wbuf) {
  62                 $self->{wbuf} = $wbuf;
  63         } else {
  64                 greet($self);
  65         }
  66         $self->update_idle_time;
  67         $self;
  68 }
  69
  70 sub args_ok ($$) {
  71         my ($cb, $argc) = @_;
  72         my $tot = prototype $cb;
  73         my ($nreq, undef) = split(';', $tot);
  74         $nreq = ($nreq =~ tr/$//) - 1;
  75         $tot = ($tot =~ tr/$//) - 1;
  76         ($argc <= $tot && $argc >= $nreq);
  77 }
  78
  79 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  80 sub process_line ($$) {
  81         my ($self, $l) = @_;
  82         my ($req, @args) = split(/[ \t]/, $l);
  83         return 1 unless defined($req); # skip blank line
  84         $req = eval {
  85                 no strict 'refs';
  86                 *{'cmd_'.lc($req)}{CODE};
  87         };
  88         return res($self, '500 command not recognized') unless $req;
  89         return res($self, r501) unless args_ok($req, scalar @args);
  90
  91         my $res = eval { $req->($self, @args) };
  92         my $err = $@;
  93         if ($err && $self->{sock}) {
  94                 local $/ = "\n";
  95                 chomp($l);
  96                 err($self, 'error from: %s (%s)', $l, $err);
  97                 $res = '503 program fault - command not performed';
  98         }
  99         return 0 unless defined $res;
 100         res($self, $res);
 101 }
 102
 103 # The keyword argument is not used (rfc3977 5.2.2)
 104 sub cmd_capabilities ($;$) {
 105         my ($self, undef) = @_;
 106         my $res = $CAPABILITIES;
 107         if (ref($self->{sock}) ne 'IO::Socket::SSL' &&
 108                         $self->{nntpd}->{accept_tls}) {
 109                 $res .= "STARTTLS\r\n";
 110         }
 111         $res .= '.';
 112 }
 113
 114 sub cmd_mode ($$) {
 115         my ($self, $arg) = @_;
 116         $arg = uc $arg;
 117         return r501 unless $arg eq 'READER';
 118         '201 Posting prohibited';
 119 }
 120
 121 sub cmd_slave ($) { '202 slave status noted' }
 122
 123 sub cmd_xgtitle ($;$) {
 124         my ($self, $wildmat) = @_;
 125         more($self, '282 list of groups and descriptions follows');
 126         list_newsgroups($self, $wildmat);
 127         '.'
 128 }
 129
 130 sub list_overview_fmt ($) {
 131         my ($self) = @_;
 132         $self->msg_more($OVERVIEW_FMT);
 133 }
 134
 135 sub list_headers ($;$) {
 136         my ($self) = @_;
 137         $self->msg_more($LIST_HEADERS);
 138 }
 139
 140 sub list_active ($;$) {
 141         my ($self, $wildmat) = @_;
 142         wildmat2re($wildmat);
 143         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 144                 $ng->{newsgroup} =~ $wildmat or next;
 145                 group_line($self, $ng);
 146         }
 147 }
 148
 149 sub list_active_times ($;$) {
 150         my ($self, $wildmat) = @_;
 151         wildmat2re($wildmat);
 152         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 153                 $ng->{newsgroup} =~ $wildmat or next;
 154                 my $c = eval { $ng->mm->created_at } || time;
 155                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 156         }
 157 }
 158
 159 sub list_newsgroups ($;$) {
 160         my ($self, $wildmat) = @_;
 161         wildmat2re($wildmat);
 162         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 163                 $ng->{newsgroup} =~ $wildmat or next;
 164                 my $d = $ng->description;
 165                 more($self, "$ng->{newsgroup} $d");
 166         }
 167 }
 168
 169 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 170 sub cmd_list ($;$$) {
 171         my ($self, @args) = @_;
 172         if (scalar @args) {
 173                 my $arg = shift @args;
 174                 $arg =~ tr/A-Z./a-z_/;
 175                 $arg = "list_$arg";
 176
 177                 $arg = eval {
 178                         no strict 'refs';
 179                         *{$arg}{CODE};
 180                 };
 181                 return r501 unless $arg && args_ok($arg, scalar @args);
 182                 more($self, '215 information follows');
 183                 $arg->($self, @args);
 184         } else {
 185                 more($self, '215 list of newsgroups follows');
 186                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 187                         group_line($self, $ng);
 188                 }
 189         }
 190         '.'
 191 }
 192
 193 sub cmd_listgroup ($;$$) {
 194         my ($self, $group, $range) = @_;
 195         if (defined $group) {
 196                 my $res = cmd_group($self, $group);
 197                 return $res if ($res !~ /\A211 /);
 198                 more($self, $res);
 199         }
 200         my $ng = $self->{ng} or return '412 no newsgroup selected';
 201         my $mm = $ng->mm;
 202         if (defined $range) {
 203                 my $r = get_range($self, $range);
 204                 return $r unless ref $r;
 205                 my ($beg, $end) = @$r;
 206                 long_response($self, sub {
 207                         $r = $mm->msg_range(\$beg, $end, 'num');
 208                         scalar(@$r) or return;
 209                         more($self, join("\r\n", map { $_->[0] } @$r));
 210                         1;
 211                 });
 212         } else { # grab every article number
 213                 my $n = 0;
 214                 long_response($self, sub {
 215                         my $ary = $mm->ids_after(\$n);
 216                         scalar(@$ary) or return;
 217                         more($self, join("\r\n", @$ary));
 218                         1;
 219                 });
 220         }
 221 }
 222
 223 sub parse_time ($$;$) {
 224         my ($date, $time, $gmt) = @_;
 225         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 226         if (defined $gmt) {
 227                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 228                 $gmt = 1;
 229         }
 230         my @now = $gmt ? gmtime : localtime;
 231         my ($YYYY, $MM, $DD);
 232         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 233                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 234         } else { # legacy clients send YYMMDD
 235                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 236                 my $cur_year = $now[5] + 1900;
 237                 if ($YYYY > $cur_year) {
 238                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 239                 }
 240         }
 241         if ($gmt) {
 242                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 243         } else {
 244                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 245         }
 246 }
 247
 248 sub group_line ($$) {
 249         my ($self, $ng) = @_;
 250         my ($min, $max) = $ng->mm->minmax;
 251         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 252 }
 253
 254 sub cmd_newgroups ($$$;$$) {
 255         my ($self, $date, $time, $gmt, $dists) = @_;
 256         my $ts = eval { parse_time($date, $time, $gmt) };
 257         return r501 if $@;
 258
 259         # TODO dists
 260         more($self, '231 list of new newsgroups follows');
 261         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 262                 my $c = eval { $ng->mm->created_at } || 0;
 263                 next unless $c > $ts;
 264                 group_line($self, $ng);
 265         }
 266         '.'
 267 }
 268
 269 sub wildmat2re (;$) {
 270         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 271         my %keep;
 272         my $salt = rand;
 273         my $tmp = $_[0];
 274
 275         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 276                 my $orig = $1;
 277                 my $key = sha1_hex($orig . $salt);
 278                 $orig =~ s/([^\w\-])+/\Q$1/g;
 279                 $keep{$key} = $orig;
 280                 $key
 281                 #gex;
 282         my %map = ('*' => '.*', '?' => '.' );
 283         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 284         if (scalar %keep) {
 285                 $tmp =~ s#([a-f0-9]{40})#
 286                         my $orig = $keep{$1};
 287                         defined $orig ? $orig : $1;
 288                         #ge;
 289         }
 290         $_[0] = qr/\A$tmp\z/;
 291 }
 292
 293 sub ngpat2re (;$) {
 294         return $_[0] = qr/\A\z/ unless defined $_[0];
 295         my %map = ('*' => '.*', ',' => '|');
 296         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 297         $_[0] = qr/\A(?:$_[0])\z/;
 298 }
 299
 300 sub cmd_newnews ($$$$;$$) {
 301         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 302         my $ts = eval { parse_time($date, $time, $gmt) };
 303         return r501 if $@;
 304         more($self, '230 list of new articles by message-id follows');
 305         my ($keep, $skip) = split('!', $newsgroups, 2);
 306         ngpat2re($keep);
 307         ngpat2re($skip);
 308         my @over;
 309         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 310                 $ng->{newsgroup} =~ $keep or next;
 311                 $ng->{newsgroup} =~ $skip and next;
 312                 my $over = $ng->over or next;
 313                 push @over, $over;
 314         };
 315         return '.' unless @over;
 316
 317         my $prev = 0;
 318         long_response($self, sub {
 319                 my $over = $over[0];
 320                 my $msgs = $over->query_ts($ts, $prev);
 321                 if (scalar @$msgs) {
 322                         more($self, '<' .
 323                                 join(">\r\n<", map { $_->mid } @$msgs ).
 324                                 '>');
 325                         $prev = $msgs->[-1]->{num};
 326                 } else {
 327                         shift @over;
 328                         if (@over) { # continue onto next newsgroup
 329                                 $prev = 0;
 330                                 return 1;
 331                         } else { # break out of the long response.
 332                                 return;
 333                         }
 334                 }
 335         });
 336 }
 337
 338 sub cmd_group ($$) {
 339         my ($self, $group) = @_;
 340         my $no_such = '411 no such news group';
 341         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 342
 343         $self->{ng} = $ng;
 344         my ($min, $max) = $ng->mm->minmax;
 345         $min ||= 0;
 346         $max ||= 0;
 347         $self->{article} = $min;
 348         my $est_size = $max - $min;
 349         "211 $est_size $min $max $group";
 350 }
 351
 352 sub article_adj ($$) {
 353         my ($self, $off) = @_;
 354         my $ng = $self->{ng} or return '412 no newsgroup selected';
 355
 356         my $n = $self->{article};
 357         defined $n or return '420 no current article has been selected';
 358
 359         $n += $off;
 360         my $mid = $ng->mm->mid_for($n);
 361         unless ($mid) {
 362                 $n = $off > 0 ? 'next' : 'previous';
 363                 return "421 no $n article in this group";
 364         }
 365         $self->{article} = $n;
 366         "223 $n <$mid> article retrieved - request text separately";
 367 }
 368
 369 sub cmd_next ($) { article_adj($_[0], 1) }
 370 sub cmd_last ($) { article_adj($_[0], -1) }
 371
 372 # We want to encourage using email and CC-ing everybody involved to avoid
 373 # the single-point-of-failure a single server provides.
 374 sub cmd_post ($) {
 375         my ($self) = @_;
 376         my $ng = $self->{ng};
 377         $ng ? "440 mailto:$ng->{-primary_address} to post"
 378                 : '440 posting not allowed'
 379 }
 380
 381 sub cmd_quit ($) {
 382         my ($self) = @_;
 383         res($self, '205 closing connection - goodbye!');
 384         $self->shutdn;
 385         undef;
 386 }
 387
 388 sub header_append ($$$) {
 389         my ($hdr, $k, $v) = @_;
 390         my @v = $hdr->header($k);
 391         foreach (@v) {
 392                 return if $v eq $_;
 393         }
 394         $hdr->header_set($k, @v, $v);
 395 }
 396
 397 sub xref ($$$$) {
 398         my ($self, $ng, $n, $mid) = @_;
 399         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 400
 401         # num_for is pretty cheap and sometimes we'll lookup the existence
 402         # of an article without getting even the OVER info.  In other words,
 403         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 404         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 405         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 406                 next if $ng eq $other;
 407                 my $num = eval { $other->mm->num_for($mid) } or next;
 408                 $ret .= " $other->{newsgroup}:$num";
 409         }
 410         $ret;
 411 }
 412
 413 sub set_nntp_headers ($$$$$) {
 414         my ($self, $hdr, $ng, $n, $mid) = @_;
 415
 416         # why? leafnode requires a Path: header for some inexplicable
 417         # reason.  We'll fake the shortest one possible.
 418         $hdr->header_set('Path', 'y');
 419
 420         # leafnode (and maybe other NNTP clients) have trouble dealing
 421         # with v2 messages which have multiple Message-IDs (either due
 422         # to our own content-based dedupe or buggy git-send-email versions).
 423         my @mids = $hdr->header('Message-ID');
 424         if (scalar(@mids) > 1) {
 425                 my $mid0 = "<$mid>";
 426                 $hdr->header_set('Message-ID', $mid0);
 427                 my @alt = $hdr->header('X-Alt-Message-ID');
 428                 my %seen = map { $_ => 1 } (@alt, $mid0);
 429                 foreach my $m (@mids) {
 430                         next if $seen{$m}++;
 431                         push @alt, $m;
 432                 }
 433                 $hdr->header_set('X-Alt-Message-ID', @alt);
 434         }
 435
 436         # clobber some
 437         my $xref = xref($self, $ng, $n, $mid);
 438         $hdr->header_set('Xref', $xref);
 439         $xref =~ s/:[0-9]+//g;
 440         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 441         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 442         if (my $url = $ng->base_url) {
 443                 $mid = mid_escape($mid);
 444                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 445                 header_append($hdr, 'List-Archive', "<$url>");
 446         }
 447 }
 448
 449 sub art_lookup ($$$) {
 450         my ($self, $art, $set_headers) = @_;
 451         my $ng = $self->{ng};
 452         my ($n, $mid);
 453         my $err;
 454         if (defined $art) {
 455                 if ($art =~ /\A[0-9]+\z/) {
 456                         $err = '423 no such article number in this group';
 457                         $n = int($art);
 458                         goto find_mid;
 459                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 460                         $mid = $1;
 461                         $err = r430;
 462                         $n = $ng->mm->num_for($mid) if $ng;
 463                         goto found if defined $n;
 464                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 465                                 $n = $g->mm->num_for($mid);
 466                                 if (defined $n) {
 467                                         $ng = $g;
 468                                         goto found;
 469                                 }
 470                         }
 471                         return $err;
 472                 } else {
 473                         return r501;
 474                 }
 475         } else {
 476                 $err = '420 no current article has been selected';
 477                 $n = $self->{article};
 478                 defined $n or return $err;
 479 find_mid:
 480                 $ng or return '412 no newsgroup has been selected';
 481                 $mid = $ng->mm->mid_for($n);
 482                 defined $mid or return $err;
 483         }
 484 found:
 485         my $smsg = $ng->over->get_art($n) or return $err;
 486         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 487
 488         # Email::Simple->new will modify $msg in-place as documented
 489         # in its manpage, so what's left is the body and we won't need
 490         # to call Email::Simple::body(), later
 491         my $hdr = Email::Simple->new($msg)->header_obj;
 492         set_nntp_headers($self, $hdr, $ng, $n, $mid) if $set_headers;
 493         [ $n, $mid, $msg, $hdr ];
 494 }
 495
 496 sub msg_body_write ($$) {
 497         my ($self, $msg) = @_;
 498
 499         # these can momentarily double the memory consumption :<
 500         $$msg =~ s/^\./../smg;
 501         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 502         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 503         $self->msg_more($$msg);
 504         '.'
 505 }
 506
 507 sub set_art {
 508         my ($self, $art) = @_;
 509         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 510 }
 511
 512 sub msg_hdr_write ($$$) {
 513         my ($self, $hdr, $body_follows) = @_;
 514         $hdr = $hdr->as_string;
 515         utf8::encode($hdr);
 516         $hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 517
 518         # for leafnode compatibility, we need to ensure Message-ID headers
 519         # are only a single line.  We can't subclass Email::Simple::Header
 520         # and override _default_fold_at in here, either; since that won't
 521         # affect messages already in the archive.
 522         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 523         $hdr .= "\r\n" if $body_follows;
 524         $self->msg_more($hdr);
 525 }
 526
 527 sub cmd_article ($;$) {
 528         my ($self, $art) = @_;
 529         my $r = art_lookup($self, $art, 1);
 530         return $r unless ref $r;
 531         my ($n, $mid, $msg, $hdr) = @$r;
 532         set_art($self, $art);
 533         more($self, "220 $n <$mid> article retrieved - head and body follow");
 534         msg_hdr_write($self, $hdr, 1);
 535         msg_body_write($self, $msg);
 536 }
 537
 538 sub cmd_head ($;$) {
 539         my ($self, $art) = @_;
 540         my $r = art_lookup($self, $art, 2);
 541         return $r unless ref $r;
 542         my ($n, $mid, undef, $hdr) = @$r;
 543         set_art($self, $art);
 544         more($self, "221 $n <$mid> article retrieved - head follows");
 545         msg_hdr_write($self, $hdr, 0);
 546         '.'
 547 }
 548
 549 sub cmd_body ($;$) {
 550         my ($self, $art) = @_;
 551         my $r = art_lookup($self, $art, 0);
 552         return $r unless ref $r;
 553         my ($n, $mid, $msg) = @$r;
 554         set_art($self, $art);
 555         more($self, "222 $n <$mid> article retrieved - body follows");
 556         msg_body_write($self, $msg);
 557 }
 558
 559 sub cmd_stat ($;$) {
 560         my ($self, $art) = @_;
 561         my $r = art_lookup($self, $art, 0);
 562         return $r unless ref $r;
 563         my ($n, $mid) = @$r;
 564         set_art($self, $art);
 565         "223 $n <$mid> article retrieved - request text separately";
 566 }
 567
 568 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 569
 570 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 571
 572 sub cmd_help ($) {
 573         my ($self) = @_;
 574         more($self, '100 help text follows');
 575         '.'
 576 }
 577
 578 sub get_range ($$) {
 579         my ($self, $range) = @_;
 580         my $ng = $self->{ng} or return '412 no news group has been selected';
 581         defined $range or return '420 No article(s) selected';
 582         my ($beg, $end);
 583         my ($min, $max) = $ng->mm->minmax;
 584         if ($range =~ /\A([0-9]+)\z/) {
 585                 $beg = $end = $1;
 586         } elsif ($range =~ /\A([0-9]+)-\z/) {
 587                 ($beg, $end) = ($1, $max);
 588         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 589                 ($beg, $end) = ($1, $2);
 590         } else {
 591                 return r501;
 592         }
 593         $beg = $min if ($beg < $min);
 594         $end = $max if ($end > $max);
 595         return '420 No article(s) selected' if ($beg > $end);
 596         [ $beg, $end ];
 597 }
 598
 599 sub long_response ($$) {
 600         my ($self, $cb) = @_; # cb returns true if more, false if done
 601
 602         my $fd = fileno($self->{sock});
 603         defined $fd or return;
 604         # make sure we disable reading during a long response,
 605         # clients should not be sending us stuff and making us do more
 606         # work while we are stream a response to them
 607         my $t0 = now();
 608         my $long_cb; # DANGER: self-referential
 609         $long_cb = sub {
 610                 # wbuf is unset or empty, here; $cb may add to it
 611                 my $more = eval { $cb->() };
 612                 if ($@ || !$self->{sock}) { # something bad happened...
 613                         $long_cb = undef;
 614                         my $diff = now() - $t0;
 615                         if ($@) {
 616                                 err($self,
 617                                     "%s during long response[$fd] - %0.6f",
 618                                     $@, $diff);
 619                         }
 620                         out($self, " deferred[$fd] aborted - %0.6f", $diff);
 621                         $self->close;
 622                 } elsif ($more) { # $self->{wbuf}:
 623                         $self->update_idle_time;
 624
 625                         # COMPRESS users all share the same DEFLATE context.
 626                         # Flush it here to ensure clients don't see
 627                         # each other's data
 628                         $self->zflush;
 629
 630                         # no recursion, schedule another call ASAP
 631                         # but only after all pending writes are done
 632                         my $wbuf = $self->{wbuf} ||= [];
 633                         push @$wbuf, $long_cb;
 634
 635                         # wbuf may be populated by $cb, no need to rearm if so:
 636                         $self->requeue if scalar(@$wbuf) == 1;
 637                 } else { # all done!
 638                         $long_cb = undef;
 639                         res($self, '.');
 640                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 641                         my $wbuf = $self->{wbuf};
 642                         $self->requeue unless $wbuf && @$wbuf;
 643                 }
 644         };
 645         $self->write($long_cb); # kick off!
 646         undef;
 647 }
 648
 649 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 650         my ($self, $xhdr, $range) = @_;
 651
 652         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 653                 my ($ng, $n) = mid_lookup($self, $1);
 654                 return r430 unless $n;
 655                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 656         } else { # numeric range
 657                 $range = $self->{article} unless defined $range;
 658                 my $r = get_range($self, $range);
 659                 return $r unless ref $r;
 660                 my $mm = $self->{ng}->mm;
 661                 my ($beg, $end) = @$r;
 662                 more($self, $xhdr ? r221 : r225);
 663                 long_response($self, sub {
 664                         my $r = $mm->msg_range(\$beg, $end);
 665                         @$r or return;
 666                         more($self, join("\r\n", map {
 667                                 "$_->[0] <$_->[1]>"
 668                         } @$r));
 669                         1;
 670                 });
 671         }
 672 }
 673
 674 sub mid_lookup ($$) {
 675         my ($self, $mid) = @_;
 676         my $self_ng = $self->{ng};
 677         if ($self_ng) {
 678                 my $n = $self_ng->mm->num_for($mid);
 679                 return ($self_ng, $n) if defined $n;
 680         }
 681         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 682                 next if defined $self_ng && $ng eq $self_ng;
 683                 my $n = $ng->mm->num_for($mid);
 684                 return ($ng, $n) if defined $n;
 685         }
 686         (undef, undef);
 687 }
 688
 689 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 690         my ($self, $xhdr, $range) = @_;
 691
 692         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 693                 my $mid = $1;
 694                 my ($ng, $n) = mid_lookup($self, $mid);
 695                 return r430 unless $n;
 696                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 697                                 xref($self, $ng, $n, $mid));
 698         } else { # numeric range
 699                 $range = $self->{article} unless defined $range;
 700                 my $r = get_range($self, $range);
 701                 return $r unless ref $r;
 702                 my $ng = $self->{ng};
 703                 my $mm = $ng->mm;
 704                 my ($beg, $end) = @$r;
 705                 more($self, $xhdr ? r221 : r225);
 706                 long_response($self, sub {
 707                         my $r = $mm->msg_range(\$beg, $end);
 708                         @$r or return;
 709                         more($self, join("\r\n", map {
 710                                 my $num = $_->[0];
 711                                 "$num ".xref($self, $ng, $num, $_->[1]);
 712                         } @$r));
 713                         1;
 714                 });
 715         }
 716 }
 717
 718 sub over_header_for {
 719         my ($over, $num, $field) = @_;
 720         my $smsg = $over->get_art($num) or return;
 721         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 722         $smsg->{$field};
 723 }
 724
 725 sub hdr_searchmsg ($$$$) {
 726         my ($self, $xhdr, $field, $range) = @_;
 727         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 728                 my ($ng, $n) = mid_lookup($self, $1);
 729                 return r430 unless defined $n;
 730                 my $v = over_header_for($ng->over, $n, $field);
 731                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 732         } else { # numeric range
 733                 $range = $self->{article} unless defined $range;
 734                 my $over = $self->{ng}->over;
 735                 my $mm = $self->{ng}->mm;
 736                 my $r = get_range($self, $range);
 737                 return $r unless ref $r;
 738                 my ($beg, $end) = @$r;
 739                 more($self, $xhdr ? r221 : r225);
 740                 my $cur = $beg;
 741                 long_response($self, sub {
 742                         my $msgs = $over->query_xover($cur, $end);
 743                         my $nr = scalar @$msgs or return;
 744                         my $tmp = '';
 745                         foreach my $s (@$msgs) {
 746                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 747                         }
 748                         utf8::encode($tmp);
 749                         $self->msg_more($tmp);
 750                         $cur = $msgs->[-1]->{num} + 1;
 751                 });
 752         }
 753 }
 754
 755 sub do_hdr ($$$;$) {
 756         my ($self, $xhdr, $header, $range) = @_;
 757         my $sub = lc $header;
 758         if ($sub eq 'message-id') {
 759                 hdr_message_id($self, $xhdr, $range);
 760         } elsif ($sub eq 'xref') {
 761                 hdr_xref($self, $xhdr, $range);
 762         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 763                                 bytes|lines)\z/x) {
 764                 hdr_searchmsg($self, $xhdr, $sub, $range);
 765         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 766                 hdr_searchmsg($self, $xhdr, $1, $range);
 767         } else {
 768                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 769         }
 770 }
 771
 772 # RFC 3977
 773 sub cmd_hdr ($$;$) {
 774         my ($self, $header, $range) = @_;
 775         do_hdr($self, 0, $header, $range);
 776 }
 777
 778 # RFC 2980
 779 sub cmd_xhdr ($$;$) {
 780         my ($self, $header, $range) = @_;
 781         do_hdr($self, 1, $header, $range);
 782 }
 783
 784 sub hdr_mid_prefix ($$$$$) {
 785         my ($self, $xhdr, $ng, $n, $mid) = @_;
 786         return $mid if $xhdr;
 787
 788         # HDR for RFC 3977 users
 789         if (my $self_ng = $self->{ng}) {
 790                 ($self_ng eq $ng) ? $n : '0';
 791         } else {
 792                 '0';
 793         }
 794 }
 795
 796 sub hdr_mid_response ($$$$$$) {
 797         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 798         my $res = '';
 799         if ($xhdr) {
 800                 $res .= r221 . "\r\n";
 801                 $res .= "$mid $v\r\n";
 802         } else {
 803                 $res .= r225 . "\r\n";
 804                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 805                 $res .= "$pfx $v\r\n";
 806         }
 807         res($self, $res .= '.');
 808         undef;
 809 }
 810
 811 sub cmd_xrover ($;$) {
 812         my ($self, $range) = @_;
 813         my $ng = $self->{ng} or return '412 no newsgroup selected';
 814         (defined $range && $range =~ /[<>]/) and
 815                 return '420 No article(s) selected'; # no message IDs
 816
 817         $range = $self->{article} unless defined $range;
 818         my $r = get_range($self, $range);
 819         return $r unless ref $r;
 820         my ($beg, $end) = @$r;
 821         my $mm = $ng->mm;
 822         my $over = $ng->over;
 823         more($self, '224 Overview information follows');
 824
 825         long_response($self, sub {
 826                 my $h = over_header_for($over, $beg, 'references');
 827                 more($self, "$beg $h") if defined($h);
 828                 $beg++ < $end;
 829         });
 830 }
 831
 832 sub over_line ($$$$) {
 833         my ($self, $ng, $num, $smsg) = @_;
 834         # n.b. field access and procedural calls can be
 835         # 10%-15% faster than OO method calls:
 836         my $s = join("\t", $num,
 837                 $smsg->{subject},
 838                 $smsg->{from},
 839                 PublicInbox::SearchMsg::date($smsg),
 840                 "<$smsg->{mid}>",
 841                 $smsg->{references},
 842                 $smsg->{bytes},
 843                 $smsg->{lines},
 844                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 845         utf8::encode($s);
 846         $s
 847 }
 848
 849 sub cmd_over ($;$) {
 850         my ($self, $range) = @_;
 851         if ($range && $range =~ /\A<(.+)>\z/) {
 852                 my ($ng, $n) = mid_lookup($self, $1);
 853                 defined $n or return r430;
 854                 my $smsg = $ng->over->get_art($n) or return r430;
 855                 more($self, '224 Overview information follows (multi-line)');
 856
 857                 # Only set article number column if it's the current group
 858                 my $self_ng = $self->{ng};
 859                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 860                 more($self, over_line($self, $ng, $n, $smsg));
 861                 '.';
 862         } else {
 863                 cmd_xover($self, $range);
 864         }
 865 }
 866
 867 sub cmd_xover ($;$) {
 868         my ($self, $range) = @_;
 869         $range = $self->{article} unless defined $range;
 870         my $r = get_range($self, $range);
 871         return $r unless ref $r;
 872         my ($beg, $end) = @$r;
 873         more($self, "224 Overview information follows for $beg to $end");
 874         my $over = $self->{ng}->over;
 875         my $cur = $beg;
 876         long_response($self, sub {
 877                 my $msgs = $over->query_xover($cur, $end);
 878                 my $nr = scalar @$msgs or return;
 879
 880                 # OVERVIEW.FMT
 881                 more($self, join("\r\n", map {
 882                         over_line($self, $self->{ng}, $_->{num}, $_);
 883                         } @$msgs));
 884                 $cur = $msgs->[-1]->{num} + 1;
 885         });
 886 }
 887
 888 sub compressed { undef }
 889
 890 sub cmd_starttls ($) {
 891         my ($self) = @_;
 892         my $sock = $self->{sock} or return;
 893         # RFC 4642 2.2.1
 894         return r502 if (ref($sock) eq 'IO::Socket::SSL' || $self->compressed);
 895         my $opt = $self->{nntpd}->{accept_tls} or
 896                 return '580 can not initiate TLS negotiation';
 897         res($self, '382 Continue with TLS negotiation');
 898         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 899         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 900         undef;
 901 }
 902
 903 # RFC 8054
 904 sub cmd_compress ($$) {
 905         my ($self, $alg) = @_;
 906         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 907         return r502 if $self->compressed || !$have_deflate;
 908         PublicInbox::NNTPdeflate->enable($self);
 909         $self->requeue;
 910         undef
 911 }
 912
 913 sub zflush {} # overridden by NNTPdeflate
 914
 915 sub cmd_xpath ($$) {
 916         my ($self, $mid) = @_;
 917         return r501 unless $mid =~ /\A<(.+)>\z/;
 918         $mid = $1;
 919         my @paths;
 920         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 921                 my $n = $ng->mm->num_for($mid);
 922                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 923         }
 924         return '430 no such article on server' unless @paths;
 925         '223 '.join(' ', @paths);
 926 }
 927
 928 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 929
 930 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 931
 932 sub do_write ($$) {
 933         my $self = $_[0];
 934         my $done = $self->write(\($_[1]));
 935         return 0 unless $self->{sock};
 936
 937         $done;
 938 }
 939
 940 sub err ($$;@) {
 941         my ($self, $fmt, @args) = @_;
 942         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 943 }
 944
 945 sub out ($$;@) {
 946         my ($self, $fmt, @args) = @_;
 947         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 948 }
 949
 950 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 951 sub event_step {
 952         my ($self) = @_;
 953
 954         return unless $self->flush_write && $self->{sock};
 955
 956         $self->update_idle_time;
 957         # only read more requests if we've drained the write buffer,
 958         # otherwise we can be buffering infinitely w/o backpressure
 959
 960         my $rbuf = $self->{rbuf} // (\(my $x = ''));
 961         my $r = 1;
 962
 963         if (index($$rbuf, "\n") < 0) {
 964                 my $off = bytes::length($$rbuf);
 965                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 966         }
 967         while ($r > 0 && $$rbuf =~ s/\A[ \t]*([^\n]*?)\r?\n//) {
 968                 my $line = $1;
 969                 return $self->close if $line =~ /[[:cntrl:]]/s;
 970                 my $t0 = now();
 971                 my $fd = fileno($self->{sock});
 972                 $r = eval { process_line($self, $line) };
 973                 my $pending = $self->{wbuf} ? ' pending' : '';
 974                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
 975         }
 976
 977         return $self->close if $r < 0;
 978         my $len = bytes::length($$rbuf);
 979         return $self->close if ($len >= LINE_MAX);
 980         $self->rbuf_idle($rbuf);
 981         $self->update_idle_time;
 982
 983         # maybe there's more pipelined data, or we'll have
 984         # to register it for socket-readiness notifications
 985         $self->requeue unless $self->{wbuf};
 986 }
 987
 988 # for graceful shutdown in PublicInbox::Daemon:
 989 sub busy {
 990         my ($self, $now) = @_;
 991         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
 992 }
 993
 994 # this is an import to prevent "perl -c" from complaining about fields
 995 sub import {
 996         $have_deflate = eval { require PublicInbox::NNTPdeflate } and
 997                 $CAPABILITIES .= "COMPRESS DEFLATE\r\n";
 998 }
 999
1000 1;