lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::NNTP;
   4 use strict;
   5 use warnings;
   6 use base qw(Danga::Socket);
   7 use fields qw(nntpd article rbuf ng long_res);
   8 use PublicInbox::Msgmap;
   9 use PublicInbox::GitCatFile;
  10 use PublicInbox::MID qw(mid2path);
  11 use Email::MIME;
  12 use Data::Dumper qw(Dumper);
  13 use POSIX qw(strftime);
  14 use Time::HiRes qw(clock_gettime ualarm CLOCK_MONOTONIC);
  15 use constant {
  16         r501 => '501 command syntax error',
  17         long_response_limit => 0xffffffff,
  18 };
  19
  20 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  21
  22 my @OVERVIEW = qw(Subject From Date Message-ID References Bytes Lines);
  23 my %OVERVIEW = map { $_ => 1 } @OVERVIEW;
  24
  25 # disable commands with easy DoS potential:
  26 # LISTGROUP could get pretty bad, too...
  27 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  28
  29 sub new ($$$) {
  30         my ($class, $sock, $nntpd) = @_;
  31         my $self = fields::new($class);
  32         binmode $sock, ':utf8'; # RFC 3977
  33         $self->SUPER::new($sock);
  34         $self->{nntpd} = $nntpd;
  35         res($self, '201 server ready - post via email');
  36         $self->{rbuf} = '';
  37         $self->watch_read(1);
  38         $self;
  39 }
  40
  41 sub args_ok ($$) {
  42         my ($cb, $argc) = @_;
  43         my $tot = prototype $cb;
  44         my ($nreq, undef) = split(';', $tot);
  45         $nreq = ($nreq =~ tr/$//) - 1;
  46         $tot = ($tot =~ tr/$//) - 1;
  47         ($argc <= $tot && $argc >= $nreq);
  48 }
  49
  50 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  51 sub process_line ($$) {
  52         my ($self, $l) = @_;
  53         my ($req, @args) = split(/\s+/, $l);
  54         $req = lc($req);
  55         $req = eval {
  56                 no strict 'refs';
  57                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
  58         };
  59         return res($self, '500 command not recognized') unless $req;
  60         return res($self, r501) unless args_ok($req, scalar @args);
  61
  62         my $res = eval { $req->($self, @args) };
  63         my $err = $@;
  64         if ($err && !$self->{closed}) {
  65                 chomp($l = Dumper(\$l));
  66                 err($self, "error from: $l $err");
  67                 $res = '503 program fault - command not performed';
  68         }
  69         return 0 unless defined $res;
  70         res($self, $res);
  71 }
  72
  73 sub cmd_mode ($$) {
  74         my ($self, $arg) = @_;
  75         $arg = uc $arg;
  76         return r501 unless $arg eq 'READER';
  77         '200 reader status acknowledged';
  78 }
  79
  80 sub cmd_slave ($) { '202 slave status noted' }
  81
  82 sub cmd_xgtitle ($;$) {
  83         my ($self, $wildmat) = @_;
  84         more($self, '282 list of groups and descriptions follows');
  85         list_newsgroups($self, $wildmat);
  86         '.'
  87 }
  88
  89 sub list_overview_fmt ($$) {
  90         my ($self) = @_;
  91         more($self, $_ . ':') foreach @OVERVIEW;
  92 }
  93
  94 sub list_active ($;$) {
  95         my ($self, $wildmat) = @_;
  96         wildmat2re($wildmat);
  97         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
  98                 $ng->{name} =~ $wildmat or next;
  99                 group_line($self, $ng);
 100         }
 101 }
 102
 103 sub list_active_times ($;$) {
 104         my ($self, $wildmat) = @_;
 105         wildmat2re($wildmat);
 106         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 107                 $ng->{name} =~ $wildmat or next;
 108                 my $c = eval { $ng->mm->created_at } || time;
 109                 more($self, "$ng->{name} $c $ng->{address}");
 110         }
 111 }
 112
 113 sub list_newsgroups ($;$) {
 114         my ($self, $wildmat) = @_;
 115         wildmat2re($wildmat);
 116         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 117                 $ng->{name} =~ $wildmat or next;
 118                 my $d = $ng->description;
 119                 more($self, "$ng->{name} $d");
 120         }
 121 }
 122
 123 # LIST SUBSCRIPTIONS not supported
 124 sub cmd_list ($;$$) {
 125         my ($self, @args) = @_;
 126         if (scalar @args) {
 127                 my $arg = shift @args;
 128                 $arg =~ tr/A-Z./a-z_/;
 129                 $arg = "list_$arg";
 130                 return '503 function not performed' if $DISABLED{$arg};
 131
 132                 $arg = eval {
 133                         no strict 'refs';
 134                         *{$arg}{CODE};
 135                 };
 136                 return r501 unless $arg && args_ok($arg, scalar @args);
 137                 more($self, '215 information follows');
 138                 $arg->($self, @args);
 139         } else {
 140                 more($self, '215 list of newsgroups follows');
 141                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 142                         group_line($self, $ng);
 143                 }
 144         }
 145         '.'
 146 }
 147
 148 sub cmd_listgroup ($;$) {
 149         my ($self, $group) = @_;
 150         if (defined $group) {
 151                 my $res = cmd_group($self, $group);
 152                 return $res if ($res !~ /\A211 /);
 153                 more($self, $res);
 154         }
 155
 156         $self->{ng} or return '412 no newsgroup selected';
 157         $self->long_response(0, long_response_limit, sub {
 158                 my ($i) = @_;
 159                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 160                         my ($ary) = @_;
 161                         more($self, join("\r\n", @$ary));
 162                 });
 163
 164                 # -1 to adjust for implicit increment in long_response
 165                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 166         });
 167 }
 168
 169 sub parse_time ($$;$) {
 170         my ($date, $time, $gmt) = @_;
 171         use Time::Local qw();
 172         my ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 173         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 174         if (defined $gmt) {
 175                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt\n";
 176                 $gmt = 1;
 177         }
 178         my @now = $gmt ? gmtime : localtime;
 179         if ($YY > strftime('%y', @now)) {
 180                 my $cur_year = $now[5] + 1900;
 181                 $YY += int($cur_year / 1000) * 1000 - 100;
 182         }
 183
 184         if ($gmt) {
 185                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YY);
 186         } else {
 187                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YY);
 188         }
 189 }
 190
 191 sub group_line ($$) {
 192         my ($self, $ng) = @_;
 193         my ($min, $max) = $ng->mm->minmax;
 194         more($self, "$ng->{name} $max $min n") if defined $min && defined $max;
 195 }
 196
 197 sub cmd_newgroups ($$$;$$) {
 198         my ($self, $date, $time, $gmt, $dists) = @_;
 199         my $ts = eval { parse_time($date, $time, $gmt) };
 200         return r501 if $@;
 201
 202         # TODO dists
 203         more($self, '231 list of new newsgroups follows');
 204         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 205                 my $c = eval { $ng->mm->created_at } || 0;
 206                 next unless $c > $ts;
 207                 group_line($self, $ng);
 208         }
 209         '.'
 210 }
 211
 212 sub wildmat2re (;$) {
 213         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 214         my %keep;
 215         my $salt = rand;
 216         use Digest::SHA qw(sha1_hex);
 217         my $tmp = $_[0];
 218
 219         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 220                 my $orig = $1;
 221                 my $key = sha1_hex($orig . $salt);
 222                 $orig =~ s/([^\w\-])+/\Q$1/g;
 223                 $keep{$key} = $orig;
 224                 $key
 225                 #gex;
 226         my %map = ('*' => '.*', '?' => '.' );
 227         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 228         if (scalar %keep) {
 229                 $tmp =~ s#([a-f0-9]{40})#
 230                         my $orig = $keep{$1};
 231                         defined $orig ? $orig : $1;
 232                         #ge;
 233         }
 234         $_[0] = qr/\A$tmp\z/;
 235 }
 236
 237 sub ngpat2re (;$) {
 238         return $_[0] = qr/\A\z/ unless defined $_[0];
 239         my %map = ('*' => '.*', ',' => '|');
 240         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 241         $_[0] = qr/\A(?:$_[0])\z/;
 242 }
 243
 244 sub cmd_newnews ($$$$;$$) {
 245         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 246         my $ts = eval { parse_time($date, $time, $gmt) };
 247         return r501 if $@;
 248         more($self, '230 list of new articles by message-id follows');
 249         my ($keep, $skip) = split('!', $newsgroups, 2);
 250         ngpat2re($keep);
 251         ngpat2re($skip);
 252         my @srch;
 253         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 254                 $ng->{name} =~ $keep or next;
 255                 $ng->{name} =~ $skip and next;
 256                 my $srch = $ng->search or next;
 257                 push @srch, $srch;
 258         };
 259         return '.' unless @srch;
 260
 261         $ts .= '..';
 262         my $opts = { asc => 1, limit => 1000, offset => 0 };
 263         $self->long_response(0, long_response_limit, sub {
 264                 my ($i) = @_;
 265                 my $srch = $srch[0];
 266                 my $res = $srch->query($ts, $opts);
 267                 my $msgs = $res->{msgs};
 268                 if (my $nr = scalar @$msgs) {
 269                         more($self, '<' .
 270                                 join(">\r\n<", map { $_->mid } @$msgs ).
 271                                 '>');
 272                         $opts->{offset} += $nr;
 273                 } else {
 274                         shift @srch;
 275                         if (@srch) { # continue onto next newsgroup
 276                                 $opts->{offset} = 0;
 277                         } else { # break out of the long response.
 278                                 $$i = long_response_limit;
 279                         }
 280                 }
 281         });
 282 }
 283
 284 sub cmd_group ($$) {
 285         my ($self, $group) = @_;
 286         my $no_such = '411 no such news group';
 287         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 288
 289         $self->{ng} = $ng;
 290         my ($min, $max) = $ng->mm->minmax;
 291         $min ||= 0;
 292         $max ||= 0;
 293         $self->{article} = $min;
 294         my $est_size = $max - $min;
 295         "211 $est_size $min $max $group";
 296 }
 297
 298 sub article_adj ($$) {
 299         my ($self, $off) = @_;
 300         my $ng = $self->{ng} or return '412 no newsgroup selected';
 301
 302         my $n = $self->{article};
 303         defined $n or return '420 no current article has been selected';
 304
 305         $n += $off;
 306         my $mid = $ng->mm->mid_for($n);
 307         unless ($mid) {
 308                 $n = $off > 0 ? 'next' : 'previous';
 309                 return "421 no $n article in this group";
 310         }
 311         $self->{article} = $n;
 312         "223 $n <$mid> article retrieved - request text separately";
 313 }
 314
 315 sub cmd_next ($) { article_adj($_[0], 1) }
 316 sub cmd_last ($) { article_adj($_[0], -1) }
 317
 318 # We want to encourage using email and CC-ing everybody involved to avoid
 319 # the single-point-of-failure a single server provides.
 320 sub cmd_post ($) {
 321         my ($self) = @_;
 322         my $ng = $self->{ng};
 323         $ng ? "440 mailto:$ng->{address} to post" : '440 posting not allowed'
 324 }
 325
 326 sub cmd_quit ($) {
 327         my ($self) = @_;
 328         res($self, '205 closing connection - goodbye!');
 329         $self->close;
 330         undef;
 331 }
 332
 333 sub art_lookup ($$$) {
 334         my ($self, $art, $set_headers) = @_;
 335         my $ng = $self->{ng};
 336         my ($n, $mid);
 337         my $err;
 338         if (defined $art) {
 339                 if ($art =~ /\A\d+\z/o) {
 340                         $err = '423 no such article number in this group';
 341                         $n = int($art);
 342                         goto find_mid;
 343                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 344                         $mid = $1;
 345                         $err = '430 no such article found';
 346                         $n = $ng->mm->num_for($mid) if $ng;
 347                         goto found if defined $n;
 348                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 349                                 $n = $g->mm->num_for($mid);
 350                                 if (defined $n) {
 351                                         $ng = $g;
 352                                         goto found;
 353                                 }
 354                         }
 355                         return $err;
 356                 } else {
 357                         return r501;
 358                 }
 359         } else {
 360                 $err = '420 no current article has been selected';
 361                 $n = $self->{article};
 362                 defined $n or return $err;
 363 find_mid:
 364                 $ng or return '412 no newsgroup has been selected';
 365                 $mid = $ng->mm->mid_for($n);
 366                 defined $mid or return $err;
 367         }
 368 found:
 369         my $o = 'HEAD:' . mid2path($mid);
 370         my $bytes;
 371         my $s = eval { Email::MIME->new($ng->gcf->cat_file($o, \$bytes)) };
 372         return $err unless $s;
 373         if ($set_headers) {
 374                 $s->header_set('Newsgroups', $ng->{name});
 375                 $s->header_set('Lines', $s->body =~ tr!\n!\n!);
 376                 $s->header_set('Xref', xref($ng, $n));
 377
 378                 # must be last
 379                 if ($set_headers == 2) {
 380                         $s->header_set('Bytes', $bytes);
 381                         $s->body_set('');
 382                 }
 383         }
 384         [ $n, $mid, $s ];
 385 }
 386
 387 sub simple_body_write ($$) {
 388         my ($self, $s) = @_;
 389         my $body = $s->body;
 390         $s->body_set('');
 391         $body =~ s/^\./../smg;
 392         do_more($self, $body);
 393         '.'
 394 }
 395
 396 sub header_str ($) {
 397         my ($s) = @_;
 398         my $h = $s->header_obj;
 399         $h->header_set('Bytes');
 400         $h->as_string
 401 }
 402
 403 sub set_art {
 404         my ($self, $art) = @_;
 405         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 406 }
 407
 408 sub cmd_article ($;$) {
 409         my ($self, $art) = @_;
 410         my $r = $self->art_lookup($art, 1);
 411         return $r unless ref $r;
 412         my ($n, $mid, $s) = @$r;
 413         set_art($self, $art);
 414         more($self, "220 $n <$mid> article retrieved - head and body follow");
 415         do_more($self, header_str($s));
 416         do_more($self, "\r\n");
 417         simple_body_write($self, $s);
 418 }
 419
 420 sub cmd_head ($;$) {
 421         my ($self, $art) = @_;
 422         my $r = $self->art_lookup($art, 2);
 423         return $r unless ref $r;
 424         my ($n, $mid, $s) = @$r;
 425         set_art($self, $art);
 426         more($self, "221 $n <$mid> article retrieved - head follows");
 427         do_more($self, header_str($s));
 428         '.'
 429 }
 430
 431 sub cmd_body ($;$) {
 432         my ($self, $art) = @_;
 433         my $r = $self->art_lookup($art, 0);
 434         return $r unless ref $r;
 435         my ($n, $mid, $s) = @$r;
 436         set_art($self, $art);
 437         more($self, "222 $n <$mid> article retrieved - body follows");
 438         simple_body_write($self, $s);
 439 }
 440
 441 sub cmd_stat ($;$) {
 442         my ($self, $art) = @_;
 443         my $r = $self->art_lookup($art, 0);
 444         return $r unless ref $r;
 445         my ($n, $mid, undef) = @$r;
 446         set_art($self, $art);
 447         "223 $n <$mid> article retrieved - request text separately";
 448 }
 449
 450 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 451
 452 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 453
 454 sub cmd_help ($) {
 455         my ($self) = @_;
 456         more($self, '100 help text follows');
 457         '.'
 458 }
 459
 460 sub get_range ($$) {
 461         my ($self, $range) = @_;
 462         my $ng = $self->{ng} or return '412 no news group has been selected';
 463         defined $range or return '420 No article(s) selected';
 464         my ($beg, $end);
 465         my ($min, $max) = $ng->mm->minmax;
 466         if ($range =~ /\A(\d+)\z/) {
 467                 $beg = $end = $1;
 468         } elsif ($range =~ /\A(\d+)-\z/) {
 469                 ($beg, $end) = ($1, $max);
 470         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 471                 ($beg, $end) = ($1, $2);
 472         } else {
 473                 return r501;
 474         }
 475         $beg = $min if ($beg < $min);
 476         $end = $max if ($end > $max);
 477         return '420 No article(s) selected' if ($beg > $end);
 478         [ $beg, $end ];
 479 }
 480
 481 sub xhdr ($$) {
 482         my ($r, $header) = @_;
 483         $r = $r->[2]->header_obj->header($header);
 484         defined $r or return;
 485         $r =~ s/[\r\n\t]+/ /sg;
 486         $r;
 487 }
 488
 489 sub long_response ($$$$) {
 490         my ($self, $beg, $end, $cb) = @_;
 491         die "BUG: nested long response" if $self->{long_res};
 492
 493         # make sure we disable reading during a long response,
 494         # clients should not be sending us stuff and making us do more
 495         # work while we are stream a response to them
 496         $self->watch_read(0);
 497         my $fd = fileno $self->{sock};
 498         my $t0 = now();
 499         $self->{long_res} = sub {
 500                 # limit our own running time for fairness with other
 501                 # clients and to avoid buffering too much:
 502                 my $yield;
 503                 local $SIG{ALRM} = sub { $yield = 1 };
 504                 ualarm(100000);
 505
 506                 my $err;
 507                 do {
 508                         eval { $cb->(\$beg) };
 509                 } until (($err = $@) || $self->{closed} || $yield ||
 510                          $self->{write_buf_size} || ++$beg > $end);
 511                 ualarm(0);
 512
 513                 if ($err || $self->{closed}) {
 514                         $self->{long_res} = undef;
 515
 516                         if ($err) {
 517                                 err($self,
 518                                     "$err during long response[$fd] - %0.6f",
 519                                         now() - $t0);
 520                         }
 521                         if ($self->{closed}) {
 522                                 out($self, " deferred[$fd] aborted - %0.6f",
 523                                            now() - $t0);
 524                         } else {
 525                                 $self->watch_read(1);
 526                         }
 527                 } elsif ($yield || $self->{write_buf_size}) {
 528                         # no recursion, schedule another call ASAP
 529                         # but only after all pending writes are done
 530                         Danga::Socket->AddTimer(0, sub {
 531                                 $self->write($self->{long_res});
 532                         });
 533                 } else { # all done!
 534                         $self->{long_res} = undef;
 535                         $self->watch_read(1);
 536                         res($self, '.');
 537                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 538                 }
 539         };
 540         $self->{long_res}->(); # kick off!
 541         undef;
 542 }
 543
 544 sub xhdr_message_id ($$) { # optimize XHDR Message-ID [range] for slrnpull.
 545         my ($self, $range) = @_;
 546
 547         my $mm = $self->{ng}->mm;
 548         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 549                 my $n = $mm->num_for($range);
 550                 more($self, '221 Header follows');
 551                 more($self, "<$range> <$range>") if defined $n;
 552                 '.';
 553         } else { # numeric range
 554                 $range = $self->{article} unless defined $range;
 555                 my $r = get_range($self, $range);
 556                 return $r unless ref $r;
 557                 my ($beg, $end) = @$r;
 558                 more($self, '221 Header follows');
 559                 $self->long_response($beg, $end, sub {
 560                         my ($i) = @_;
 561                         my $mid = $mm->mid_for($$i);
 562                         more($self, "$$i <$mid>") if defined $mid;
 563                 });
 564         }
 565 }
 566
 567 sub xref ($$) {
 568         my ($ng, $n) = @_;
 569         "$ng->{domain} $ng->{name}:$n"
 570 }
 571
 572 sub xhdr_xref ($$) { # optimize XHDR Xref [range] for rtin
 573         my ($self, $range) = @_;
 574
 575         my $ng = $self->{ng};
 576         my $mm = $ng->mm;
 577         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 578                 my $n = $mm->num_for($range);
 579                 more($self, '221 Header follows');
 580                 more($self, "<$range> ".xref($ng, $n)) if defined $n;
 581                 '.';
 582         } else { # numeric range
 583                 $range = $self->{article} unless defined $range;
 584                 my $r = get_range($self, $range);
 585                 return $r unless ref $r;
 586                 my ($beg, $end) = @$r;
 587                 more($self, '221 Header follows');
 588                 $self->long_response($beg, $end, sub {
 589                         my ($i) = @_;
 590                         my $mid = $mm->mid_for($$i);
 591                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 592                 });
 593         }
 594 }
 595
 596 sub header_obj_for {
 597         my ($srch, $mid) = @_;
 598         eval {
 599                 my $smsg = $srch->lookup_message($mid);
 600                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 601                 $smsg->mini_mime->header_obj;
 602         };
 603 };
 604
 605 sub xhdr_searchmsg ($$$) {
 606         my ($self, $sub, $range) = @_;
 607         my $srch = $self->{ng}->search;
 608         my $emit = ($sub eq 'date') ? sub {
 609                 my ($pfx, $m) = @_;
 610                 my @t = gmtime($m->header('X-PI-TS'));
 611                 more($self, "$pfx ". strftime('%a, %d %b %Y %T %z', @t));
 612         } : sub {
 613                 my ($pfx, $m) = @_;
 614                 my $h = $m->header($sub);
 615                 more($self, "$pfx $h") if defined $h;
 616         };
 617
 618         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 619                 more($self, '221 Header follows');
 620                 my $m = header_obj_for($srch, $1);
 621                 $emit->($range, $m) if defined $m;
 622                 '.';
 623         } else { # numeric range
 624                 $range = $self->{article} unless defined $range;
 625                 my $mm = $self->{ng}->mm;
 626                 my $r = get_range($self, $range);
 627                 return $r unless ref $r;
 628                 my ($beg, $end) = @$r;
 629                 more($self, '221 Header follows');
 630                 $self->long_response($beg, $end, sub {
 631                         my ($i) = @_;
 632                         my $mid = $mm->mid_for($$i) or return;
 633                         my $m = header_obj_for($srch, $mid) or return;
 634                         $emit->($$i, $m);
 635                 });
 636         }
 637 }
 638
 639 sub cmd_xhdr ($$;$) {
 640         my ($self, $header, $range) = @_;
 641         my $ng = $self->{ng};
 642         defined $ng or return '412 no news group currently selected';
 643         my $sub = lc $header;
 644         if ($sub eq 'message-id') {
 645                 xhdr_message_id($self, $range);
 646         } elsif ($sub eq 'xref') {
 647                 xhdr_xref($self, $range);
 648         } elsif ($sub =~ /\A(subject|references|date)\z/ && $ng->search) {
 649                 xhdr_searchmsg($self, $sub, $range);
 650         } else {
 651                 xhdr_slow($self, $header, $range);
 652         }
 653 }
 654
 655 sub xhdr_slow ($$$) {
 656         my ($self, $header, $range) = @_;
 657
 658         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 659                 my $r = $self->art_lookup($range, 2);
 660                 return $r unless ref $r;
 661                 more($self, '221 Header follows');
 662                 if (defined($r = xhdr($r, $header))) {
 663                         more($self, "<$range> $r");
 664                 }
 665                 '.';
 666         } else { # numeric range
 667                 $range = $self->{article} unless defined $range;
 668                 my $r = get_range($self, $range);
 669                 return $r unless ref $r;
 670                 my ($beg, $end) = @$r;
 671                 more($self, '221 Header follows');
 672                 $self->long_response($beg, $end, sub {
 673                         my ($i) = @_;
 674                         $r = $self->art_lookup($$i, 2);
 675                         return unless ref $r;
 676                         defined($r = xhdr($r, $header)) or return;
 677                         more($self, "$$i $r");
 678                 });
 679         }
 680 }
 681
 682 sub cmd_xrover ($;$) {
 683         my ($self, $range) = @_;
 684         my $ng = $self->{ng} or return '412 no newsgroup selected';
 685         (defined $range && $range =~ /[<>]/) and
 686                 return '420 No article(s) selected'; # no message IDs
 687
 688         $range = $self->{article} unless defined $range;
 689         my $r = get_range($self, $range);
 690         return $r unless ref $r;
 691         my ($beg, $end) = @$r;
 692         my $mm = $ng->mm;
 693         my $srch = $ng->search;
 694         more($self, '224 Overview information follows');
 695         $self->long_response($beg, $end, sub {
 696                 my ($i) = @_;
 697                 my $mid = $mm->mid_for($$i) or return;
 698                 my $m = header_obj_for($srch, $mid) or return;
 699                 my $h = $m->header('references');
 700                 more($self, "$$i $h") if defined $h;
 701         });
 702 }
 703
 704 sub cmd_xover ($;$) {
 705         my ($self, $range) = @_;
 706         $range = $self->{article} unless defined $range;
 707         my $r = get_range($self, $range);
 708         return $r unless ref $r;
 709         my ($beg, $end) = @$r;
 710         more($self, "224 Overview information follows for $beg to $end");
 711         $self->long_response($beg, $end, sub {
 712                 my ($i) = @_;
 713                 my $r = $self->art_lookup($$i, 2);
 714                 return unless ref $r;
 715                 more($self, join("\t", $r->[0],
 716                                 map {
 717                                         my $h = xhdr($r, $_);
 718                                         defined $h ? $h : '';
 719                                 } @OVERVIEW ));
 720         });
 721 }
 722
 723 sub cmd_xpath ($$) {
 724         my ($self, $mid) = @_;
 725         return r501 unless $mid =~ /\A<(.+)>\z/;
 726         $mid = $1;
 727         my @paths;
 728         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 729                 my $n = $ng->mm->num_for($mid);
 730                 push @paths, "$ng->{name}/$n" if defined $n;
 731         }
 732         return '430 no such article on server' unless @paths;
 733         '223 '.join(' ', @paths);
 734 }
 735
 736 sub res ($$) {
 737         my ($self, $line) = @_;
 738         do_write($self, $line . "\r\n");
 739 }
 740
 741 sub more ($$) {
 742         my ($self, $line) = @_;
 743         do_more($self, $line . "\r\n");
 744 }
 745
 746 sub do_write ($$) {
 747         my ($self, $data) = @_;
 748         my $done = $self->write($data);
 749         die if $self->{closed};
 750
 751         # Do not watch for readability if we have data in the queue,
 752         # instead re-enable watching for readability when we can
 753         $self->watch_read(0) if (!$done || $self->{long_res});
 754
 755         $done;
 756 }
 757
 758 sub err ($$;@) {
 759         my ($self, $fmt, @args) = @_;
 760         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 761 }
 762
 763 sub out ($$;@) {
 764         my ($self, $fmt, @args) = @_;
 765         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 766 }
 767
 768 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 769
 770 sub do_more ($$) {
 771         my ($self, $data) = @_;
 772         if (MSG_MORE && !$self->{write_buf_size}) {
 773                 my $n = send($self->{sock}, $data, MSG_MORE);
 774                 if (defined $n) {
 775                         my $dlen = length($data);
 776                         return 1 if $n == $dlen; # all done!
 777                         $data = substr($data, $n, $dlen - $n);
 778                 }
 779         }
 780         $self->do_write($data);
 781 }
 782
 783 # callbacks for by Danga::Socket
 784
 785 sub event_hup { $_[0]->close }
 786 sub event_err { $_[0]->close }
 787
 788 sub event_write {
 789         my ($self) = @_;
 790         # only continue watching for readability when we are done writing:
 791         if ($self->write(undef) == 1 && !$self->{long_res}) {
 792                 $self->watch_read(1);
 793         }
 794 }
 795
 796 sub event_read {
 797         my ($self) = @_;
 798         use constant LINE_MAX => 512; # RFC 977 section 2.3
 799         my $line;
 800         my $r = 1;
 801 again:
 802         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 803                 $line = $1;
 804                 my $t0 = now();
 805                 $r = eval { $self->process_line($line) };
 806                 my $d = $self->{long_res} ?
 807                         ' deferred['.fileno($self->{sock}).']' : '';
 808                 out($self, "$line - %0.6f$d", now() - $t0);
 809         }
 810         unless (defined $line) {
 811                 my $buf = $self->read(LINE_MAX) or return $self->close;
 812                 $self->{rbuf} .= $$buf;
 813                 goto again;
 814         }
 815
 816         return $self->close if $r < 0;
 817         my $len = length($self->{rbuf});
 818         return $self->close if ($len >= LINE_MAX);
 819 }
 820
 821 sub watch_read {
 822         my ($self, $bool) = @_;
 823         my $rv = $self->SUPER::watch_read($bool);
 824         if ($bool && $self->{rbuf} ne '') {
 825                 # Force another read if there is a pipelined request.
 826                 # We don't know if the socket has anything for us to read,
 827                 # and we must double-check again by the time the timer fires
 828                 # in case we really did dispatch a read event and started
 829                 # another long response.
 830                 Danga::Socket->AddTimer(0, sub {
 831                         if (&Danga::Socket::POLLIN & $self->{event_watch}) {
 832                                 $self->event_read;
 833                         }
 834                 });
 835         }
 836         $rv;
 837 }
 838
 839 1;