lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10
  11 our %IMAPflags2kw = map {; "\\\u$_" => $_ } qw(seen answered flagged draft);
  12
  13 # TODO: trim this down, this is huge
  14 our @EXPORT = qw(uri_new uri_scheme uri_section
  15                 nn_new nn_for
  16                 imap_uri nntp_url
  17                 cfg_bool cfg_intvl imap_common_init
  18                 );
  19
  20 # avoid exposing deprecated "snews" to users.
  21 my %SCHEME_MAP = ('snews' => 'nntps');
  22
  23 sub uri_scheme ($) {
  24         my ($uri) = @_;
  25         my $scheme = $uri->scheme;
  26         $SCHEME_MAP{$scheme} // $scheme;
  27 }
  28
  29 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  30 # without the mailbox, so we can share connections between different inboxes
  31 sub uri_section ($) {
  32         my ($uri) = @_;
  33         uri_scheme($uri) . '://' . $uri->authority;
  34 }
  35
  36 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  37
  38 # mic_for may prompt the user and store auth info, prepares mic_get
  39 sub mic_for { # mic = Mail::IMAPClient
  40         my ($self, $url, $mic_args, $lei) = @_;
  41         require PublicInbox::URIimap;
  42         my $uri = PublicInbox::URIimap->new($url);
  43         require PublicInbox::GitCredential;
  44         my $cred = bless {
  45                 url => $url,
  46                 protocol => $uri->scheme,
  47                 host => $uri->host,
  48                 username => $uri->user,
  49                 password => $uri->password,
  50         }, 'PublicInbox::GitCredential';
  51         my $common = $mic_args->{uri_section($uri)} // {};
  52         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
  53         my $host = $cred->{host};
  54         $host = '127.0.0.1' if $host eq '0';
  55         my $mic_arg = {
  56                 Port => $uri->port,
  57                 Server => $host,
  58                 Ssl => $uri->scheme eq 'imaps',
  59                 Keepalive => 1, # SO_KEEPALIVE
  60                 %$common, # may set Starttls, Compress, Debug ....
  61         };
  62         require PublicInbox::IMAPClient;
  63         my $mic = PublicInbox::IMAPClient->new(%$mic_arg) or
  64                 die "E: <$url> new: $@\n";
  65
  66         # default to using STARTTLS if it's available, but allow
  67         # it to be disabled since I usually connect to localhost
  68         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
  69                         $mic->has_capability('STARTTLS') &&
  70                         $mic->can('starttls')) {
  71                 $mic->starttls or die "E: <$url> STARTTLS: $@\n";
  72         }
  73
  74         # do we even need credentials?
  75         if (!defined($cred->{username}) &&
  76                         $mic->has_capability('AUTH=ANONYMOUS')) {
  77                 $cred = undef;
  78         }
  79         if ($cred) {
  80                 $cred->check_netrc unless defined $cred->{password};
  81                 $cred->fill($lei); # may prompt user here
  82                 $mic->User($mic_arg->{User} = $cred->{username});
  83                 $mic->Password($mic_arg->{Password} = $cred->{password});
  84         } else { # AUTH=ANONYMOUS
  85                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
  86                 $mic_arg->{Authcallback} = 'auth_anon_cb';
  87                 $mic->Authcallback(\&auth_anon_cb);
  88         }
  89         my $err;
  90         if ($mic->login && $mic->IsAuthenticated) {
  91                 # success! keep IMAPClient->new arg in case we get disconnected
  92                 $self->{mic_arg}->{uri_section($uri)} = $mic_arg;
  93         } else {
  94                 $err = "E: <$url> LOGIN: $@\n";
  95                 if ($cred && defined($cred->{password})) {
  96                         $err =~ s/\Q$cred->{password}\E/*******/g;
  97                 }
  98                 $mic = undef;
  99         }
 100         $cred->run($mic ? 'approve' : 'reject') if $cred;
 101         if ($err) {
 102                 $lei ? $lei->fail($err) : warn($err);
 103         }
 104         $mic;
 105 }
 106
 107 sub uri_new {
 108         my ($url) = @_;
 109         require URI;
 110
 111         # URI::snews exists, URI::nntps does not, so use URI::snews
 112         $url =~ s!\Anntps://!snews://!i;
 113         URI->new($url);
 114 }
 115
 116 # Net::NNTP doesn't support CAPABILITIES, yet
 117 sub try_starttls ($) {
 118         my ($host) = @_;
 119         return if $host =~ /\.onion\z/s;
 120         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 121         return if $host eq '::1';
 122         1;
 123 }
 124
 125 sub nn_new ($$$) {
 126         my ($nn_arg, $nntp_opt, $url) = @_;
 127         my $nn = Net::NNTP->new(%$nn_arg) or die "E: <$url> new: $!\n";
 128
 129         # default to using STARTTLS if it's available, but allow
 130         # it to be disabled for localhost/VPN users
 131         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 132                 if (!defined($nntp_opt->{starttls}) &&
 133                                 try_starttls($nn_arg->{Host})) {
 134                         # soft fail by default
 135                         $nn->starttls or warn <<"";
 136 W: <$url> STARTTLS tried and failed (not requested)
 137
 138                 } elsif ($nntp_opt->{starttls}) {
 139                         # hard fail if explicitly configured
 140                         $nn->starttls or die <<"";
 141 E: <$url> STARTTLS requested and failed
 142
 143                 }
 144         } elsif ($nntp_opt->{starttls}) {
 145                 $nn->can('starttls') or
 146                         die "E: <$url> Net::NNTP too old for STARTTLS\n";
 147                 $nn->starttls or die <<"";
 148 E: <$url> STARTTLS requested and failed
 149
 150         }
 151         $nn;
 152 }
 153
 154 sub nn_for ($$$;$) { # nn = Net::NNTP
 155         my ($self, $url, $nn_args, $lei) = @_;
 156         my $uri = uri_new($url);
 157         my $sec = uri_section($uri);
 158         my $nntp_opt = $self->{nntp_opt}->{$sec} //= {};
 159         my $host = $uri->host;
 160         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 161         $host = '127.0.0.1' if $host eq '0';
 162         my $cred;
 163         my ($u, $p);
 164         if (defined(my $ui = $uri->userinfo)) {
 165                 require PublicInbox::GitCredential;
 166                 $cred = bless {
 167                         url => $sec,
 168                         protocol => uri_scheme($uri),
 169                         host => $host,
 170                 }, 'PublicInbox::GitCredential';
 171                 ($u, $p) = split(/:/, $ui, 2);
 172                 ($cred->{username}, $cred->{password}) = ($u, $p);
 173                 $cred->check_netrc unless defined $p;
 174         }
 175         my $common = $nn_args->{$sec} // {};
 176         my $nn_arg = {
 177                 Port => $uri->port,
 178                 Host => $host,
 179                 SSL => $uri->secure, # snews == nntps
 180                 %$common, # may Debug ....
 181         };
 182         my $nn = nn_new($nn_arg, $nntp_opt, $url);
 183
 184         if ($cred) {
 185                 $cred->fill($lei); # may prompt user here
 186                 if ($nn->authinfo($u, $p)) {
 187                         push @{$nntp_opt->{-postconn}}, [ 'authinfo', $u, $p ];
 188                 } else {
 189                         warn "E: <$url> AUTHINFO $u XXXX failed\n";
 190                         $nn = undef;
 191                 }
 192         }
 193
 194         if ($nntp_opt->{compress}) {
 195                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 196                 if ($nn->can('compress')) {
 197                         if ($nn->compress) {
 198                                 push @{$nntp_opt->{-postconn}}, [ 'compress' ];
 199                         } else {
 200                                 warn "W: <$url> COMPRESS failed\n";
 201                         }
 202                 } else {
 203                         delete $nntp_opt->{compress};
 204                         warn <<"";
 205 W: <$url> COMPRESS not supported by Net::NNTP
 206 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 207
 208                 }
 209         }
 210
 211         $self->{nn_arg}->{$sec} = $nn_arg;
 212         $cred->run($nn ? 'approve' : 'reject') if $cred;
 213         $nn;
 214 }
 215
 216 sub imap_uri {
 217         my ($url) = @_;
 218         require PublicInbox::URIimap;
 219         my $uri = PublicInbox::URIimap->new($url);
 220         $uri ? $uri->canonical : undef;
 221 }
 222
 223 my %IS_NNTP = (news => 1, snews => 1, nntp => 1);
 224 sub nntp_url {
 225         my ($url) = @_;
 226         my $uri = uri_new($url);
 227         return unless $uri && $IS_NNTP{$uri->scheme} && $uri->group;
 228         $url = $uri->canonical->as_string;
 229         # nntps is IANA registered, snews is deprecated
 230         $url =~ s!\Asnews://!nntps://!;
 231         $url;
 232 }
 233
 234 sub cfg_intvl ($$$) {
 235         my ($cfg, $key, $url) = @_;
 236         my $v = $cfg->urlmatch($key, $url) // return;
 237         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 238         if (ref($v) eq 'ARRAY') {
 239                 $v = join(', ', @$v);
 240                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 241         } else {
 242                 warn "W: $key=$v is not a numeric value in seconds\n";
 243         }
 244 }
 245
 246 sub cfg_bool ($$$) {
 247         my ($cfg, $key, $url) = @_;
 248         my $orig = $cfg->urlmatch($key, $url) // return;
 249         my $bool = $cfg->git_bool($orig);
 250         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 251         $bool;
 252 }
 253
 254 # flesh out common IMAP-specific data structures
 255 sub imap_common_init ($;$) {
 256         my ($self, $lei) = @_;
 257         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 258         eval { require PublicInbox::IMAPClient } or
 259                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 260         eval { require PublicInbox::IMAPTracker } or
 261                 die "DBD::SQLite is required for IMAP\n:$@\n";
 262         require PublicInbox::URIimap;
 263         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 264         my $mic_args = {}; # scheme://authority => Mail:IMAPClient arg
 265         for my $uri (@{$self->{imap_order}}) {
 266                 my $sec = uri_section($uri);
 267                 for my $k (qw(Starttls Debug Compress)) {
 268                         my $bool = cfg_bool($cfg, "imap.$k", $$uri) // next;
 269                         $mic_args->{$sec}->{$k} = $bool;
 270                 }
 271                 my $to = cfg_intvl($cfg, 'imap.timeout', $$uri);
 272                 $mic_args->{$sec}->{Timeout} = $to if $to;
 273                 for my $k (qw(pollInterval idleInterval)) {
 274                         $to = cfg_intvl($cfg, "imap.$k", $$uri) // next;
 275                         $self->{imap_opt}->{$sec}->{$k} = $to;
 276                 }
 277                 my $k = 'imap.fetchBatchSize';
 278                 my $bs = $cfg->urlmatch($k, $$uri) // next;
 279                 if ($bs =~ /\A([0-9]+)\z/) {
 280                         $self->{imap_opt}->{$sec}->{batch_size} = $bs;
 281                 } else {
 282                         warn "$k=$bs is not an integer\n";
 283                 }
 284         }
 285         # make sure we can connect and cache the credentials in memory
 286         $self->{mic_arg} = {}; # schema://authority => IMAPClient->new args
 287         my $mics = {}; # schema://authority => IMAPClient obj
 288         for my $uri (@{$self->{imap_order}}) {
 289                 my $sec = uri_section($uri);
 290                 $mics->{$sec} //= mic_for($self, "$sec/", $mic_args, $lei);
 291                 next unless $self->isa('PublicInbox::NetWriter');
 292                 my $dst = $uri->mailbox // next;
 293                 my $mic = $mics->{$sec};
 294                 next if $mic->exists($dst); # already exists
 295                 $mic->create($dst) or die "CREATE $dst failed <$uri>: $@";
 296         }
 297         $mics;
 298 }
 299
 300 sub add_url {
 301         my ($self, $arg) = @_;
 302         if (my $uri = imap_uri($arg)) {
 303                 push @{$self->{imap_order}}, $uri;
 304         } else {
 305                 push @{$self->{unsupported_url}}, $arg;
 306         }
 307 }
 308
 309 sub errors {
 310         my ($self) = @_;
 311         if (my $u = $self->{unsupported_url}) {
 312                 return "Unsupported URL(s): @$u";
 313         }
 314         if ($self->{imap_order}) {
 315                 eval { require PublicInbox::IMAPClient } or
 316                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 317         }
 318         undef;
 319 }
 320
 321 sub _imap_do_msg ($$$$$) {
 322         my ($self, $uri, $uid, $raw, $flags) = @_;
 323         # our target audience expects LF-only, save storage
 324         $$raw =~ s/\r\n/\n/sg;
 325         my $kw = [];
 326         for my $f (split(/ /, $flags)) {
 327                 my $k = $IMAPflags2kw{$f} // next; # TODO: X-Label?
 328                 push @$kw, $k;
 329         }
 330         my ($eml_cb, @args) = @{$self->{eml_each}};
 331         $eml_cb->($uri, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 332 }
 333
 334 sub _imap_fetch_all ($$$) {
 335         my ($self, $mic, $uri) = @_;
 336         my $sec = uri_section($uri);
 337         my $mbx = $uri->mailbox;
 338         $mic->Clear(1); # trim results history
 339         $mic->examine($mbx) or return "E: EXAMINE $mbx ($sec) failed: $!";
 340         my ($r_uidval, $r_uidnext);
 341         for ($mic->Results) {
 342                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 343                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 344                 last if $r_uidval && $r_uidnext;
 345         }
 346         $r_uidval //= $mic->uidvalidity($mbx) //
 347                 return "E: $uri cannot get UIDVALIDITY";
 348         $r_uidnext //= $mic->uidnext($mbx) //
 349                 return "E: $uri cannot get UIDNEXT";
 350         my $itrk = $self->{incremental} ?
 351                         PublicInbox::IMAPTracker->new($$uri) : 0;
 352         my ($l_uidval, $l_uid) = $itrk ? $itrk->get_last : ();
 353         $l_uidval //= $r_uidval; # first time
 354         $l_uid //= 0;
 355         if ($l_uidval != $r_uidval) {
 356                 return "E: $uri UIDVALIDITY mismatch\n".
 357                         "E: local=$l_uidval != remote=$r_uidval";
 358         }
 359         my $r_uid = $r_uidnext - 1;
 360         if ($l_uid > $r_uid) {
 361                 return "E: $uri local UID exceeds remote ($l_uid > $r_uid)\n".
 362                         "E: $uri strangely, UIDVALIDLITY matches ($l_uidval)\n";
 363         }
 364         return if $l_uid >= $r_uid; # nothing to do
 365         $l_uid ||= 1;
 366         my ($mod, $shard) = @{$self->{shard_info} // []};
 367         unless ($self->{quiet}) {
 368                 my $m = $mod ? " [(UID % $mod) == $shard]" : '';
 369                 warn "# $uri fetching UID $l_uid:$r_uid$m\n";
 370         }
 371         $mic->Uid(1); # the default, we hope
 372         my $bs = $self->{imap_opt}->{$sec}->{batch_size} // 1;
 373         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 374         my $key = $req;
 375         $key =~ s/\.PEEK//;
 376         my ($uids, $batch);
 377         my $err;
 378         do {
 379                 # I wish "UID FETCH $START:*" could work, but:
 380                 # 1) servers do not need to return results in any order
 381                 # 2) Mail::IMAPClient doesn't offer a streaming API
 382                 $uids = $mic->search("UID $l_uid:*") or
 383                         return "E: $uri UID SEARCH $l_uid:* error: $!";
 384                 return if scalar(@$uids) == 0;
 385
 386                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 387                 # responses, so sort it ourselves.  Order matters so
 388                 # IMAPTracker can store the newest UID.
 389                 @$uids = sort { $a <=> $b } @$uids;
 390
 391                 # Did we actually get new messages?
 392                 return if $uids->[0] < $l_uid;
 393
 394                 $l_uid = $uids->[-1] + 1; # for next search
 395                 my $last_uid;
 396                 my $n = $self->{max_batch};
 397
 398                 @$uids = grep { ($_ % $mod) == $shard } @$uids if $mod;
 399                 while (scalar @$uids) {
 400                         my @batch = splice(@$uids, 0, $bs);
 401                         $batch = join(',', @batch);
 402                         local $0 = "UID:$batch $mbx $sec";
 403                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 404                         unless ($r) { # network error?
 405                                 $err = "E: $uri UID FETCH $batch error: $!";
 406                                 last;
 407                         }
 408                         for my $uid (@batch) {
 409                                 # messages get deleted, so holes appear
 410                                 my $per_uid = delete $r->{$uid} // next;
 411                                 my $raw = delete($per_uid->{$key}) // next;
 412                                 _imap_do_msg($self, $uri, $uid, \$raw,
 413                                                 $per_uid->{FLAGS});
 414                                 $last_uid = $uid;
 415                                 last if $self->{quit};
 416                         }
 417                         last if $self->{quit};
 418                 }
 419                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 420         } until ($err || $self->{quit});
 421         $err;
 422 }
 423
 424 # uses cached auth info prepared by mic_for
 425 sub mic_get {
 426         my ($self, $uri) = @_;
 427         my $sec = uri_section($uri);
 428         # see if caller saved result of imap_common_init
 429         my $cached = $self->{mics_cached};
 430         if ($cached) {
 431                 my $mic = $cached->{$sec};
 432                 return $mic if $mic && $mic->IsConnected;
 433                 delete $cached->{$sec};
 434         }
 435         my $mic_arg = $self->{mic_arg}->{$sec} or
 436                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 437         if (defined(my $cb_name = $mic_arg->{Authcallback})) {
 438                 if (ref($cb_name) ne 'CODE') {
 439                         $mic_arg->{Authcallback} = $self->can($cb_name);
 440                 }
 441         }
 442         my $mic = PublicInbox::IMAPClient->new(%$mic_arg);
 443         $cached //= {}; # invalid placeholder if no cache enabled
 444         $mic && $mic->IsConnected ? ($cached->{$sec} = $mic) : undef;
 445 }
 446
 447 sub imap_each {
 448         my ($self, $url, $eml_cb, @args) = @_;
 449         my $uri = ref($url) ? $url : PublicInbox::URIimap->new($url);
 450         my $sec = uri_section($uri);
 451         local $0 = $uri->mailbox." $sec";
 452         my $mic = mic_get($self, $uri);
 453         my $err;
 454         if ($mic) {
 455                 local $self->{eml_each} = [ $eml_cb, @args ];
 456                 $err = _imap_fetch_all($self, $mic, $uri);
 457         } else {
 458                 $err = "E: not connected: $!";
 459         }
 460         warn $err if $err;
 461         $mic;
 462 }
 463
 464 sub new { bless {}, shift };
 465
 466 1;