lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10
  11 our %IMAPflags2kw = map {; "\\\u$_" => $_ } qw(seen answered flagged draft);
  12
  13 our @EXPORT = qw(uri_section imap_uri nntp_uri);
  14
  15 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  16 # without the mailbox, so we can share connections between different inboxes
  17 sub uri_section ($) {
  18         my ($uri) = @_;
  19         $uri->scheme . '://' . $uri->authority;
  20 }
  21
  22 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  23
  24 # mic_for may prompt the user and store auth info, prepares mic_get
  25 sub mic_for { # mic = Mail::IMAPClient
  26         my ($self, $url, $mic_args, $lei) = @_;
  27         require PublicInbox::URIimap;
  28         my $uri = PublicInbox::URIimap->new($url);
  29         require PublicInbox::GitCredential;
  30         my $cred = bless {
  31                 url => $url,
  32                 protocol => $uri->scheme,
  33                 host => $uri->host,
  34                 username => $uri->user,
  35                 password => $uri->password,
  36         }, 'PublicInbox::GitCredential';
  37         my $common = $mic_args->{uri_section($uri)} // {};
  38         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
  39         my $host = $cred->{host};
  40         $host = '127.0.0.1' if $host eq '0';
  41         my $mic_arg = {
  42                 Port => $uri->port,
  43                 Server => $host,
  44                 Ssl => $uri->scheme eq 'imaps',
  45                 Keepalive => 1, # SO_KEEPALIVE
  46                 %$common, # may set Starttls, Compress, Debug ....
  47         };
  48         require PublicInbox::IMAPClient;
  49         my $mic = PublicInbox::IMAPClient->new(%$mic_arg) or
  50                 die "E: <$url> new: $@\n";
  51
  52         # default to using STARTTLS if it's available, but allow
  53         # it to be disabled since I usually connect to localhost
  54         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
  55                         $mic->has_capability('STARTTLS') &&
  56                         $mic->can('starttls')) {
  57                 $mic->starttls or die "E: <$url> STARTTLS: $@\n";
  58         }
  59
  60         # do we even need credentials?
  61         if (!defined($cred->{username}) &&
  62                         $mic->has_capability('AUTH=ANONYMOUS')) {
  63                 $cred = undef;
  64         }
  65         if ($cred) {
  66                 $cred->check_netrc unless defined $cred->{password};
  67                 $cred->fill($lei); # may prompt user here
  68                 $mic->User($mic_arg->{User} = $cred->{username});
  69                 $mic->Password($mic_arg->{Password} = $cred->{password});
  70         } else { # AUTH=ANONYMOUS
  71                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
  72                 $mic_arg->{Authcallback} = 'auth_anon_cb';
  73                 $mic->Authcallback(\&auth_anon_cb);
  74         }
  75         my $err;
  76         if ($mic->login && $mic->IsAuthenticated) {
  77                 # success! keep IMAPClient->new arg in case we get disconnected
  78                 $self->{mic_arg}->{uri_section($uri)} = $mic_arg;
  79         } else {
  80                 $err = "E: <$url> LOGIN: $@\n";
  81                 if ($cred && defined($cred->{password})) {
  82                         $err =~ s/\Q$cred->{password}\E/*******/g;
  83                 }
  84                 $mic = undef;
  85         }
  86         $cred->run($mic ? 'approve' : 'reject') if $cred;
  87         if ($err) {
  88                 $lei ? $lei->fail($err) : warn($err);
  89         }
  90         $mic;
  91 }
  92
  93 # Net::NNTP doesn't support CAPABILITIES, yet
  94 sub try_starttls ($) {
  95         my ($host) = @_;
  96         return if $host =~ /\.onion\z/s;
  97         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
  98         return if $host eq '::1';
  99         1;
 100 }
 101
 102 sub nn_new ($$$) {
 103         my ($nn_arg, $nntp_opt, $uri) = @_;
 104         my $nn = Net::NNTP->new(%$nn_arg) or die "E: <$uri> new: $!\n";
 105
 106         # default to using STARTTLS if it's available, but allow
 107         # it to be disabled for localhost/VPN users
 108         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 109                 if (!defined($nntp_opt->{starttls}) &&
 110                                 try_starttls($nn_arg->{Host})) {
 111                         # soft fail by default
 112                         $nn->starttls or warn <<"";
 113 W: <$uri> STARTTLS tried and failed (not requested)
 114
 115                 } elsif ($nntp_opt->{starttls}) {
 116                         # hard fail if explicitly configured
 117                         $nn->starttls or die <<"";
 118 E: <$uri> STARTTLS requested and failed
 119
 120                 }
 121         } elsif ($nntp_opt->{starttls}) {
 122                 $nn->can('starttls') or
 123                         die "E: <$uri> Net::NNTP too old for STARTTLS\n";
 124                 $nn->starttls or die <<"";
 125 E: <$uri> STARTTLS requested and failed
 126
 127         }
 128         $nn;
 129 }
 130
 131 sub nn_for ($$$;$) { # nn = Net::NNTP
 132         my ($self, $uri, $nn_args, $lei) = @_;
 133         my $sec = uri_section($uri);
 134         my $nntp_opt = $self->{nntp_opt}->{$sec} //= {};
 135         my $host = $uri->host;
 136         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 137         $host = '127.0.0.1' if $host eq '0';
 138         my $cred;
 139         my ($u, $p);
 140         if (defined(my $ui = $uri->userinfo)) {
 141                 require PublicInbox::GitCredential;
 142                 $cred = bless {
 143                         url => $sec,
 144                         protocol => $uri->scheme,
 145                         host => $host,
 146                 }, 'PublicInbox::GitCredential';
 147                 ($u, $p) = split(/:/, $ui, 2);
 148                 ($cred->{username}, $cred->{password}) = ($u, $p);
 149                 $cred->check_netrc unless defined $p;
 150         }
 151         my $common = $nn_args->{$sec} // {};
 152         my $nn_arg = {
 153                 Port => $uri->port,
 154                 Host => $host,
 155                 SSL => $uri->secure, # snews == nntps
 156                 %$common, # may Debug ....
 157         };
 158         my $nn = nn_new($nn_arg, $nntp_opt, $uri);
 159         if ($cred) {
 160                 $cred->fill($lei); # may prompt user here
 161                 if ($nn->authinfo($u, $p)) {
 162                         push @{$nntp_opt->{-postconn}}, [ 'authinfo', $u, $p ];
 163                 } else {
 164                         warn "E: <$uri> AUTHINFO $u XXXX failed\n";
 165                         $nn = undef;
 166                 }
 167         }
 168
 169         if ($nntp_opt->{compress}) {
 170                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 171                 if ($nn->can('compress')) {
 172                         if ($nn->compress) {
 173                                 push @{$nntp_opt->{-postconn}}, [ 'compress' ];
 174                         } else {
 175                                 warn "W: <$uri> COMPRESS failed\n";
 176                         }
 177                 } else {
 178                         delete $nntp_opt->{compress};
 179                         warn <<"";
 180 W: <$uri> COMPRESS not supported by Net::NNTP
 181 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 182
 183                 }
 184         }
 185
 186         $self->{nn_arg}->{$sec} = $nn_arg;
 187         $cred->run($nn ? 'approve' : 'reject') if $cred;
 188         $nn;
 189 }
 190
 191 sub imap_uri {
 192         my ($url) = @_;
 193         require PublicInbox::URIimap;
 194         my $uri = PublicInbox::URIimap->new($url);
 195         $uri ? $uri->canonical : undef;
 196 }
 197
 198 my %IS_NNTP = (news => 1, snews => 1, nntp => 1, nntps => 1);
 199 sub nntp_uri {
 200         my ($url) = @_;
 201         require PublicInbox::URInntps;
 202         my $uri = PublicInbox::URInntps->new($url);
 203         $uri && $IS_NNTP{$uri->scheme} && $uri->group ? $uri->canonical : undef;
 204 }
 205
 206 sub cfg_intvl ($$$) {
 207         my ($cfg, $key, $url) = @_;
 208         my $v = $cfg->urlmatch($key, $url) // return;
 209         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 210         if (ref($v) eq 'ARRAY') {
 211                 $v = join(', ', @$v);
 212                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 213         } else {
 214                 warn "W: $key=$v is not a numeric value in seconds\n";
 215         }
 216 }
 217
 218 sub cfg_bool ($$$) {
 219         my ($cfg, $key, $url) = @_;
 220         my $orig = $cfg->urlmatch($key, $url) // return;
 221         my $bool = $cfg->git_bool($orig);
 222         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 223         $bool;
 224 }
 225
 226 # flesh out common IMAP-specific data structures
 227 sub imap_common_init ($;$) {
 228         my ($self, $lei) = @_;
 229         return unless $self->{imap_order};
 230         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 231         eval { require PublicInbox::IMAPClient } or
 232                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 233         eval { require PublicInbox::IMAPTracker } or
 234                 die "DBD::SQLite is required for IMAP\n:$@\n";
 235         require PublicInbox::URIimap;
 236         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 237         my $mic_args = {}; # scheme://authority => Mail:IMAPClient arg
 238         for my $uri (@{$self->{imap_order}}) {
 239                 my $sec = uri_section($uri);
 240                 for my $k (qw(Starttls Debug Compress)) {
 241                         my $bool = cfg_bool($cfg, "imap.$k", $$uri) // next;
 242                         $mic_args->{$sec}->{$k} = $bool;
 243                 }
 244                 my $to = cfg_intvl($cfg, 'imap.timeout', $$uri);
 245                 $mic_args->{$sec}->{Timeout} = $to if $to;
 246                 for my $k (qw(pollInterval idleInterval)) {
 247                         $to = cfg_intvl($cfg, "imap.$k", $$uri) // next;
 248                         $self->{imap_opt}->{$sec}->{$k} = $to;
 249                 }
 250                 my $k = 'imap.fetchBatchSize';
 251                 my $bs = $cfg->urlmatch($k, $$uri) // next;
 252                 if ($bs =~ /\A([0-9]+)\z/) {
 253                         $self->{imap_opt}->{$sec}->{batch_size} = $bs;
 254                 } else {
 255                         warn "$k=$bs is not an integer\n";
 256                 }
 257         }
 258         # make sure we can connect and cache the credentials in memory
 259         $self->{mic_arg} = {}; # schema://authority => IMAPClient->new args
 260         my $mics = {}; # schema://authority => IMAPClient obj
 261         for my $uri (@{$self->{imap_order}}) {
 262                 my $sec = uri_section($uri);
 263                 $mics->{$sec} //= mic_for($self, "$sec/", $mic_args, $lei);
 264                 next unless $self->isa('PublicInbox::NetWriter');
 265                 my $dst = $uri->mailbox // next;
 266                 my $mic = $mics->{$sec};
 267                 next if $mic->exists($dst); # already exists
 268                 $mic->create($dst) or die "CREATE $dst failed <$uri>: $@";
 269         }
 270         $mics;
 271 }
 272
 273 # flesh out common NNTP-specific data structures
 274 sub nntp_common_init ($;$) {
 275         my ($self, $lei) = @_;
 276         return unless $self->{nntp_order};
 277         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 278         eval { require Net::NNTP } or
 279                 die "Net::NNTP is required for NNTP:\n$@\n";
 280         eval { require PublicInbox::IMAPTracker } or
 281                 die "DBD::SQLite is required for NNTP\n:$@\n";
 282         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 283         my $nn_args = {}; # scheme://authority => Net::NNTP->new arg
 284         for my $uri (@{$self->{nntp_order}}) {
 285                 my $sec = uri_section($uri);
 286
 287                 # Debug and Timeout are passed to Net::NNTP->new
 288                 my $v = cfg_bool($cfg, 'nntp.Debug', $$uri);
 289                 $nn_args->{$sec}->{Debug} = $v if defined $v;
 290                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $$uri);
 291                 $nn_args->{$sec}->{Timeout} = $to if $to;
 292
 293                 # Net::NNTP post-connect commands
 294                 for my $k (qw(starttls compress)) {
 295                         $v = cfg_bool($cfg, "nntp.$k", $$uri) // next;
 296                         $self->{nntp_opt}->{$sec}->{$k} = $v;
 297                 }
 298
 299                 # internal option
 300                 for my $k (qw(pollInterval)) {
 301                         $to = cfg_intvl($cfg, "nntp.$k", $$uri) // next;
 302                         $self->{nntp_opt}->{$sec}->{$k} = $to;
 303                 }
 304         }
 305         # make sure we can connect and cache the credentials in memory
 306         $self->{nn_arg} = {}; # schema://authority => Net::NNTP->new args
 307         my %nn; # schema://authority => Net::NNTP object
 308         for my $uri (@{$self->{nntp_order}}) {
 309                 my $sec = uri_section($uri);
 310                 $nn{$sec} //= nn_for($self, $uri, $nn_args, $lei);
 311         }
 312         \%nn; # for optional {nn_cached}
 313 }
 314
 315 sub add_url {
 316         my ($self, $arg) = @_;
 317         my $uri;
 318         if ($uri = imap_uri($arg)) {
 319                 push @{$self->{imap_order}}, $uri;
 320         } elsif ($uri = nntp_uri($arg)) {
 321                 push @{$self->{nntp_order}}, $uri;
 322         } else {
 323                 push @{$self->{unsupported_url}}, $arg;
 324         }
 325 }
 326
 327 sub errors {
 328         my ($self) = @_;
 329         if (my $u = $self->{unsupported_url}) {
 330                 return "Unsupported URL(s): @$u";
 331         }
 332         if ($self->{imap_order}) {
 333                 eval { require PublicInbox::IMAPClient } or
 334                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 335         }
 336         if ($self->{nntp_order}) {
 337                 eval { require Net::NNTP } or
 338                         die "Net::NNTP is required for NNTP:\n$@\n";
 339         }
 340         undef;
 341 }
 342
 343 sub _imap_do_msg ($$$$$) {
 344         my ($self, $uri, $uid, $raw, $flags) = @_;
 345         # our target audience expects LF-only, save storage
 346         $$raw =~ s/\r\n/\n/sg;
 347         my $kw = [];
 348         for my $f (split(/ /, $flags)) {
 349                 if (my $k = $IMAPflags2kw{$f}) {
 350                         push @$kw, $k;
 351                 } elsif ($f eq "\\Recent") { # not in JMAP
 352                 } elsif ($self->{verbose}) {
 353                         warn "# unknown IMAP flag $f <$uri;uid=$uid>\n";
 354                 }
 355         }
 356         @$kw = sort @$kw; # for all UI/UX purposes
 357         my ($eml_cb, @args) = @{$self->{eml_each}};
 358         $eml_cb->($uri, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 359 }
 360
 361 sub run_commit_cb ($) {
 362         my ($self) = @_;
 363         my $cmt_cb_args = $self->{on_commit} or return;
 364         my ($cb, @args) = @$cmt_cb_args;
 365         $cb->(@args);
 366 }
 367
 368 sub _imap_fetch_all ($$$) {
 369         my ($self, $mic, $uri) = @_;
 370         my $sec = uri_section($uri);
 371         my $mbx = $uri->mailbox;
 372         $mic->Clear(1); # trim results history
 373         $mic->examine($mbx) or return "E: EXAMINE $mbx ($sec) failed: $!";
 374         my ($r_uidval, $r_uidnext);
 375         for ($mic->Results) {
 376                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 377                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 378                 last if $r_uidval && $r_uidnext;
 379         }
 380         $r_uidval //= $mic->uidvalidity($mbx) //
 381                 return "E: $uri cannot get UIDVALIDITY";
 382         $r_uidnext //= $mic->uidnext($mbx) //
 383                 return "E: $uri cannot get UIDNEXT";
 384         my $itrk = $self->{incremental} ?
 385                         PublicInbox::IMAPTracker->new($$uri) : 0;
 386         my ($l_uidval, $l_uid) = $itrk ? $itrk->get_last : ();
 387         $l_uidval //= $r_uidval; # first time
 388         $l_uid //= 0;
 389         if ($l_uidval != $r_uidval) {
 390                 return "E: $uri UIDVALIDITY mismatch\n".
 391                         "E: local=$l_uidval != remote=$r_uidval";
 392         }
 393         my $r_uid = $r_uidnext - 1;
 394         if ($l_uid > $r_uid) {
 395                 return "E: $uri local UID exceeds remote ($l_uid > $r_uid)\n".
 396                         "E: $uri strangely, UIDVALIDLITY matches ($l_uidval)\n";
 397         }
 398         return if $l_uid >= $r_uid; # nothing to do
 399         $l_uid ||= 1;
 400         my ($mod, $shard) = @{$self->{shard_info} // []};
 401         unless ($self->{quiet}) {
 402                 my $m = $mod ? " [(UID % $mod) == $shard]" : '';
 403                 warn "# $uri fetching UID $l_uid:$r_uid$m\n";
 404         }
 405         $mic->Uid(1); # the default, we hope
 406         my $bs = $self->{imap_opt}->{$sec}->{batch_size} // 1;
 407         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 408         my $key = $req;
 409         $key =~ s/\.PEEK//;
 410         my ($uids, $batch);
 411         my $err;
 412         do {
 413                 # I wish "UID FETCH $START:*" could work, but:
 414                 # 1) servers do not need to return results in any order
 415                 # 2) Mail::IMAPClient doesn't offer a streaming API
 416                 unless ($uids = $mic->search("UID $l_uid:*")) {
 417                         return if $!{EINTR} && $self->{quit};
 418                         return "E: $uri UID SEARCH $l_uid:* error: $!";
 419                 }
 420                 return if scalar(@$uids) == 0;
 421
 422                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 423                 # responses, so sort it ourselves.  Order matters so
 424                 # IMAPTracker can store the newest UID.
 425                 @$uids = sort { $a <=> $b } @$uids;
 426
 427                 # Did we actually get new messages?
 428                 return if $uids->[0] < $l_uid;
 429
 430                 $l_uid = $uids->[-1] + 1; # for next search
 431                 my $last_uid;
 432                 my $n = $self->{max_batch};
 433
 434                 @$uids = grep { ($_ % $mod) == $shard } @$uids if $mod;
 435                 while (scalar @$uids) {
 436                         my @batch = splice(@$uids, 0, $bs);
 437                         $batch = join(',', @batch);
 438                         local $0 = "UID:$batch $mbx $sec";
 439                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 440                         unless ($r) { # network error?
 441                                 last if $!{EINTR} && $self->{quit};
 442                                 $err = "E: $uri UID FETCH $batch error: $!";
 443                                 last;
 444                         }
 445                         for my $uid (@batch) {
 446                                 # messages get deleted, so holes appear
 447                                 my $per_uid = delete $r->{$uid} // next;
 448                                 my $raw = delete($per_uid->{$key}) // next;
 449                                 _imap_do_msg($self, $uri, $uid, \$raw,
 450                                                 $per_uid->{FLAGS});
 451                                 $last_uid = $uid;
 452                                 last if $self->{quit};
 453                         }
 454                         last if $self->{quit};
 455                 }
 456                 run_commit_cb($self);
 457                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 458         } until ($err || $self->{quit});
 459         $err;
 460 }
 461
 462 # uses cached auth info prepared by mic_for
 463 sub mic_get {
 464         my ($self, $uri) = @_;
 465         my $sec = uri_section($uri);
 466         # see if caller saved result of imap_common_init
 467         my $cached = $self->{mics_cached};
 468         if ($cached) {
 469                 my $mic = $cached->{$sec};
 470                 return $mic if $mic && $mic->IsConnected;
 471                 delete $cached->{$sec};
 472         }
 473         my $mic_arg = $self->{mic_arg}->{$sec} or
 474                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 475         if (defined(my $cb_name = $mic_arg->{Authcallback})) {
 476                 if (ref($cb_name) ne 'CODE') {
 477                         $mic_arg->{Authcallback} = $self->can($cb_name);
 478                 }
 479         }
 480         my $mic = PublicInbox::IMAPClient->new(%$mic_arg);
 481         $cached //= {}; # invalid placeholder if no cache enabled
 482         $mic && $mic->IsConnected ? ($cached->{$sec} = $mic) : undef;
 483 }
 484
 485 sub imap_each {
 486         my ($self, $url, $eml_cb, @args) = @_;
 487         my $uri = ref($url) ? $url : PublicInbox::URIimap->new($url);
 488         my $sec = uri_section($uri);
 489         local $0 = $uri->mailbox." $sec";
 490         my $mic = mic_get($self, $uri);
 491         my $err;
 492         if ($mic) {
 493                 local $self->{eml_each} = [ $eml_cb, @args ];
 494                 $err = _imap_fetch_all($self, $mic, $uri);
 495         } else {
 496                 $err = "E: <$uri> not connected: $!";
 497         }
 498         warn $err if $err;
 499         $mic;
 500 }
 501
 502 # may used cached auth info prepared by nn_for once
 503 sub nn_get {
 504         my ($self, $uri) = @_;
 505         my $sec = uri_section($uri);
 506         # see if caller saved result of nntp_common_init
 507         my $cached = $self->{nn_cached} // {};
 508         my $nn;
 509         $nn = delete($cached->{$sec}) and return $nn;
 510         my $nn_arg = $self->{nn_arg}->{$sec} or
 511                         die "BUG: no Net::NNTP->new arg for $sec";
 512         my $nntp_opt = $self->{nntp_opt}->{$sec};
 513         $nn = nn_new($nn_arg, $nntp_opt, $uri) or return;
 514         if (my $postconn = $nntp_opt->{-postconn}) {
 515                 for my $m_arg (@$postconn) {
 516                         my ($method, @args) = @$m_arg;
 517                         $nn->$method(@args) and next;
 518                         die "E: <$uri> $method failed\n";
 519                         return;
 520                 }
 521         }
 522         $nn;
 523 }
 524
 525 sub _nntp_fetch_all ($$$) {
 526         my ($self, $nn, $uri) = @_;
 527         my ($group, $num_a, $num_b) = $uri->group;
 528         my $sec = uri_section($uri);
 529         my ($nr, $beg, $end) = $nn->group($group);
 530         unless (defined($nr)) {
 531                 chomp(my $msg = $nn->message);
 532                 return "E: GROUP $group <$sec> $msg";
 533         }
 534
 535         # IMAPTracker is also used for tracking NNTP, UID == article number
 536         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 537         # expensive.  So we assume newsgroups don't change:
 538         my $itrk = $self->{incremental} ?
 539                         PublicInbox::IMAPTracker->new($$uri) : 0;
 540         my (undef, $l_art) = $itrk ? $itrk->get_last : ();
 541
 542         # allow users to specify articles to refetch
 543         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 544         # nntp://example.com/inbox.foo/$num_a-$num_b
 545         $beg = $num_a if defined($num_a) && $num_a < $beg;
 546         $end = $num_b if defined($num_b) && $num_b < $end;
 547         if (defined $l_art) {
 548                 return if $l_art >= $end; # nothing to do
 549                 $beg = $l_art + 1;
 550         }
 551         my ($err, $art);
 552         unless ($self->{quiet}) {
 553                 warn "# $uri fetching ARTICLE $beg..$end\n";
 554         }
 555         my $last_art;
 556         my $n = $self->{max_batch};
 557         for ($beg..$end) {
 558                 last if $self->{quit};
 559                 $art = $_;
 560                 if (--$n < 0) {
 561                         run_commit_cb($self);
 562                         $itrk->update_last(0, $last_art) if $itrk;
 563                         $n = $self->{max_batch};
 564                 }
 565                 my $raw = $nn->article($art);
 566                 unless (defined($raw)) {
 567                         my $msg = $nn->message;
 568                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 569                                 $err = "E: $msg";
 570                                 last;
 571                         } else { # probably just a deleted message (spam)
 572                                 warn "W: $msg";
 573                                 next;
 574                         }
 575                 }
 576                 $raw = join('', @$raw);
 577                 $raw =~ s/\r\n/\n/sg;
 578                 my ($eml_cb, @args) = @{$self->{eml_each}};
 579                 $eml_cb->($uri, $art, [], PublicInbox::Eml->new(\$raw), @args);
 580                 $last_art = $art;
 581         }
 582         run_commit_cb($self);
 583         $itrk->update_last(0, $last_art) if $itrk;
 584         $err;
 585 }
 586
 587 sub nntp_each {
 588         my ($self, $url, $eml_cb, @args) = @_;
 589         my $uri = ref($url) ? $url : PublicInbox::URInntps->new($url);
 590         my $sec = uri_section($uri);
 591         local $0 = $uri->group ." $sec";
 592         my $nn = nn_get($self, $uri);
 593         return if $self->{quit};
 594         my $err;
 595         if ($nn) {
 596                 local $self->{eml_each} = [ $eml_cb, @args ];
 597                 $err = _nntp_fetch_all($self, $nn, $uri);
 598         } else {
 599                 $err = "E: <$uri> not connected: $!";
 600         }
 601         warn $err if $err;
 602         $nn;
 603 }
 604
 605 sub new { bless {}, shift };
 606
 607 1;