lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article ng);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 use Email::Simple;
  15 use POSIX qw(strftime);
  16 use PublicInbox::DS qw(now);
  17 use Digest::SHA qw(sha1_hex);
  18 use Time::Local qw(timegm timelocal);
  19 use constant {
  20         LINE_MAX => 512, # RFC 977 section 2.3
  21         r501 => '501 command syntax error',
  22         r502 => '502 Command unavailable',
  23         r221 => '221 Header follows',
  24         r224 => '224 Overview information follows (multi-line)',
  25         r225 => '225 Headers follow (multi-line)',
  26         r430 => '430 No article with that message-id',
  27 };
  28 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  29 use Errno qw(EAGAIN);
  30
  31 my @OVERVIEW = qw(Subject From Date Message-ID References);
  32 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  33                 "Xref:full\r\n";
  34 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  35                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  36 my $CAPABILITIES = <<"";
  37 101 Capability list:\r
  38 VERSION 2\r
  39 READER\r
  40 NEWNEWS\r
  41 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  42 HDR\r
  43 OVER\r
  44
  45 my $have_deflate;
  46
  47 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  48
  49 sub new ($$$) {
  50         my ($class, $sock, $nntpd) = @_;
  51         my $self = fields::new($class);
  52         my $ev = EPOLLIN;
  53         my $wbuf;
  54         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  55                 return CORE::close($sock) if $! != EAGAIN;
  56                 $ev = PublicInbox::TLS::epollbit();
  57                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  58         }
  59         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  60         $self->{nntpd} = $nntpd;
  61         if ($wbuf) {
  62                 $self->{wbuf} = $wbuf;
  63         } else {
  64                 greet($self);
  65         }
  66         $self->update_idle_time;
  67         $self;
  68 }
  69
  70 sub args_ok ($$) {
  71         my ($cb, $argc) = @_;
  72         my $tot = prototype $cb;
  73         my ($nreq, undef) = split(';', $tot);
  74         $nreq = ($nreq =~ tr/$//) - 1;
  75         $tot = ($tot =~ tr/$//) - 1;
  76         ($argc <= $tot && $argc >= $nreq);
  77 }
  78
  79 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  80 sub process_line ($$) {
  81         my ($self, $l) = @_;
  82         my ($req, @args) = split(/[ \t]/, $l);
  83         return 1 unless defined($req); # skip blank line
  84         $req = $self->can('cmd_'.lc($req));
  85         return res($self, '500 command not recognized') unless $req;
  86         return res($self, r501) unless args_ok($req, scalar @args);
  87
  88         my $res = eval { $req->($self, @args) };
  89         my $err = $@;
  90         if ($err && $self->{sock}) {
  91                 local $/ = "\n";
  92                 chomp($l);
  93                 err($self, 'error from: %s (%s)', $l, $err);
  94                 $res = '503 program fault - command not performed';
  95         }
  96         return 0 unless defined $res;
  97         res($self, $res);
  98 }
  99
 100 # The keyword argument is not used (rfc3977 5.2.2)
 101 sub cmd_capabilities ($;$) {
 102         my ($self, undef) = @_;
 103         my $res = $CAPABILITIES;
 104         if (ref($self->{sock}) ne 'IO::Socket::SSL' &&
 105                         $self->{nntpd}->{accept_tls}) {
 106                 $res .= "STARTTLS\r\n";
 107         }
 108         $res .= '.';
 109 }
 110
 111 sub cmd_mode ($$) {
 112         my ($self, $arg) = @_;
 113         $arg = uc $arg;
 114         return r501 unless $arg eq 'READER';
 115         '201 Posting prohibited';
 116 }
 117
 118 sub cmd_slave ($) { '202 slave status noted' }
 119
 120 sub cmd_xgtitle ($;$) {
 121         my ($self, $wildmat) = @_;
 122         more($self, '282 list of groups and descriptions follows');
 123         list_newsgroups($self, $wildmat);
 124         '.'
 125 }
 126
 127 sub list_overview_fmt ($) {
 128         my ($self) = @_;
 129         $self->msg_more($OVERVIEW_FMT);
 130 }
 131
 132 sub list_headers ($;$) {
 133         my ($self) = @_;
 134         $self->msg_more($LIST_HEADERS);
 135 }
 136
 137 sub list_active ($;$) {
 138         my ($self, $wildmat) = @_;
 139         wildmat2re($wildmat);
 140         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 141                 $ng->{newsgroup} =~ $wildmat or next;
 142                 group_line($self, $ng);
 143         }
 144 }
 145
 146 sub list_active_times ($;$) {
 147         my ($self, $wildmat) = @_;
 148         wildmat2re($wildmat);
 149         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 150                 $ng->{newsgroup} =~ $wildmat or next;
 151                 my $c = eval { $ng->mm->created_at } || time;
 152                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 153         }
 154 }
 155
 156 sub list_newsgroups ($;$) {
 157         my ($self, $wildmat) = @_;
 158         wildmat2re($wildmat);
 159         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 160                 $ng->{newsgroup} =~ $wildmat or next;
 161                 my $d = $ng->description;
 162                 more($self, "$ng->{newsgroup} $d");
 163         }
 164 }
 165
 166 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 167 sub cmd_list ($;$$) {
 168         my ($self, @args) = @_;
 169         if (scalar @args) {
 170                 my $arg = shift @args;
 171                 $arg =~ tr/A-Z./a-z_/;
 172                 $arg = "list_$arg";
 173                 $arg = $self->can($arg);
 174                 return r501 unless $arg && args_ok($arg, scalar @args);
 175                 more($self, '215 information follows');
 176                 $arg->($self, @args);
 177         } else {
 178                 more($self, '215 list of newsgroups follows');
 179                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 180                         group_line($self, $ng);
 181                 }
 182         }
 183         '.'
 184 }
 185
 186 sub cmd_listgroup ($;$$) {
 187         my ($self, $group, $range) = @_;
 188         if (defined $group) {
 189                 my $res = cmd_group($self, $group);
 190                 return $res if ($res !~ /\A211 /);
 191                 more($self, $res);
 192         }
 193         my $ng = $self->{ng} or return '412 no newsgroup selected';
 194         my $mm = $ng->mm;
 195         if (defined $range) {
 196                 my $r = get_range($self, $range);
 197                 return $r unless ref $r;
 198                 my ($beg, $end) = @$r;
 199                 long_response($self, sub {
 200                         $r = $mm->msg_range(\$beg, $end, 'num');
 201                         scalar(@$r) or return;
 202                         more($self, join("\r\n", map { $_->[0] } @$r));
 203                         1;
 204                 });
 205         } else { # grab every article number
 206                 my $n = 0;
 207                 long_response($self, sub {
 208                         my $ary = $mm->ids_after(\$n);
 209                         scalar(@$ary) or return;
 210                         more($self, join("\r\n", @$ary));
 211                         1;
 212                 });
 213         }
 214 }
 215
 216 sub parse_time ($$;$) {
 217         my ($date, $time, $gmt) = @_;
 218         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 219         if (defined $gmt) {
 220                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 221                 $gmt = 1;
 222         }
 223         my @now = $gmt ? gmtime : localtime;
 224         my ($YYYY, $MM, $DD);
 225         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 226                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 227         } else { # legacy clients send YYMMDD
 228                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 229                 my $cur_year = $now[5] + 1900;
 230                 if ($YYYY > $cur_year) {
 231                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 232                 }
 233         }
 234         if ($gmt) {
 235                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 236         } else {
 237                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 238         }
 239 }
 240
 241 sub group_line ($$) {
 242         my ($self, $ng) = @_;
 243         my ($min, $max) = $ng->mm->minmax;
 244         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 245 }
 246
 247 sub cmd_newgroups ($$$;$$) {
 248         my ($self, $date, $time, $gmt, $dists) = @_;
 249         my $ts = eval { parse_time($date, $time, $gmt) };
 250         return r501 if $@;
 251
 252         # TODO dists
 253         more($self, '231 list of new newsgroups follows');
 254         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 255                 my $c = eval { $ng->mm->created_at } || 0;
 256                 next unless $c > $ts;
 257                 group_line($self, $ng);
 258         }
 259         '.'
 260 }
 261
 262 sub wildmat2re (;$) {
 263         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 264         my %keep;
 265         my $salt = rand;
 266         my $tmp = $_[0];
 267
 268         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 269                 my $orig = $1;
 270                 my $key = sha1_hex($orig . $salt);
 271                 $orig =~ s/([^\w\-])+/\Q$1/g;
 272                 $keep{$key} = $orig;
 273                 $key
 274                 #gex;
 275         my %map = ('*' => '.*', '?' => '.' );
 276         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 277         if (scalar %keep) {
 278                 $tmp =~ s#([a-f0-9]{40})#
 279                         my $orig = $keep{$1};
 280                         defined $orig ? $orig : $1;
 281                         #ge;
 282         }
 283         $_[0] = qr/\A$tmp\z/;
 284 }
 285
 286 sub ngpat2re (;$) {
 287         return $_[0] = qr/\A\z/ unless defined $_[0];
 288         my %map = ('*' => '.*', ',' => '|');
 289         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 290         $_[0] = qr/\A(?:$_[0])\z/;
 291 }
 292
 293 sub cmd_newnews ($$$$;$$) {
 294         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 295         my $ts = eval { parse_time($date, $time, $gmt) };
 296         return r501 if $@;
 297         more($self, '230 list of new articles by message-id follows');
 298         my ($keep, $skip) = split('!', $newsgroups, 2);
 299         ngpat2re($keep);
 300         ngpat2re($skip);
 301         my @over;
 302         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 303                 $ng->{newsgroup} =~ $keep or next;
 304                 $ng->{newsgroup} =~ $skip and next;
 305                 my $over = $ng->over or next;
 306                 push @over, $over;
 307         };
 308         return '.' unless @over;
 309
 310         my $prev = 0;
 311         long_response($self, sub {
 312                 my $over = $over[0];
 313                 my $msgs = $over->query_ts($ts, $prev);
 314                 if (scalar @$msgs) {
 315                         more($self, '<' .
 316                                 join(">\r\n<", map { $_->mid } @$msgs ).
 317                                 '>');
 318                         $prev = $msgs->[-1]->{num};
 319                 } else {
 320                         shift @over;
 321                         if (@over) { # continue onto next newsgroup
 322                                 $prev = 0;
 323                                 return 1;
 324                         } else { # break out of the long response.
 325                                 return;
 326                         }
 327                 }
 328         });
 329 }
 330
 331 sub cmd_group ($$) {
 332         my ($self, $group) = @_;
 333         my $no_such = '411 no such news group';
 334         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 335
 336         $self->{ng} = $ng;
 337         my ($min, $max) = $ng->mm->minmax;
 338         $min ||= 0;
 339         $max ||= 0;
 340         $self->{article} = $min;
 341         my $est_size = $max - $min;
 342         "211 $est_size $min $max $group";
 343 }
 344
 345 sub article_adj ($$) {
 346         my ($self, $off) = @_;
 347         my $ng = $self->{ng} or return '412 no newsgroup selected';
 348
 349         my $n = $self->{article};
 350         defined $n or return '420 no current article has been selected';
 351
 352         $n += $off;
 353         my $mid = $ng->mm->mid_for($n);
 354         unless ($mid) {
 355                 $n = $off > 0 ? 'next' : 'previous';
 356                 return "421 no $n article in this group";
 357         }
 358         $self->{article} = $n;
 359         "223 $n <$mid> article retrieved - request text separately";
 360 }
 361
 362 sub cmd_next ($) { article_adj($_[0], 1) }
 363 sub cmd_last ($) { article_adj($_[0], -1) }
 364
 365 # We want to encourage using email and CC-ing everybody involved to avoid
 366 # the single-point-of-failure a single server provides.
 367 sub cmd_post ($) {
 368         my ($self) = @_;
 369         my $ng = $self->{ng};
 370         $ng ? "440 mailto:$ng->{-primary_address} to post"
 371                 : '440 posting not allowed'
 372 }
 373
 374 sub cmd_quit ($) {
 375         my ($self) = @_;
 376         res($self, '205 closing connection - goodbye!');
 377         $self->shutdn;
 378         undef;
 379 }
 380
 381 sub header_append ($$$) {
 382         my ($hdr, $k, $v) = @_;
 383         my @v = $hdr->header($k);
 384         foreach (@v) {
 385                 return if $v eq $_;
 386         }
 387         $hdr->header_set($k, @v, $v);
 388 }
 389
 390 sub xref ($$$$) {
 391         my ($self, $ng, $n, $mid) = @_;
 392         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 393
 394         # num_for is pretty cheap and sometimes we'll lookup the existence
 395         # of an article without getting even the OVER info.  In other words,
 396         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 397         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 398         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 399                 next if $ng eq $other;
 400                 my $num = eval { $other->mm->num_for($mid) } or next;
 401                 $ret .= " $other->{newsgroup}:$num";
 402         }
 403         $ret;
 404 }
 405
 406 sub set_nntp_headers ($$$$$) {
 407         my ($self, $hdr, $ng, $n, $mid) = @_;
 408
 409         # why? leafnode requires a Path: header for some inexplicable
 410         # reason.  We'll fake the shortest one possible.
 411         $hdr->header_set('Path', 'y');
 412
 413         # leafnode (and maybe other NNTP clients) have trouble dealing
 414         # with v2 messages which have multiple Message-IDs (either due
 415         # to our own content-based dedupe or buggy git-send-email versions).
 416         my @mids = $hdr->header('Message-ID');
 417         if (scalar(@mids) > 1) {
 418                 my $mid0 = "<$mid>";
 419                 $hdr->header_set('Message-ID', $mid0);
 420                 my @alt = $hdr->header('X-Alt-Message-ID');
 421                 my %seen = map { $_ => 1 } (@alt, $mid0);
 422                 foreach my $m (@mids) {
 423                         next if $seen{$m}++;
 424                         push @alt, $m;
 425                 }
 426                 $hdr->header_set('X-Alt-Message-ID', @alt);
 427         }
 428
 429         # clobber some
 430         my $xref = xref($self, $ng, $n, $mid);
 431         $hdr->header_set('Xref', $xref);
 432         $xref =~ s/:[0-9]+//g;
 433         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 434         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 435         if (my $url = $ng->base_url) {
 436                 $mid = mid_escape($mid);
 437                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 438                 header_append($hdr, 'List-Archive', "<$url>");
 439         }
 440 }
 441
 442 sub art_lookup ($$$) {
 443         my ($self, $art, $set_headers) = @_;
 444         my $ng = $self->{ng};
 445         my ($n, $mid);
 446         my $err;
 447         if (defined $art) {
 448                 if ($art =~ /\A[0-9]+\z/) {
 449                         $err = '423 no such article number in this group';
 450                         $n = int($art);
 451                         goto find_mid;
 452                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 453                         $mid = $1;
 454                         $err = r430;
 455                         $n = $ng->mm->num_for($mid) if $ng;
 456                         goto found if defined $n;
 457                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 458                                 $n = $g->mm->num_for($mid);
 459                                 if (defined $n) {
 460                                         $ng = $g;
 461                                         goto found;
 462                                 }
 463                         }
 464                         return $err;
 465                 } else {
 466                         return r501;
 467                 }
 468         } else {
 469                 $err = '420 no current article has been selected';
 470                 $n = $self->{article};
 471                 defined $n or return $err;
 472 find_mid:
 473                 $ng or return '412 no newsgroup has been selected';
 474                 $mid = $ng->mm->mid_for($n);
 475                 defined $mid or return $err;
 476         }
 477 found:
 478         my $smsg = $ng->over->get_art($n) or return $err;
 479         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 480
 481         # Email::Simple->new will modify $msg in-place as documented
 482         # in its manpage, so what's left is the body and we won't need
 483         # to call Email::Simple::body(), later
 484         my $hdr = Email::Simple->new($msg)->header_obj;
 485         set_nntp_headers($self, $hdr, $ng, $n, $mid) if $set_headers;
 486         [ $n, $mid, $msg, $hdr ];
 487 }
 488
 489 sub msg_body_write ($$) {
 490         my ($self, $msg) = @_;
 491
 492         # these can momentarily double the memory consumption :<
 493         $$msg =~ s/^\./../smg;
 494         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 495         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 496         $self->msg_more($$msg);
 497         '.'
 498 }
 499
 500 sub set_art {
 501         my ($self, $art) = @_;
 502         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 503 }
 504
 505 sub msg_hdr_write ($$$) {
 506         my ($self, $hdr, $body_follows) = @_;
 507         $hdr = $hdr->as_string;
 508         utf8::encode($hdr);
 509         $hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 510
 511         # for leafnode compatibility, we need to ensure Message-ID headers
 512         # are only a single line.  We can't subclass Email::Simple::Header
 513         # and override _default_fold_at in here, either; since that won't
 514         # affect messages already in the archive.
 515         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 516         $hdr .= "\r\n" if $body_follows;
 517         $self->msg_more($hdr);
 518 }
 519
 520 sub cmd_article ($;$) {
 521         my ($self, $art) = @_;
 522         my $r = art_lookup($self, $art, 1);
 523         return $r unless ref $r;
 524         my ($n, $mid, $msg, $hdr) = @$r;
 525         set_art($self, $art);
 526         more($self, "220 $n <$mid> article retrieved - head and body follow");
 527         msg_hdr_write($self, $hdr, 1);
 528         msg_body_write($self, $msg);
 529 }
 530
 531 sub cmd_head ($;$) {
 532         my ($self, $art) = @_;
 533         my $r = art_lookup($self, $art, 2);
 534         return $r unless ref $r;
 535         my ($n, $mid, undef, $hdr) = @$r;
 536         set_art($self, $art);
 537         more($self, "221 $n <$mid> article retrieved - head follows");
 538         msg_hdr_write($self, $hdr, 0);
 539         '.'
 540 }
 541
 542 sub cmd_body ($;$) {
 543         my ($self, $art) = @_;
 544         my $r = art_lookup($self, $art, 0);
 545         return $r unless ref $r;
 546         my ($n, $mid, $msg) = @$r;
 547         set_art($self, $art);
 548         more($self, "222 $n <$mid> article retrieved - body follows");
 549         msg_body_write($self, $msg);
 550 }
 551
 552 sub cmd_stat ($;$) {
 553         my ($self, $art) = @_;
 554         my $r = art_lookup($self, $art, 0);
 555         return $r unless ref $r;
 556         my ($n, $mid) = @$r;
 557         set_art($self, $art);
 558         "223 $n <$mid> article retrieved - request text separately";
 559 }
 560
 561 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 562
 563 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 564
 565 sub cmd_help ($) {
 566         my ($self) = @_;
 567         more($self, '100 help text follows');
 568         '.'
 569 }
 570
 571 sub get_range ($$) {
 572         my ($self, $range) = @_;
 573         my $ng = $self->{ng} or return '412 no news group has been selected';
 574         defined $range or return '420 No article(s) selected';
 575         my ($beg, $end);
 576         my ($min, $max) = $ng->mm->minmax;
 577         if ($range =~ /\A([0-9]+)\z/) {
 578                 $beg = $end = $1;
 579         } elsif ($range =~ /\A([0-9]+)-\z/) {
 580                 ($beg, $end) = ($1, $max);
 581         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 582                 ($beg, $end) = ($1, $2);
 583         } else {
 584                 return r501;
 585         }
 586         $beg = $min if ($beg < $min);
 587         $end = $max if ($end > $max);
 588         return '420 No article(s) selected' if ($beg > $end);
 589         [ $beg, $end ];
 590 }
 591
 592 sub long_response ($$) {
 593         my ($self, $cb) = @_; # cb returns true if more, false if done
 594
 595         my $fd = fileno($self->{sock});
 596         defined $fd or return;
 597         # make sure we disable reading during a long response,
 598         # clients should not be sending us stuff and making us do more
 599         # work while we are stream a response to them
 600         my $t0 = now();
 601         my $long_cb; # DANGER: self-referential
 602         $long_cb = sub {
 603                 # wbuf is unset or empty, here; $cb may add to it
 604                 my $more = eval { $cb->() };
 605                 if ($@ || !$self->{sock}) { # something bad happened...
 606                         $long_cb = undef;
 607                         my $diff = now() - $t0;
 608                         if ($@) {
 609                                 err($self,
 610                                     "%s during long response[$fd] - %0.6f",
 611                                     $@, $diff);
 612                         }
 613                         out($self, " deferred[$fd] aborted - %0.6f", $diff);
 614                         $self->close;
 615                 } elsif ($more) { # $self->{wbuf}:
 616                         $self->update_idle_time;
 617
 618                         # COMPRESS users all share the same DEFLATE context.
 619                         # Flush it here to ensure clients don't see
 620                         # each other's data
 621                         $self->zflush;
 622
 623                         # no recursion, schedule another call ASAP
 624                         # but only after all pending writes are done
 625                         my $wbuf = $self->{wbuf} ||= [];
 626                         push @$wbuf, $long_cb;
 627
 628                         # wbuf may be populated by $cb, no need to rearm if so:
 629                         $self->requeue if scalar(@$wbuf) == 1;
 630                 } else { # all done!
 631                         $long_cb = undef;
 632                         res($self, '.');
 633                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 634                         my $wbuf = $self->{wbuf};
 635                         $self->requeue unless $wbuf && @$wbuf;
 636                 }
 637         };
 638         $self->write($long_cb); # kick off!
 639         undef;
 640 }
 641
 642 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 643         my ($self, $xhdr, $range) = @_;
 644
 645         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 646                 my ($ng, $n) = mid_lookup($self, $1);
 647                 return r430 unless $n;
 648                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 649         } else { # numeric range
 650                 $range = $self->{article} unless defined $range;
 651                 my $r = get_range($self, $range);
 652                 return $r unless ref $r;
 653                 my $mm = $self->{ng}->mm;
 654                 my ($beg, $end) = @$r;
 655                 more($self, $xhdr ? r221 : r225);
 656                 long_response($self, sub {
 657                         my $r = $mm->msg_range(\$beg, $end);
 658                         @$r or return;
 659                         more($self, join("\r\n", map {
 660                                 "$_->[0] <$_->[1]>"
 661                         } @$r));
 662                         1;
 663                 });
 664         }
 665 }
 666
 667 sub mid_lookup ($$) {
 668         my ($self, $mid) = @_;
 669         my $self_ng = $self->{ng};
 670         if ($self_ng) {
 671                 my $n = $self_ng->mm->num_for($mid);
 672                 return ($self_ng, $n) if defined $n;
 673         }
 674         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 675                 next if defined $self_ng && $ng eq $self_ng;
 676                 my $n = $ng->mm->num_for($mid);
 677                 return ($ng, $n) if defined $n;
 678         }
 679         (undef, undef);
 680 }
 681
 682 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 683         my ($self, $xhdr, $range) = @_;
 684
 685         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 686                 my $mid = $1;
 687                 my ($ng, $n) = mid_lookup($self, $mid);
 688                 return r430 unless $n;
 689                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 690                                 xref($self, $ng, $n, $mid));
 691         } else { # numeric range
 692                 $range = $self->{article} unless defined $range;
 693                 my $r = get_range($self, $range);
 694                 return $r unless ref $r;
 695                 my $ng = $self->{ng};
 696                 my $mm = $ng->mm;
 697                 my ($beg, $end) = @$r;
 698                 more($self, $xhdr ? r221 : r225);
 699                 long_response($self, sub {
 700                         my $r = $mm->msg_range(\$beg, $end);
 701                         @$r or return;
 702                         more($self, join("\r\n", map {
 703                                 my $num = $_->[0];
 704                                 "$num ".xref($self, $ng, $num, $_->[1]);
 705                         } @$r));
 706                         1;
 707                 });
 708         }
 709 }
 710
 711 sub over_header_for {
 712         my ($over, $num, $field) = @_;
 713         my $smsg = $over->get_art($num) or return;
 714         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 715         $smsg->{$field};
 716 }
 717
 718 sub hdr_searchmsg ($$$$) {
 719         my ($self, $xhdr, $field, $range) = @_;
 720         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 721                 my ($ng, $n) = mid_lookup($self, $1);
 722                 return r430 unless defined $n;
 723                 my $v = over_header_for($ng->over, $n, $field);
 724                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 725         } else { # numeric range
 726                 $range = $self->{article} unless defined $range;
 727                 my $over = $self->{ng}->over;
 728                 my $mm = $self->{ng}->mm;
 729                 my $r = get_range($self, $range);
 730                 return $r unless ref $r;
 731                 my ($beg, $end) = @$r;
 732                 more($self, $xhdr ? r221 : r225);
 733                 my $cur = $beg;
 734                 long_response($self, sub {
 735                         my $msgs = $over->query_xover($cur, $end);
 736                         my $nr = scalar @$msgs or return;
 737                         my $tmp = '';
 738                         foreach my $s (@$msgs) {
 739                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 740                         }
 741                         utf8::encode($tmp);
 742                         $self->msg_more($tmp);
 743                         $cur = $msgs->[-1]->{num} + 1;
 744                 });
 745         }
 746 }
 747
 748 sub do_hdr ($$$;$) {
 749         my ($self, $xhdr, $header, $range) = @_;
 750         my $sub = lc $header;
 751         if ($sub eq 'message-id') {
 752                 hdr_message_id($self, $xhdr, $range);
 753         } elsif ($sub eq 'xref') {
 754                 hdr_xref($self, $xhdr, $range);
 755         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 756                                 bytes|lines)\z/x) {
 757                 hdr_searchmsg($self, $xhdr, $sub, $range);
 758         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 759                 hdr_searchmsg($self, $xhdr, $1, $range);
 760         } else {
 761                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 762         }
 763 }
 764
 765 # RFC 3977
 766 sub cmd_hdr ($$;$) {
 767         my ($self, $header, $range) = @_;
 768         do_hdr($self, 0, $header, $range);
 769 }
 770
 771 # RFC 2980
 772 sub cmd_xhdr ($$;$) {
 773         my ($self, $header, $range) = @_;
 774         do_hdr($self, 1, $header, $range);
 775 }
 776
 777 sub hdr_mid_prefix ($$$$$) {
 778         my ($self, $xhdr, $ng, $n, $mid) = @_;
 779         return $mid if $xhdr;
 780
 781         # HDR for RFC 3977 users
 782         if (my $self_ng = $self->{ng}) {
 783                 ($self_ng eq $ng) ? $n : '0';
 784         } else {
 785                 '0';
 786         }
 787 }
 788
 789 sub hdr_mid_response ($$$$$$) {
 790         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 791         my $res = '';
 792         if ($xhdr) {
 793                 $res .= r221 . "\r\n";
 794                 $res .= "$mid $v\r\n";
 795         } else {
 796                 $res .= r225 . "\r\n";
 797                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 798                 $res .= "$pfx $v\r\n";
 799         }
 800         res($self, $res .= '.');
 801         undef;
 802 }
 803
 804 sub cmd_xrover ($;$) {
 805         my ($self, $range) = @_;
 806         my $ng = $self->{ng} or return '412 no newsgroup selected';
 807         (defined $range && $range =~ /[<>]/) and
 808                 return '420 No article(s) selected'; # no message IDs
 809
 810         $range = $self->{article} unless defined $range;
 811         my $r = get_range($self, $range);
 812         return $r unless ref $r;
 813         my ($beg, $end) = @$r;
 814         my $mm = $ng->mm;
 815         my $over = $ng->over;
 816         more($self, '224 Overview information follows');
 817
 818         long_response($self, sub {
 819                 my $h = over_header_for($over, $beg, 'references');
 820                 more($self, "$beg $h") if defined($h);
 821                 $beg++ < $end;
 822         });
 823 }
 824
 825 sub over_line ($$$$) {
 826         my ($self, $ng, $num, $smsg) = @_;
 827         # n.b. field access and procedural calls can be
 828         # 10%-15% faster than OO method calls:
 829         my $s = join("\t", $num,
 830                 $smsg->{subject},
 831                 $smsg->{from},
 832                 PublicInbox::SearchMsg::date($smsg),
 833                 "<$smsg->{mid}>",
 834                 $smsg->{references},
 835                 $smsg->{bytes},
 836                 $smsg->{lines},
 837                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 838         utf8::encode($s);
 839         $s
 840 }
 841
 842 sub cmd_over ($;$) {
 843         my ($self, $range) = @_;
 844         if ($range && $range =~ /\A<(.+)>\z/) {
 845                 my ($ng, $n) = mid_lookup($self, $1);
 846                 defined $n or return r430;
 847                 my $smsg = $ng->over->get_art($n) or return r430;
 848                 more($self, '224 Overview information follows (multi-line)');
 849
 850                 # Only set article number column if it's the current group
 851                 my $self_ng = $self->{ng};
 852                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 853                 more($self, over_line($self, $ng, $n, $smsg));
 854                 '.';
 855         } else {
 856                 cmd_xover($self, $range);
 857         }
 858 }
 859
 860 sub cmd_xover ($;$) {
 861         my ($self, $range) = @_;
 862         $range = $self->{article} unless defined $range;
 863         my $r = get_range($self, $range);
 864         return $r unless ref $r;
 865         my ($beg, $end) = @$r;
 866         more($self, "224 Overview information follows for $beg to $end");
 867         my $over = $self->{ng}->over;
 868         my $cur = $beg;
 869         long_response($self, sub {
 870                 my $msgs = $over->query_xover($cur, $end);
 871                 my $nr = scalar @$msgs or return;
 872
 873                 # OVERVIEW.FMT
 874                 more($self, join("\r\n", map {
 875                         over_line($self, $self->{ng}, $_->{num}, $_);
 876                         } @$msgs));
 877                 $cur = $msgs->[-1]->{num} + 1;
 878         });
 879 }
 880
 881 sub compressed { undef }
 882
 883 sub cmd_starttls ($) {
 884         my ($self) = @_;
 885         my $sock = $self->{sock} or return;
 886         # RFC 4642 2.2.1
 887         return r502 if (ref($sock) eq 'IO::Socket::SSL' || $self->compressed);
 888         my $opt = $self->{nntpd}->{accept_tls} or
 889                 return '580 can not initiate TLS negotiation';
 890         res($self, '382 Continue with TLS negotiation');
 891         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 892         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 893         undef;
 894 }
 895
 896 # RFC 8054
 897 sub cmd_compress ($$) {
 898         my ($self, $alg) = @_;
 899         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 900         return r502 if $self->compressed || !$have_deflate;
 901         PublicInbox::NNTPdeflate->enable($self);
 902         $self->requeue;
 903         undef
 904 }
 905
 906 sub zflush {} # overridden by NNTPdeflate
 907
 908 sub cmd_xpath ($$) {
 909         my ($self, $mid) = @_;
 910         return r501 unless $mid =~ /\A<(.+)>\z/;
 911         $mid = $1;
 912         my @paths;
 913         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 914                 my $n = $ng->mm->num_for($mid);
 915                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 916         }
 917         return '430 no such article on server' unless @paths;
 918         '223 '.join(' ', @paths);
 919 }
 920
 921 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 922
 923 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 924
 925 sub do_write ($$) {
 926         my $self = $_[0];
 927         my $done = $self->write(\($_[1]));
 928         return 0 unless $self->{sock};
 929
 930         $done;
 931 }
 932
 933 sub err ($$;@) {
 934         my ($self, $fmt, @args) = @_;
 935         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 936 }
 937
 938 sub out ($$;@) {
 939         my ($self, $fmt, @args) = @_;
 940         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 941 }
 942
 943 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 944 sub event_step {
 945         my ($self) = @_;
 946
 947         return unless $self->flush_write && $self->{sock};
 948
 949         $self->update_idle_time;
 950         # only read more requests if we've drained the write buffer,
 951         # otherwise we can be buffering infinitely w/o backpressure
 952
 953         my $rbuf = $self->{rbuf} // (\(my $x = ''));
 954         my $r = 1;
 955
 956         if (index($$rbuf, "\n") < 0) {
 957                 my $off = bytes::length($$rbuf);
 958                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 959         }
 960         while ($r > 0 && $$rbuf =~ s/\A[ \t]*([^\n]*?)\r?\n//) {
 961                 my $line = $1;
 962                 return $self->close if $line =~ /[[:cntrl:]]/s;
 963                 my $t0 = now();
 964                 my $fd = fileno($self->{sock});
 965                 $r = eval { process_line($self, $line) };
 966                 my $pending = $self->{wbuf} ? ' pending' : '';
 967                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
 968         }
 969
 970         return $self->close if $r < 0;
 971         my $len = bytes::length($$rbuf);
 972         return $self->close if ($len >= LINE_MAX);
 973         $self->rbuf_idle($rbuf);
 974         $self->update_idle_time;
 975
 976         # maybe there's more pipelined data, or we'll have
 977         # to register it for socket-readiness notifications
 978         $self->requeue unless $self->{wbuf};
 979 }
 980
 981 # for graceful shutdown in PublicInbox::Daemon:
 982 sub busy {
 983         my ($self, $now) = @_;
 984         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
 985 }
 986
 987 # this is an import to prevent "perl -c" from complaining about fields
 988 sub import {
 989         $have_deflate = eval { require PublicInbox::NNTPdeflate } and
 990                 $CAPABILITIES .= "COMPRESS DEFLATE\r\n";
 991 }
 992
 993 1;