lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 our %IMAPflags2kw = map {; "\\\u$_" => $_ } qw(seen answered flagged draft);
  11 $IMAPflags2kw{'$Forwarded'} = 'forwarded';  # RFC 5550
  12
  13 our @EXPORT = qw(uri_section imap_uri nntp_uri);
  14
  15 sub ndump {
  16         require Data::Dumper;
  17         Data::Dumper->new(\@_)->Useqq(1)->Terse(1)->Dump;
  18 }
  19
  20 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  21 # without the mailbox, so we can share connections between different inboxes
  22 sub uri_section ($) {
  23         my ($uri) = @_;
  24         $uri->scheme . '://' . $uri->authority;
  25 }
  26
  27 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  28
  29 # mic_for may prompt the user and store auth info, prepares mic_get
  30 sub mic_for { # mic = Mail::IMAPClient
  31         my ($self, $url, $mic_args, $lei) = @_;
  32         require PublicInbox::URIimap;
  33         my $uri = PublicInbox::URIimap->new($url);
  34         require PublicInbox::GitCredential;
  35         my $cred = bless {
  36                 url => $url,
  37                 protocol => $uri->scheme,
  38                 host => $uri->host,
  39                 username => $uri->user,
  40                 password => $uri->password,
  41         }, 'PublicInbox::GitCredential';
  42         my $common = $mic_args->{uri_section($uri)} // {};
  43         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
  44         my $host = $cred->{host};
  45         $host = '127.0.0.1' if $host eq '0';
  46         my $mic_arg = {
  47                 Port => $uri->port,
  48                 Server => $host,
  49                 Ssl => $uri->scheme eq 'imaps',
  50                 Keepalive => 1, # SO_KEEPALIVE
  51                 %$common, # may set Starttls, Compress, Debug ....
  52         };
  53         require PublicInbox::IMAPClient;
  54         my $mic = PublicInbox::IMAPClient->new(%$mic_arg) or
  55                 die "E: <$url> new: $@\n";
  56
  57         # default to using STARTTLS if it's available, but allow
  58         # it to be disabled since I usually connect to localhost
  59         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
  60                         $mic->has_capability('STARTTLS') &&
  61                         $mic->can('starttls')) {
  62                 $mic->starttls or die "E: <$url> STARTTLS: $@\n";
  63         }
  64
  65         # do we even need credentials?
  66         if (!defined($cred->{username}) &&
  67                         $mic->has_capability('AUTH=ANONYMOUS')) {
  68                 $cred = undef;
  69         }
  70         if ($cred) {
  71                 $cred->check_netrc unless defined $cred->{password};
  72                 $cred->fill($lei); # may prompt user here
  73                 $mic->User($mic_arg->{User} = $cred->{username});
  74                 $mic->Password($mic_arg->{Password} = $cred->{password});
  75         } else { # AUTH=ANONYMOUS
  76                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
  77                 $mic_arg->{Authcallback} = 'auth_anon_cb';
  78                 $mic->Authcallback(\&auth_anon_cb);
  79         }
  80         my $err;
  81         if ($mic->login && $mic->IsAuthenticated) {
  82                 # success! keep IMAPClient->new arg in case we get disconnected
  83                 $self->{mic_arg}->{uri_section($uri)} = $mic_arg;
  84         } else {
  85                 $err = "E: <$url> LOGIN: $@\n";
  86                 if ($cred && defined($cred->{password})) {
  87                         $err =~ s/\Q$cred->{password}\E/*******/g;
  88                 }
  89                 $mic = undef;
  90         }
  91         $cred->run($mic ? 'approve' : 'reject') if $cred;
  92         if ($err) {
  93                 $lei ? $lei->fail($err) : warn($err);
  94         }
  95         $mic;
  96 }
  97
  98 # Net::NNTP doesn't support CAPABILITIES, yet
  99 sub try_starttls ($) {
 100         my ($host) = @_;
 101         return if $host =~ /\.onion\z/s;
 102         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 103         return if $host eq '::1';
 104         1;
 105 }
 106
 107 sub nn_new ($$$) {
 108         my ($nn_arg, $nntp_opt, $uri) = @_;
 109         my $nn = Net::NNTP->new(%$nn_arg) or die "E: <$uri> new: $!\n";
 110
 111         # default to using STARTTLS if it's available, but allow
 112         # it to be disabled for localhost/VPN users
 113         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 114                 if (!defined($nntp_opt->{starttls}) &&
 115                                 try_starttls($nn_arg->{Host})) {
 116                         # soft fail by default
 117                         $nn->starttls or warn <<"";
 118 W: <$uri> STARTTLS tried and failed (not requested)
 119
 120                 } elsif ($nntp_opt->{starttls}) {
 121                         # hard fail if explicitly configured
 122                         $nn->starttls or die <<"";
 123 E: <$uri> STARTTLS requested and failed
 124
 125                 }
 126         } elsif ($nntp_opt->{starttls}) {
 127                 $nn->can('starttls') or
 128                         die "E: <$uri> Net::NNTP too old for STARTTLS\n";
 129                 $nn->starttls or die <<"";
 130 E: <$uri> STARTTLS requested and failed
 131
 132         }
 133         $nn;
 134 }
 135
 136 sub nn_for ($$$;$) { # nn = Net::NNTP
 137         my ($self, $uri, $nn_args, $lei) = @_;
 138         my $sec = uri_section($uri);
 139         my $nntp_opt = $self->{nntp_opt}->{$sec} //= {};
 140         my $host = $uri->host;
 141         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 142         $host = '127.0.0.1' if $host eq '0';
 143         my $cred;
 144         my ($u, $p);
 145         if (defined(my $ui = $uri->userinfo)) {
 146                 require PublicInbox::GitCredential;
 147                 $cred = bless {
 148                         url => $sec,
 149                         protocol => $uri->scheme,
 150                         host => $host,
 151                 }, 'PublicInbox::GitCredential';
 152                 ($u, $p) = split(/:/, $ui, 2);
 153                 ($cred->{username}, $cred->{password}) = ($u, $p);
 154                 $cred->check_netrc unless defined $p;
 155         }
 156         my $common = $nn_args->{$sec} // {};
 157         my $nn_arg = {
 158                 Port => $uri->port,
 159                 Host => $host,
 160                 SSL => $uri->secure, # snews == nntps
 161                 %$common, # may Debug ....
 162         };
 163         my $nn = nn_new($nn_arg, $nntp_opt, $uri);
 164         if ($cred) {
 165                 $cred->fill($lei); # may prompt user here
 166                 if ($nn->authinfo($u, $p)) {
 167                         push @{$nntp_opt->{-postconn}}, [ 'authinfo', $u, $p ];
 168                 } else {
 169                         warn "E: <$uri> AUTHINFO $u XXXX failed\n";
 170                         $nn = undef;
 171                 }
 172         }
 173
 174         if ($nntp_opt->{compress}) {
 175                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 176                 if ($nn->can('compress')) {
 177                         if ($nn->compress) {
 178                                 push @{$nntp_opt->{-postconn}}, [ 'compress' ];
 179                         } else {
 180                                 warn "W: <$uri> COMPRESS failed\n";
 181                         }
 182                 } else {
 183                         delete $nntp_opt->{compress};
 184                         warn <<"";
 185 W: <$uri> COMPRESS not supported by Net::NNTP
 186 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 187
 188                 }
 189         }
 190
 191         $self->{nn_arg}->{$sec} = $nn_arg;
 192         $cred->run($nn ? 'approve' : 'reject') if $cred;
 193         $nn;
 194 }
 195
 196 sub imap_uri {
 197         my ($url) = @_;
 198         require PublicInbox::URIimap;
 199         my $uri = PublicInbox::URIimap->new($url);
 200         $uri ? $uri->canonical : undef;
 201 }
 202
 203 my %IS_NNTP = (news => 1, snews => 1, nntp => 1, nntps => 1);
 204 sub nntp_uri {
 205         my ($url) = @_;
 206         require PublicInbox::URInntps;
 207         my $uri = PublicInbox::URInntps->new($url);
 208         $uri && $IS_NNTP{$uri->scheme} && $uri->group ? $uri->canonical : undef;
 209 }
 210
 211 sub cfg_intvl ($$$) {
 212         my ($cfg, $key, $url) = @_;
 213         my $v = $cfg->urlmatch($key, $url) // return;
 214         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 215         if (ref($v) eq 'ARRAY') {
 216                 $v = join(', ', @$v);
 217                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 218         } else {
 219                 warn "W: $key=$v is not a numeric value in seconds\n";
 220         }
 221 }
 222
 223 sub cfg_bool ($$$) {
 224         my ($cfg, $key, $url) = @_;
 225         my $orig = $cfg->urlmatch($key, $url) // return;
 226         my $bool = $cfg->git_bool($orig);
 227         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 228         $bool;
 229 }
 230
 231 # flesh out common IMAP-specific data structures
 232 sub imap_common_init ($;$) {
 233         my ($self, $lei) = @_;
 234         return unless $self->{imap_order};
 235         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 236         eval { require PublicInbox::IMAPClient } or
 237                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 238         eval { require PublicInbox::IMAPTracker } or
 239                 die "DBD::SQLite is required for IMAP\n:$@\n";
 240         require PublicInbox::URIimap;
 241         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 242         my $mic_args = {}; # scheme://authority => Mail:IMAPClient arg
 243         for my $uri (@{$self->{imap_order}}) {
 244                 my $sec = uri_section($uri);
 245                 for my $k (qw(Starttls Debug Compress)) {
 246                         my $bool = cfg_bool($cfg, "imap.$k", $$uri) // next;
 247                         $mic_args->{$sec}->{$k} = $bool;
 248                 }
 249                 my $to = cfg_intvl($cfg, 'imap.timeout', $$uri);
 250                 $mic_args->{$sec}->{Timeout} = $to if $to;
 251                 for my $k (qw(pollInterval idleInterval)) {
 252                         $to = cfg_intvl($cfg, "imap.$k", $$uri) // next;
 253                         $self->{imap_opt}->{$sec}->{$k} = $to;
 254                 }
 255                 my $k = 'imap.fetchBatchSize';
 256                 my $bs = $cfg->urlmatch($k, $$uri) // next;
 257                 if ($bs =~ /\A([0-9]+)\z/) {
 258                         $self->{imap_opt}->{$sec}->{batch_size} = $bs;
 259                 } else {
 260                         warn "$k=$bs is not an integer\n";
 261                 }
 262         }
 263         # make sure we can connect and cache the credentials in memory
 264         $self->{mic_arg} = {}; # schema://authority => IMAPClient->new args
 265         my $mics = {}; # schema://authority => IMAPClient obj
 266         for my $uri (@{$self->{imap_order}}) {
 267                 my $sec = uri_section($uri);
 268                 my $mic = $mics->{$sec} //=
 269                                 mic_for($self, "$sec/", $mic_args, $lei) //
 270                                 die "Unable to continue\n";
 271                 next unless $self->isa('PublicInbox::NetWriter');
 272                 my $dst = $uri->mailbox // next;
 273                 next if $mic->exists($dst); # already exists
 274                 $mic->create($dst) or die "CREATE $dst failed <$uri>: $@";
 275         }
 276         $mics;
 277 }
 278
 279 # flesh out common NNTP-specific data structures
 280 sub nntp_common_init ($;$) {
 281         my ($self, $lei) = @_;
 282         return unless $self->{nntp_order};
 283         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 284         eval { require Net::NNTP } or
 285                 die "Net::NNTP is required for NNTP:\n$@\n";
 286         eval { require PublicInbox::IMAPTracker } or
 287                 die "DBD::SQLite is required for NNTP\n:$@\n";
 288         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 289         my $nn_args = {}; # scheme://authority => Net::NNTP->new arg
 290         for my $uri (@{$self->{nntp_order}}) {
 291                 my $sec = uri_section($uri);
 292
 293                 # Debug and Timeout are passed to Net::NNTP->new
 294                 my $v = cfg_bool($cfg, 'nntp.Debug', $$uri);
 295                 $nn_args->{$sec}->{Debug} = $v if defined $v;
 296                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $$uri);
 297                 $nn_args->{$sec}->{Timeout} = $to if $to;
 298
 299                 # Net::NNTP post-connect commands
 300                 for my $k (qw(starttls compress)) {
 301                         $v = cfg_bool($cfg, "nntp.$k", $$uri) // next;
 302                         $self->{nntp_opt}->{$sec}->{$k} = $v;
 303                 }
 304
 305                 # internal option
 306                 for my $k (qw(pollInterval)) {
 307                         $to = cfg_intvl($cfg, "nntp.$k", $$uri) // next;
 308                         $self->{nntp_opt}->{$sec}->{$k} = $to;
 309                 }
 310         }
 311         # make sure we can connect and cache the credentials in memory
 312         $self->{nn_arg} = {}; # schema://authority => Net::NNTP->new args
 313         my %nn; # schema://authority => Net::NNTP object
 314         for my $uri (@{$self->{nntp_order}}) {
 315                 my $sec = uri_section($uri);
 316                 $nn{$sec} //= nn_for($self, $uri, $nn_args, $lei);
 317         }
 318         \%nn; # for optional {nn_cached}
 319 }
 320
 321 sub add_url {
 322         my ($self, $arg) = @_;
 323         my $uri;
 324         if ($uri = imap_uri($arg)) {
 325                 push @{$self->{imap_order}}, $uri;
 326         } elsif ($uri = nntp_uri($arg)) {
 327                 push @{$self->{nntp_order}}, $uri;
 328         } else {
 329                 push @{$self->{unsupported_url}}, $arg;
 330         }
 331 }
 332
 333 sub errors {
 334         my ($self) = @_;
 335         if (my $u = $self->{unsupported_url}) {
 336                 return "Unsupported URL(s): @$u";
 337         }
 338         if ($self->{imap_order}) {
 339                 eval { require PublicInbox::IMAPClient } or
 340                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 341         }
 342         if ($self->{nntp_order}) {
 343                 eval { require Net::NNTP } or
 344                         die "Net::NNTP is required for NNTP:\n$@\n";
 345         }
 346         undef;
 347 }
 348
 349 sub _imap_do_msg ($$$$$) {
 350         my ($self, $uri, $uid, $raw, $flags) = @_;
 351         # our target audience expects LF-only, save storage
 352         $$raw =~ s/\r\n/\n/sg;
 353         my $kw = [];
 354         for my $f (split(/ /, $flags)) {
 355                 if (my $k = $IMAPflags2kw{$f}) {
 356                         push @$kw, $k;
 357                 } elsif ($f eq "\\Recent") { # not in JMAP
 358                 } elsif ($f eq "\\Deleted") { # not in JMAP
 359                         return;
 360                 } elsif ($self->{verbose}) {
 361                         warn "# unknown IMAP flag $f <$uri;uid=$uid>\n";
 362                 }
 363         }
 364         @$kw = sort @$kw; # for all UI/UX purposes
 365         my ($eml_cb, @args) = @{$self->{eml_each}};
 366         $eml_cb->($uri, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 367 }
 368
 369 sub run_commit_cb ($) {
 370         my ($self) = @_;
 371         my $cmt_cb_args = $self->{on_commit} or return;
 372         my ($cb, @args) = @$cmt_cb_args;
 373         $cb->(@args);
 374 }
 375
 376 sub _itrk ($$) {
 377         my ($self, $uri) = @_;
 378         return unless $self->{incremental};
 379         # itrk_fn is set by lei
 380         PublicInbox::IMAPTracker->new($$uri, $self->{itrk_fn});
 381 }
 382
 383 sub _imap_fetch_all ($$$) {
 384         my ($self, $mic, $uri) = @_;
 385         my $sec = uri_section($uri);
 386         my $mbx = $uri->mailbox;
 387         $mic->Clear(1); # trim results history
 388         $mic->examine($mbx) or return "E: EXAMINE $mbx ($sec) failed: $!";
 389         my ($r_uidval, $r_uidnext);
 390         for ($mic->Results) {
 391                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 392                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 393                 last if $r_uidval && $r_uidnext;
 394         }
 395         $r_uidval //= $mic->uidvalidity($mbx) //
 396                 return "E: $uri cannot get UIDVALIDITY";
 397         $r_uidnext //= $mic->uidnext($mbx) //
 398                 return "E: $uri cannot get UIDNEXT";
 399         my $itrk = _itrk($self, $uri);
 400         my ($l_uidval, $l_uid) = $itrk ? $itrk->get_last : ();
 401         $l_uidval //= $r_uidval; # first time
 402         $l_uid //= 0;
 403         if ($l_uidval != $r_uidval) {
 404                 return "E: $uri UIDVALIDITY mismatch\n".
 405                         "E: local=$l_uidval != remote=$r_uidval";
 406         }
 407         my $r_uid = $r_uidnext - 1;
 408         if ($l_uid > $r_uid) {
 409                 return "E: $uri local UID exceeds remote ($l_uid > $r_uid)\n".
 410                         "E: $uri strangely, UIDVALIDLITY matches ($l_uidval)\n";
 411         }
 412         return if $l_uid >= $r_uid; # nothing to do
 413         $l_uid ||= 1;
 414         my ($mod, $shard) = @{$self->{shard_info} // []};
 415         unless ($self->{quiet}) {
 416                 my $m = $mod ? " [(UID % $mod) == $shard]" : '';
 417                 warn "# $uri fetching UID $l_uid:$r_uid$m\n";
 418         }
 419         $mic->Uid(1); # the default, we hope
 420         my $bs = $self->{imap_opt}->{$sec}->{batch_size} // 1;
 421         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 422         my $key = $req;
 423         $key =~ s/\.PEEK//;
 424         my ($uids, $batch);
 425         my $err;
 426         do {
 427                 # I wish "UID FETCH $START:*" could work, but:
 428                 # 1) servers do not need to return results in any order
 429                 # 2) Mail::IMAPClient doesn't offer a streaming API
 430                 unless ($uids = $mic->search("UID $l_uid:*")) {
 431                         return if $!{EINTR} && $self->{quit};
 432                         return "E: $uri UID SEARCH $l_uid:* error: $!";
 433                 }
 434                 return if scalar(@$uids) == 0;
 435
 436                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 437                 # responses, so sort it ourselves.  Order matters so
 438                 # IMAPTracker can store the newest UID.
 439                 @$uids = sort { $a <=> $b } @$uids;
 440
 441                 # Did we actually get new messages?
 442                 return if $uids->[0] < $l_uid;
 443
 444                 $l_uid = $uids->[-1] + 1; # for next search
 445                 my $last_uid;
 446                 my $n = $self->{max_batch};
 447
 448                 @$uids = grep { ($_ % $mod) == $shard } @$uids if $mod;
 449                 while (scalar @$uids) {
 450                         my @batch = splice(@$uids, 0, $bs);
 451                         $batch = join(',', @batch);
 452                         local $0 = "UID:$batch $mbx $sec";
 453                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 454                         unless ($r) { # network error?
 455                                 last if $!{EINTR} && $self->{quit};
 456                                 $err = "E: $uri UID FETCH $batch error: $!";
 457                                 last;
 458                         }
 459                         for my $uid (@batch) {
 460                                 # messages get deleted, so holes appear
 461                                 my $per_uid = delete $r->{$uid} // next;
 462                                 my $raw = delete($per_uid->{$key}) // next;
 463                                 _imap_do_msg($self, $uri, $uid, \$raw,
 464                                                 $per_uid->{FLAGS});
 465                                 $last_uid = $uid;
 466                                 last if $self->{quit};
 467                         }
 468                         last if $self->{quit};
 469                 }
 470                 run_commit_cb($self);
 471                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 472         } until ($err || $self->{quit});
 473         $err;
 474 }
 475
 476 # uses cached auth info prepared by mic_for
 477 sub mic_get {
 478         my ($self, $uri) = @_;
 479         my $sec = uri_section($uri);
 480         # see if caller saved result of imap_common_init
 481         my $cached = $self->{mics_cached};
 482         if ($cached) {
 483                 my $mic = $cached->{$sec};
 484                 return $mic if $mic && $mic->IsConnected;
 485                 delete $cached->{$sec};
 486         }
 487         my $mic_arg = $self->{mic_arg}->{$sec} or
 488                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 489         if (defined(my $cb_name = $mic_arg->{Authcallback})) {
 490                 if (ref($cb_name) ne 'CODE') {
 491                         $mic_arg->{Authcallback} = $self->can($cb_name);
 492                 }
 493         }
 494         my $mic = PublicInbox::IMAPClient->new(%$mic_arg);
 495         $cached //= {}; # invalid placeholder if no cache enabled
 496         $mic && $mic->IsConnected ? ($cached->{$sec} = $mic) : undef;
 497 }
 498
 499 sub imap_each {
 500         my ($self, $url, $eml_cb, @args) = @_;
 501         my $uri = ref($url) ? $url : PublicInbox::URIimap->new($url);
 502         my $sec = uri_section($uri);
 503         local $0 = $uri->mailbox." $sec";
 504         my $mic = mic_get($self, $uri);
 505         my $err;
 506         if ($mic) {
 507                 local $self->{eml_each} = [ $eml_cb, @args ];
 508                 $err = _imap_fetch_all($self, $mic, $uri);
 509         } else {
 510                 $err = "E: <$uri> not connected: $!";
 511         }
 512         warn $err if $err;
 513         $mic;
 514 }
 515
 516 # may used cached auth info prepared by nn_for once
 517 sub nn_get {
 518         my ($self, $uri) = @_;
 519         my $sec = uri_section($uri);
 520         # see if caller saved result of nntp_common_init
 521         my $cached = $self->{nn_cached} // {};
 522         my $nn;
 523         $nn = delete($cached->{$sec}) and return $nn;
 524         my $nn_arg = $self->{nn_arg}->{$sec} or
 525                         die "BUG: no Net::NNTP->new arg for $sec";
 526         my $nntp_opt = $self->{nntp_opt}->{$sec};
 527         $nn = nn_new($nn_arg, $nntp_opt, $uri) or return;
 528         if (my $postconn = $nntp_opt->{-postconn}) {
 529                 for my $m_arg (@$postconn) {
 530                         my ($method, @args) = @$m_arg;
 531                         $nn->$method(@args) and next;
 532                         die "E: <$uri> $method failed\n";
 533                         return;
 534                 }
 535         }
 536         $nn;
 537 }
 538
 539 sub _nntp_fetch_all ($$$) {
 540         my ($self, $nn, $uri) = @_;
 541         my ($group, $num_a, $num_b) = $uri->group;
 542         my $sec = uri_section($uri);
 543         my ($nr, $beg, $end) = $nn->group($group);
 544         unless (defined($nr)) {
 545                 my $msg = ndump($nn->message);
 546                 return "E: GROUP $group <$sec> $msg";
 547         }
 548
 549         # IMAPTracker is also used for tracking NNTP, UID == article number
 550         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 551         # expensive.  So we assume newsgroups don't change:
 552         my $itrk = _itrk($self, $uri);
 553         my (undef, $l_art) = $itrk ? $itrk->get_last : ();
 554
 555         # allow users to specify articles to refetch
 556         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 557         # nntp://example.com/inbox.foo/$num_a-$num_b
 558         $beg = $num_a if defined($num_a) && $num_a < $beg;
 559         $end = $num_b if defined($num_b) && $num_b < $end;
 560         if (defined $l_art) {
 561                 return if $l_art >= $end; # nothing to do
 562                 $beg = $l_art + 1;
 563         }
 564         my ($err, $art, $last_art, $kw); # kw stays undef, no keywords in NNTP
 565         unless ($self->{quiet}) {
 566                 warn "# $uri fetching ARTICLE $beg..$end\n";
 567         }
 568         my $n = $self->{max_batch};
 569         for ($beg..$end) {
 570                 last if $self->{quit};
 571                 $art = $_;
 572                 if (--$n < 0) {
 573                         run_commit_cb($self);
 574                         $itrk->update_last(0, $last_art) if $itrk;
 575                         $n = $self->{max_batch};
 576                 }
 577                 my $raw = $nn->article($art);
 578                 unless (defined($raw)) {
 579                         my $msg = ndump($nn->message);
 580                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 581                                 $err = "E: $msg";
 582                                 last;
 583                         } else { # probably just a deleted message (spam)
 584                                 warn "W: $msg";
 585                                 next;
 586                         }
 587                 }
 588                 $raw = join('', @$raw);
 589                 $raw =~ s/\r\n/\n/sg;
 590                 my ($eml_cb, @args) = @{$self->{eml_each}};
 591                 $eml_cb->($uri, $art, $kw, PublicInbox::Eml->new(\$raw), @args);
 592                 $last_art = $art;
 593         }
 594         run_commit_cb($self);
 595         $itrk->update_last(0, $last_art) if $itrk;
 596         $err;
 597 }
 598
 599 sub nntp_each {
 600         my ($self, $url, $eml_cb, @args) = @_;
 601         my $uri = ref($url) ? $url : PublicInbox::URInntps->new($url);
 602         my $sec = uri_section($uri);
 603         local $0 = $uri->group ." $sec";
 604         my $nn = nn_get($self, $uri);
 605         return if $self->{quit};
 606         my $err;
 607         if ($nn) {
 608                 local $self->{eml_each} = [ $eml_cb, @args ];
 609                 $err = _nntp_fetch_all($self, $nn, $uri);
 610         } else {
 611                 $err = "E: <$uri> not connected: $!";
 612         }
 613         warn $err if $err;
 614         $nn;
 615 }
 616
 617 sub new { bless {}, shift };
 618
 619 1;