lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Config;
  11 our %IMAPflags2kw = map {; "\\\u$_" => $_ } qw(seen answered flagged draft);
  12 $IMAPflags2kw{'$Forwarded'} = 'forwarded';  # RFC 5550
  13
  14 our @EXPORT = qw(uri_section imap_uri nntp_uri);
  15
  16 sub ndump {
  17         require Data::Dumper;
  18         Data::Dumper->new(\@_)->Useqq(1)->Terse(1)->Dump;
  19 }
  20
  21 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  22 # without the mailbox, so we can share connections between different inboxes
  23 sub uri_section ($) {
  24         my ($uri) = @_;
  25         $uri->scheme . '://' . $uri->authority;
  26 }
  27
  28 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  29
  30 # mic_for may prompt the user and store auth info, prepares mic_get
  31 sub mic_for ($$$$) { # mic = Mail::IMAPClient
  32         my ($self, $url, $mic_args, $lei) = @_;
  33         require PublicInbox::URIimap;
  34         my $uri = PublicInbox::URIimap->new($url);
  35         require PublicInbox::GitCredential;
  36         my $cred = bless {
  37                 url => $url,
  38                 protocol => $uri->scheme,
  39                 host => $uri->host,
  40                 username => $uri->user,
  41                 password => $uri->password,
  42         }, 'PublicInbox::GitCredential';
  43         my $common = $mic_args->{uri_section($uri)} // {};
  44         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
  45         my $host = $cred->{host};
  46         $host = '127.0.0.1' if $host eq '0';
  47         my $mic_arg = {
  48                 Port => $uri->port,
  49                 Server => $host,
  50                 Ssl => $uri->scheme eq 'imaps',
  51                 Keepalive => 1, # SO_KEEPALIVE
  52                 %$common, # may set Starttls, Compress, Debug ....
  53         };
  54         require PublicInbox::IMAPClient;
  55         my %socks;
  56         if ($lei && $lei->{socks5h}) {
  57                 my %opt = %{$lei->{socks5h}};
  58                 $opt{ConnectAddr} = delete $mic_arg->{Server};
  59                 $opt{ConnectPort} = delete $mic_arg->{Port};
  60                 $socks{Socket} = IO::Socket::Socks->new(%opt) or die
  61                         "E: <$url> ".eval('$IO::Socket::Socks::SOCKS_ERROR');
  62                 $self->{mic_socks5h} = \%opt;
  63         }
  64         my $mic = PublicInbox::IMAPClient->new(%$mic_arg, %socks) or
  65                 die "E: <$url> new: $@\n";
  66
  67         # default to using STARTTLS if it's available, but allow
  68         # it to be disabled since I usually connect to localhost
  69         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
  70                         $mic->has_capability('STARTTLS') &&
  71                         $mic->can('starttls')) {
  72                 $mic->starttls or die "E: <$url> STARTTLS: $@\n";
  73         }
  74
  75         # do we even need credentials?
  76         if (!defined($cred->{username}) &&
  77                         $mic->has_capability('AUTH=ANONYMOUS')) {
  78                 $cred = undef;
  79         }
  80         if ($cred) {
  81                 $cred->check_netrc unless defined $cred->{password};
  82                 $cred->fill($lei); # may prompt user here
  83                 $mic->User($mic_arg->{User} = $cred->{username});
  84                 $mic->Password($mic_arg->{Password} = $cred->{password});
  85         } else { # AUTH=ANONYMOUS
  86                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
  87                 $mic_arg->{Authcallback} = 'auth_anon_cb';
  88                 $mic->Authcallback(\&auth_anon_cb);
  89         }
  90         my $err;
  91         if ($mic->login && $mic->IsAuthenticated) {
  92                 # success! keep IMAPClient->new arg in case we get disconnected
  93                 $self->{mic_arg}->{uri_section($uri)} = $mic_arg;
  94         } else {
  95                 $err = "E: <$url> LOGIN: $@\n";
  96                 if ($cred && defined($cred->{password})) {
  97                         $err =~ s/\Q$cred->{password}\E/*******/g;
  98                 }
  99                 $mic = undef;
 100         }
 101         $cred->run($mic ? 'approve' : 'reject') if $cred;
 102         if ($err) {
 103                 $lei ? $lei->fail($err) : warn($err);
 104         }
 105         $mic;
 106 }
 107
 108 # Net::NNTP doesn't support CAPABILITIES, yet
 109 sub try_starttls ($) {
 110         my ($host) = @_;
 111         return if $host =~ /\.onion\z/s;
 112         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 113         return if $host eq '::1';
 114         1;
 115 }
 116
 117 sub nn_new ($$$) {
 118         my ($nn_arg, $nntp_opt, $uri) = @_;
 119         my $nn = Net::NNTP->new(%$nn_arg) or die "E: <$uri> new: $!\n";
 120
 121         # default to using STARTTLS if it's available, but allow
 122         # it to be disabled for localhost/VPN users
 123         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 124                 if (!defined($nntp_opt->{starttls}) &&
 125                                 try_starttls($nn_arg->{Host})) {
 126                         # soft fail by default
 127                         $nn->starttls or warn <<"";
 128 W: <$uri> STARTTLS tried and failed (not requested)
 129
 130                 } elsif ($nntp_opt->{starttls}) {
 131                         # hard fail if explicitly configured
 132                         $nn->starttls or die <<"";
 133 E: <$uri> STARTTLS requested and failed
 134
 135                 }
 136         } elsif ($nntp_opt->{starttls}) {
 137                 $nn->can('starttls') or
 138                         die "E: <$uri> Net::NNTP too old for STARTTLS\n";
 139                 $nn->starttls or die <<"";
 140 E: <$uri> STARTTLS requested and failed
 141
 142         }
 143         $nn;
 144 }
 145
 146 sub nn_for ($$$$) { # nn = Net::NNTP
 147         my ($self, $uri, $nn_args, $lei) = @_;
 148         my $sec = uri_section($uri);
 149         my $nntp_opt = $self->{nntp_opt}->{$sec} //= {};
 150         my $host = $uri->host;
 151         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 152         $host = '127.0.0.1' if $host eq '0';
 153         my $cred;
 154         my ($u, $p);
 155         if (defined(my $ui = $uri->userinfo)) {
 156                 require PublicInbox::GitCredential;
 157                 $cred = bless {
 158                         url => $sec,
 159                         protocol => $uri->scheme,
 160                         host => $host,
 161                 }, 'PublicInbox::GitCredential';
 162                 ($u, $p) = split(/:/, $ui, 2);
 163                 ($cred->{username}, $cred->{password}) = ($u, $p);
 164                 $cred->check_netrc unless defined $p;
 165         }
 166         my $common = $nn_args->{$sec} // {};
 167         my $nn_arg = {
 168                 Port => $uri->port,
 169                 Host => $host,
 170                 SSL => $uri->secure, # snews == nntps
 171                 %$common, # may Debug ....
 172         };
 173         my $nn = nn_new($nn_arg, $nntp_opt, $uri);
 174         if ($cred) {
 175                 $cred->fill($lei); # may prompt user here
 176                 if ($nn->authinfo($u, $p)) {
 177                         push @{$nntp_opt->{-postconn}}, [ 'authinfo', $u, $p ];
 178                 } else {
 179                         warn "E: <$uri> AUTHINFO $u XXXX failed\n";
 180                         $nn = undef;
 181                 }
 182         }
 183
 184         if ($nntp_opt->{compress}) {
 185                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 186                 if ($nn->can('compress')) {
 187                         if ($nn->compress) {
 188                                 push @{$nntp_opt->{-postconn}}, [ 'compress' ];
 189                         } else {
 190                                 warn "W: <$uri> COMPRESS failed\n";
 191                         }
 192                 } else {
 193                         delete $nntp_opt->{compress};
 194                         warn <<"";
 195 W: <$uri> COMPRESS not supported by Net::NNTP
 196 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 197
 198                 }
 199         }
 200
 201         $self->{nn_arg}->{$sec} = $nn_arg;
 202         $cred->run($nn ? 'approve' : 'reject') if $cred;
 203         $nn;
 204 }
 205
 206 sub imap_uri {
 207         my ($url) = @_;
 208         require PublicInbox::URIimap;
 209         my $uri = PublicInbox::URIimap->new($url);
 210         $uri ? $uri->canonical : undef;
 211 }
 212
 213 my %IS_NNTP = (news => 1, snews => 1, nntp => 1, nntps => 1);
 214 sub nntp_uri {
 215         my ($url) = @_;
 216         require PublicInbox::URInntps;
 217         my $uri = PublicInbox::URInntps->new($url);
 218         $uri && $IS_NNTP{$uri->scheme} && $uri->group ? $uri->canonical : undef;
 219 }
 220
 221 sub cfg_intvl ($$$) {
 222         my ($cfg, $key, $url) = @_;
 223         my $v = $cfg->urlmatch($key, $url) // return;
 224         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 225         if (ref($v) eq 'ARRAY') {
 226                 $v = join(', ', @$v);
 227                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 228         } else {
 229                 warn "W: $key=$v is not a numeric value in seconds\n";
 230         }
 231 }
 232
 233 sub cfg_bool ($$$) {
 234         my ($cfg, $key, $url) = @_;
 235         my $orig = $cfg->urlmatch($key, $url) // return;
 236         my $bool = $cfg->git_bool($orig);
 237         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 238         $bool;
 239 }
 240
 241 # flesh out common IMAP-specific data structures
 242 sub imap_common_init ($;$) {
 243         my ($self, $lei) = @_;
 244         return unless $self->{imap_order};
 245         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 246         eval { require PublicInbox::IMAPClient } or
 247                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 248         ($lei || eval { require PublicInbox::IMAPTracker }) or
 249                 die "DBD::SQLite is required for IMAP\n:$@\n";
 250         require PublicInbox::URIimap;
 251         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 252         my $mic_args = {}; # scheme://authority => Mail:IMAPClient arg
 253         for my $uri (@{$self->{imap_order}}) {
 254                 my $sec = uri_section($uri);
 255                 for my $k (qw(Starttls Debug Compress)) {
 256                         my $bool = cfg_bool($cfg, "imap.$k", $$uri) // next;
 257                         $mic_args->{$sec}->{$k} = $bool;
 258                 }
 259                 my $to = cfg_intvl($cfg, 'imap.timeout', $$uri);
 260                 $mic_args->{$sec}->{Timeout} = $to if $to;
 261                 for my $k (qw(pollInterval idleInterval)) {
 262                         $to = cfg_intvl($cfg, "imap.$k", $$uri) // next;
 263                         $self->{imap_opt}->{$sec}->{$k} = $to;
 264                 }
 265                 my $k = 'imap.fetchBatchSize';
 266                 my $bs = $cfg->urlmatch($k, $$uri) // next;
 267                 if ($bs =~ /\A([0-9]+)\z/) {
 268                         $self->{imap_opt}->{$sec}->{batch_size} = $bs;
 269                 } else {
 270                         warn "$k=$bs is not an integer\n";
 271                 }
 272         }
 273         # make sure we can connect and cache the credentials in memory
 274         $self->{mic_arg} = {}; # schema://authority => IMAPClient->new args
 275         my $mics = {}; # schema://authority => IMAPClient obj
 276         for my $uri (@{$self->{imap_order}}) {
 277                 my $sec = uri_section($uri);
 278                 my $mic = $mics->{$sec} //=
 279                                 mic_for($self, "$sec/", $mic_args, $lei) //
 280                                 die "Unable to continue\n";
 281                 next unless $self->isa('PublicInbox::NetWriter');
 282                 my $dst = $uri->mailbox // next;
 283                 next if $mic->exists($dst); # already exists
 284                 $mic->create($dst) or die "CREATE $dst failed <$uri>: $@";
 285         }
 286         $mics;
 287 }
 288
 289 # flesh out common NNTP-specific data structures
 290 sub nntp_common_init ($;$) {
 291         my ($self, $lei) = @_;
 292         return unless $self->{nntp_order};
 293         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 294         eval { require Net::NNTP } or
 295                 die "Net::NNTP is required for NNTP:\n$@\n";
 296         ($lei || eval { require PublicInbox::IMAPTracker }) or
 297                 die "DBD::SQLite is required for NNTP\n:$@\n";
 298         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 299         my $nn_args = {}; # scheme://authority => Net::NNTP->new arg
 300         for my $uri (@{$self->{nntp_order}}) {
 301                 my $sec = uri_section($uri);
 302
 303                 # Debug and Timeout are passed to Net::NNTP->new
 304                 my $v = cfg_bool($cfg, 'nntp.Debug', $$uri);
 305                 $nn_args->{$sec}->{Debug} = $v if defined $v;
 306                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $$uri);
 307                 $nn_args->{$sec}->{Timeout} = $to if $to;
 308
 309                 # Net::NNTP post-connect commands
 310                 for my $k (qw(starttls compress)) {
 311                         $v = cfg_bool($cfg, "nntp.$k", $$uri) // next;
 312                         $self->{nntp_opt}->{$sec}->{$k} = $v;
 313                 }
 314
 315                 # internal option
 316                 for my $k (qw(pollInterval)) {
 317                         $to = cfg_intvl($cfg, "nntp.$k", $$uri) // next;
 318                         $self->{nntp_opt}->{$sec}->{$k} = $to;
 319                 }
 320         }
 321         # make sure we can connect and cache the credentials in memory
 322         $self->{nn_arg} = {}; # schema://authority => Net::NNTP->new args
 323         my %nn; # schema://authority => Net::NNTP object
 324         for my $uri (@{$self->{nntp_order}}) {
 325                 my $sec = uri_section($uri);
 326                 $nn{$sec} //= nn_for($self, $uri, $nn_args, $lei);
 327         }
 328         \%nn; # for optional {nn_cached}
 329 }
 330
 331 sub add_url {
 332         my ($self, $arg) = @_;
 333         my $uri;
 334         if ($uri = imap_uri($arg)) {
 335                 push @{$self->{imap_order}}, $uri;
 336         } elsif ($uri = nntp_uri($arg)) {
 337                 push @{$self->{nntp_order}}, $uri;
 338         } else {
 339                 push @{$self->{unsupported_url}}, $arg;
 340         }
 341 }
 342
 343 sub errors {
 344         my ($self, $lei) = @_;
 345         if (my $u = $self->{unsupported_url}) {
 346                 return "Unsupported URL(s): @$u";
 347         }
 348         if ($self->{imap_order}) {
 349                 eval { require PublicInbox::IMAPClient } or
 350                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 351         }
 352         if ($self->{nntp_order}) {
 353                 eval { require Net::NNTP } or
 354                         die "Net::NNTP is required for NNTP:\n$@\n";
 355         }
 356         if ($lei && (($lei->{opt}->{proxy}//'') =~ m!\Asocks5h://
 357                                 (?: \[ ([^\]]+) \] | ([^:/]+) )
 358                                 (?::([0-9]+))?/?(?:,|\z)!ix)) {
 359                 my ($h, $p) = ($1 // $2, $3 + 0);
 360                 $h = '127.0.0.1' if $h eq '0';
 361                 eval { require IO::Socket::Socks } or die <<EOM;
 362 IO::Socket::Socks missing for socks5h://$h:$p
 363 EOM
 364                 $lei->{socks5h} = { ProxyAddr => $h, ProxyPort => $p };
 365         }
 366         undef;
 367 }
 368
 369 sub _imap_do_msg ($$$$$) {
 370         my ($self, $url, $uid, $raw, $flags) = @_;
 371         # our target audience expects LF-only, save storage
 372         $$raw =~ s/\r\n/\n/sg;
 373         my $kw = [];
 374         for my $f (split(/ /, $flags)) {
 375                 if (my $k = $IMAPflags2kw{$f}) {
 376                         push @$kw, $k;
 377                 } elsif ($f eq "\\Recent") { # not in JMAP
 378                 } elsif ($f eq "\\Deleted") { # not in JMAP
 379                         return;
 380                 } elsif ($self->{verbose}) {
 381                         warn "# unknown IMAP flag $f <$url/;UID=$uid>\n";
 382                 }
 383         }
 384         @$kw = sort @$kw; # for all UI/UX purposes
 385         my ($eml_cb, @args) = @{$self->{eml_each}};
 386         $eml_cb->($url, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 387 }
 388
 389 sub run_commit_cb ($) {
 390         my ($self) = @_;
 391         my $cmt_cb_args = $self->{on_commit} or return;
 392         my ($cb, @args) = @$cmt_cb_args;
 393         $cb->(@args);
 394 }
 395
 396 sub _itrk_last ($$;$) {
 397         my ($self, $uri, $r_uidval) = @_;
 398         return (undef, undef, $r_uidval) unless $self->{incremental};
 399         my ($itrk, $l_uid, $l_uidval);
 400         if (defined(my $lms = $self->{-lms_ro})) { # LeiMailSync or 0
 401                 $uri->uidvalidity($r_uidval) if defined $r_uidval;
 402                 my $x;
 403                 $l_uid = ($lms && ($x = $lms->location_stats($$uri))) ?
 404                                 $x->{'uid.max'} : undef;
 405                 # itrk remains undef, lei/store worker writes to
 406                 # mail_sync.sqlite3
 407         } else {
 408                 $itrk = PublicInbox::IMAPTracker->new($$uri);
 409                 ($l_uidval, $l_uid) = $itrk->get_last($$uri);
 410         }
 411         ($itrk, $l_uid, $l_uidval //= $r_uidval);
 412 }
 413
 414 sub _imap_fetch_all ($$$) {
 415         my ($self, $mic, $orig_uri) = @_;
 416         my $sec = uri_section($orig_uri);
 417         my $mbx = $orig_uri->mailbox;
 418         $mic->Clear(1); # trim results history
 419         $mic->examine($mbx) or return "E: EXAMINE $mbx ($sec) failed: $!";
 420         my ($r_uidval, $r_uidnext);
 421         for ($mic->Results) {
 422                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 423                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 424                 last if $r_uidval && $r_uidnext;
 425         }
 426         $r_uidval //= $mic->uidvalidity($mbx) //
 427                 return "E: $orig_uri cannot get UIDVALIDITY";
 428         $r_uidnext //= $mic->uidnext($mbx) //
 429                 return "E: $orig_uri cannot get UIDNEXT";
 430         my $expect = $orig_uri->uidvalidity // $r_uidval;
 431         return <<EOF if $expect != $r_uidval;
 432 E: $orig_uri UIDVALIDITY mismatch (got $r_uidval)
 433 EOF
 434
 435         my $uri = $orig_uri->clone;
 436         my ($itrk, $l_uid, $l_uidval) = _itrk_last($self, $uri, $r_uidval);
 437         return <<EOF if $l_uidval != $r_uidval;
 438 E: $uri UIDVALIDITY mismatch
 439 E: local=$l_uidval != remote=$r_uidval
 440 EOF
 441         $uri->uidvalidity($r_uidval);
 442         $l_uid //= 0;
 443         my $r_uid = $r_uidnext - 1;
 444         return <<EOF if $l_uid > $r_uid;
 445 E: $uri local UID exceeds remote ($l_uid > $r_uid)
 446 E: $uri strangely, UIDVALIDLITY matches ($l_uidval)
 447 EOF
 448         return if $l_uid >= $r_uid; # nothing to do
 449         $l_uid ||= 1;
 450         my ($mod, $shard) = @{$self->{shard_info} // []};
 451         unless ($self->{quiet}) {
 452                 my $m = $mod ? " [(UID % $mod) == $shard]" : '';
 453                 warn "# $uri fetching UID $l_uid:$r_uid$m\n";
 454         }
 455         $mic->Uid(1); # the default, we hope
 456         my $bs = $self->{imap_opt}->{$sec}->{batch_size} // 1;
 457         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 458         my $key = $req;
 459         $key =~ s/\.PEEK//;
 460         my ($uids, $batch);
 461         my $err;
 462         do {
 463                 # I wish "UID FETCH $START:*" could work, but:
 464                 # 1) servers do not need to return results in any order
 465                 # 2) Mail::IMAPClient doesn't offer a streaming API
 466                 unless ($uids = $mic->search("UID $l_uid:*")) {
 467                         return if $!{EINTR} && $self->{quit};
 468                         return "E: $uri UID SEARCH $l_uid:* error: $!";
 469                 }
 470                 return if scalar(@$uids) == 0;
 471
 472                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 473                 # responses, so sort it ourselves.  Order matters so
 474                 # IMAPTracker can store the newest UID.
 475                 @$uids = sort { $a <=> $b } @$uids;
 476
 477                 # Did we actually get new messages?
 478                 return if $uids->[0] < $l_uid;
 479
 480                 $l_uid = $uids->[-1] + 1; # for next search
 481                 my $last_uid;
 482                 my $n = $self->{max_batch};
 483
 484                 @$uids = grep { ($_ % $mod) == $shard } @$uids if $mod;
 485                 while (scalar @$uids) {
 486                         my @batch = splice(@$uids, 0, $bs);
 487                         $batch = join(',', @batch);
 488                         local $0 = "UID:$batch $mbx $sec";
 489                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 490                         unless ($r) { # network error?
 491                                 last if $!{EINTR} && $self->{quit};
 492                                 $err = "E: $uri UID FETCH $batch error: $!";
 493                                 last;
 494                         }
 495                         for my $uid (@batch) {
 496                                 # messages get deleted, so holes appear
 497                                 my $per_uid = delete $r->{$uid} // next;
 498                                 my $raw = delete($per_uid->{$key}) // next;
 499                                 _imap_do_msg($self, $$uri, $uid, \$raw,
 500                                                 $per_uid->{FLAGS});
 501                                 $last_uid = $uid;
 502                                 last if $self->{quit};
 503                         }
 504                         last if $self->{quit};
 505                 }
 506                 run_commit_cb($self);
 507                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 508         } until ($err || $self->{quit});
 509         $err;
 510 }
 511
 512 # uses cached auth info prepared by mic_for
 513 sub mic_get {
 514         my ($self, $uri) = @_;
 515         my $sec = uri_section($uri);
 516         # see if caller saved result of imap_common_init
 517         my $cached = $self->{mics_cached};
 518         if ($cached) {
 519                 my $mic = $cached->{$sec};
 520                 return $mic if $mic && $mic->IsConnected;
 521                 delete $cached->{$sec};
 522         }
 523         my $mic_arg = $self->{mic_arg}->{$sec} or
 524                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 525         if (defined(my $cb_name = $mic_arg->{Authcallback})) {
 526                 if (ref($cb_name) ne 'CODE') {
 527                         $mic_arg->{Authcallback} = $self->can($cb_name);
 528                 }
 529         }
 530         my %socks;
 531         if (my $s5h = $self->{mic_socks5h}) {
 532                 $socks{Socket} = IO::Socket::Socks->new(%$s5h) or die
 533                         "E: <$$uri> ".eval('$IO::Socket::Socks::SOCKS_ERROR');
 534         }
 535         my $mic = PublicInbox::IMAPClient->new(%$mic_arg, %socks);
 536         $cached //= {}; # invalid placeholder if no cache enabled
 537         $mic && $mic->IsConnected ? ($cached->{$sec} = $mic) : undef;
 538 }
 539
 540 sub imap_each {
 541         my ($self, $url, $eml_cb, @args) = @_;
 542         my $uri = ref($url) ? $url : PublicInbox::URIimap->new($url);
 543         my $sec = uri_section($uri);
 544         local $0 = $uri->mailbox." $sec";
 545         my $mic = mic_get($self, $uri);
 546         my $err;
 547         if ($mic) {
 548                 local $self->{eml_each} = [ $eml_cb, @args ];
 549                 $err = _imap_fetch_all($self, $mic, $uri);
 550         } else {
 551                 $err = "E: <$uri> not connected: $!";
 552         }
 553         die $err if $err && $self->{-can_die};
 554         warn $err if $err;
 555         $mic;
 556 }
 557
 558 # may used cached auth info prepared by nn_for once
 559 sub nn_get {
 560         my ($self, $uri) = @_;
 561         my $sec = uri_section($uri);
 562         # see if caller saved result of nntp_common_init
 563         my $cached = $self->{nn_cached} // {};
 564         my $nn;
 565         $nn = delete($cached->{$sec}) and return $nn;
 566         my $nn_arg = $self->{nn_arg}->{$sec} or
 567                         die "BUG: no Net::NNTP->new arg for $sec";
 568         my $nntp_opt = $self->{nntp_opt}->{$sec};
 569         $nn = nn_new($nn_arg, $nntp_opt, $uri) or return;
 570         if (my $postconn = $nntp_opt->{-postconn}) {
 571                 for my $m_arg (@$postconn) {
 572                         my ($method, @args) = @$m_arg;
 573                         $nn->$method(@args) and next;
 574                         die "E: <$uri> $method failed\n";
 575                         return;
 576                 }
 577         }
 578         $nn;
 579 }
 580
 581 sub _nntp_fetch_all ($$$) {
 582         my ($self, $nn, $uri) = @_;
 583         my ($group, $num_a, $num_b) = $uri->group;
 584         my $sec = uri_section($uri);
 585         my ($nr, $beg, $end) = $nn->group($group);
 586         unless (defined($nr)) {
 587                 my $msg = ndump($nn->message);
 588                 return "E: GROUP $group <$sec> $msg";
 589         }
 590
 591         # IMAPTracker is also used for tracking NNTP, UID == article number
 592         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 593         # expensive.  So we assume newsgroups don't change:
 594         my ($itrk, $l_art) = _itrk_last($self, $uri);
 595
 596         # allow users to specify articles to refetch
 597         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 598         # nntp://example.com/inbox.foo/$num_a-$num_b
 599         $beg = $num_a if defined($num_a) && $num_a < $beg;
 600         $end = $num_b if defined($num_b) && $num_b < $end;
 601         if (defined $l_art) {
 602                 return if $l_art >= $end; # nothing to do
 603                 $beg = $l_art + 1;
 604         }
 605         my ($err, $art, $last_art, $kw); # kw stays undef, no keywords in NNTP
 606         unless ($self->{quiet}) {
 607                 warn "# $uri fetching ARTICLE $beg..$end\n";
 608         }
 609         my $n = $self->{max_batch};
 610         for ($beg..$end) {
 611                 last if $self->{quit};
 612                 $art = $_;
 613                 if (--$n < 0) {
 614                         run_commit_cb($self);
 615                         $itrk->update_last(0, $last_art) if $itrk;
 616                         $n = $self->{max_batch};
 617                 }
 618                 my $raw = $nn->article($art);
 619                 unless (defined($raw)) {
 620                         my $msg = ndump($nn->message);
 621                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 622                                 $err = "E: $msg";
 623                                 last;
 624                         } else { # probably just a deleted message (spam)
 625                                 warn "W: $msg";
 626                                 next;
 627                         }
 628                 }
 629                 $raw = join('', @$raw);
 630                 $raw =~ s/\r\n/\n/sg;
 631                 my ($eml_cb, @args) = @{$self->{eml_each}};
 632                 $eml_cb->($uri, $art, $kw, PublicInbox::Eml->new(\$raw), @args);
 633                 $last_art = $art;
 634         }
 635         run_commit_cb($self);
 636         $itrk->update_last(0, $last_art) if $itrk;
 637         $err;
 638 }
 639
 640 sub nntp_each {
 641         my ($self, $url, $eml_cb, @args) = @_;
 642         my $uri = ref($url) ? $url : PublicInbox::URInntps->new($url);
 643         my $sec = uri_section($uri);
 644         local $0 = $uri->group ." $sec";
 645         my $nn = nn_get($self, $uri);
 646         return if $self->{quit};
 647         my $err;
 648         if ($nn) {
 649                 local $self->{eml_each} = [ $eml_cb, @args ];
 650                 $err = _nntp_fetch_all($self, $nn, $uri);
 651         } else {
 652                 $err = "E: <$uri> not connected: $!";
 653         }
 654         die $err if $err && $self->{-can_die};
 655         warn $err if $err;
 656         $nn;
 657 }
 658
 659 sub new { bless {}, shift };
 660
 661 1;