lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10
  11 our %IMAPflags2kw = map {; "\\\u$_" => $_ } qw(seen answered flagged draft);
  12
  13 our @EXPORT = qw(uri_section imap_uri nntp_uri);
  14
  15 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  16 # without the mailbox, so we can share connections between different inboxes
  17 sub uri_section ($) {
  18         my ($uri) = @_;
  19         $uri->scheme . '://' . $uri->authority;
  20 }
  21
  22 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  23
  24 # mic_for may prompt the user and store auth info, prepares mic_get
  25 sub mic_for { # mic = Mail::IMAPClient
  26         my ($self, $url, $mic_args, $lei) = @_;
  27         require PublicInbox::URIimap;
  28         my $uri = PublicInbox::URIimap->new($url);
  29         require PublicInbox::GitCredential;
  30         my $cred = bless {
  31                 url => $url,
  32                 protocol => $uri->scheme,
  33                 host => $uri->host,
  34                 username => $uri->user,
  35                 password => $uri->password,
  36         }, 'PublicInbox::GitCredential';
  37         my $common = $mic_args->{uri_section($uri)} // {};
  38         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
  39         my $host = $cred->{host};
  40         $host = '127.0.0.1' if $host eq '0';
  41         my $mic_arg = {
  42                 Port => $uri->port,
  43                 Server => $host,
  44                 Ssl => $uri->scheme eq 'imaps',
  45                 Keepalive => 1, # SO_KEEPALIVE
  46                 %$common, # may set Starttls, Compress, Debug ....
  47         };
  48         require PublicInbox::IMAPClient;
  49         my $mic = PublicInbox::IMAPClient->new(%$mic_arg) or
  50                 die "E: <$url> new: $@\n";
  51
  52         # default to using STARTTLS if it's available, but allow
  53         # it to be disabled since I usually connect to localhost
  54         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
  55                         $mic->has_capability('STARTTLS') &&
  56                         $mic->can('starttls')) {
  57                 $mic->starttls or die "E: <$url> STARTTLS: $@\n";
  58         }
  59
  60         # do we even need credentials?
  61         if (!defined($cred->{username}) &&
  62                         $mic->has_capability('AUTH=ANONYMOUS')) {
  63                 $cred = undef;
  64         }
  65         if ($cred) {
  66                 $cred->check_netrc unless defined $cred->{password};
  67                 $cred->fill($lei); # may prompt user here
  68                 $mic->User($mic_arg->{User} = $cred->{username});
  69                 $mic->Password($mic_arg->{Password} = $cred->{password});
  70         } else { # AUTH=ANONYMOUS
  71                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
  72                 $mic_arg->{Authcallback} = 'auth_anon_cb';
  73                 $mic->Authcallback(\&auth_anon_cb);
  74         }
  75         my $err;
  76         if ($mic->login && $mic->IsAuthenticated) {
  77                 # success! keep IMAPClient->new arg in case we get disconnected
  78                 $self->{mic_arg}->{uri_section($uri)} = $mic_arg;
  79         } else {
  80                 $err = "E: <$url> LOGIN: $@\n";
  81                 if ($cred && defined($cred->{password})) {
  82                         $err =~ s/\Q$cred->{password}\E/*******/g;
  83                 }
  84                 $mic = undef;
  85         }
  86         $cred->run($mic ? 'approve' : 'reject') if $cred;
  87         if ($err) {
  88                 $lei ? $lei->fail($err) : warn($err);
  89         }
  90         $mic;
  91 }
  92
  93 # Net::NNTP doesn't support CAPABILITIES, yet
  94 sub try_starttls ($) {
  95         my ($host) = @_;
  96         return if $host =~ /\.onion\z/s;
  97         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
  98         return if $host eq '::1';
  99         1;
 100 }
 101
 102 sub nn_new ($$$) {
 103         my ($nn_arg, $nntp_opt, $uri) = @_;
 104         my $nn = Net::NNTP->new(%$nn_arg) or die "E: <$uri> new: $!\n";
 105
 106         # default to using STARTTLS if it's available, but allow
 107         # it to be disabled for localhost/VPN users
 108         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 109                 if (!defined($nntp_opt->{starttls}) &&
 110                                 try_starttls($nn_arg->{Host})) {
 111                         # soft fail by default
 112                         $nn->starttls or warn <<"";
 113 W: <$uri> STARTTLS tried and failed (not requested)
 114
 115                 } elsif ($nntp_opt->{starttls}) {
 116                         # hard fail if explicitly configured
 117                         $nn->starttls or die <<"";
 118 E: <$uri> STARTTLS requested and failed
 119
 120                 }
 121         } elsif ($nntp_opt->{starttls}) {
 122                 $nn->can('starttls') or
 123                         die "E: <$uri> Net::NNTP too old for STARTTLS\n";
 124                 $nn->starttls or die <<"";
 125 E: <$uri> STARTTLS requested and failed
 126
 127         }
 128         $nn;
 129 }
 130
 131 sub nn_for ($$$;$) { # nn = Net::NNTP
 132         my ($self, $uri, $nn_args, $lei) = @_;
 133         my $sec = uri_section($uri);
 134         my $nntp_opt = $self->{nntp_opt}->{$sec} //= {};
 135         my $host = $uri->host;
 136         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 137         $host = '127.0.0.1' if $host eq '0';
 138         my $cred;
 139         my ($u, $p);
 140         if (defined(my $ui = $uri->userinfo)) {
 141                 require PublicInbox::GitCredential;
 142                 $cred = bless {
 143                         url => $sec,
 144                         protocol => $uri->scheme,
 145                         host => $host,
 146                 }, 'PublicInbox::GitCredential';
 147                 ($u, $p) = split(/:/, $ui, 2);
 148                 ($cred->{username}, $cred->{password}) = ($u, $p);
 149                 $cred->check_netrc unless defined $p;
 150         }
 151         my $common = $nn_args->{$sec} // {};
 152         my $nn_arg = {
 153                 Port => $uri->port,
 154                 Host => $host,
 155                 SSL => $uri->secure, # snews == nntps
 156                 %$common, # may Debug ....
 157         };
 158         my $nn = nn_new($nn_arg, $nntp_opt, $uri);
 159         if ($cred) {
 160                 $cred->fill($lei); # may prompt user here
 161                 if ($nn->authinfo($u, $p)) {
 162                         push @{$nntp_opt->{-postconn}}, [ 'authinfo', $u, $p ];
 163                 } else {
 164                         warn "E: <$uri> AUTHINFO $u XXXX failed\n";
 165                         $nn = undef;
 166                 }
 167         }
 168
 169         if ($nntp_opt->{compress}) {
 170                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 171                 if ($nn->can('compress')) {
 172                         if ($nn->compress) {
 173                                 push @{$nntp_opt->{-postconn}}, [ 'compress' ];
 174                         } else {
 175                                 warn "W: <$uri> COMPRESS failed\n";
 176                         }
 177                 } else {
 178                         delete $nntp_opt->{compress};
 179                         warn <<"";
 180 W: <$uri> COMPRESS not supported by Net::NNTP
 181 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 182
 183                 }
 184         }
 185
 186         $self->{nn_arg}->{$sec} = $nn_arg;
 187         $cred->run($nn ? 'approve' : 'reject') if $cred;
 188         $nn;
 189 }
 190
 191 sub imap_uri {
 192         my ($url) = @_;
 193         require PublicInbox::URIimap;
 194         my $uri = PublicInbox::URIimap->new($url);
 195         $uri ? $uri->canonical : undef;
 196 }
 197
 198 my %IS_NNTP = (news => 1, snews => 1, nntp => 1, nntps => 1);
 199 sub nntp_uri {
 200         my ($url) = @_;
 201         require PublicInbox::URInntps;
 202         my $uri = PublicInbox::URInntps->new($url);
 203         $uri && $IS_NNTP{$uri->scheme} && $uri->group ? $uri->canonical : undef;
 204 }
 205
 206 sub cfg_intvl ($$$) {
 207         my ($cfg, $key, $url) = @_;
 208         my $v = $cfg->urlmatch($key, $url) // return;
 209         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 210         if (ref($v) eq 'ARRAY') {
 211                 $v = join(', ', @$v);
 212                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 213         } else {
 214                 warn "W: $key=$v is not a numeric value in seconds\n";
 215         }
 216 }
 217
 218 sub cfg_bool ($$$) {
 219         my ($cfg, $key, $url) = @_;
 220         my $orig = $cfg->urlmatch($key, $url) // return;
 221         my $bool = $cfg->git_bool($orig);
 222         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 223         $bool;
 224 }
 225
 226 # flesh out common IMAP-specific data structures
 227 sub imap_common_init ($;$) {
 228         my ($self, $lei) = @_;
 229         return unless $self->{imap_order};
 230         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 231         eval { require PublicInbox::IMAPClient } or
 232                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 233         eval { require PublicInbox::IMAPTracker } or
 234                 die "DBD::SQLite is required for IMAP\n:$@\n";
 235         require PublicInbox::URIimap;
 236         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 237         my $mic_args = {}; # scheme://authority => Mail:IMAPClient arg
 238         for my $uri (@{$self->{imap_order}}) {
 239                 my $sec = uri_section($uri);
 240                 for my $k (qw(Starttls Debug Compress)) {
 241                         my $bool = cfg_bool($cfg, "imap.$k", $$uri) // next;
 242                         $mic_args->{$sec}->{$k} = $bool;
 243                 }
 244                 my $to = cfg_intvl($cfg, 'imap.timeout', $$uri);
 245                 $mic_args->{$sec}->{Timeout} = $to if $to;
 246                 for my $k (qw(pollInterval idleInterval)) {
 247                         $to = cfg_intvl($cfg, "imap.$k", $$uri) // next;
 248                         $self->{imap_opt}->{$sec}->{$k} = $to;
 249                 }
 250                 my $k = 'imap.fetchBatchSize';
 251                 my $bs = $cfg->urlmatch($k, $$uri) // next;
 252                 if ($bs =~ /\A([0-9]+)\z/) {
 253                         $self->{imap_opt}->{$sec}->{batch_size} = $bs;
 254                 } else {
 255                         warn "$k=$bs is not an integer\n";
 256                 }
 257         }
 258         # make sure we can connect and cache the credentials in memory
 259         $self->{mic_arg} = {}; # schema://authority => IMAPClient->new args
 260         my $mics = {}; # schema://authority => IMAPClient obj
 261         for my $uri (@{$self->{imap_order}}) {
 262                 my $sec = uri_section($uri);
 263                 $mics->{$sec} //= mic_for($self, "$sec/", $mic_args, $lei);
 264                 next unless $self->isa('PublicInbox::NetWriter');
 265                 my $dst = $uri->mailbox // next;
 266                 my $mic = $mics->{$sec};
 267                 next if $mic->exists($dst); # already exists
 268                 $mic->create($dst) or die "CREATE $dst failed <$uri>: $@";
 269         }
 270         $mics;
 271 }
 272
 273 # flesh out common NNTP-specific data structures
 274 sub nntp_common_init ($;$) {
 275         my ($self, $lei) = @_;
 276         return unless $self->{nntp_order};
 277         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 278         eval { require Net::NNTP } or
 279                 die "Net::NNTP is required for NNTP:\n$@\n";
 280         eval { require PublicInbox::IMAPTracker } or
 281                 die "DBD::SQLite is required for NNTP\n:$@\n";
 282         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 283         my $nn_args = {}; # scheme://authority => Net::NNTP->new arg
 284         for my $uri (@{$self->{nntp_order}}) {
 285                 my $sec = uri_section($uri);
 286
 287                 # Debug and Timeout are passed to Net::NNTP->new
 288                 my $v = cfg_bool($cfg, 'nntp.Debug', $$uri);
 289                 $nn_args->{$sec}->{Debug} = $v if defined $v;
 290                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $$uri);
 291                 $nn_args->{$sec}->{Timeout} = $to if $to;
 292
 293                 # Net::NNTP post-connect commands
 294                 for my $k (qw(starttls compress)) {
 295                         $v = cfg_bool($cfg, "nntp.$k", $$uri) // next;
 296                         $self->{nntp_opt}->{$sec}->{$k} = $v;
 297                 }
 298
 299                 # internal option
 300                 for my $k (qw(pollInterval)) {
 301                         $to = cfg_intvl($cfg, "nntp.$k", $$uri) // next;
 302                         $self->{nntp_opt}->{$sec}->{$k} = $to;
 303                 }
 304         }
 305         # make sure we can connect and cache the credentials in memory
 306         $self->{nn_arg} = {}; # schema://authority => Net::NNTP->new args
 307         my %nn; # schema://authority => Net::NNTP object
 308         for my $uri (@{$self->{nntp_order}}) {
 309                 my $sec = uri_section($uri);
 310                 $nn{$sec} //= nn_for($self, $uri, $nn_args, $lei);
 311         }
 312         \%nn; # for optional {nn_cached}
 313 }
 314
 315 sub add_url {
 316         my ($self, $arg) = @_;
 317         my $uri;
 318         if ($uri = imap_uri($arg)) {
 319                 push @{$self->{imap_order}}, $uri;
 320         } elsif ($uri = nntp_uri($arg)) {
 321                 push @{$self->{nntp_order}}, $uri;
 322         } else {
 323                 push @{$self->{unsupported_url}}, $arg;
 324         }
 325 }
 326
 327 sub errors {
 328         my ($self) = @_;
 329         if (my $u = $self->{unsupported_url}) {
 330                 return "Unsupported URL(s): @$u";
 331         }
 332         if ($self->{imap_order}) {
 333                 eval { require PublicInbox::IMAPClient } or
 334                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 335         }
 336         if ($self->{nntp_order}) {
 337                 eval { require Net::NNTP } or
 338                         die "Net::NNTP is required for NNTP:\n$@\n";
 339         }
 340         undef;
 341 }
 342
 343 sub _imap_do_msg ($$$$$) {
 344         my ($self, $uri, $uid, $raw, $flags) = @_;
 345         # our target audience expects LF-only, save storage
 346         $$raw =~ s/\r\n/\n/sg;
 347         my $kw = [];
 348         for my $f (split(/ /, $flags)) {
 349                 my $k = $IMAPflags2kw{$f} // next; # TODO: X-Label?
 350                 push @$kw, $k;
 351         }
 352         my ($eml_cb, @args) = @{$self->{eml_each}};
 353         $eml_cb->($uri, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 354 }
 355
 356 sub run_commit_cb ($) {
 357         my ($self) = @_;
 358         my $cmt_cb_args = $self->{on_commit} or return;
 359         my ($cb, @args) = @$cmt_cb_args;
 360         $cb->(@args);
 361 }
 362
 363 sub _imap_fetch_all ($$$) {
 364         my ($self, $mic, $uri) = @_;
 365         my $sec = uri_section($uri);
 366         my $mbx = $uri->mailbox;
 367         $mic->Clear(1); # trim results history
 368         $mic->examine($mbx) or return "E: EXAMINE $mbx ($sec) failed: $!";
 369         my ($r_uidval, $r_uidnext);
 370         for ($mic->Results) {
 371                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 372                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 373                 last if $r_uidval && $r_uidnext;
 374         }
 375         $r_uidval //= $mic->uidvalidity($mbx) //
 376                 return "E: $uri cannot get UIDVALIDITY";
 377         $r_uidnext //= $mic->uidnext($mbx) //
 378                 return "E: $uri cannot get UIDNEXT";
 379         my $itrk = $self->{incremental} ?
 380                         PublicInbox::IMAPTracker->new($$uri) : 0;
 381         my ($l_uidval, $l_uid) = $itrk ? $itrk->get_last : ();
 382         $l_uidval //= $r_uidval; # first time
 383         $l_uid //= 0;
 384         if ($l_uidval != $r_uidval) {
 385                 return "E: $uri UIDVALIDITY mismatch\n".
 386                         "E: local=$l_uidval != remote=$r_uidval";
 387         }
 388         my $r_uid = $r_uidnext - 1;
 389         if ($l_uid > $r_uid) {
 390                 return "E: $uri local UID exceeds remote ($l_uid > $r_uid)\n".
 391                         "E: $uri strangely, UIDVALIDLITY matches ($l_uidval)\n";
 392         }
 393         return if $l_uid >= $r_uid; # nothing to do
 394         $l_uid ||= 1;
 395         my ($mod, $shard) = @{$self->{shard_info} // []};
 396         unless ($self->{quiet}) {
 397                 my $m = $mod ? " [(UID % $mod) == $shard]" : '';
 398                 warn "# $uri fetching UID $l_uid:$r_uid$m\n";
 399         }
 400         $mic->Uid(1); # the default, we hope
 401         my $bs = $self->{imap_opt}->{$sec}->{batch_size} // 1;
 402         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 403         my $key = $req;
 404         $key =~ s/\.PEEK//;
 405         my ($uids, $batch);
 406         my $err;
 407         do {
 408                 # I wish "UID FETCH $START:*" could work, but:
 409                 # 1) servers do not need to return results in any order
 410                 # 2) Mail::IMAPClient doesn't offer a streaming API
 411                 unless ($uids = $mic->search("UID $l_uid:*")) {
 412                         return if $!{EINTR} && $self->{quit};
 413                         return "E: $uri UID SEARCH $l_uid:* error: $!";
 414                 }
 415                 return if scalar(@$uids) == 0;
 416
 417                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 418                 # responses, so sort it ourselves.  Order matters so
 419                 # IMAPTracker can store the newest UID.
 420                 @$uids = sort { $a <=> $b } @$uids;
 421
 422                 # Did we actually get new messages?
 423                 return if $uids->[0] < $l_uid;
 424
 425                 $l_uid = $uids->[-1] + 1; # for next search
 426                 my $last_uid;
 427                 my $n = $self->{max_batch};
 428
 429                 @$uids = grep { ($_ % $mod) == $shard } @$uids if $mod;
 430                 while (scalar @$uids) {
 431                         my @batch = splice(@$uids, 0, $bs);
 432                         $batch = join(',', @batch);
 433                         local $0 = "UID:$batch $mbx $sec";
 434                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 435                         unless ($r) { # network error?
 436                                 last if $!{EINTR} && $self->{quit};
 437                                 $err = "E: $uri UID FETCH $batch error: $!";
 438                                 last;
 439                         }
 440                         for my $uid (@batch) {
 441                                 # messages get deleted, so holes appear
 442                                 my $per_uid = delete $r->{$uid} // next;
 443                                 my $raw = delete($per_uid->{$key}) // next;
 444                                 _imap_do_msg($self, $uri, $uid, \$raw,
 445                                                 $per_uid->{FLAGS});
 446                                 $last_uid = $uid;
 447                                 last if $self->{quit};
 448                         }
 449                         last if $self->{quit};
 450                 }
 451                 run_commit_cb($self);
 452                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 453         } until ($err || $self->{quit});
 454         $err;
 455 }
 456
 457 # uses cached auth info prepared by mic_for
 458 sub mic_get {
 459         my ($self, $uri) = @_;
 460         my $sec = uri_section($uri);
 461         # see if caller saved result of imap_common_init
 462         my $cached = $self->{mics_cached};
 463         if ($cached) {
 464                 my $mic = $cached->{$sec};
 465                 return $mic if $mic && $mic->IsConnected;
 466                 delete $cached->{$sec};
 467         }
 468         my $mic_arg = $self->{mic_arg}->{$sec} or
 469                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 470         if (defined(my $cb_name = $mic_arg->{Authcallback})) {
 471                 if (ref($cb_name) ne 'CODE') {
 472                         $mic_arg->{Authcallback} = $self->can($cb_name);
 473                 }
 474         }
 475         my $mic = PublicInbox::IMAPClient->new(%$mic_arg);
 476         $cached //= {}; # invalid placeholder if no cache enabled
 477         $mic && $mic->IsConnected ? ($cached->{$sec} = $mic) : undef;
 478 }
 479
 480 sub imap_each {
 481         my ($self, $url, $eml_cb, @args) = @_;
 482         my $uri = ref($url) ? $url : PublicInbox::URIimap->new($url);
 483         my $sec = uri_section($uri);
 484         local $0 = $uri->mailbox." $sec";
 485         my $mic = mic_get($self, $uri);
 486         my $err;
 487         if ($mic) {
 488                 local $self->{eml_each} = [ $eml_cb, @args ];
 489                 $err = _imap_fetch_all($self, $mic, $uri);
 490         } else {
 491                 $err = "E: <$uri> not connected: $!";
 492         }
 493         warn $err if $err;
 494         $mic;
 495 }
 496
 497 # may used cached auth info prepared by nn_for once
 498 sub nn_get {
 499         my ($self, $uri) = @_;
 500         my $sec = uri_section($uri);
 501         # see if caller saved result of nntp_common_init
 502         my $cached = $self->{nn_cached} // {};
 503         my $nn;
 504         $nn = delete($cached->{$sec}) and return $nn;
 505         my $nn_arg = $self->{nn_arg}->{$sec} or
 506                         die "BUG: no Net::NNTP->new arg for $sec";
 507         my $nntp_opt = $self->{nntp_opt}->{$sec};
 508         $nn = nn_new($nn_arg, $nntp_opt, $uri) or return;
 509         if (my $postconn = $nntp_opt->{-postconn}) {
 510                 for my $m_arg (@$postconn) {
 511                         my ($method, @args) = @$m_arg;
 512                         $nn->$method(@args) and next;
 513                         die "E: <$uri> $method failed\n";
 514                         return;
 515                 }
 516         }
 517         $nn;
 518 }
 519
 520 sub _nntp_fetch_all ($$$) {
 521         my ($self, $nn, $uri) = @_;
 522         my ($group, $num_a, $num_b) = $uri->group;
 523         my $sec = uri_section($uri);
 524         my ($nr, $beg, $end) = $nn->group($group);
 525         unless (defined($nr)) {
 526                 chomp(my $msg = $nn->message);
 527                 return "E: GROUP $group <$sec> $msg";
 528         }
 529
 530         # IMAPTracker is also used for tracking NNTP, UID == article number
 531         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 532         # expensive.  So we assume newsgroups don't change:
 533         my $itrk = $self->{incremental} ?
 534                         PublicInbox::IMAPTracker->new($$uri) : 0;
 535         my (undef, $l_art) = $itrk ? $itrk->get_last : ();
 536
 537         # allow users to specify articles to refetch
 538         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 539         # nntp://example.com/inbox.foo/$num_a-$num_b
 540         $beg = $num_a if defined($num_a) && $num_a < $beg;
 541         $end = $num_b if defined($num_b) && $num_b < $end;
 542         if (defined $l_art) {
 543                 return if $l_art >= $end; # nothing to do
 544                 $beg = $l_art + 1;
 545         }
 546         my ($err, $art);
 547         unless ($self->{quiet}) {
 548                 warn "# $uri fetching ARTICLE $beg..$end\n";
 549         }
 550         my $last_art;
 551         my $n = $self->{max_batch};
 552         for ($beg..$end) {
 553                 last if $self->{quit};
 554                 $art = $_;
 555                 if (--$n < 0) {
 556                         run_commit_cb($self);
 557                         $itrk->update_last(0, $last_art) if $itrk;
 558                         $n = $self->{max_batch};
 559                 }
 560                 my $raw = $nn->article($art);
 561                 unless (defined($raw)) {
 562                         my $msg = $nn->message;
 563                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 564                                 $err = "E: $msg";
 565                                 last;
 566                         } else { # probably just a deleted message (spam)
 567                                 warn "W: $msg";
 568                                 next;
 569                         }
 570                 }
 571                 $raw = join('', @$raw);
 572                 $raw =~ s/\r\n/\n/sg;
 573                 my ($eml_cb, @args) = @{$self->{eml_each}};
 574                 $eml_cb->($uri, $art, [], PublicInbox::Eml->new(\$raw), @args);
 575                 $last_art = $art;
 576         }
 577         run_commit_cb($self);
 578         $itrk->update_last(0, $last_art) if $itrk;
 579         $err;
 580 }
 581
 582 sub nntp_each {
 583         my ($self, $url, $eml_cb, @args) = @_;
 584         my $uri = ref($url) ? $url : PublicInbox::URInntps->new($url);
 585         my $sec = uri_section($uri);
 586         local $0 = $uri->group ." $sec";
 587         my $nn = nn_get($self, $uri);
 588         return if $self->{quit};
 589         my $err;
 590         if ($nn) {
 591                 local $self->{eml_each} = [ $eml_cb, @args ];
 592                 $err = _nntp_fetch_all($self, $nn, $uri);
 593         } else {
 594                 $err = "E: <$uri> not connected: $!";
 595         }
 596         warn $err if $err;
 597         $nn;
 598 }
 599
 600 sub new { bless {}, shift };
 601
 602 1;