lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Config;
  11 our %IMAPflags2kw = map {; "\\\u$_" => $_ } qw(seen answered flagged draft);
  12 $IMAPflags2kw{'$Forwarded'} = 'forwarded';  # RFC 5550
  13
  14 our @EXPORT = qw(uri_section imap_uri nntp_uri);
  15
  16 sub ndump {
  17         require Data::Dumper;
  18         Data::Dumper->new(\@_)->Useqq(1)->Terse(1)->Dump;
  19 }
  20
  21 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  22 # without the mailbox, so we can share connections between different inboxes
  23 sub uri_section ($) {
  24         my ($uri) = @_;
  25         $uri->scheme . '://' . $uri->authority;
  26 }
  27
  28 sub socks_args ($) {
  29         my ($val) = @_;
  30         return if ($val // '') eq '';
  31         if ($val =~ m!\Asocks5h:// (?: \[ ([^\]]+) \] | ([^:/]+) )
  32                                         (?::([0-9]+))?/*\z!ix) {
  33                 my ($h, $p) = ($1 // $2, $3 + 0);
  34                 $h = '127.0.0.1' if $h eq '0';
  35                 eval { require IO::Socket::Socks } or die <<EOM;
  36 IO::Socket::Socks missing for socks5h://$h:$p
  37 EOM
  38                 return { ProxyAddr => $h, ProxyPort => $p };
  39         }
  40         die "$val not understood (only socks5h:// is supported)\n";
  41 }
  42
  43 sub mic_new ($$$$) {
  44         my ($self, $mic_arg, $sec, $uri) = @_;
  45         my %socks;
  46         my $sa = $self->{imap_opt}->{$sec}->{-proxy_cfg} || $self->{-proxy_cli};
  47         if ($sa) {
  48                 my %opt = %$sa;
  49                 $opt{ConnectAddr} = delete $mic_arg->{Server};
  50                 $opt{ConnectPort} = delete $mic_arg->{Port};
  51                 $socks{Socket} = IO::Socket::Socks->new(%opt) or die
  52                         "E: <$$uri> ".eval('$IO::Socket::Socks::SOCKS_ERROR');
  53         }
  54         PublicInbox::IMAPClient->new(%$mic_arg, %socks);
  55 }
  56
  57 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  58
  59 # mic_for may prompt the user and store auth info, prepares mic_get
  60 sub mic_for ($$$$) { # mic = Mail::IMAPClient
  61         my ($self, $uri, $mic_args, $lei) = @_;
  62         require PublicInbox::GitCredential;
  63         my $cred = bless {
  64                 url => "$uri",
  65                 protocol => $uri->scheme,
  66                 host => $uri->host,
  67                 username => $uri->user,
  68                 password => $uri->password,
  69         }, 'PublicInbox::GitCredential';
  70         my $sec = uri_section($uri);
  71         my $common = $mic_args->{$sec} // {};
  72         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
  73         my $host = $cred->{host};
  74         $host = '127.0.0.1' if $host eq '0';
  75         my $mic_arg = {
  76                 Port => $uri->port,
  77                 Server => $host,
  78                 Ssl => $uri->scheme eq 'imaps',
  79                 Keepalive => 1, # SO_KEEPALIVE
  80                 %$common, # may set Starttls, Compress, Debug ....
  81         };
  82         require PublicInbox::IMAPClient;
  83         my $mic = mic_new($self, $mic_arg, $sec, $uri) or
  84                         die "E: <$uri> new: $@\n";
  85         # default to using STARTTLS if it's available, but allow
  86         # it to be disabled since I usually connect to localhost
  87         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
  88                         $mic->has_capability('STARTTLS') &&
  89                         $mic->can('starttls')) {
  90                 $mic->starttls or die "E: <$uri> STARTTLS: $@\n";
  91         }
  92
  93         # do we even need credentials?
  94         if (!defined($cred->{username}) &&
  95                         $mic->has_capability('AUTH=ANONYMOUS')) {
  96                 $cred = undef;
  97         }
  98         if ($cred) {
  99                 $cred->check_netrc unless defined $cred->{password};
 100                 $cred->fill($lei); # may prompt user here
 101                 $mic->User($mic_arg->{User} = $cred->{username});
 102                 $mic->Password($mic_arg->{Password} = $cred->{password});
 103         } else { # AUTH=ANONYMOUS
 104                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
 105                 $mic_arg->{Authcallback} = 'auth_anon_cb';
 106                 $mic->Authcallback(\&auth_anon_cb);
 107         }
 108         my $err;
 109         if ($mic->login && $mic->IsAuthenticated) {
 110                 # success! keep IMAPClient->new arg in case we get disconnected
 111                 $self->{mic_arg}->{$sec} = $mic_arg;
 112                 if ($cred) {
 113                         $uri->user($cred->{username}) if !defined($uri->user);
 114                 } elsif ($mic_arg->{Authmechanism} eq 'ANONYMOUS') {
 115                         $uri->auth('ANONYMOUS') if !defined($uri->auth);
 116                 }
 117         } else {
 118                 $err = "E: <$uri> LOGIN: $@\n";
 119                 if ($cred && defined($cred->{password})) {
 120                         $err =~ s/\Q$cred->{password}\E/*******/g;
 121                 }
 122                 $mic = undef;
 123         }
 124         $cred->run($mic ? 'approve' : 'reject') if $cred;
 125         if ($err) {
 126                 $lei ? $lei->fail($err) : warn($err);
 127         }
 128         $mic;
 129 }
 130
 131 # Net::NNTP doesn't support CAPABILITIES, yet
 132 sub try_starttls ($) {
 133         my ($host) = @_;
 134         return if $host =~ /\.onion\z/s;
 135         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 136         return if $host eq '::1';
 137         1;
 138 }
 139
 140 sub nn_new ($$$) {
 141         my ($nn_arg, $nntp_opt, $uri) = @_;
 142         my $nn;
 143         if (defined $nn_arg->{ProxyAddr}) {
 144                 require PublicInbox::NetNNTPSocks;
 145                 eval { $nn = PublicInbox::NetNNTPSocks->new_socks(%$nn_arg) };
 146                 die "E: <$uri> $@\n" if $@;
 147         } else {
 148                 $nn = Net::NNTP->new(%$nn_arg) or die "E: <$uri> new: $!\n";
 149         }
 150
 151         # default to using STARTTLS if it's available, but allow
 152         # it to be disabled for localhost/VPN users
 153         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 154                 if (!defined($nntp_opt->{starttls}) &&
 155                                 try_starttls($nn_arg->{Host})) {
 156                         # soft fail by default
 157                         $nn->starttls or warn <<"";
 158 W: <$uri> STARTTLS tried and failed (not requested)
 159
 160                 } elsif ($nntp_opt->{starttls}) {
 161                         # hard fail if explicitly configured
 162                         $nn->starttls or die <<"";
 163 E: <$uri> STARTTLS requested and failed
 164
 165                 }
 166         } elsif ($nntp_opt->{starttls}) {
 167                 $nn->can('starttls') or
 168                         die "E: <$uri> Net::NNTP too old for STARTTLS\n";
 169                 $nn->starttls or die <<"";
 170 E: <$uri> STARTTLS requested and failed
 171
 172         }
 173         $nn;
 174 }
 175
 176 sub nn_for ($$$$) { # nn = Net::NNTP
 177         my ($self, $uri, $nn_args, $lei) = @_;
 178         my $sec = uri_section($uri);
 179         my $nntp_opt = $self->{nntp_opt}->{$sec} //= {};
 180         my $host = $uri->host;
 181         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 182         $host = '127.0.0.1' if $host eq '0';
 183         my $cred;
 184         my ($u, $p);
 185         if (defined(my $ui = $uri->userinfo)) {
 186                 require PublicInbox::GitCredential;
 187                 $cred = bless {
 188                         url => $sec,
 189                         protocol => $uri->scheme,
 190                         host => $host,
 191                 }, 'PublicInbox::GitCredential';
 192                 ($u, $p) = split(/:/, $ui, 2);
 193                 ($cred->{username}, $cred->{password}) = ($u, $p);
 194                 $cred->check_netrc unless defined $p;
 195         }
 196         my $common = $nn_args->{$sec} // {};
 197         my $nn_arg = {
 198                 Port => $uri->port,
 199                 Host => $host,
 200                 SSL => $uri->secure, # snews == nntps
 201                 %$common, # may Debug ....
 202         };
 203         my $sa = $self->{-proxy_cli};
 204         %$nn_arg = (%$nn_arg, %$sa) if $sa;
 205         my $nn = nn_new($nn_arg, $nntp_opt, $uri);
 206         if ($cred) {
 207                 $cred->fill($lei); # may prompt user here
 208                 if ($nn->authinfo($u, $p)) {
 209                         push @{$nntp_opt->{-postconn}}, [ 'authinfo', $u, $p ];
 210                 } else {
 211                         warn "E: <$uri> AUTHINFO $u XXXX failed\n";
 212                         $nn = undef;
 213                 }
 214         }
 215
 216         if ($nntp_opt->{compress}) {
 217                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 218                 if ($nn->can('compress')) {
 219                         if ($nn->compress) {
 220                                 push @{$nntp_opt->{-postconn}}, [ 'compress' ];
 221                         } else {
 222                                 warn "W: <$uri> COMPRESS failed\n";
 223                         }
 224                 } else {
 225                         delete $nntp_opt->{compress};
 226                         warn <<"";
 227 W: <$uri> COMPRESS not supported by Net::NNTP
 228 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 229
 230                 }
 231         }
 232
 233         $self->{nn_arg}->{$sec} = $nn_arg;
 234         $cred->run($nn ? 'approve' : 'reject') if $cred;
 235         $nn;
 236 }
 237
 238 sub imap_uri {
 239         my ($url) = @_;
 240         require PublicInbox::URIimap;
 241         my $uri = PublicInbox::URIimap->new($url);
 242         $uri ? $uri->canonical : undef;
 243 }
 244
 245 my %IS_NNTP = (news => 1, snews => 1, nntp => 1, nntps => 1);
 246 sub nntp_uri {
 247         my ($url) = @_;
 248         require PublicInbox::URInntps;
 249         my $uri = PublicInbox::URInntps->new($url);
 250         $uri && $IS_NNTP{$uri->scheme} && $uri->group ? $uri->canonical : undef;
 251 }
 252
 253 sub cfg_intvl ($$$) {
 254         my ($cfg, $key, $url) = @_;
 255         my $v = $cfg->urlmatch($key, $url) // return;
 256         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 257         if (ref($v) eq 'ARRAY') {
 258                 $v = join(', ', @$v);
 259                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 260         } else {
 261                 warn "W: $key=$v is not a numeric value in seconds\n";
 262         }
 263 }
 264
 265 sub cfg_bool ($$$) {
 266         my ($cfg, $key, $url) = @_;
 267         my $orig = $cfg->urlmatch($key, $url) // return;
 268         my $bool = $cfg->git_bool($orig);
 269         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 270         $bool;
 271 }
 272
 273 # flesh out common IMAP-specific data structures
 274 sub imap_common_init ($;$) {
 275         my ($self, $lei) = @_;
 276         return unless $self->{imap_order};
 277         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 278         eval { require PublicInbox::IMAPClient } or
 279                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 280         ($lei || eval { require PublicInbox::IMAPTracker }) or
 281                 die "DBD::SQLite is required for IMAP\n:$@\n";
 282         require PublicInbox::URIimap;
 283         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 284         my $mic_args = {}; # scheme://authority => Mail:IMAPClient arg
 285         for my $uri (@{$self->{imap_order}}) {
 286                 my $sec = uri_section($uri);
 287                 for my $k (qw(Starttls Debug Compress)) {
 288                         my $bool = cfg_bool($cfg, "imap.$k", $$uri) // next;
 289                         $mic_args->{$sec}->{$k} = $bool;
 290                 }
 291                 my $to = cfg_intvl($cfg, 'imap.timeout', $$uri);
 292                 $mic_args->{$sec}->{Timeout} = $to if $to;
 293                 my $sa = socks_args($cfg->urlmatch('imap.Proxy', $$uri));
 294                 $self->{imap_opt}->{$sec}->{-proxy_cfg} = $sa if $sa;
 295                 for my $k (qw(pollInterval idleInterval)) {
 296                         $to = cfg_intvl($cfg, "imap.$k", $$uri) // next;
 297                         $self->{imap_opt}->{$sec}->{$k} = $to;
 298                 }
 299                 my $k = 'imap.fetchBatchSize';
 300                 my $bs = $cfg->urlmatch($k, $$uri) // next;
 301                 if ($bs =~ /\A([0-9]+)\z/) {
 302                         $self->{imap_opt}->{$sec}->{batch_size} = $bs;
 303                 } else {
 304                         warn "$k=$bs is not an integer\n";
 305                 }
 306         }
 307         # make sure we can connect and cache the credentials in memory
 308         $self->{mic_arg} = {}; # schema://authority => IMAPClient->new args
 309         my $mics = {}; # schema://authority => IMAPClient obj
 310         for my $orig_uri (@{$self->{imap_order}}) {
 311                 my $sec = uri_section($orig_uri);
 312                 my $uri = PublicInbox::URIimap->new("$sec/");
 313                 my $mic = $mics->{$sec} //=
 314                                 mic_for($self, $uri, $mic_args, $lei) //
 315                                 die "Unable to continue\n";
 316                 next unless $self->isa('PublicInbox::NetWriter');
 317                 my $dst = $orig_uri->mailbox // next;
 318                 next if $mic->exists($dst); # already exists
 319                 $mic->create($dst) or die "CREATE $dst failed <$orig_uri>: $@";
 320         }
 321         $mics;
 322 }
 323
 324 # flesh out common NNTP-specific data structures
 325 sub nntp_common_init ($;$) {
 326         my ($self, $lei) = @_;
 327         return unless $self->{nntp_order};
 328         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 329         eval { require Net::NNTP } or
 330                 die "Net::NNTP is required for NNTP:\n$@\n";
 331         ($lei || eval { require PublicInbox::IMAPTracker }) or
 332                 die "DBD::SQLite is required for NNTP\n:$@\n";
 333         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 334         my $nn_args = {}; # scheme://authority => Net::NNTP->new arg
 335         for my $uri (@{$self->{nntp_order}}) {
 336                 my $sec = uri_section($uri);
 337                 my $args = $nn_args->{$sec} //= {};
 338
 339                 # Debug and Timeout are passed to Net::NNTP->new
 340                 my $v = cfg_bool($cfg, 'nntp.Debug', $$uri);
 341                 $args->{Debug} = $v if defined $v;
 342                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $$uri);
 343                 $args->{Timeout} = $to if $to;
 344                 my $sa = socks_args($cfg->urlmatch('nntp.Proxy', $$uri));
 345                 %$args = (%$args, %$sa) if $sa;
 346
 347                 # Net::NNTP post-connect commands
 348                 for my $k (qw(starttls compress)) {
 349                         $v = cfg_bool($cfg, "nntp.$k", $$uri) // next;
 350                         $self->{nntp_opt}->{$sec}->{$k} = $v;
 351                 }
 352
 353                 # -watch internal option
 354                 for my $k (qw(pollInterval)) {
 355                         $to = cfg_intvl($cfg, "nntp.$k", $$uri) // next;
 356                         $self->{nntp_opt}->{$sec}->{$k} = $to;
 357                 }
 358         }
 359         # make sure we can connect and cache the credentials in memory
 360         $self->{nn_arg} = {}; # schema://authority => Net::NNTP->new args
 361         my %nn; # schema://authority => Net::NNTP object
 362         for my $uri (@{$self->{nntp_order}}) {
 363                 my $sec = uri_section($uri);
 364                 $nn{$sec} //= nn_for($self, $uri, $nn_args, $lei);
 365         }
 366         \%nn; # for optional {nn_cached}
 367 }
 368
 369 sub add_url {
 370         my ($self, $arg) = @_;
 371         my $uri;
 372         if ($uri = imap_uri($arg)) {
 373                 push @{$self->{imap_order}}, $uri;
 374         } elsif ($uri = nntp_uri($arg)) {
 375                 push @{$self->{nntp_order}}, $uri;
 376         } else {
 377                 push @{$self->{unsupported_url}}, $arg;
 378         }
 379 }
 380
 381 sub errors {
 382         my ($self, $lei) = @_;
 383         if (my $u = $self->{unsupported_url}) {
 384                 return "Unsupported URL(s): @$u";
 385         }
 386         if ($self->{imap_order}) {
 387                 eval { require PublicInbox::IMAPClient } or
 388                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 389         }
 390         if ($self->{nntp_order}) {
 391                 eval { require Net::NNTP } or
 392                         die "Net::NNTP is required for NNTP:\n$@\n";
 393         }
 394         my $sa = socks_args($lei ? $lei->{opt}->{proxy} : undef);
 395         $self->{-proxy_cli} = $sa if $sa;
 396         undef;
 397 }
 398
 399 sub flags2kw ($$$$) {
 400         my ($self, $uri, $uid, $flags) = @_;
 401         my $kw = [];
 402         for my $f (split(/ /, $flags)) {
 403                 if (my $k = $IMAPflags2kw{$f}) {
 404                         push @$kw, $k;
 405                 } elsif ($f eq "\\Recent") { # not in JMAP
 406                 } elsif ($f eq "\\Deleted") { # not in JMAP
 407                         return;
 408                 } elsif ($self->{verbose}) {
 409                         warn "# unknown IMAP flag $f <$uri/;UID=$uid>\n";
 410                 }
 411         }
 412         @$kw = sort @$kw; # for LeiSearch->kw_changed and UI/UX purposes
 413         $kw;
 414 }
 415
 416 sub _imap_do_msg ($$$$$) {
 417         my ($self, $uri, $uid, $raw, $flags) = @_;
 418         # our target audience expects LF-only, save storage
 419         $$raw =~ s/\r\n/\n/sg;
 420         my $kw = flags2kw($self, $uri, $uid, $flags) // return;
 421         my ($eml_cb, @args) = @{$self->{eml_each}};
 422         $eml_cb->($uri, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 423 }
 424
 425 sub run_commit_cb ($) {
 426         my ($self) = @_;
 427         my $cmt_cb_args = $self->{on_commit} or return;
 428         my ($cb, @args) = @$cmt_cb_args;
 429         $cb->(@args);
 430 }
 431
 432 sub itrk_last ($$;$$) {
 433         my ($self, $uri, $r_uidval, $mic) = @_;
 434         return (undef, undef, $r_uidval) unless $self->{incremental};
 435         my ($itrk, $l_uid, $l_uidval);
 436         if (defined(my $lms = $self->{-lms_ro})) { # LeiMailSync or 0
 437                 $uri->uidvalidity($r_uidval) if defined $r_uidval;
 438                 if ($mic) {
 439                         my $auth = $mic->Authmechanism // '';
 440                         $uri->auth($auth) if $auth eq 'ANONYMOUS';
 441                         my $user = $mic->User;
 442                         $uri->user($user) if defined($user);
 443                 }
 444                 my $x;
 445                 $l_uid = ($lms && ($x = $lms->location_stats($$uri))) ?
 446                                 $x->{'uid.max'} : undef;
 447                 # itrk remains undef, lei/store worker writes to
 448                 # mail_sync.sqlite3
 449         } else {
 450                 $itrk = PublicInbox::IMAPTracker->new($$uri);
 451                 ($l_uidval, $l_uid) = $itrk->get_last($$uri);
 452         }
 453         ($itrk, $l_uid, $l_uidval //= $r_uidval);
 454 }
 455
 456 # import flags of already-seen messages
 457 sub each_old_flags ($$$$) {
 458         my ($self, $mic, $uri, $l_uid) = @_;
 459         $l_uid ||= 1;
 460         my $sec = uri_section($uri);
 461         my $bs = $self->{imap_opt}->{$sec}->{batch_size} // 10000;
 462         my ($eml_cb, @args) = @{$self->{eml_each}};
 463         for (my $n = 1; $n <= $l_uid; $n += $bs) {
 464                 my $end = $n + $bs;
 465                 $end = $l_uid if $end > $l_uid;
 466                 my $r = $mic->fetch_hash("$n:$end", 'FLAGS');
 467                 if (!$r) {
 468                         return if $!{EINTR} && $self->{quit};
 469                         return "E: $uri UID FETCH $n:$end error: $!";
 470                 }
 471                 while (my ($uid, $per_uid) = each %$r) {
 472                         my $kw = flags2kw($self, $uri, $uid, $per_uid->{FLAGS})
 473                                 // next;
 474                         # LeiImport->input_net_cb
 475                         $eml_cb->($uri, $uid, $kw, undef, @args);
 476                 }
 477         }
 478 }
 479
 480 # returns true if PERMANENTFLAGS indicates FLAGS of already imported
 481 # messages are meaningful
 482 sub perm_fl_ok ($) {
 483         my ($perm_fl) = @_;
 484         return if !defined($perm_fl);
 485         for my $f (split(/[ \t]+/, $perm_fl)) {
 486                 return 1 if $IMAPflags2kw{$f};
 487         }
 488         undef;
 489 }
 490
 491 sub _imap_fetch_all ($$$) {
 492         my ($self, $mic, $orig_uri) = @_;
 493         my $sec = uri_section($orig_uri);
 494         my $mbx = $orig_uri->mailbox;
 495         $mic->Clear(1); # trim results history
 496
 497         # we need to check for mailbox writability to see if we care about
 498         # FLAGS from already-imported messages.
 499         my $cmd = $self->{each_old} ? 'select' : 'examine';
 500         $mic->$cmd($mbx) or return "E: \U$cmd\E $mbx ($sec) failed: $!";
 501
 502         my ($r_uidval, $r_uidnext, $perm_fl);
 503         for ($mic->Results) {
 504                 /^\* OK \[PERMANENTFLAGS \(([^\)]*)\)\].*/ and $perm_fl = $1;
 505                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 506                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 507         }
 508         $r_uidval //= $mic->uidvalidity($mbx) //
 509                 return "E: $orig_uri cannot get UIDVALIDITY";
 510         $r_uidnext //= $mic->uidnext($mbx) //
 511                 return "E: $orig_uri cannot get UIDNEXT";
 512         my $expect = $orig_uri->uidvalidity // $r_uidval;
 513         return <<EOF if $expect != $r_uidval;
 514 E: $orig_uri UIDVALIDITY mismatch (got $r_uidval)
 515 EOF
 516
 517         my $uri = $orig_uri->clone;
 518         my $single_uid = $uri->uid;
 519         my ($itrk, $l_uid, $l_uidval) = itrk_last($self, $uri, $r_uidval, $mic);
 520         if (defined($single_uid)) {
 521                 $itrk = $l_uid = undef;
 522                 $uri->uid(undef); # for eml_cb
 523         }
 524         return <<EOF if $l_uidval != $r_uidval;
 525 E: $uri UIDVALIDITY mismatch
 526 E: local=$l_uidval != remote=$r_uidval
 527 EOF
 528         $uri->uidvalidity($r_uidval);
 529         $l_uid //= 0;
 530         my $r_uid = $r_uidnext - 1;
 531         return <<EOF if $l_uid > $r_uid;
 532 E: $uri local UID exceeds remote ($l_uid > $r_uid)
 533 E: $uri strangely, UIDVALIDLITY matches ($l_uidval)
 534 EOF
 535         $mic->Uid(1); # the default, we hope
 536         my $err;
 537         if (!defined($single_uid) && $self->{each_old} &&
 538                                 perm_fl_ok($perm_fl)) {
 539                 $err = each_old_flags($self, $mic, $uri, $l_uid);
 540                 return $err if $err;
 541         }
 542         return if $l_uid >= $r_uid; # nothing to do
 543         $l_uid ||= 1;
 544         my ($mod, $shard) = @{$self->{shard_info} // []};
 545         unless ($self->{quiet}) {
 546                 my $m = $mod ? " [(UID % $mod) == $shard]" : '';
 547                 warn "# $uri fetching UID $l_uid:$r_uid$m\n";
 548         }
 549         my $bs = $self->{imap_opt}->{$sec}->{batch_size} // 1;
 550         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 551         my $key = $req;
 552         $key =~ s/\.PEEK//;
 553         my ($uids, $batch);
 554         do {
 555                 # I wish "UID FETCH $START:*" could work, but:
 556                 # 1) servers do not need to return results in any order
 557                 # 2) Mail::IMAPClient doesn't offer a streaming API
 558                 if (defined $single_uid) {
 559                         $uids = [ $single_uid ];
 560                 } elsif (!($uids = $mic->search("UID $l_uid:*"))) {
 561                         return if $!{EINTR} && $self->{quit};
 562                         return "E: $uri UID SEARCH $l_uid:* error: $!";
 563                 }
 564                 return if scalar(@$uids) == 0;
 565
 566                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 567                 # responses, so sort it ourselves.  Order matters so
 568                 # IMAPTracker can store the newest UID.
 569                 @$uids = sort { $a <=> $b } @$uids;
 570
 571                 # Did we actually get new messages?
 572                 return if $uids->[0] < $l_uid;
 573
 574                 $l_uid = $uids->[-1] + 1; # for next search
 575                 my $last_uid;
 576                 my $n = $self->{max_batch};
 577
 578                 @$uids = grep { ($_ % $mod) == $shard } @$uids if $mod;
 579                 while (scalar @$uids) {
 580                         my @batch = splice(@$uids, 0, $bs);
 581                         $batch = join(',', @batch);
 582                         local $0 = "UID:$batch $mbx $sec";
 583                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 584                         unless ($r) { # network error?
 585                                 last if $!{EINTR} && $self->{quit};
 586                                 $err = "E: $uri UID FETCH $batch error: $!";
 587                                 last;
 588                         }
 589                         for my $uid (@batch) {
 590                                 # messages get deleted, so holes appear
 591                                 my $per_uid = delete $r->{$uid} // next;
 592                                 my $raw = delete($per_uid->{$key}) // next;
 593                                 _imap_do_msg($self, $uri, $uid, \$raw,
 594                                                 $per_uid->{FLAGS});
 595                                 $last_uid = $uid;
 596                                 last if $self->{quit};
 597                         }
 598                         last if $self->{quit};
 599                 }
 600                 run_commit_cb($self);
 601                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 602         } until ($err || $self->{quit} || defined($single_uid));
 603         $err;
 604 }
 605
 606 # uses cached auth info prepared by mic_for
 607 sub mic_get {
 608         my ($self, $uri) = @_;
 609         my $sec = uri_section($uri);
 610         # see if caller saved result of imap_common_init
 611         my $cached = $self->{mics_cached};
 612         if ($cached) {
 613                 my $mic = $cached->{$sec};
 614                 return $mic if $mic && $mic->IsConnected;
 615                 delete $cached->{$sec};
 616         }
 617         my $mic_arg = $self->{mic_arg}->{$sec} or
 618                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 619         if (defined(my $cb_name = $mic_arg->{Authcallback})) {
 620                 if (ref($cb_name) ne 'CODE') {
 621                         $mic_arg->{Authcallback} = $self->can($cb_name);
 622                 }
 623         }
 624         my $mic = mic_new($self, $mic_arg, $sec, $uri);
 625         $cached //= {}; # invalid placeholder if no cache enabled
 626         $mic && $mic->IsConnected ? ($cached->{$sec} = $mic) : undef;
 627 }
 628
 629 sub imap_each {
 630         my ($self, $url, $eml_cb, @args) = @_;
 631         my $uri = ref($url) ? $url : PublicInbox::URIimap->new($url);
 632         my $sec = uri_section($uri);
 633         local $0 = $uri->mailbox." $sec";
 634         my $mic = mic_get($self, $uri);
 635         my $err;
 636         if ($mic) {
 637                 local $self->{eml_each} = [ $eml_cb, @args ];
 638                 $err = _imap_fetch_all($self, $mic, $uri);
 639         } else {
 640                 $err = "E: <$uri> not connected: $!";
 641         }
 642         die $err if $err && $self->{-can_die};
 643         warn $err if $err;
 644         $mic;
 645 }
 646
 647 # may used cached auth info prepared by nn_for once
 648 sub nn_get {
 649         my ($self, $uri) = @_;
 650         my $sec = uri_section($uri);
 651         # see if caller saved result of nntp_common_init
 652         my $cached = $self->{nn_cached} // {};
 653         my $nn;
 654         $nn = delete($cached->{$sec}) and return $nn;
 655         my $nn_arg = $self->{nn_arg}->{$sec} or
 656                         die "BUG: no Net::NNTP->new arg for $sec";
 657         my $nntp_opt = $self->{nntp_opt}->{$sec};
 658         $nn = nn_new($nn_arg, $nntp_opt, $uri) or return;
 659         if (my $postconn = $nntp_opt->{-postconn}) {
 660                 for my $m_arg (@$postconn) {
 661                         my ($method, @args) = @$m_arg;
 662                         $nn->$method(@args) and next;
 663                         die "E: <$uri> $method failed\n";
 664                         return;
 665                 }
 666         }
 667         $nn;
 668 }
 669
 670 sub _nntp_fetch_all ($$$) {
 671         my ($self, $nn, $uri) = @_;
 672         my ($group, $num_a, $num_b) = $uri->group;
 673         my $sec = uri_section($uri);
 674         my ($nr, $beg, $end) = $nn->group($group);
 675         unless (defined($nr)) {
 676                 my $msg = ndump($nn->message);
 677                 return "E: GROUP $group <$sec> $msg";
 678         }
 679
 680         # IMAPTracker is also used for tracking NNTP, UID == article number
 681         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 682         # expensive.  So we assume newsgroups don't change:
 683         my ($itrk, $l_art) = itrk_last($self, $uri);
 684
 685         # allow users to specify articles to refetch
 686         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 687         # nntp://example.com/inbox.foo/$num_a-$num_b
 688         $beg = $num_a if defined($num_a) && $num_a < $beg;
 689         $end = $num_b if defined($num_b) && $num_b < $end;
 690         if (defined $l_art) {
 691                 return if $l_art >= $end; # nothing to do
 692                 $beg = $l_art + 1;
 693         }
 694         my ($err, $art, $last_art, $kw); # kw stays undef, no keywords in NNTP
 695         unless ($self->{quiet}) {
 696                 warn "# $uri fetching ARTICLE $beg..$end\n";
 697         }
 698         my $n = $self->{max_batch};
 699         for ($beg..$end) {
 700                 last if $self->{quit};
 701                 $art = $_;
 702                 if (--$n < 0) {
 703                         run_commit_cb($self);
 704                         $itrk->update_last(0, $last_art) if $itrk;
 705                         $n = $self->{max_batch};
 706                 }
 707                 my $raw = $nn->article($art);
 708                 unless (defined($raw)) {
 709                         my $msg = ndump($nn->message);
 710                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 711                                 $err = "E: $msg";
 712                                 last;
 713                         } else { # probably just a deleted message (spam)
 714                                 warn "W: $msg";
 715                                 next;
 716                         }
 717                 }
 718                 $raw = join('', @$raw);
 719                 $raw =~ s/\r\n/\n/sg;
 720                 my ($eml_cb, @args) = @{$self->{eml_each}};
 721                 $eml_cb->($uri, $art, $kw, PublicInbox::Eml->new(\$raw), @args);
 722                 $last_art = $art;
 723         }
 724         run_commit_cb($self);
 725         $itrk->update_last(0, $last_art) if $itrk;
 726         $err;
 727 }
 728
 729 sub nntp_each {
 730         my ($self, $url, $eml_cb, @args) = @_;
 731         my $uri = ref($url) ? $url : PublicInbox::URInntps->new($url);
 732         my $sec = uri_section($uri);
 733         local $0 = $uri->group ." $sec";
 734         my $nn = nn_get($self, $uri);
 735         return if $self->{quit};
 736         my $err;
 737         if ($nn) {
 738                 local $self->{eml_each} = [ $eml_cb, @args ];
 739                 $err = _nntp_fetch_all($self, $nn, $uri);
 740         } else {
 741                 $err = "E: <$uri> not connected: $!";
 742         }
 743         die $err if $err && $self->{-can_die};
 744         warn $err if $err;
 745         $nn;
 746 }
 747
 748 sub new { bless {}, shift };
 749
 750 1;