lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Config;
  11 our %IMAPflags2kw = map {; "\\\u$_" => $_ } qw(seen answered flagged draft);
  12 $IMAPflags2kw{'$Forwarded'} = 'forwarded';  # RFC 5550
  13
  14 our @EXPORT = qw(uri_section imap_uri nntp_uri);
  15
  16 sub ndump {
  17         require Data::Dumper;
  18         Data::Dumper->new(\@_)->Useqq(1)->Terse(1)->Dump;
  19 }
  20
  21 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  22 # without the mailbox, so we can share connections between different inboxes
  23 sub uri_section ($) {
  24         my ($uri) = @_;
  25         $uri->scheme . '://' . $uri->authority;
  26 }
  27
  28 sub socks_args ($) {
  29         my ($val) = @_;
  30         return if ($val // '') eq '';
  31         if ($val =~ m!\Asocks5h:// (?: \[ ([^\]]+) \] | ([^:/]+) )
  32                                         (?::([0-9]+))?/*\z!ix) {
  33                 my ($h, $p) = ($1 // $2, $3 + 0);
  34                 $h = '127.0.0.1' if $h eq '0';
  35                 eval { require IO::Socket::Socks } or die <<EOM;
  36 IO::Socket::Socks missing for socks5h://$h:$p
  37 EOM
  38                 # for IO::Socket::Socks
  39                 return { ProxyAddr => $h, ProxyPort => $p };
  40         }
  41         die "$val not understood (only socks5h:// is supported)\n";
  42 }
  43
  44 sub mic_new ($$$$) {
  45         my ($self, $mic_arg, $sec, $uri) = @_;
  46         my %mic_arg = (%$mic_arg, Keepalive => 1);
  47         my $sa = $self->{cfg_opt}->{$sec}->{-proxy_cfg} || $self->{-proxy_cli};
  48         if ($sa) {
  49                 # this `require' needed for worker[1..Inf], since socks_args
  50                 # only got called in worker[0]
  51                 require IO::Socket::Socks;
  52                 my %opt = (%$sa, Keepalive => 1);
  53                 $opt{SocksDebug} = 1 if $mic_arg{Debug};
  54                 $opt{ConnectAddr} = delete $mic_arg{Server};
  55                 $opt{ConnectPort} = delete $mic_arg{Port};
  56                 my $s = IO::Socket::Socks->new(%opt) or die
  57                         "E: <$uri> ".eval('$IO::Socket::Socks::SOCKS_ERROR');
  58                 if ($mic_arg->{Ssl}) { # for imaps://
  59                         require IO::Socket::SSL;
  60                         $s = IO::Socket::SSL->start_SSL($s) or die
  61                                 "E: <$uri> ".(IO::Socket::SSL->errstr // '');
  62                 }
  63                 $mic_arg{Socket} = $s;
  64         }
  65         PublicInbox::IMAPClient->new(%mic_arg);
  66 }
  67
  68 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  69
  70 sub onion_hint ($$) {
  71         my ($lei, $uri) = @_;
  72         $uri->host =~ /\.onion\z/i or return "\n";
  73         my $t = $uri->isa('PublicInbox::URIimap') ? 'imap' : 'nntp';
  74         my $url = PublicInbox::Config::squote_maybe(uri_section($uri));
  75         my $set_cfg = 'lei config';
  76         if (!$lei) { # public-inbox-watch
  77                 my $f = PublicInbox::Config::squote_maybe(
  78                                 $ENV{PI_CONFIG} || '~/.public-inbox/config');
  79                 $set_cfg = "git config -f $f";
  80         }
  81         my $dq = substr($url, 0, 1) eq "'" ? '"' : '';
  82         <<EOM
  83
  84 Assuming you have Tor configured and running locally on port 9050,
  85 try configuring a socks5h:// proxy:
  86
  87         url=$url
  88         $set_cfg $t.$dq\$url$dq.proxy socks5h://127.0.0.1:9050
  89
  90 ...before retrying your current command
  91 EOM
  92 }
  93
  94 # mic_for may prompt the user and store auth info, prepares mic_get
  95 sub mic_for ($$$$) { # mic = Mail::IMAPClient
  96         my ($self, $uri, $mic_common, $lei) = @_;
  97         require PublicInbox::GitCredential;
  98         my $cred = bless {
  99                 url => "$uri",
 100                 protocol => $uri->scheme,
 101                 host => $uri->host,
 102                 username => $uri->user,
 103                 password => $uri->password,
 104         }, 'PublicInbox::GitCredential';
 105         my $sec = uri_section($uri);
 106         my $common = $mic_common->{$sec} // {};
 107         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
 108         my $host = $cred->{host};
 109         $host = '127.0.0.1' if $host eq '0';
 110         my $mic_arg = {
 111                 Port => $uri->port,
 112                 Server => $host,
 113                 %$common, # may set Starttls, Compress, Debug ....
 114         };
 115         $mic_arg->{Ssl} = 1 if $uri->scheme eq 'imaps';
 116         require PublicInbox::IMAPClient;
 117         my $mic = mic_new($self, $mic_arg, $sec, $uri);
 118         ($mic && $mic->IsConnected) or
 119                 die "E: <$uri> new: $@".onion_hint($lei, $uri);
 120
 121         # default to using STARTTLS if it's available, but allow
 122         # it to be disabled since I usually connect to localhost
 123         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
 124                         $mic->has_capability('STARTTLS') &&
 125                         $mic->can('starttls')) {
 126                 $mic->starttls or die "E: <$uri> STARTTLS: $@\n";
 127         }
 128
 129         # do we even need credentials?
 130         if (!defined($cred->{username}) &&
 131                         $mic->has_capability('AUTH=ANONYMOUS')) {
 132                 $cred = undef;
 133         }
 134         if ($cred) {
 135                 my $p = $cred->{password} // $cred->check_netrc($lei);
 136                 $cred->fill($lei) unless defined($p); # may prompt user here
 137                 $mic->User($mic_arg->{User} = $cred->{username});
 138                 $mic->Password($mic_arg->{Password} = $cred->{password});
 139         } else { # AUTH=ANONYMOUS
 140                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
 141                 $mic_arg->{Authcallback} = 'auth_anon_cb';
 142                 $mic->Authcallback(\&auth_anon_cb);
 143         }
 144         my $err;
 145         if ($mic->login && $mic->IsAuthenticated) {
 146                 # success! keep IMAPClient->new arg in case we get disconnected
 147                 $self->{net_arg}->{$sec} = $mic_arg;
 148                 if ($cred) {
 149                         $uri->user($cred->{username}) if !defined($uri->user);
 150                 } elsif ($mic_arg->{Authmechanism} eq 'ANONYMOUS') {
 151                         $uri->auth('ANONYMOUS') if !defined($uri->auth);
 152                 }
 153         } else {
 154                 $err = "E: <$uri> LOGIN: $@\n";
 155                 if ($cred && defined($cred->{password})) {
 156                         $err =~ s/\Q$cred->{password}\E/*******/g;
 157                 }
 158                 $mic = undef;
 159         }
 160         $cred->run($mic ? 'approve' : 'reject') if $cred && $cred->{filled};
 161         if ($err) {
 162                 $lei ? $lei->fail($err) : warn($err);
 163         }
 164         $mic;
 165 }
 166
 167 # Net::NNTP doesn't support CAPABILITIES, yet
 168 sub try_starttls ($) {
 169         my ($host) = @_;
 170         return if $host =~ /\.onion\z/s;
 171         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 172         return if $host eq '::1';
 173         1;
 174 }
 175
 176 sub nn_new ($$$) {
 177         my ($nn_arg, $nntp_cfg, $uri) = @_;
 178         my $nn;
 179         if (defined $nn_arg->{ProxyAddr}) {
 180                 require PublicInbox::NetNNTPSocks;
 181                 $nn_arg->{SocksDebug} = 1 if $nn_arg->{Debug};
 182                 eval { $nn = PublicInbox::NetNNTPSocks->new_socks(%$nn_arg) };
 183                 die "E: <$uri> $@\n" if $@;
 184         } else {
 185                 $nn = Net::NNTP->new(%$nn_arg) or return;
 186         }
 187         setsockopt($nn, Socket::SOL_SOCKET(), Socket::SO_KEEPALIVE(), 1);
 188
 189         # default to using STARTTLS if it's available, but allow
 190         # it to be disabled for localhost/VPN users
 191         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 192                 if (!defined($nntp_cfg->{starttls}) &&
 193                                 try_starttls($nn_arg->{Host})) {
 194                         # soft fail by default
 195                         $nn->starttls or warn <<"";
 196 W: <$uri> STARTTLS tried and failed (not requested)
 197
 198                 } elsif ($nntp_cfg->{starttls}) {
 199                         # hard fail if explicitly configured
 200                         $nn->starttls or die <<"";
 201 E: <$uri> STARTTLS requested and failed
 202
 203                 }
 204         } elsif ($nntp_cfg->{starttls}) {
 205                 $nn->can('starttls') or
 206                         die "E: <$uri> Net::NNTP too old for STARTTLS\n";
 207                 $nn->starttls or die <<"";
 208 E: <$uri> STARTTLS requested and failed
 209
 210         }
 211         $nn;
 212 }
 213
 214 sub nn_for ($$$$) { # nn = Net::NNTP
 215         my ($self, $uri, $nn_common, $lei) = @_;
 216         my $sec = uri_section($uri);
 217         my $nntp_cfg = $self->{cfg_opt}->{$sec} //= {};
 218         my $host = $uri->host;
 219         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 220         $host = '127.0.0.1' if $host eq '0';
 221         my $cred;
 222         my ($u, $p);
 223         if (defined(my $ui = $uri->userinfo)) {
 224                 require PublicInbox::GitCredential;
 225                 $cred = bless {
 226                         url => $sec,
 227                         protocol => $uri->scheme,
 228                         host => $host,
 229                 }, 'PublicInbox::GitCredential';
 230                 ($u, $p) = split(/:/, $ui, 2);
 231                 ($cred->{username}, $cred->{password}) = ($u, $p);
 232                 $p //= $cred->check_netrc($lei);
 233         }
 234         my $common = $nn_common->{$sec} // {};
 235         my $nn_arg = {
 236                 Port => $uri->port,
 237                 Host => $host,
 238                 %$common, # may Debug ....
 239         };
 240         $nn_arg->{SSL} = 1 if $uri->secure; # snews == nntps
 241         my $sa = $self->{-proxy_cli};
 242         %$nn_arg = (%$nn_arg, %$sa) if $sa;
 243         my $nn = nn_new($nn_arg, $nntp_cfg, $uri) or
 244                 die "E: <$uri> new: $@".onion_hint($lei, $uri);
 245         if ($cred) {
 246                 $cred->fill($lei) unless defined($p); # may prompt user here
 247                 if ($nn->authinfo($u, $p)) {
 248                         push @{$nntp_cfg->{-postconn}}, [ 'authinfo', $u, $p ];
 249                 } else {
 250                         warn "E: <$uri> AUTHINFO $u XXXX failed\n";
 251                         $nn = undef;
 252                 }
 253         }
 254
 255         if ($nntp_cfg->{compress}) {
 256                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 257                 if ($nn->can('compress')) {
 258                         if ($nn->compress) {
 259                                 push @{$nntp_cfg->{-postconn}}, [ 'compress' ];
 260                         } else {
 261                                 warn "W: <$uri> COMPRESS failed\n";
 262                         }
 263                 } else {
 264                         delete $nntp_cfg->{compress};
 265                         warn <<"";
 266 W: <$uri> COMPRESS not supported by Net::NNTP
 267 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 268
 269                 }
 270         }
 271
 272         $self->{net_arg}->{$sec} = $nn_arg;
 273         $cred->run($nn ? 'approve' : 'reject') if $cred && $cred->{filled};
 274         $nn;
 275 }
 276
 277 sub imap_uri {
 278         my ($url, $ls_ok) = @_;
 279         require PublicInbox::URIimap;
 280         my $uri = PublicInbox::URIimap->new($url);
 281         $uri && ($ls_ok || $uri->mailbox) ? $uri->canonical : undef;
 282 }
 283
 284 my %IS_NNTP = (news => 1, snews => 1, nntp => 1, nntps => 1);
 285 sub nntp_uri {
 286         my ($url, $ls_ok) = @_;
 287         require PublicInbox::URInntps;
 288         my $uri = PublicInbox::URInntps->new($url);
 289         $uri && $IS_NNTP{$uri->scheme} && ($ls_ok || $uri->group) ?
 290                 $uri->canonical : undef;
 291 }
 292
 293 sub cfg_intvl ($$$) {
 294         my ($cfg, $key, $url) = @_;
 295         my $v = $cfg->urlmatch($key, $url) // return;
 296         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 297         if (ref($v) eq 'ARRAY') {
 298                 $v = join(', ', @$v);
 299                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 300         } else {
 301                 warn "W: $key=$v is not a numeric value in seconds\n";
 302         }
 303 }
 304
 305 sub cfg_bool ($$$) {
 306         my ($cfg, $key, $url) = @_;
 307         my $orig = $cfg->urlmatch($key, $url) // return;
 308         my $bool = $cfg->git_bool($orig);
 309         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 310         $bool;
 311 }
 312
 313 # flesh out common IMAP-specific data structures
 314 sub imap_common_init ($;$) {
 315         my ($self, $lei) = @_;
 316         return unless $self->{imap_order};
 317         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 318         eval { require PublicInbox::IMAPClient } or
 319                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 320         ($lei || eval { require PublicInbox::IMAPTracker }) or
 321                 die "DBD::SQLite is required for IMAP\n:$@\n";
 322         require PublicInbox::URIimap;
 323         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 324         my $mic_common = {}; # scheme://authority => Mail:IMAPClient arg
 325         for my $uri (@{$self->{imap_order}}) {
 326                 my $sec = uri_section($uri);
 327
 328                 # knobs directly for Mail::IMAPClient->new
 329                 for my $k (qw(Starttls Debug Compress Ignoresizeerrors)) {
 330                         my $bool = cfg_bool($cfg, "imap.$k", $$uri) // next;
 331                         $mic_common->{$sec}->{$k} = $bool;
 332                 }
 333                 my $to = cfg_intvl($cfg, 'imap.timeout', $$uri);
 334                 $mic_common->{$sec}->{Timeout} = $to if $to;
 335
 336                 # knobs we use ourselves:
 337                 my $sa = socks_args($cfg->urlmatch('imap.Proxy', $$uri));
 338                 $self->{cfg_opt}->{$sec}->{-proxy_cfg} = $sa if $sa;
 339                 for my $k (qw(pollInterval idleInterval)) {
 340                         $to = cfg_intvl($cfg, "imap.$k", $$uri) // next;
 341                         $self->{cfg_opt}->{$sec}->{$k} = $to;
 342                 }
 343                 my $k = 'imap.fetchBatchSize';
 344                 my $bs = $cfg->urlmatch($k, $$uri) // next;
 345                 if ($bs =~ /\A([0-9]+)\z/) {
 346                         $self->{cfg_opt}->{$sec}->{batch_size} = $bs;
 347                 } else {
 348                         warn "$k=$bs is not an integer\n";
 349                 }
 350         }
 351         # make sure we can connect and cache the credentials in memory
 352         my $mics = {}; # schema://authority => IMAPClient obj
 353         for my $orig_uri (@{$self->{imap_order}}) {
 354                 my $sec = uri_section($orig_uri);
 355                 my $uri = PublicInbox::URIimap->new("$sec/");
 356                 my $mic = $mics->{$sec} //=
 357                                 mic_for($self, $uri, $mic_common, $lei) //
 358                                 die "Unable to continue\n";
 359                 next unless $self->isa('PublicInbox::NetWriter');
 360                 my $dst = $orig_uri->mailbox // next;
 361                 next if $mic->exists($dst); # already exists
 362                 $mic->create($dst) or die "CREATE $dst failed <$orig_uri>: $@";
 363         }
 364         $mics;
 365 }
 366
 367 # flesh out common NNTP-specific data structures
 368 sub nntp_common_init ($;$) {
 369         my ($self, $lei) = @_;
 370         return unless $self->{nntp_order};
 371         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 372         eval { require Net::NNTP } or
 373                 die "Net::NNTP is required for NNTP:\n$@\n";
 374         ($lei || eval { require PublicInbox::IMAPTracker }) or
 375                 die "DBD::SQLite is required for NNTP\n:$@\n";
 376         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 377         my $nn_common = {}; # scheme://authority => Net::NNTP->new arg
 378         for my $uri (@{$self->{nntp_order}}) {
 379                 my $sec = uri_section($uri);
 380                 my $args = $nn_common->{$sec} //= {};
 381
 382                 # Debug and Timeout are passed to Net::NNTP->new
 383                 my $v = cfg_bool($cfg, 'nntp.Debug', $$uri);
 384                 $args->{Debug} = $v if defined $v;
 385                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $$uri);
 386                 $args->{Timeout} = $to if $to;
 387                 my $sa = socks_args($cfg->urlmatch('nntp.Proxy', $$uri));
 388                 %$args = (%$args, %$sa) if $sa;
 389
 390                 # Net::NNTP post-connect commands
 391                 for my $k (qw(starttls compress)) {
 392                         $v = cfg_bool($cfg, "nntp.$k", $$uri) // next;
 393                         $self->{cfg_opt}->{$sec}->{$k} = $v;
 394                 }
 395
 396                 # -watch internal option
 397                 for my $k (qw(pollInterval)) {
 398                         $to = cfg_intvl($cfg, "nntp.$k", $$uri) // next;
 399                         $self->{cfg_opt}->{$sec}->{$k} = $to;
 400                 }
 401         }
 402         # make sure we can connect and cache the credentials in memory
 403         my %nn; # schema://authority => Net::NNTP object
 404         for my $uri (@{$self->{nntp_order}}) {
 405                 my $sec = uri_section($uri);
 406                 $nn{$sec} //= nn_for($self, $uri, $nn_common, $lei);
 407         }
 408         \%nn; # for optional {nn_cached}
 409 }
 410
 411 sub add_url {
 412         my ($self, $arg, $ls_ok) = @_;
 413         my $uri;
 414         if ($uri = imap_uri($arg, $ls_ok)) {
 415                 $_[1] = $$uri; # canonicalized
 416                 push @{$self->{imap_order}}, $uri;
 417         } elsif ($uri = nntp_uri($arg, $ls_ok)) {
 418                 $_[1] = $$uri; # canonicalized
 419                 push @{$self->{nntp_order}}, $uri;
 420         } else {
 421                 push @{$self->{unsupported_url}}, $arg;
 422         }
 423 }
 424
 425 sub errors {
 426         my ($self, $lei) = @_;
 427         if (my $u = $self->{unsupported_url}) {
 428                 return "Unsupported URL(s): @$u";
 429         }
 430         if ($self->{imap_order}) {
 431                 eval { require PublicInbox::IMAPClient } or
 432                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 433         }
 434         if ($self->{nntp_order}) {
 435                 eval { require Net::NNTP } or
 436                         die "Net::NNTP is required for NNTP:\n$@\n";
 437         }
 438         my $sa = socks_args($lei ? $lei->{opt}->{proxy} : undef);
 439         $self->{-proxy_cli} = $sa if $sa;
 440         undef;
 441 }
 442
 443 sub flags2kw ($$$$) {
 444         my ($self, $uri, $uid, $flags) = @_;
 445         my $kw = [];
 446         for my $f (split(/ /, $flags)) {
 447                 if (my $k = $IMAPflags2kw{$f}) {
 448                         push @$kw, $k;
 449                 } elsif ($f eq "\\Recent") { # not in JMAP
 450                 } elsif ($f eq "\\Deleted") { # not in JMAP
 451                         return;
 452                 } elsif ($self->{verbose}) {
 453                         warn "# unknown IMAP flag $f <$uri/;UID=$uid>\n";
 454                 }
 455         }
 456         @$kw = sort @$kw; # for LeiSearch->kw_changed and UI/UX purposes
 457         $kw;
 458 }
 459
 460 sub _imap_do_msg ($$$$$) {
 461         my ($self, $uri, $uid, $raw, $flags) = @_;
 462         # our target audience expects LF-only, save storage
 463         $$raw =~ s/\r\n/\n/sg;
 464         my $kw = defined($flags) ?
 465                 (flags2kw($self, $uri, $uid, $flags) // return) : undef;
 466         my ($eml_cb, @args) = @{$self->{eml_each}};
 467         $eml_cb->($uri, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 468 }
 469
 470 sub run_commit_cb ($) {
 471         my ($self) = @_;
 472         my $cmt_cb_args = $self->{on_commit} or return;
 473         my ($cb, @args) = @$cmt_cb_args;
 474         $cb->(@args);
 475 }
 476
 477 sub itrk_last ($$;$$) {
 478         my ($self, $uri, $r_uidval, $mic) = @_;
 479         return (undef, undef, $r_uidval) unless $self->{incremental};
 480         my ($itrk, $l_uid, $l_uidval);
 481         if (defined(my $lms = $self->{-lms_ro})) { # LeiMailSync or 0
 482                 $uri->uidvalidity($r_uidval) if defined $r_uidval;
 483                 if ($mic) {
 484                         my $auth = $mic->Authmechanism // '';
 485                         $uri->auth($auth) if $auth eq 'ANONYMOUS';
 486                         my $user = $mic->User;
 487                         $uri->user($user) if defined($user);
 488                 }
 489                 my $x;
 490                 $l_uid = ($lms && ($x = $lms->location_stats($$uri))) ?
 491                                 $x->{'uid.max'} : undef;
 492                 # itrk remains undef, lei/store worker writes to
 493                 # mail_sync.sqlite3
 494         } else {
 495                 $itrk = PublicInbox::IMAPTracker->new($$uri);
 496                 ($l_uidval, $l_uid) = $itrk->get_last($$uri);
 497         }
 498         ($itrk, $l_uid, $l_uidval //= $r_uidval);
 499 }
 500
 501 # import flags of already-seen messages
 502 sub each_old_flags ($$$$) {
 503         my ($self, $mic, $uri, $l_uid) = @_;
 504         $l_uid ||= 1;
 505         my $sec = uri_section($uri);
 506         my $bs = ($self->{cfg_opt}->{$sec}->{batch_size} // 1) * 10000;
 507         my ($eml_cb, @args) = @{$self->{eml_each}};
 508         $self->{quiet} or warn "# $uri syncing flags 1:$l_uid\n";
 509         for (my $n = 1; $n <= $l_uid; $n += $bs) {
 510                 my $end = $n + $bs;
 511                 $end = $l_uid if $end > $l_uid;
 512                 my $r = $mic->fetch_hash("$n:$end", 'FLAGS');
 513                 if (!$r) {
 514                         return if $!{EINTR} && $self->{quit};
 515                         return "E: $uri UID FETCH $n:$end error: $!";
 516                 }
 517                 while (my ($uid, $per_uid) = each %$r) {
 518                         my $kw = flags2kw($self, $uri, $uid, $per_uid->{FLAGS})
 519                                 // next;
 520                         # LeiImport->input_net_cb
 521                         $eml_cb->($uri, $uid, $kw, undef, @args);
 522                 }
 523         }
 524 }
 525
 526 # returns true if PERMANENTFLAGS indicates FLAGS of already imported
 527 # messages are meaningful
 528 sub perm_fl_ok ($) {
 529         my ($perm_fl) = @_;
 530         return if !defined($perm_fl);
 531         for my $f (split(/[ \t]+/, $perm_fl)) {
 532                 return 1 if $IMAPflags2kw{$f};
 533         }
 534         undef;
 535 }
 536
 537 # may be overridden in NetWriter or Watch
 538 sub folder_select { $_[0]->{each_old} ? 'select' : 'examine' }
 539
 540 sub _imap_fetch_all ($$$) {
 541         my ($self, $mic, $orig_uri) = @_;
 542         my $sec = uri_section($orig_uri);
 543         my $mbx = $orig_uri->mailbox;
 544         $mic->Clear(1); # trim results history
 545
 546         # we need to check for mailbox writability to see if we care about
 547         # FLAGS from already-imported messages.
 548         my $cmd = $self->folder_select;
 549         $mic->$cmd($mbx) or return "E: \U$cmd\E $mbx ($sec) failed: $!";
 550
 551         my ($r_uidval, $r_uidnext, $perm_fl);
 552         for ($mic->Results) {
 553                 /^\* OK \[PERMANENTFLAGS \(([^\)]*)\)\].*/ and $perm_fl = $1;
 554                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 555                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 556         }
 557         $r_uidval //= $mic->uidvalidity($mbx) //
 558                 return "E: $orig_uri cannot get UIDVALIDITY";
 559         $r_uidnext //= $mic->uidnext($mbx) //
 560                 return "E: $orig_uri cannot get UIDNEXT";
 561         my $expect = $orig_uri->uidvalidity // $r_uidval;
 562         return <<EOF if $expect != $r_uidval;
 563 E: $orig_uri UIDVALIDITY mismatch (got $r_uidval)
 564 EOF
 565
 566         my $uri = $orig_uri->clone;
 567         my $single_uid = $uri->uid;
 568         my ($itrk, $l_uid, $l_uidval) = itrk_last($self, $uri, $r_uidval, $mic);
 569         if (defined($single_uid)) {
 570                 $itrk = $l_uid = undef;
 571                 $uri->uid(undef); # for eml_cb
 572         }
 573         return <<EOF if $l_uidval != $r_uidval;
 574 E: $uri UIDVALIDITY mismatch
 575 E: local=$l_uidval != remote=$r_uidval
 576 EOF
 577         $uri->uidvalidity($r_uidval);
 578         $l_uid //= 0;
 579         my $r_uid = $r_uidnext - 1;
 580         return <<EOF if $l_uid > $r_uid;
 581 E: $uri local UID exceeds remote ($l_uid > $r_uid)
 582 E: $uri strangely, UIDVALIDLITY matches ($l_uidval)
 583 EOF
 584         $mic->Uid(1); # the default, we hope
 585         my $err;
 586         my $use_fl = perm_fl_ok($perm_fl);
 587         if (!defined($single_uid) && $self->{each_old} && $use_fl) {
 588                 $err = each_old_flags($self, $mic, $uri, $l_uid);
 589                 return $err if $err;
 590         }
 591         return if $l_uid >= $r_uid; # nothing to do
 592         $l_uid ||= 1;
 593         my ($mod, $shard) = @{$self->{shard_info} // []};
 594         unless ($self->{quiet}) {
 595                 my $m = $mod ? " [(UID % $mod) == $shard]" : '';
 596                 warn "# $uri fetching UID $l_uid:$r_uid$m\n";
 597         }
 598         my $bs = $self->{cfg_opt}->{$sec}->{batch_size} // 1;
 599         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 600         my $key = $req;
 601         $key =~ s/\.PEEK//;
 602         my ($uids, $batch);
 603         do {
 604                 # I wish "UID FETCH $START:*" could work, but:
 605                 # 1) servers do not need to return results in any order
 606                 # 2) Mail::IMAPClient doesn't offer a streaming API
 607                 if (defined $single_uid) {
 608                         $uids = [ $single_uid ];
 609                 } elsif (!($uids = $mic->search("UID $l_uid:*"))) {
 610                         return if $!{EINTR} && $self->{quit};
 611                         return "E: $uri UID SEARCH $l_uid:* error: $!";
 612                 }
 613                 return if scalar(@$uids) == 0;
 614
 615                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 616                 # responses, so sort it ourselves.  Order matters so
 617                 # IMAPTracker can store the newest UID.
 618                 @$uids = sort { $a <=> $b } @$uids;
 619
 620                 # Did we actually get new messages?
 621                 return if $uids->[0] < $l_uid;
 622
 623                 $l_uid = $uids->[-1] + 1; # for next search
 624                 my $last_uid;
 625                 my $n = $self->{max_batch};
 626
 627                 @$uids = grep { ($_ % $mod) == $shard } @$uids if $mod;
 628                 while (scalar @$uids) {
 629                         my @batch = splice(@$uids, 0, $bs);
 630                         $batch = join(',', @batch);
 631                         local $0 = "UID:$batch $mbx $sec";
 632                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 633                         unless ($r) { # network error?
 634                                 last if $!{EINTR} && $self->{quit};
 635                                 $err = "E: $uri UID FETCH $batch error: $!";
 636                                 last;
 637                         }
 638                         for my $uid (@batch) {
 639                                 # messages get deleted, so holes appear
 640                                 my $per_uid = delete $r->{$uid} // next;
 641                                 my $raw = delete($per_uid->{$key}) // next;
 642                                 my $fl = $use_fl ? $per_uid->{FLAGS} : undef;
 643                                 _imap_do_msg($self, $uri, $uid, \$raw, $fl);
 644                                 $last_uid = $uid;
 645                                 last if $self->{quit};
 646                         }
 647                         last if $self->{quit};
 648                 }
 649                 run_commit_cb($self);
 650                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 651         } until ($err || $self->{quit} || defined($single_uid));
 652         $err;
 653 }
 654
 655 # uses cached auth info prepared by mic_for
 656 sub mic_get {
 657         my ($self, $uri) = @_;
 658         my $sec = uri_section($uri);
 659         # see if caller saved result of imap_common_init
 660         my $cached = $self->{mics_cached};
 661         if ($cached) {
 662                 my $mic = $cached->{$sec};
 663                 return $mic if $mic && $mic->IsConnected;
 664                 delete $cached->{$sec};
 665         }
 666         my $mic_arg = $self->{net_arg}->{$sec} or
 667                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 668         if (defined(my $cb_name = $mic_arg->{Authcallback})) {
 669                 if (ref($cb_name) ne 'CODE') {
 670                         $mic_arg->{Authcallback} = $self->can($cb_name);
 671                 }
 672         }
 673         my $mic = mic_new($self, $mic_arg, $sec, $uri);
 674         $cached //= {}; # invalid placeholder if no cache enabled
 675         $mic && $mic->IsConnected ? ($cached->{$sec} = $mic) : undef;
 676 }
 677
 678 sub imap_each {
 679         my ($self, $url, $eml_cb, @args) = @_;
 680         my $uri = ref($url) ? $url : PublicInbox::URIimap->new($url);
 681         my $sec = uri_section($uri);
 682         local $0 = $uri->mailbox." $sec";
 683         my $mic = mic_get($self, $uri);
 684         my $err;
 685         if ($mic) {
 686                 local $self->{eml_each} = [ $eml_cb, @args ];
 687                 $err = _imap_fetch_all($self, $mic, $uri);
 688         } else {
 689                 $err = "E: <$uri> not connected: $!";
 690         }
 691         die $err if $err && $self->{-can_die};
 692         warn $err if $err;
 693         $mic;
 694 }
 695
 696 # may used cached auth info prepared by nn_for once
 697 sub nn_get {
 698         my ($self, $uri) = @_;
 699         my $sec = uri_section($uri);
 700         # see if caller saved result of nntp_common_init
 701         my $cached = $self->{nn_cached} // {};
 702         my $nn;
 703         $nn = delete($cached->{$sec}) and return $nn;
 704         my $nn_arg = $self->{net_arg}->{$sec} or
 705                         die "BUG: no Net::NNTP->new arg for $sec";
 706         my $nntp_cfg = $self->{cfg_opt}->{$sec};
 707         $nn = nn_new($nn_arg, $nntp_cfg, $uri) or return;
 708         if (my $postconn = $nntp_cfg->{-postconn}) {
 709                 for my $m_arg (@$postconn) {
 710                         my ($method, @args) = @$m_arg;
 711                         $nn->$method(@args) and next;
 712                         die "E: <$uri> $method failed\n";
 713                         return;
 714                 }
 715         }
 716         $nn;
 717 }
 718
 719 sub _nntp_fetch_all ($$$) {
 720         my ($self, $nn, $uri) = @_;
 721         my ($group, $num_a, $num_b) = $uri->group;
 722         my $sec = uri_section($uri);
 723         my ($nr, $beg, $end) = $nn->group($group);
 724         unless (defined($nr)) {
 725                 my $msg = ndump($nn->message);
 726                 return "E: GROUP $group <$sec> $msg";
 727         }
 728         (defined($num_a) && defined($num_b) && $num_a > $num_b) and
 729                 return "E: $uri: backwards range: $num_a > $num_b";
 730
 731         # IMAPTracker is also used for tracking NNTP, UID == article number
 732         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 733         # expensive.  So we assume newsgroups don't change:
 734         my ($itrk, $l_art) = itrk_last($self, $uri);
 735
 736         if (defined($l_art) && !defined($num_a)) {
 737                 return if $l_art >= $end; # nothing to do
 738                 $beg = $l_art + 1;
 739         }
 740         # allow users to specify articles to refetch
 741         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 742         # nntp://example.com/inbox.foo/$num_a-$num_b
 743         $beg = $num_a if defined($num_a) && $num_a > $beg && $num_a <= $end;
 744         $end = $num_b if defined($num_b) && $num_b >= $beg && $num_b < $end;
 745         $end = $beg if defined($num_a) && !defined($num_b);
 746         my ($err, $art, $last_art, $kw); # kw stays undef, no keywords in NNTP
 747         unless ($self->{quiet}) {
 748                 warn "# $uri fetching ARTICLE $beg..$end\n";
 749         }
 750         my $n = $self->{max_batch};
 751         for ($beg..$end) {
 752                 last if $self->{quit};
 753                 $art = $_;
 754                 if (--$n < 0) {
 755                         run_commit_cb($self);
 756                         $itrk->update_last(0, $last_art) if $itrk;
 757                         $n = $self->{max_batch};
 758                 }
 759                 my $raw = $nn->article($art);
 760                 unless (defined($raw)) {
 761                         my $msg = ndump($nn->message);
 762                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 763                                 $err = "E: $msg";
 764                                 last;
 765                         } else { # probably just a deleted message (spam)
 766                                 warn "W: $msg";
 767                                 next;
 768                         }
 769                 }
 770                 $raw = join('', @$raw);
 771                 $raw =~ s/\r\n/\n/sg;
 772                 my ($eml_cb, @args) = @{$self->{eml_each}};
 773                 $eml_cb->($uri, $art, $kw, PublicInbox::Eml->new(\$raw), @args);
 774                 $last_art = $art;
 775         }
 776         run_commit_cb($self);
 777         $itrk->update_last(0, $last_art) if $itrk;
 778         $err;
 779 }
 780
 781 sub nntp_each {
 782         my ($self, $url, $eml_cb, @args) = @_;
 783         my $uri = ref($url) ? $url : PublicInbox::URInntps->new($url);
 784         my $sec = uri_section($uri);
 785         local $0 = $uri->group ." $sec";
 786         my $nn = nn_get($self, $uri);
 787         return if $self->{quit};
 788         my $err;
 789         if ($nn) {
 790                 local $self->{eml_each} = [ $eml_cb, @args ];
 791                 $err = _nntp_fetch_all($self, $nn, $uri);
 792         } else {
 793                 $err = "E: <$uri> not connected: $!";
 794         }
 795         die $err if $err && $self->{-can_die};
 796         warn $err if $err;
 797         $nn;
 798 }
 799
 800 sub new { bless {}, shift };
 801
 802 # updates $uri with UIDVALIDITY
 803 sub mic_for_folder {
 804         my ($self, $uri) = @_;
 805         my $mic = $self->mic_get($uri) or die "E: not connected: $@";
 806         my $m = $self->isa('PublicInbox::NetWriter') ? 'select' : 'examine';
 807         $mic->$m($uri->mailbox) or return;
 808         my $uidval;
 809         for ($mic->Results) {
 810                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ or next;
 811                 $uidval = $1;
 812                 last;
 813         }
 814         $uidval //= $mic->uidvalidity($uri->mailbox) or
 815                 die "E: failed to get uidvalidity from <$uri>: $@";
 816         $uri->uidvalidity($uidval);
 817         $mic;
 818 }
 819
 820
 821 1;