lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 # fields:
   6 # nntpd: PublicInbox::NNTPD ref
   7 # article: per-session current article number
   8 # ng: PublicInbox::Inbox ref
   9 # long_cb: long_response private data
  10 package PublicInbox::NNTP;
  11 use strict;
  12 use parent qw(PublicInbox::DS);
  13 use PublicInbox::MID qw(mid_escape $MID_EXTRACT);
  14 use PublicInbox::Eml;
  15 use POSIX qw(strftime);
  16 use PublicInbox::DS qw(now);
  17 use Digest::SHA qw(sha1_hex);
  18 use Time::Local qw(timegm timelocal);
  19 use PublicInbox::GitAsyncCat;
  20 use constant {
  21         LINE_MAX => 512, # RFC 977 section 2.3
  22         r501 => '501 command syntax error',
  23         r502 => '502 Command unavailable',
  24         r221 => '221 Header follows',
  25         r224 => '224 Overview information follows (multi-line)',
  26         r225 => '225 Headers follow (multi-line)',
  27         r430 => '430 No article with that message-id',
  28 };
  29 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  30 use Errno qw(EAGAIN);
  31 my $ONE_MSGID = qr/\A$MID_EXTRACT\z/;
  32 my @OVERVIEW = qw(Subject From Date Message-ID References);
  33 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  34                 "Xref:full\r\n";
  35 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  36                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  37 my $CAPABILITIES = <<"";
  38 101 Capability list:\r
  39 VERSION 2\r
  40 READER\r
  41 NEWNEWS\r
  42 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  43 HDR\r
  44 OVER\r
  45 COMPRESS DEFLATE\r
  46
  47 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  48
  49 sub new ($$$) {
  50         my ($class, $sock, $nntpd) = @_;
  51         my $self = bless { nntpd => $nntpd }, $class;
  52         my $ev = EPOLLIN;
  53         my $wbuf;
  54         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
  55                 return CORE::close($sock) if $! != EAGAIN;
  56                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
  57                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  58         }
  59         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  60         if ($wbuf) {
  61                 $self->{wbuf} = $wbuf;
  62         } else {
  63                 greet($self);
  64         }
  65         $self->update_idle_time;
  66         $self;
  67 }
  68
  69 sub args_ok ($$) {
  70         my ($cb, $argc) = @_;
  71         my $tot = prototype $cb;
  72         my ($nreq, undef) = split(';', $tot);
  73         $nreq = ($nreq =~ tr/$//) - 1;
  74         $tot = ($tot =~ tr/$//) - 1;
  75         ($argc <= $tot && $argc >= $nreq);
  76 }
  77
  78 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  79 sub process_line ($$) {
  80         my ($self, $l) = @_;
  81         my ($req, @args) = split(/[ \t]+/, $l);
  82         return 1 unless defined($req); # skip blank line
  83         $req = $self->can('cmd_'.lc($req));
  84         return res($self, '500 command not recognized') unless $req;
  85         return res($self, r501) unless args_ok($req, scalar @args);
  86
  87         my $res = eval { $req->($self, @args) };
  88         my $err = $@;
  89         if ($err && $self->{sock}) {
  90                 local $/ = "\n";
  91                 chomp($l);
  92                 err($self, 'error from: %s (%s)', $l, $err);
  93                 $res = '503 program fault - command not performed';
  94         }
  95         return 0 unless defined $res;
  96         res($self, $res);
  97 }
  98
  99 # The keyword argument is not used (rfc3977 5.2.2)
 100 sub cmd_capabilities ($;$) {
 101         my ($self, undef) = @_;
 102         my $res = $CAPABILITIES;
 103         if (!$self->{sock}->can('accept_SSL') &&
 104                         $self->{nntpd}->{accept_tls}) {
 105                 $res .= "STARTTLS\r\n";
 106         }
 107         $res .= '.';
 108 }
 109
 110 sub cmd_mode ($$) {
 111         my ($self, $arg) = @_;
 112         $arg = uc $arg;
 113         return r501 unless $arg eq 'READER';
 114         '201 Posting prohibited';
 115 }
 116
 117 sub cmd_slave ($) { '202 slave status noted' }
 118
 119 sub cmd_xgtitle ($;$) {
 120         my ($self, $wildmat) = @_;
 121         more($self, '282 list of groups and descriptions follows');
 122         list_newsgroups($self, $wildmat);
 123         '.'
 124 }
 125
 126 sub list_overview_fmt ($) {
 127         my ($self) = @_;
 128         $self->msg_more($OVERVIEW_FMT);
 129 }
 130
 131 sub list_headers ($;$) {
 132         my ($self) = @_;
 133         $self->msg_more($LIST_HEADERS);
 134 }
 135
 136 sub list_active ($;$) {
 137         my ($self, $wildmat) = @_;
 138         wildmat2re($wildmat);
 139         my $groups = $self->{nntpd}->{groups};
 140         for my $ngname (grep(/$wildmat/, @{$self->{nntpd}->{groupnames}})) {
 141                 group_line($self, $groups->{$ngname});
 142         }
 143 }
 144
 145 sub list_active_times ($;$) {
 146         my ($self, $wildmat) = @_;
 147         wildmat2re($wildmat);
 148         my $groups = $self->{nntpd}->{groups};
 149         for my $ngname (grep(/$wildmat/, @{$self->{nntpd}->{groupnames}})) {
 150                 my $ibx = $groups->{$ngname};
 151                 my $c = eval { $ibx->uidvalidity } // time;
 152                 more($self, "$ngname $c <$ibx->{-primary_address}>");
 153         }
 154 }
 155
 156 sub list_newsgroups ($;$) {
 157         my ($self, $wildmat) = @_;
 158         wildmat2re($wildmat);
 159         my $groups = $self->{nntpd}->{groups};
 160         for my $ngname (grep(/$wildmat/, @{$self->{nntpd}->{groupnames}})) {
 161                 more($self, "$ngname ".$groups->{$ngname}->description);
 162         }
 163 }
 164
 165 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 166 sub cmd_list ($;$$) {
 167         my ($self, @args) = @_;
 168         if (scalar @args) {
 169                 my $arg = shift @args;
 170                 $arg =~ tr/A-Z./a-z_/;
 171                 $arg = "list_$arg";
 172                 $arg = $self->can($arg);
 173                 return r501 unless $arg && args_ok($arg, scalar @args);
 174                 more($self, '215 information follows');
 175                 $arg->($self, @args);
 176         } else {
 177                 more($self, '215 list of newsgroups follows');
 178                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 179                         group_line($self, $ng);
 180                 }
 181         }
 182         '.'
 183 }
 184
 185 sub listgroup_range_i {
 186         my ($self, $beg, $end) = @_;
 187         my $r = $self->{ng}->mm->msg_range($beg, $end, 'num');
 188         scalar(@$r) or return;
 189         more($self, join("\r\n", map { $_->[0] } @$r));
 190         1;
 191 }
 192
 193 sub listgroup_all_i {
 194         my ($self, $num) = @_;
 195         my $ary = $self->{ng}->mm->ids_after($num);
 196         scalar(@$ary) or return;
 197         more($self, join("\r\n", @$ary));
 198         1;
 199 }
 200
 201 sub cmd_listgroup ($;$$) {
 202         my ($self, $group, $range) = @_;
 203         if (defined $group) {
 204                 my $res = cmd_group($self, $group);
 205                 return $res if ($res !~ /\A211 /);
 206                 more($self, $res);
 207         }
 208         $self->{ng} or return '412 no newsgroup selected';
 209         if (defined $range) {
 210                 my $r = get_range($self, $range);
 211                 return $r unless ref $r;
 212                 long_response($self, \&listgroup_range_i, @$r);
 213         } else { # grab every article number
 214                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 215         }
 216 }
 217
 218 sub parse_time ($$;$) {
 219         my ($date, $time, $gmt) = @_;
 220         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 221         if (defined $gmt) {
 222                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 223                 $gmt = 1;
 224         }
 225         my ($YYYY, $MM, $DD);
 226         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 227                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 228         } else { # legacy clients send YYMMDD
 229                 my $YY;
 230                 ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 231                 my @now = $gmt ? gmtime : localtime;
 232                 my $cur_year = $now[5] + 1900;
 233                 my $cur_cent = int($cur_year / 100) * 100;
 234                 $YYYY = (($YY + $cur_cent) > $cur_year) ?
 235                         ($YY + 1900) : ($YY + $cur_cent);
 236         }
 237         if ($gmt) {
 238                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 239         } else {
 240                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 241         }
 242 }
 243
 244 sub group_line ($$) {
 245         my ($self, $ng) = @_;
 246         my ($min, $max) = $ng->mm->minmax;
 247         more($self, "$ng->{newsgroup} $max $min n");
 248 }
 249
 250 sub cmd_newgroups ($$$;$$) {
 251         my ($self, $date, $time, $gmt, $dists) = @_;
 252         my $ts = eval { parse_time($date, $time, $gmt) };
 253         return r501 if $@;
 254
 255         # TODO dists
 256         more($self, '231 list of new newsgroups follows');
 257         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 258                 my $c = eval { $ng->uidvalidity } // 0;
 259                 next unless $c > $ts;
 260                 group_line($self, $ng);
 261         }
 262         '.'
 263 }
 264
 265 sub wildmat2re (;$) {
 266         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 267         my %keep;
 268         my $salt = rand;
 269         my $tmp = $_[0];
 270
 271         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 272                 my $orig = $1;
 273                 my $key = sha1_hex($orig . $salt);
 274                 $orig =~ s/([^\w\-])+/\Q$1/g;
 275                 $keep{$key} = $orig;
 276                 $key
 277                 #gex;
 278         my %map = ('*' => '.*', '?' => '.' );
 279         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 280         if (scalar %keep) {
 281                 $tmp =~ s#([a-f0-9]{40})#
 282                         my $orig = $keep{$1};
 283                         defined $orig ? $orig : $1;
 284                         #ge;
 285         }
 286         $_[0] = qr/\A$tmp\z/;
 287 }
 288
 289 sub ngpat2re (;$) {
 290         return $_[0] = qr/\A\z/ unless defined $_[0];
 291         my %map = ('*' => '.*', ',' => '|');
 292         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 293         $_[0] = qr/\A(?:$_[0])\z/;
 294 }
 295
 296 sub newnews_i {
 297         my ($self, $names, $ts, $prev) = @_;
 298         my $ngname = $names->[0];
 299         if (my $ibx = $self->{nntpd}->{groups}->{$ngname}) {
 300                 if (my $over = $ibx->over) {
 301                         my $msgs = $over->query_ts($ts, $$prev);
 302                         if (scalar @$msgs) {
 303                                 more($self, '<' .
 304                                         join(">\r\n<",
 305                                                 map { $_->{mid} } @$msgs ) .
 306                                         '>');
 307                                 $$prev = $msgs->[-1]->{num};
 308                                 return 1; # continue on current group
 309                         }
 310                 }
 311         }
 312         shift @$names;
 313         if (@$names) { # continue onto next newsgroup
 314                 $$prev = 0;
 315                 1;
 316         } else { # all done, break out of the long_response
 317                 undef;
 318         }
 319 }
 320
 321 sub cmd_newnews ($$$$;$$) {
 322         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 323         my $ts = eval { parse_time($date, $time, $gmt) };
 324         return r501 if $@;
 325         more($self, '230 list of new articles by message-id follows');
 326         my ($keep, $skip) = split('!', $newsgroups, 2);
 327         ngpat2re($keep);
 328         ngpat2re($skip);
 329         my @names = grep(!/$skip/, grep(/$keep/,
 330                                 @{$self->{nntpd}->{groupnames}}));
 331         return '.' unless scalar(@names);
 332         my $prev = 0;
 333         long_response($self, \&newnews_i, \@names, $ts, \$prev);
 334 }
 335
 336 sub cmd_group ($$) {
 337         my ($self, $group) = @_;
 338         my $no_such = '411 no such news group';
 339         my $nntpd = $self->{nntpd};
 340         my $ng = $nntpd->{groups}->{$group} or return $no_such;
 341         $nntpd->idler_start;
 342
 343         $self->{ng} = $ng;
 344         my ($min, $max) = $ng->mm->minmax;
 345         $self->{article} = $min;
 346         my $est_size = $max - $min;
 347         "211 $est_size $min $max $group";
 348 }
 349
 350 sub article_adj ($$) {
 351         my ($self, $off) = @_;
 352         my $ng = $self->{ng} or return '412 no newsgroup selected';
 353
 354         my $n = $self->{article};
 355         defined $n or return '420 no current article has been selected';
 356
 357         $n += $off;
 358         my $mid = $ng->mm->mid_for($n);
 359         unless ($mid) {
 360                 $n = $off > 0 ? 'next' : 'previous';
 361                 return "421 no $n article in this group";
 362         }
 363         $self->{article} = $n;
 364         "223 $n <$mid> article retrieved - request text separately";
 365 }
 366
 367 sub cmd_next ($) { article_adj($_[0], 1) }
 368 sub cmd_last ($) { article_adj($_[0], -1) }
 369
 370 # We want to encourage using email and CC-ing everybody involved to avoid
 371 # the single-point-of-failure a single server provides.
 372 sub cmd_post ($) {
 373         my ($self) = @_;
 374         my $ng = $self->{ng};
 375         $ng ? "440 mailto:$ng->{-primary_address} to post"
 376                 : '440 posting not allowed'
 377 }
 378
 379 sub cmd_quit ($) {
 380         my ($self) = @_;
 381         res($self, '205 closing connection - goodbye!');
 382         $self->shutdn;
 383         undef;
 384 }
 385
 386 sub header_append ($$$) {
 387         my ($hdr, $k, $v) = @_;
 388         my @v = $hdr->header_raw($k);
 389         foreach (@v) {
 390                 return if $v eq $_;
 391         }
 392         $hdr->header_set($k, @v, $v);
 393 }
 394
 395 sub xref ($$$$) {
 396         my ($self, $ng, $n, $mid) = @_;
 397         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 398
 399         # num_for is pretty cheap and sometimes we'll lookup the existence
 400         # of an article without getting even the OVER info.  In other words,
 401         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 402         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 403         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 404                 next if $ng eq $other;
 405                 my $num = eval { $other->mm->num_for($mid) } or next;
 406                 $ret .= " $other->{newsgroup}:$num";
 407         }
 408         $ret;
 409 }
 410
 411 sub set_nntp_headers ($$) {
 412         my ($hdr, $smsg) = @_;
 413         my ($mid) = $smsg->{mid};
 414
 415         # leafnode (and maybe other NNTP clients) have trouble dealing
 416         # with v2 messages which have multiple Message-IDs (either due
 417         # to our own content-based dedupe or buggy git-send-email versions).
 418         my @mids = $hdr->header_raw('Message-ID');
 419         if (scalar(@mids) > 1) {
 420                 my $mid0 = "<$mid>";
 421                 $hdr->header_set('Message-ID', $mid0);
 422                 my @alt = $hdr->header_raw('X-Alt-Message-ID');
 423                 my %seen = map { $_ => 1 } (@alt, $mid0);
 424                 push(@alt, grep { !$seen{$_}++ } @mids);
 425                 $hdr->header_set('X-Alt-Message-ID', @alt);
 426         }
 427
 428         # clobber some existing headers
 429         my $ibx = $smsg->{-ibx};
 430         my $xref = xref($smsg->{nntp}, $ibx, $smsg->{num}, $mid);
 431         $hdr->header_set('Xref', $xref);
 432
 433         # RFC 5536 3.1.4
 434         my ($server_name, $newsgroups) = split(/ /, $xref, 2);
 435         $newsgroups =~ s/:[0-9]+\b//g; # drop NNTP article numbers
 436         $newsgroups =~ tr/ /,/;
 437         $hdr->header_set('Newsgroups', $newsgroups);
 438
 439         # *something* here is required for leafnode, try to follow
 440         # RFC 5536 3.1.5...
 441         $hdr->header_set('Path', $server_name . '!not-for-mail');
 442
 443         header_append($hdr, 'List-Post', "<mailto:$ibx->{-primary_address}>");
 444         if (my $url = $ibx->base_url) {
 445                 $mid = mid_escape($mid);
 446                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 447                 header_append($hdr, 'List-Archive', "<$url>");
 448         }
 449 }
 450
 451 sub art_lookup ($$$) {
 452         my ($self, $art, $code) = @_;
 453         my $ng = $self->{ng};
 454         my ($n, $mid);
 455         my $err;
 456         if (defined $art) {
 457                 if ($art =~ /\A[0-9]+\z/) {
 458                         $err = '423 no such article number in this group';
 459                         $n = int($art);
 460                         goto find_mid;
 461                 } elsif ($art =~ $ONE_MSGID) {
 462                         $mid = $1;
 463                         $err = r430;
 464                         $n = $ng->mm->num_for($mid) if $ng;
 465                         goto found if defined $n;
 466                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 467                                 $n = $g->mm->num_for($mid);
 468                                 if (defined $n) {
 469                                         $ng = $g;
 470                                         goto found;
 471                                 }
 472                         }
 473                         return $err;
 474                 } else {
 475                         return r501;
 476                 }
 477         } else {
 478                 $err = '420 no current article has been selected';
 479                 $n = $self->{article};
 480                 defined $n or return $err;
 481 find_mid:
 482                 $ng or return '412 no newsgroup has been selected';
 483                 $mid = $ng->mm->mid_for($n);
 484                 defined $mid or return $err;
 485         }
 486 found:
 487         my $smsg = $ng->over->get_art($n) or return $err;
 488         $smsg->{-ibx} = $ng;
 489         if ($code == 223) { # STAT
 490                 set_art($self, $n);
 491                 "223 $n <$smsg->{mid}> article retrieved - " .
 492                         "request text separately";
 493         } else { # HEAD | BODY | ARTICLE
 494                 $smsg->{nntp} = $self;
 495                 $smsg->{nntp_code} = $code;
 496                 set_art($self, $art);
 497                 # this dereferences to `undef'
 498                 ${git_async_cat($ng->git, $smsg->{blob}, \&blob_cb, $smsg)};
 499         }
 500 }
 501
 502 sub msg_body_write ($$) {
 503         my ($self, $msg) = @_;
 504
 505         # these can momentarily double the memory consumption :<
 506         $$msg =~ s/^\./../smg;
 507         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 508         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 509         $self->msg_more($$msg);
 510 }
 511
 512 sub set_art {
 513         my ($self, $art) = @_;
 514         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 515 }
 516
 517 sub msg_hdr_write ($$) {
 518         my ($eml, $smsg) = @_;
 519         set_nntp_headers($eml, $smsg);
 520
 521         my $hdr = $eml->{hdr} // \(my $x = '');
 522         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 523         $$hdr =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 524         $$hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 525
 526         # for leafnode compatibility, we need to ensure Message-ID headers
 527         # are only a single line.
 528         $$hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 529         $smsg->{nntp}->msg_more($$hdr);
 530 }
 531
 532 sub blob_cb { # called by git->cat_async via git_async_cat
 533         my ($bref, $oid, $type, $size, $smsg) = @_;
 534         my $self = $smsg->{nntp};
 535         my $code = $smsg->{nntp_code};
 536         if (!defined($oid)) {
 537                 # it's possible to have TOCTOU if an admin runs
 538                 # public-inbox-(edit|purge), just move onto the next message
 539                 warn "E: $smsg->{blob} missing in $smsg->{-ibx}->{inboxdir}\n";
 540                 return $self->requeue;
 541         } elsif ($smsg->{blob} ne $oid) {
 542                 $self->close;
 543                 die "BUG: $smsg->{blob} != $oid";
 544         }
 545         my $r = "$code $smsg->{num} <$smsg->{mid}> article retrieved - ";
 546         my $eml = PublicInbox::Eml->new($bref);
 547         if ($code == 220) {
 548                 more($self, $r .= 'head and body follow');
 549                 msg_hdr_write($eml, $smsg);
 550                 $self->msg_more("\r\n");
 551                 msg_body_write($self, $bref);
 552         } elsif ($code == 221) {
 553                 more($self, $r .= 'head follows');
 554                 msg_hdr_write($eml, $smsg);
 555         } elsif ($code == 222) {
 556                 more($self, $r .= 'body follows');
 557                 msg_body_write($self, $bref);
 558         } else {
 559                 $self->close;
 560                 die "BUG: bad code: $r";
 561         }
 562         $self->write(\".\r\n"); # flushes (includes ->zflush)
 563         $self->requeue;
 564 }
 565
 566 sub cmd_article ($;$) {
 567         my ($self, $art) = @_;
 568         art_lookup($self, $art, 220);
 569 }
 570
 571 sub cmd_head ($;$) {
 572         my ($self, $art) = @_;
 573         art_lookup($self, $art, 221);
 574 }
 575
 576 sub cmd_body ($;$) {
 577         my ($self, $art) = @_;
 578         art_lookup($self, $art, 222);
 579 }
 580
 581 sub cmd_stat ($;$) {
 582         my ($self, $art) = @_;
 583         art_lookup($self, $art, 223); # art may be msgid
 584 }
 585
 586 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 587
 588 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 589
 590 sub cmd_help ($) {
 591         my ($self) = @_;
 592         more($self, '100 help text follows');
 593         '.'
 594 }
 595
 596 sub get_range ($$) {
 597         my ($self, $range) = @_;
 598         my $ng = $self->{ng} or return '412 no news group has been selected';
 599         defined $range or return '420 No article(s) selected';
 600         my ($beg, $end);
 601         my ($min, $max) = $ng->mm->minmax;
 602         if ($range =~ /\A([0-9]+)\z/) {
 603                 $beg = $end = $1;
 604         } elsif ($range =~ /\A([0-9]+)-\z/) {
 605                 ($beg, $end) = ($1, $max);
 606         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 607                 ($beg, $end) = ($1, $2);
 608         } else {
 609                 return r501;
 610         }
 611         $beg = $min if ($beg < $min);
 612         $end = $max if ($end > $max);
 613         return '420 No article(s) selected' if ($beg > $end);
 614         [ \$beg, $end ];
 615 }
 616
 617 sub long_step {
 618         my ($self) = @_;
 619         # wbuf is unset or empty, here; {long} may add to it
 620         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
 621         my $more = eval { $cb->($self, @args) };
 622         if ($@ || !$self->{sock}) { # something bad happened...
 623                 delete $self->{long_cb};
 624                 my $elapsed = now() - $t0;
 625                 if ($@) {
 626                         err($self,
 627                             "%s during long response[$fd] - %0.6f",
 628                             $@, $elapsed);
 629                 }
 630                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 631                 $self->close;
 632         } elsif ($more) { # $self->{wbuf}:
 633                 $self->update_idle_time;
 634
 635                 # COMPRESS users all share the same DEFLATE context.
 636                 # Flush it here to ensure clients don't see
 637                 # each other's data
 638                 $self->zflush;
 639
 640                 # no recursion, schedule another call ASAP, but only after
 641                 # all pending writes are done.  autovivify wbuf:
 642                 my $new_size = push(@{$self->{wbuf}}, \&long_step);
 643
 644                 # wbuf may be populated by $cb, no need to rearm if so:
 645                 $self->requeue if $new_size == 1;
 646         } else { # all done!
 647                 delete $self->{long_cb};
 648                 res($self, '.');
 649                 my $elapsed = now() - $t0;
 650                 my $fd = fileno($self->{sock});
 651                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 652                 my $wbuf = $self->{wbuf}; # do NOT autovivify
 653                 $self->requeue unless $wbuf && @$wbuf;
 654         }
 655 }
 656
 657 sub long_response ($$;@) {
 658         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 659
 660         my $sock = $self->{sock} or return;
 661         # make sure we disable reading during a long response,
 662         # clients should not be sending us stuff and making us do more
 663         # work while we are stream a response to them
 664         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
 665         long_step($self); # kick off!
 666         undef;
 667 }
 668
 669 sub hdr_msgid_range_i {
 670         my ($self, $beg, $end) = @_;
 671         my $r = $self->{ng}->mm->msg_range($beg, $end);
 672         @$r or return;
 673         more($self, join("\r\n", map { "$_->[0] <$_->[1]>" } @$r));
 674         1;
 675 }
 676
 677 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 678         my ($self, $xhdr, $range) = @_;
 679
 680         if (defined $range && $range =~ $ONE_MSGID) {
 681                 my ($ng, $n) = mid_lookup($self, $1);
 682                 return r430 unless $n;
 683                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 684         } else { # numeric range
 685                 $range = $self->{article} unless defined $range;
 686                 my $r = get_range($self, $range);
 687                 return $r unless ref $r;
 688                 more($self, $xhdr ? r221 : r225);
 689                 long_response($self, \&hdr_msgid_range_i, @$r);
 690         }
 691 }
 692
 693 sub mid_lookup ($$) {
 694         my ($self, $mid) = @_;
 695         my $self_ng = $self->{ng};
 696         if ($self_ng) {
 697                 my $n = $self_ng->mm->num_for($mid);
 698                 return ($self_ng, $n) if defined $n;
 699         }
 700         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 701                 next if defined $self_ng && $ng eq $self_ng;
 702                 my $n = $ng->mm->num_for($mid);
 703                 return ($ng, $n) if defined $n;
 704         }
 705         (undef, undef);
 706 }
 707
 708 sub xref_range_i {
 709         my ($self, $beg, $end) = @_;
 710         my $ng = $self->{ng};
 711         my $r = $ng->mm->msg_range($beg, $end);
 712         @$r or return;
 713         more($self, join("\r\n", map {
 714                 my $num = $_->[0];
 715                 "$num ".xref($self, $ng, $num, $_->[1]);
 716         } @$r));
 717         1;
 718 }
 719
 720 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 721         my ($self, $xhdr, $range) = @_;
 722
 723         if (defined $range && $range =~ $ONE_MSGID) {
 724                 my $mid = $1;
 725                 my ($ng, $n) = mid_lookup($self, $mid);
 726                 return r430 unless $n;
 727                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 728                                 xref($self, $ng, $n, $mid));
 729         } else { # numeric range
 730                 $range = $self->{article} unless defined $range;
 731                 my $r = get_range($self, $range);
 732                 return $r unless ref $r;
 733                 more($self, $xhdr ? r221 : r225);
 734                 long_response($self, \&xref_range_i, @$r);
 735         }
 736 }
 737
 738 sub over_header_for {
 739         my ($over, $num, $field) = @_;
 740         my $smsg = $over->get_art($num) or return;
 741         return PublicInbox::Smsg::date($smsg) if $field eq 'date';
 742         $smsg->{$field};
 743 }
 744
 745 sub smsg_range_i {
 746         my ($self, $beg, $end, $field) = @_;
 747         my $over = $self->{ng}->over;
 748         my $msgs = $over->query_xover($$beg, $end);
 749         scalar(@$msgs) or return;
 750         my $tmp = '';
 751
 752         # ->{$field} is faster than ->$field invocations, so favor that.
 753         if ($field eq 'date') {
 754                 for my $s (@$msgs) {
 755                         $tmp .= "$s->{num} ".PublicInbox::Smsg::date($s)."\r\n"
 756                 }
 757         } else {
 758                 for my $s (@$msgs) {
 759                         $tmp .= "$s->{num} $s->{$field}\r\n";
 760                 }
 761         }
 762         utf8::encode($tmp);
 763         $self->msg_more($tmp);
 764         $$beg = $msgs->[-1]->{num} + 1;
 765 }
 766
 767 sub hdr_smsg ($$$$) {
 768         my ($self, $xhdr, $field, $range) = @_;
 769         if (defined $range && $range =~ $ONE_MSGID) {
 770                 my ($ng, $n) = mid_lookup($self, $1);
 771                 return r430 unless defined $n;
 772                 my $v = over_header_for($ng->over, $n, $field);
 773                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 774         } else { # numeric range
 775                 $range = $self->{article} unless defined $range;
 776                 my $r = get_range($self, $range);
 777                 return $r unless ref $r;
 778                 more($self, $xhdr ? r221 : r225);
 779                 long_response($self, \&smsg_range_i, @$r, $field);
 780         }
 781 }
 782
 783 sub do_hdr ($$$;$) {
 784         my ($self, $xhdr, $header, $range) = @_;
 785         my $sub = lc $header;
 786         if ($sub eq 'message-id') {
 787                 hdr_message_id($self, $xhdr, $range);
 788         } elsif ($sub eq 'xref') {
 789                 hdr_xref($self, $xhdr, $range);
 790         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 791                                 bytes|lines)\z/x) {
 792                 hdr_smsg($self, $xhdr, $sub, $range);
 793         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 794                 hdr_smsg($self, $xhdr, $1, $range);
 795         } else {
 796                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 797         }
 798 }
 799
 800 # RFC 3977
 801 sub cmd_hdr ($$;$) {
 802         my ($self, $header, $range) = @_;
 803         do_hdr($self, 0, $header, $range);
 804 }
 805
 806 # RFC 2980
 807 sub cmd_xhdr ($$;$) {
 808         my ($self, $header, $range) = @_;
 809         do_hdr($self, 1, $header, $range);
 810 }
 811
 812 sub hdr_mid_prefix ($$$$$) {
 813         my ($self, $xhdr, $ng, $n, $mid) = @_;
 814         return $mid if $xhdr;
 815
 816         # HDR for RFC 3977 users
 817         if (my $self_ng = $self->{ng}) {
 818                 ($self_ng eq $ng) ? $n : '0';
 819         } else {
 820                 '0';
 821         }
 822 }
 823
 824 sub hdr_mid_response ($$$$$$) {
 825         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 826         my $res = '';
 827         if ($xhdr) {
 828                 $res .= r221 . "\r\n";
 829                 $res .= "$mid $v\r\n";
 830         } else {
 831                 $res .= r225 . "\r\n";
 832                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 833                 $res .= "$pfx $v\r\n";
 834         }
 835         res($self, $res .= '.');
 836         undef;
 837 }
 838
 839 sub xrover_i {
 840         my ($self, $beg, $end) = @_;
 841         my $h = over_header_for($self->{ng}->over, $$beg, 'references');
 842         more($self, "$$beg $h") if defined($h);
 843         $$beg++ < $end;
 844 }
 845
 846 sub cmd_xrover ($;$) {
 847         my ($self, $range) = @_;
 848         my $ng = $self->{ng} or return '412 no newsgroup selected';
 849         (defined $range && $range =~ /[<>]/) and
 850                 return '420 No article(s) selected'; # no message IDs
 851
 852         $range = $self->{article} unless defined $range;
 853         my $r = get_range($self, $range);
 854         return $r unless ref $r;
 855         more($self, '224 Overview information follows');
 856         long_response($self, \&xrover_i, @$r);
 857 }
 858
 859 sub over_line ($$$$) {
 860         my ($self, $ng, $num, $smsg) = @_;
 861         # n.b. field access and procedural calls can be
 862         # 10%-15% faster than OO method calls:
 863         my $s = join("\t", $num,
 864                 $smsg->{subject},
 865                 $smsg->{from},
 866                 PublicInbox::Smsg::date($smsg),
 867                 "<$smsg->{mid}>",
 868                 $smsg->{references},
 869                 $smsg->{bytes},
 870                 $smsg->{lines},
 871                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 872         utf8::encode($s);
 873         $s
 874 }
 875
 876 sub cmd_over ($;$) {
 877         my ($self, $range) = @_;
 878         if ($range && $range =~ $ONE_MSGID) {
 879                 my ($ng, $n) = mid_lookup($self, $1);
 880                 defined $n or return r430;
 881                 my $smsg = $ng->over->get_art($n) or return r430;
 882                 more($self, '224 Overview information follows (multi-line)');
 883
 884                 # Only set article number column if it's the current group
 885                 my $self_ng = $self->{ng};
 886                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 887                 more($self, over_line($self, $ng, $n, $smsg));
 888                 '.';
 889         } else {
 890                 cmd_xover($self, $range);
 891         }
 892 }
 893
 894 sub xover_i {
 895         my ($self, $beg, $end) = @_;
 896         my $ng = $self->{ng};
 897         my $msgs = $ng->over->query_xover($$beg, $end);
 898         my $nr = scalar @$msgs or return;
 899
 900         # OVERVIEW.FMT
 901         more($self, join("\r\n", map {
 902                 over_line($self, $ng, $_->{num}, $_);
 903                 } @$msgs));
 904         $$beg = $msgs->[-1]->{num} + 1;
 905 }
 906
 907 sub cmd_xover ($;$) {
 908         my ($self, $range) = @_;
 909         $range = $self->{article} unless defined $range;
 910         my $r = get_range($self, $range);
 911         return $r unless ref $r;
 912         my ($beg, $end) = @$r;
 913         more($self, "224 Overview information follows for $$beg to $end");
 914         long_response($self, \&xover_i, @$r);
 915 }
 916
 917 sub compressed { undef }
 918
 919 sub cmd_starttls ($) {
 920         my ($self) = @_;
 921         my $sock = $self->{sock} or return;
 922         # RFC 4642 2.2.1
 923         return r502 if ($sock->can('accept_SSL') || $self->compressed);
 924         my $opt = $self->{nntpd}->{accept_tls} or
 925                 return '580 can not initiate TLS negotiation';
 926         res($self, '382 Continue with TLS negotiation');
 927         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 928         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 929         undef;
 930 }
 931
 932 # RFC 8054
 933 sub cmd_compress ($$) {
 934         my ($self, $alg) = @_;
 935         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 936         return r502 if $self->compressed;
 937         PublicInbox::NNTPdeflate->enable($self);
 938         $self->requeue;
 939         undef
 940 }
 941
 942 sub zflush {} # overridden by NNTPdeflate
 943
 944 sub cmd_xpath ($$) {
 945         my ($self, $mid) = @_;
 946         return r501 unless $mid =~ $ONE_MSGID;
 947         $mid = $1;
 948         my @paths;
 949         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 950                 my $n = $ng->mm->num_for($mid);
 951                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 952         }
 953         return '430 no such article on server' unless @paths;
 954         '223 '.join(' ', @paths);
 955 }
 956
 957 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 958
 959 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 960
 961 sub do_write ($$) {
 962         my $self = $_[0];
 963         my $done = $self->write(\($_[1]));
 964         return 0 unless $self->{sock};
 965
 966         $done;
 967 }
 968
 969 sub err ($$;@) {
 970         my ($self, $fmt, @args) = @_;
 971         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 972 }
 973
 974 sub out ($$;@) {
 975         my ($self, $fmt, @args) = @_;
 976         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 977 }
 978
 979 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 980 sub event_step {
 981         my ($self) = @_;
 982
 983         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
 984
 985         $self->update_idle_time;
 986         # only read more requests if we've drained the write buffer,
 987         # otherwise we can be buffering infinitely w/o backpressure
 988
 989         my $rbuf = $self->{rbuf} // \(my $x = '');
 990         my $line = index($$rbuf, "\n");
 991         while ($line < 0) {
 992                 return $self->close if length($$rbuf) >= LINE_MAX;
 993                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
 994                 $line = index($$rbuf, "\n");
 995         }
 996         $line = substr($$rbuf, 0, $line + 1, '');
 997         $line =~ s/\r?\n\z//s;
 998         return $self->close if $line =~ /[[:cntrl:]]/s;
 999
1000         my $t0 = now();
1001         my $fd = fileno($self->{sock});
1002         my $r = eval { process_line($self, $line) };
1003         my $pending = $self->{wbuf} ? ' pending' : '';
1004         out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
1005         return $self->close if $r < 0;
1006         $self->rbuf_idle($rbuf);
1007         $self->update_idle_time;
1008
1009         # maybe there's more pipelined data, or we'll have
1010         # to register it for socket-readiness notifications
1011         $self->requeue unless $pending;
1012 }
1013
1014 # for graceful shutdown in PublicInbox::Daemon:
1015 sub busy {
1016         my ($self, $now) = @_;
1017         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1018 }
1019
1020 1;