lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::NNTP;
   4 use strict;
   5 use warnings;
   6 use base qw(Danga::Socket);
   7 use fields qw(nntpd article rbuf ng long_res);
   8 use PublicInbox::Msgmap;
   9 use PublicInbox::GitCatFile;
  10 use PublicInbox::MID qw(mid2path);
  11 use Email::MIME;
  12 use Data::Dumper qw(Dumper);
  13 use POSIX qw(strftime);
  14 use Time::HiRes qw(clock_gettime ualarm CLOCK_MONOTONIC);
  15 use constant {
  16         r501 => '501 command syntax error',
  17         r221 => '221 Header follows',
  18         r224 => '224 Overview information follows (multi-line)',
  19         r430 => '430 No article with that message-id',
  20         long_response_limit => 0xffffffff,
  21 };
  22
  23 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  24
  25 my @OVERVIEW = qw(Subject From Date Message-ID References Bytes Lines);
  26 my %OVERVIEW = map { $_ => 1 } @OVERVIEW;
  27
  28 # disable commands with easy DoS potential:
  29 # LISTGROUP could get pretty bad, too...
  30 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  31
  32 sub new ($$$) {
  33         my ($class, $sock, $nntpd) = @_;
  34         my $self = fields::new($class);
  35         binmode $sock, ':utf8'; # RFC 3977
  36         $self->SUPER::new($sock);
  37         $self->{nntpd} = $nntpd;
  38         res($self, '201 server ready - post via email');
  39         $self->{rbuf} = '';
  40         $self->watch_read(1);
  41         $self;
  42 }
  43
  44 sub args_ok ($$) {
  45         my ($cb, $argc) = @_;
  46         my $tot = prototype $cb;
  47         my ($nreq, undef) = split(';', $tot);
  48         $nreq = ($nreq =~ tr/$//) - 1;
  49         $tot = ($tot =~ tr/$//) - 1;
  50         ($argc <= $tot && $argc >= $nreq);
  51 }
  52
  53 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  54 sub process_line ($$) {
  55         my ($self, $l) = @_;
  56         my ($req, @args) = split(/\s+/, $l);
  57         $req = lc($req);
  58         $req = eval {
  59                 no strict 'refs';
  60                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
  61         };
  62         return res($self, '500 command not recognized') unless $req;
  63         return res($self, r501) unless args_ok($req, scalar @args);
  64
  65         my $res = eval { $req->($self, @args) };
  66         my $err = $@;
  67         if ($err && !$self->{closed}) {
  68                 chomp($l = Dumper(\$l));
  69                 err($self, "error from: $l $err");
  70                 $res = '503 program fault - command not performed';
  71         }
  72         return 0 unless defined $res;
  73         res($self, $res);
  74 }
  75
  76 sub cmd_mode ($$) {
  77         my ($self, $arg) = @_;
  78         $arg = uc $arg;
  79         return r501 unless $arg eq 'READER';
  80         '200 reader status acknowledged';
  81 }
  82
  83 sub cmd_slave ($) { '202 slave status noted' }
  84
  85 sub cmd_xgtitle ($;$) {
  86         my ($self, $wildmat) = @_;
  87         more($self, '282 list of groups and descriptions follows');
  88         list_newsgroups($self, $wildmat);
  89         '.'
  90 }
  91
  92 sub list_overview_fmt ($$) {
  93         my ($self) = @_;
  94         more($self, $_ . ':') foreach @OVERVIEW;
  95 }
  96
  97 sub list_active ($;$) {
  98         my ($self, $wildmat) = @_;
  99         wildmat2re($wildmat);
 100         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 101                 $ng->{name} =~ $wildmat or next;
 102                 group_line($self, $ng);
 103         }
 104 }
 105
 106 sub list_active_times ($;$) {
 107         my ($self, $wildmat) = @_;
 108         wildmat2re($wildmat);
 109         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 110                 $ng->{name} =~ $wildmat or next;
 111                 my $c = eval { $ng->mm->created_at } || time;
 112                 more($self, "$ng->{name} $c $ng->{address}");
 113         }
 114 }
 115
 116 sub list_newsgroups ($;$) {
 117         my ($self, $wildmat) = @_;
 118         wildmat2re($wildmat);
 119         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 120                 $ng->{name} =~ $wildmat or next;
 121                 my $d = $ng->description;
 122                 more($self, "$ng->{name} $d");
 123         }
 124 }
 125
 126 # LIST SUBSCRIPTIONS not supported
 127 sub cmd_list ($;$$) {
 128         my ($self, @args) = @_;
 129         if (scalar @args) {
 130                 my $arg = shift @args;
 131                 $arg =~ tr/A-Z./a-z_/;
 132                 $arg = "list_$arg";
 133                 return '503 function not performed' if $DISABLED{$arg};
 134
 135                 $arg = eval {
 136                         no strict 'refs';
 137                         *{$arg}{CODE};
 138                 };
 139                 return r501 unless $arg && args_ok($arg, scalar @args);
 140                 more($self, '215 information follows');
 141                 $arg->($self, @args);
 142         } else {
 143                 more($self, '215 list of newsgroups follows');
 144                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 145                         group_line($self, $ng);
 146                 }
 147         }
 148         '.'
 149 }
 150
 151 sub cmd_listgroup ($;$) {
 152         my ($self, $group) = @_;
 153         if (defined $group) {
 154                 my $res = cmd_group($self, $group);
 155                 return $res if ($res !~ /\A211 /);
 156                 more($self, $res);
 157         }
 158
 159         $self->{ng} or return '412 no newsgroup selected';
 160         $self->long_response(0, long_response_limit, sub {
 161                 my ($i) = @_;
 162                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 163                         my ($ary) = @_;
 164                         more($self, join("\r\n", @$ary));
 165                 });
 166
 167                 # -1 to adjust for implicit increment in long_response
 168                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 169         });
 170 }
 171
 172 sub parse_time ($$;$) {
 173         my ($date, $time, $gmt) = @_;
 174         use Time::Local qw();
 175         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 176         if (defined $gmt) {
 177                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt\n";
 178                 $gmt = 1;
 179         }
 180         my @now = $gmt ? gmtime : localtime;
 181         my ($YYYY, $MM, $DD);
 182         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 183                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 184         } else { # legacy clients send YYMMDD
 185                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 186                 if ($YYYY > strftime('%y', @now)) {
 187                         my $cur_year = $now[5] + 1900;
 188                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 189                 }
 190         }
 191         if ($gmt) {
 192                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 193         } else {
 194                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 195         }
 196 }
 197
 198 sub group_line ($$) {
 199         my ($self, $ng) = @_;
 200         my ($min, $max) = $ng->mm->minmax;
 201         more($self, "$ng->{name} $max $min n") if defined $min && defined $max;
 202 }
 203
 204 sub cmd_newgroups ($$$;$$) {
 205         my ($self, $date, $time, $gmt, $dists) = @_;
 206         my $ts = eval { parse_time($date, $time, $gmt) };
 207         return r501 if $@;
 208
 209         # TODO dists
 210         more($self, '231 list of new newsgroups follows');
 211         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 212                 my $c = eval { $ng->mm->created_at } || 0;
 213                 next unless $c > $ts;
 214                 group_line($self, $ng);
 215         }
 216         '.'
 217 }
 218
 219 sub wildmat2re (;$) {
 220         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 221         my %keep;
 222         my $salt = rand;
 223         use Digest::SHA qw(sha1_hex);
 224         my $tmp = $_[0];
 225
 226         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 227                 my $orig = $1;
 228                 my $key = sha1_hex($orig . $salt);
 229                 $orig =~ s/([^\w\-])+/\Q$1/g;
 230                 $keep{$key} = $orig;
 231                 $key
 232                 #gex;
 233         my %map = ('*' => '.*', '?' => '.' );
 234         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 235         if (scalar %keep) {
 236                 $tmp =~ s#([a-f0-9]{40})#
 237                         my $orig = $keep{$1};
 238                         defined $orig ? $orig : $1;
 239                         #ge;
 240         }
 241         $_[0] = qr/\A$tmp\z/;
 242 }
 243
 244 sub ngpat2re (;$) {
 245         return $_[0] = qr/\A\z/ unless defined $_[0];
 246         my %map = ('*' => '.*', ',' => '|');
 247         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 248         $_[0] = qr/\A(?:$_[0])\z/;
 249 }
 250
 251 sub cmd_newnews ($$$$;$$) {
 252         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 253         my $ts = eval { parse_time($date, $time, $gmt) };
 254         return r501 if $@;
 255         more($self, '230 list of new articles by message-id follows');
 256         my ($keep, $skip) = split('!', $newsgroups, 2);
 257         ngpat2re($keep);
 258         ngpat2re($skip);
 259         my @srch;
 260         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 261                 $ng->{name} =~ $keep or next;
 262                 $ng->{name} =~ $skip and next;
 263                 my $srch = $ng->search or next;
 264                 push @srch, $srch;
 265         };
 266         return '.' unless @srch;
 267
 268         $ts .= '..';
 269         my $opts = { asc => 1, limit => 1000, offset => 0 };
 270         $self->long_response(0, long_response_limit, sub {
 271                 my ($i) = @_;
 272                 my $srch = $srch[0];
 273                 my $res = $srch->query($ts, $opts);
 274                 my $msgs = $res->{msgs};
 275                 if (my $nr = scalar @$msgs) {
 276                         more($self, '<' .
 277                                 join(">\r\n<", map { $_->mid } @$msgs ).
 278                                 '>');
 279                         $opts->{offset} += $nr;
 280                 } else {
 281                         shift @srch;
 282                         if (@srch) { # continue onto next newsgroup
 283                                 $opts->{offset} = 0;
 284                         } else { # break out of the long response.
 285                                 $$i = long_response_limit;
 286                         }
 287                 }
 288         });
 289 }
 290
 291 sub cmd_group ($$) {
 292         my ($self, $group) = @_;
 293         my $no_such = '411 no such news group';
 294         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 295
 296         $self->{ng} = $ng;
 297         my ($min, $max) = $ng->mm->minmax;
 298         $min ||= 0;
 299         $max ||= 0;
 300         $self->{article} = $min;
 301         my $est_size = $max - $min;
 302         "211 $est_size $min $max $group";
 303 }
 304
 305 sub article_adj ($$) {
 306         my ($self, $off) = @_;
 307         my $ng = $self->{ng} or return '412 no newsgroup selected';
 308
 309         my $n = $self->{article};
 310         defined $n or return '420 no current article has been selected';
 311
 312         $n += $off;
 313         my $mid = $ng->mm->mid_for($n);
 314         unless ($mid) {
 315                 $n = $off > 0 ? 'next' : 'previous';
 316                 return "421 no $n article in this group";
 317         }
 318         $self->{article} = $n;
 319         "223 $n <$mid> article retrieved - request text separately";
 320 }
 321
 322 sub cmd_next ($) { article_adj($_[0], 1) }
 323 sub cmd_last ($) { article_adj($_[0], -1) }
 324
 325 # We want to encourage using email and CC-ing everybody involved to avoid
 326 # the single-point-of-failure a single server provides.
 327 sub cmd_post ($) {
 328         my ($self) = @_;
 329         my $ng = $self->{ng};
 330         $ng ? "440 mailto:$ng->{address} to post" : '440 posting not allowed'
 331 }
 332
 333 sub cmd_quit ($) {
 334         my ($self) = @_;
 335         res($self, '205 closing connection - goodbye!');
 336         $self->close;
 337         undef;
 338 }
 339
 340 sub art_lookup ($$$) {
 341         my ($self, $art, $set_headers) = @_;
 342         my $ng = $self->{ng};
 343         my ($n, $mid);
 344         my $err;
 345         if (defined $art) {
 346                 if ($art =~ /\A\d+\z/o) {
 347                         $err = '423 no such article number in this group';
 348                         $n = int($art);
 349                         goto find_mid;
 350                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 351                         $mid = $1;
 352                         $err = r430;
 353                         $n = $ng->mm->num_for($mid) if $ng;
 354                         goto found if defined $n;
 355                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 356                                 $n = $g->mm->num_for($mid);
 357                                 if (defined $n) {
 358                                         $ng = $g;
 359                                         goto found;
 360                                 }
 361                         }
 362                         return $err;
 363                 } else {
 364                         return r501;
 365                 }
 366         } else {
 367                 $err = '420 no current article has been selected';
 368                 $n = $self->{article};
 369                 defined $n or return $err;
 370 find_mid:
 371                 $ng or return '412 no newsgroup has been selected';
 372                 $mid = $ng->mm->mid_for($n);
 373                 defined $mid or return $err;
 374         }
 375 found:
 376         my $o = 'HEAD:' . mid2path($mid);
 377         my $bytes;
 378         my $s = eval { Email::MIME->new($ng->gcf->cat_file($o, \$bytes)) };
 379         return $err unless $s;
 380         my $lines;
 381         if ($set_headers) {
 382                 $s->header_set('Newsgroups', $ng->{name});
 383                 $s->header_set('Xref', xref($ng, $n));
 384                 $lines = $s->body =~ tr!\n!\n!;
 385
 386                 # must be last
 387                 $s->body_set('') if ($set_headers == 2);
 388         }
 389         [ $n, $mid, $s, $bytes, $lines, $ng ];
 390 }
 391
 392 sub simple_body_write ($$) {
 393         my ($self, $s) = @_;
 394         my $body = $s->body;
 395         $s->body_set('');
 396         $body =~ s/^\./../smg;
 397         $body =~ s/(?<!\r)\n/\r\n/sg;
 398         do_more($self, $body);
 399         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 400         '.'
 401 }
 402
 403 sub set_art {
 404         my ($self, $art) = @_;
 405         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 406 }
 407
 408 sub cmd_article ($;$) {
 409         my ($self, $art) = @_;
 410         my $r = $self->art_lookup($art, 1);
 411         return $r unless ref $r;
 412         my ($n, $mid, $s) = @$r;
 413         set_art($self, $art);
 414         more($self, "220 $n <$mid> article retrieved - head and body follow");
 415         do_more($self, $s->header_obj->as_string);
 416         do_more($self, "\r\n");
 417         simple_body_write($self, $s);
 418 }
 419
 420 sub cmd_head ($;$) {
 421         my ($self, $art) = @_;
 422         my $r = $self->art_lookup($art, 2);
 423         return $r unless ref $r;
 424         my ($n, $mid, $s) = @$r;
 425         set_art($self, $art);
 426         more($self, "221 $n <$mid> article retrieved - head follows");
 427         do_more($self, $s->header_obj->as_string);
 428         '.'
 429 }
 430
 431 sub cmd_body ($;$) {
 432         my ($self, $art) = @_;
 433         my $r = $self->art_lookup($art, 0);
 434         return $r unless ref $r;
 435         my ($n, $mid, $s) = @$r;
 436         set_art($self, $art);
 437         more($self, "222 $n <$mid> article retrieved - body follows");
 438         simple_body_write($self, $s);
 439 }
 440
 441 sub cmd_stat ($;$) {
 442         my ($self, $art) = @_;
 443         my $r = $self->art_lookup($art, 0);
 444         return $r unless ref $r;
 445         my ($n, $mid, undef) = @$r;
 446         set_art($self, $art);
 447         "223 $n <$mid> article retrieved - request text separately";
 448 }
 449
 450 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 451
 452 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 453
 454 sub cmd_help ($) {
 455         my ($self) = @_;
 456         more($self, '100 help text follows');
 457         '.'
 458 }
 459
 460 sub get_range ($$) {
 461         my ($self, $range) = @_;
 462         my $ng = $self->{ng} or return '412 no news group has been selected';
 463         defined $range or return '420 No article(s) selected';
 464         my ($beg, $end);
 465         my ($min, $max) = $ng->mm->minmax;
 466         if ($range =~ /\A(\d+)\z/) {
 467                 $beg = $end = $1;
 468         } elsif ($range =~ /\A(\d+)-\z/) {
 469                 ($beg, $end) = ($1, $max);
 470         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 471                 ($beg, $end) = ($1, $2);
 472         } else {
 473                 return r501;
 474         }
 475         $beg = $min if ($beg < $min);
 476         $end = $max if ($end > $max);
 477         return '420 No article(s) selected' if ($beg > $end);
 478         [ $beg, $end ];
 479 }
 480
 481 sub hdr_val ($$) {
 482         my ($r, $header) = @_;
 483         $header = lc $header;
 484         return $r->[3] if ($header eq 'bytes');
 485         return $r->[4] if ($header eq 'lines');
 486         $r = $r->[2]->header_obj->header($header);
 487         defined $r or return;
 488         $r =~ s/[\r\n\t]+/ /sg;
 489         $r;
 490 }
 491
 492 sub long_response ($$$$) {
 493         my ($self, $beg, $end, $cb) = @_;
 494         die "BUG: nested long response" if $self->{long_res};
 495
 496         # make sure we disable reading during a long response,
 497         # clients should not be sending us stuff and making us do more
 498         # work while we are stream a response to them
 499         $self->watch_read(0);
 500         my $fd = fileno $self->{sock};
 501         my $t0 = now();
 502         $self->{long_res} = sub {
 503                 # limit our own running time for fairness with other
 504                 # clients and to avoid buffering too much:
 505                 my $yield;
 506                 local $SIG{ALRM} = sub { $yield = 1 };
 507                 ualarm(100000);
 508
 509                 my $err;
 510                 do {
 511                         eval { $cb->(\$beg) };
 512                 } until (($err = $@) || $self->{closed} || $yield ||
 513                          $self->{write_buf_size} || ++$beg > $end);
 514                 ualarm(0);
 515
 516                 if ($err || $self->{closed}) {
 517                         $self->{long_res} = undef;
 518
 519                         if ($err) {
 520                                 err($self,
 521                                     "$err during long response[$fd] - %0.6f",
 522                                         now() - $t0);
 523                         }
 524                         if ($self->{closed}) {
 525                                 out($self, " deferred[$fd] aborted - %0.6f",
 526                                            now() - $t0);
 527                         } else {
 528                                 $self->watch_read(1);
 529                         }
 530                 } elsif ($yield || $self->{write_buf_size}) {
 531                         # no recursion, schedule another call ASAP
 532                         # but only after all pending writes are done
 533                         Danga::Socket->AddTimer(0, sub {
 534                                 $self->write($self->{long_res});
 535                         });
 536                 } else { # all done!
 537                         $self->{long_res} = undef;
 538                         $self->watch_read(1);
 539                         res($self, '.');
 540                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 541                 }
 542         };
 543         $self->{long_res}->(); # kick off!
 544         undef;
 545 }
 546
 547 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 548         my ($self, $xhdr, $range) = @_;
 549
 550         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 551                 my ($ng, $n) = mid_lookup($self, $1);
 552                 return r430 unless $n;
 553                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 554         } else { # numeric range
 555                 $range = $self->{article} unless defined $range;
 556                 my $r = get_range($self, $range);
 557                 return $r unless ref $r;
 558                 my $mm = $self->{ng}->mm;
 559                 my ($beg, $end) = @$r;
 560                 more($self, '221 Header follows');
 561                 $self->long_response($beg, $end, sub {
 562                         my ($i) = @_;
 563                         my $mid = $mm->mid_for($$i);
 564                         more($self, "$$i <$mid>") if defined $mid;
 565                 });
 566         }
 567 }
 568
 569 sub xref ($$) {
 570         my ($ng, $n) = @_;
 571         "$ng->{domain} $ng->{name}:$n"
 572 }
 573
 574 sub mid_lookup ($$) {
 575         my ($self, $mid) = @_;
 576         my $self_ng = $self->{ng};
 577         if ($self_ng) {
 578                 my $n = $self_ng->mm->num_for($mid);
 579                 return ($self_ng, $n) if defined $n;
 580         }
 581         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 582                 next if defined $self_ng && $ng eq $self_ng;
 583                 my $n = $ng->mm->num_for($mid);
 584                 return ($ng, $n) if defined $n;
 585         }
 586         (undef, undef);
 587 }
 588
 589 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 590         my ($self, $xhdr, $range) = @_;
 591
 592         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 593                 my ($ng, $n) = mid_lookup($self, $1);
 594                 return r430 unless $n;
 595                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 596         } else { # numeric range
 597                 $range = $self->{article} unless defined $range;
 598                 my $r = get_range($self, $range);
 599                 return $r unless ref $r;
 600                 my $ng = $self->{ng};
 601                 my $mm = $ng->mm;
 602                 my ($beg, $end) = @$r;
 603                 more($self, '221 Header follows');
 604                 $self->long_response($beg, $end, sub {
 605                         my ($i) = @_;
 606                         my $mid = $mm->mid_for($$i);
 607                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 608                 });
 609         }
 610 }
 611
 612 sub header_obj_for {
 613         my ($srch, $mid) = @_;
 614         eval {
 615                 my $smsg = $srch->lookup_message($mid);
 616                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 617                 $smsg->mini_mime->header_obj;
 618         };
 619 };
 620
 621 sub hdr_searchmsg ($$$$) {
 622         my ($self, $xhdr, $hdr, $range) = @_;
 623         my $filter;
 624         if ($hdr eq 'date') {
 625                 $hdr = 'X-PI-TS';
 626                 $filter = sub ($) {
 627                         strftime('%a, %d %b %Y %T %z', gmtime($_[0]));
 628                 };
 629         }
 630
 631         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 632                 my ($ng, $n) = mid_lookup($self, $1);
 633                 return r430 unless $n;
 634                 if (my $srch = $ng->search) {
 635                         my $m = header_obj_for($srch, $range);
 636                         my $v = $m->header($hdr);
 637                         $v = $filter->($v) if defined $v && $filter;
 638                         hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 639                 } else {
 640                         hdr_slow($self, $xhdr, $hdr, $range);
 641                 }
 642         } else { # numeric range
 643                 $range = $self->{article} unless defined $range;
 644                 my $srch = $self->{ng}->search or
 645                                 return hdr_slow($self, $xhdr, $hdr, $range);
 646                 my $mm = $self->{ng}->mm;
 647                 my $r = get_range($self, $range);
 648                 return $r unless ref $r;
 649                 my ($beg, $end) = @$r;
 650                 more($self, '221 Header follows');
 651                 $self->long_response($beg, $end, sub {
 652                         my ($i) = @_;
 653                         my $mid = $mm->mid_for($$i) or return;
 654                         my $m = header_obj_for($srch, $mid) or return;
 655                         my $v = $m->header($hdr);
 656                         defined $v or return;
 657                         $v = $filter->($v) if $filter;
 658                         more($self, "$$i $v");
 659                 });
 660         }
 661 }
 662
 663 sub do_hdr ($$$;$) {
 664         my ($self, $xhdr, $header, $range) = @_;
 665         my $sub = lc $header;
 666         if ($sub eq 'message-id') {
 667                 hdr_message_id($self, $xhdr, $range);
 668         } elsif ($sub eq 'xref') {
 669                 hdr_xref($self, $xhdr, $range);
 670         } elsif ($sub =~ /\A(subject|references|date)\z/) {
 671                 hdr_searchmsg($self, $xhdr, $sub, $range);
 672         } else {
 673                 hdr_slow($self, $xhdr, $header, $range);
 674         }
 675 }
 676
 677 # RFC 3977
 678 sub cmd_hdr ($$;$) {
 679         my ($self, $header, $range) = @_;
 680         do_hdr($self, 0, $header, $range);
 681 }
 682
 683 # RFC 2980
 684 sub cmd_xhdr ($$;$) {
 685         my ($self, $header, $range) = @_;
 686         do_hdr($self, 1, $header, $range);
 687 }
 688
 689 sub hdr_mid_prefix ($$$$$) {
 690         my ($self, $xhdr, $ng, $n, $mid) = @_;
 691         return $mid if $xhdr;
 692
 693         # HDR for RFC 3977 users
 694         if (my $self_ng = $self->{ng}) {
 695                 ($self_ng eq $ng) ? $n : '0';
 696         } else {
 697                 '0';
 698         }
 699 }
 700
 701 sub hdr_mid_response ($$$$$$) {
 702         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 703         my $res = '';
 704         if ($xhdr) {
 705                 $res .= r221 . "\r\n";
 706                 $res .= "$mid $v\r\n" if defined $v;
 707         } else {
 708                 $res .= r224 . "\r\n";
 709                 if (defined $v) {
 710                         my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 711                         $res .= "$pfx $v\r\n";
 712                 }
 713         }
 714         res($self, $res .= '.');
 715         undef;
 716 }
 717
 718 sub hdr_slow ($$$$) {
 719         my ($self, $xhdr, $header, $range) = @_;
 720
 721         if (defined $range && $range =~ /\A<.+>\z/) { # Message-ID
 722                 my $r = $self->art_lookup($range, 2);
 723                 return $r unless ref $r;
 724                 my ($n, $ng) = ($r->[0], $r->[5]);
 725                 my $v = hdr_val($r, $header);
 726                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 727         } else { # numeric range
 728                 $range = $self->{article} unless defined $range;
 729                 my $r = get_range($self, $range);
 730                 return $r unless ref $r;
 731                 my ($beg, $end) = @$r;
 732                 more($self, $xhdr ? r221 : r224);
 733                 $self->long_response($beg, $end, sub {
 734                         my ($i) = @_;
 735                         $r = $self->art_lookup($$i, 2);
 736                         return unless ref $r;
 737                         defined($r = hdr_val($r, $header)) or return;
 738                         more($self, "$$i $r");
 739                 });
 740         }
 741 }
 742
 743 sub cmd_xrover ($;$) {
 744         my ($self, $range) = @_;
 745         my $ng = $self->{ng} or return '412 no newsgroup selected';
 746         (defined $range && $range =~ /[<>]/) and
 747                 return '420 No article(s) selected'; # no message IDs
 748
 749         $range = $self->{article} unless defined $range;
 750         my $r = get_range($self, $range);
 751         return $r unless ref $r;
 752         my ($beg, $end) = @$r;
 753         my $mm = $ng->mm;
 754         my $srch = $ng->search;
 755         more($self, '224 Overview information follows');
 756         $self->long_response($beg, $end, sub {
 757                 my ($i) = @_;
 758                 my $mid = $mm->mid_for($$i) or return;
 759                 my $m = header_obj_for($srch, $mid) or return;
 760                 my $h = $m->header('references');
 761                 more($self, "$$i $h") if defined $h;
 762         });
 763 }
 764
 765 sub over_line ($$) {
 766         my ($self, $r) = @_;
 767
 768         more($self, join("\t", $r->[0], map {
 769                                 my $h = hdr_val($r, $_);
 770                                 defined $h ? $h : '';
 771                         } @OVERVIEW ));
 772 }
 773
 774 sub cmd_over ($;$) {
 775         my ($self, $range) = @_;
 776         if ($range && $range =~ /\A<.+>\z/) {
 777                 my $r = $self->art_lookup($range, 2);
 778                 return '430 No article with that message-id' unless ref $r;
 779                 more($self, '224 Overview information follows (multi-line)');
 780
 781                 # Only set article number column if it's the current group
 782                 my $ng = $self->{ng};
 783                 $r->[0] = 0 if (!$ng || $ng ne $r->[5]);
 784                 over_line($self, $r);
 785                 '.';
 786         } else {
 787                 cmd_xover($self, $range);
 788         }
 789 }
 790
 791 sub cmd_xover ($;$) {
 792         my ($self, $range) = @_;
 793         $range = $self->{article} unless defined $range;
 794         my $r = get_range($self, $range);
 795         return $r unless ref $r;
 796         my ($beg, $end) = @$r;
 797         more($self, "224 Overview information follows for $beg to $end");
 798         $self->long_response($beg, $end, sub {
 799                 my ($i) = @_;
 800                 my $r = $self->art_lookup($$i, 2);
 801                 return unless ref $r;
 802                 over_line($self, $r);
 803         });
 804 }
 805
 806 sub cmd_xpath ($$) {
 807         my ($self, $mid) = @_;
 808         return r501 unless $mid =~ /\A<(.+)>\z/;
 809         $mid = $1;
 810         my @paths;
 811         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 812                 my $n = $ng->mm->num_for($mid);
 813                 push @paths, "$ng->{name}/$n" if defined $n;
 814         }
 815         return '430 no such article on server' unless @paths;
 816         '223 '.join(' ', @paths);
 817 }
 818
 819 sub res ($$) {
 820         my ($self, $line) = @_;
 821         do_write($self, $line . "\r\n");
 822 }
 823
 824 sub more ($$) {
 825         my ($self, $line) = @_;
 826         do_more($self, $line . "\r\n");
 827 }
 828
 829 sub do_write ($$) {
 830         my ($self, $data) = @_;
 831         my $done = $self->write($data);
 832         die if $self->{closed};
 833
 834         # Do not watch for readability if we have data in the queue,
 835         # instead re-enable watching for readability when we can
 836         $self->watch_read(0) if (!$done || $self->{long_res});
 837
 838         $done;
 839 }
 840
 841 sub err ($$;@) {
 842         my ($self, $fmt, @args) = @_;
 843         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 844 }
 845
 846 sub out ($$;@) {
 847         my ($self, $fmt, @args) = @_;
 848         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 849 }
 850
 851 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 852
 853 sub do_more ($$) {
 854         my ($self, $data) = @_;
 855         if (MSG_MORE && !$self->{write_buf_size}) {
 856                 my $n = send($self->{sock}, $data, MSG_MORE);
 857                 if (defined $n) {
 858                         my $dlen = length($data);
 859                         return 1 if $n == $dlen; # all done!
 860                         $data = substr($data, $n, $dlen - $n);
 861                 }
 862         }
 863         $self->do_write($data);
 864 }
 865
 866 # callbacks for by Danga::Socket
 867
 868 sub event_hup { $_[0]->close }
 869 sub event_err { $_[0]->close }
 870
 871 sub event_write {
 872         my ($self) = @_;
 873         # only continue watching for readability when we are done writing:
 874         if ($self->write(undef) == 1 && !$self->{long_res}) {
 875                 $self->watch_read(1);
 876         }
 877 }
 878
 879 sub event_read {
 880         my ($self) = @_;
 881         use constant LINE_MAX => 512; # RFC 977 section 2.3
 882         my $line;
 883         my $r = 1;
 884 again:
 885         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 886                 $line = $1;
 887                 my $t0 = now();
 888                 $r = eval { $self->process_line($line) };
 889                 my $d = $self->{long_res} ?
 890                         ' deferred['.fileno($self->{sock}).']' : '';
 891                 out($self, "$line - %0.6f$d", now() - $t0);
 892         }
 893         unless (defined $line) {
 894                 my $buf = $self->read(LINE_MAX) or return $self->close;
 895                 $self->{rbuf} .= $$buf;
 896                 goto again;
 897         }
 898
 899         return $self->close if $r < 0;
 900         my $len = length($self->{rbuf});
 901         return $self->close if ($len >= LINE_MAX);
 902 }
 903
 904 sub watch_read {
 905         my ($self, $bool) = @_;
 906         my $rv = $self->SUPER::watch_read($bool);
 907         if ($bool && $self->{rbuf} ne '') {
 908                 # Force another read if there is a pipelined request.
 909                 # We don't know if the socket has anything for us to read,
 910                 # and we must double-check again by the time the timer fires
 911                 # in case we really did dispatch a read event and started
 912                 # another long response.
 913                 Danga::Socket->AddTimer(0, sub {
 914                         if (&Danga::Socket::POLLIN & $self->{event_watch}) {
 915                                 $self->event_read;
 916                         }
 917                 });
 918         }
 919         $rv;
 920 }
 921
 922 1;