lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Config;
  11 our %IMAPflags2kw = map {; "\\\u$_" => $_ } qw(seen answered flagged draft);
  12 $IMAPflags2kw{'$Forwarded'} = 'forwarded';  # RFC 5550
  13
  14 our @EXPORT = qw(uri_section imap_uri nntp_uri);
  15
  16 sub ndump {
  17         require Data::Dumper;
  18         Data::Dumper->new(\@_)->Useqq(1)->Terse(1)->Dump;
  19 }
  20
  21 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  22 # without the mailbox, so we can share connections between different inboxes
  23 sub uri_section ($) {
  24         my ($uri) = @_;
  25         $uri->scheme . '://' . $uri->authority;
  26 }
  27
  28 sub socks_args ($) {
  29         my ($val) = @_;
  30         return if ($val // '') eq '';
  31         if ($val =~ m!\Asocks5h:// (?: \[ ([^\]]+) \] | ([^:/]+) )
  32                                         (?::([0-9]+))?/*\z!ix) {
  33                 my ($h, $p) = ($1 // $2, $3 + 0);
  34                 $h = '127.0.0.1' if $h eq '0';
  35                 eval { require IO::Socket::Socks } or die <<EOM;
  36 IO::Socket::Socks missing for socks5h://$h:$p
  37 EOM
  38                 return { ProxyAddr => $h, ProxyPort => $p };
  39         }
  40         die "$val not understood (only socks5h:// is supported)\n";
  41 }
  42
  43 sub mic_new ($$$$) {
  44         my ($self, $mic_arg, $sec, $uri) = @_;
  45         my %socks;
  46         my $sa = $self->{imap_opt}->{$sec}->{-proxy_cfg} || $self->{-proxy_cli};
  47         if ($sa) {
  48                 my %opt = %$sa;
  49                 $opt{ConnectAddr} = delete $mic_arg->{Server};
  50                 $opt{ConnectPort} = delete $mic_arg->{Port};
  51                 $socks{Socket} = IO::Socket::Socks->new(%opt) or die
  52                         "E: <$$uri> ".eval('$IO::Socket::Socks::SOCKS_ERROR');
  53         }
  54         PublicInbox::IMAPClient->new(%$mic_arg, %socks);
  55 }
  56
  57 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  58
  59 # mic_for may prompt the user and store auth info, prepares mic_get
  60 sub mic_for ($$$$) { # mic = Mail::IMAPClient
  61         my ($self, $uri, $mic_args, $lei) = @_;
  62         require PublicInbox::GitCredential;
  63         my $cred = bless {
  64                 url => "$uri",
  65                 protocol => $uri->scheme,
  66                 host => $uri->host,
  67                 username => $uri->user,
  68                 password => $uri->password,
  69         }, 'PublicInbox::GitCredential';
  70         my $sec = uri_section($uri);
  71         my $common = $mic_args->{$sec} // {};
  72         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
  73         my $host = $cred->{host};
  74         $host = '127.0.0.1' if $host eq '0';
  75         my $mic_arg = {
  76                 Port => $uri->port,
  77                 Server => $host,
  78                 Ssl => $uri->scheme eq 'imaps',
  79                 Keepalive => 1, # SO_KEEPALIVE
  80                 %$common, # may set Starttls, Compress, Debug ....
  81         };
  82         require PublicInbox::IMAPClient;
  83         my $mic = mic_new($self, $mic_arg, $sec, $uri) or
  84                         die "E: <$uri> new: $@\n";
  85         # default to using STARTTLS if it's available, but allow
  86         # it to be disabled since I usually connect to localhost
  87         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
  88                         $mic->has_capability('STARTTLS') &&
  89                         $mic->can('starttls')) {
  90                 $mic->starttls or die "E: <$uri> STARTTLS: $@\n";
  91         }
  92
  93         # do we even need credentials?
  94         if (!defined($cred->{username}) &&
  95                         $mic->has_capability('AUTH=ANONYMOUS')) {
  96                 $cred = undef;
  97         }
  98         if ($cred) {
  99                 $cred->check_netrc unless defined $cred->{password};
 100                 $cred->fill($lei); # may prompt user here
 101                 $mic->User($mic_arg->{User} = $cred->{username});
 102                 $mic->Password($mic_arg->{Password} = $cred->{password});
 103         } else { # AUTH=ANONYMOUS
 104                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
 105                 $mic_arg->{Authcallback} = 'auth_anon_cb';
 106                 $mic->Authcallback(\&auth_anon_cb);
 107         }
 108         my $err;
 109         if ($mic->login && $mic->IsAuthenticated) {
 110                 # success! keep IMAPClient->new arg in case we get disconnected
 111                 $self->{mic_arg}->{$sec} = $mic_arg;
 112                 if ($cred) {
 113                         $uri->user($cred->{username}) if !defined($uri->user);
 114                 } elsif ($mic_arg->{Authmechanism} eq 'ANONYMOUS') {
 115                         $uri->auth('ANONYMOUS') if !defined($uri->auth);
 116                 }
 117         } else {
 118                 $err = "E: <$uri> LOGIN: $@\n";
 119                 if ($cred && defined($cred->{password})) {
 120                         $err =~ s/\Q$cred->{password}\E/*******/g;
 121                 }
 122                 $mic = undef;
 123         }
 124         $cred->run($mic ? 'approve' : 'reject') if $cred;
 125         if ($err) {
 126                 $lei ? $lei->fail($err) : warn($err);
 127         }
 128         $mic;
 129 }
 130
 131 # Net::NNTP doesn't support CAPABILITIES, yet
 132 sub try_starttls ($) {
 133         my ($host) = @_;
 134         return if $host =~ /\.onion\z/s;
 135         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 136         return if $host eq '::1';
 137         1;
 138 }
 139
 140 sub nn_new ($$$) {
 141         my ($nn_arg, $nntp_opt, $uri) = @_;
 142         my $nn;
 143         if (defined $nn_arg->{ProxyAddr}) {
 144                 require PublicInbox::NetNNTPSocks;
 145                 eval { $nn = PublicInbox::NetNNTPSocks->new_socks(%$nn_arg) };
 146                 die "E: <$uri> $@\n" if $@;
 147         } else {
 148                 $nn = Net::NNTP->new(%$nn_arg) or die "E: <$uri> new: $!\n";
 149         }
 150
 151         # default to using STARTTLS if it's available, but allow
 152         # it to be disabled for localhost/VPN users
 153         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 154                 if (!defined($nntp_opt->{starttls}) &&
 155                                 try_starttls($nn_arg->{Host})) {
 156                         # soft fail by default
 157                         $nn->starttls or warn <<"";
 158 W: <$uri> STARTTLS tried and failed (not requested)
 159
 160                 } elsif ($nntp_opt->{starttls}) {
 161                         # hard fail if explicitly configured
 162                         $nn->starttls or die <<"";
 163 E: <$uri> STARTTLS requested and failed
 164
 165                 }
 166         } elsif ($nntp_opt->{starttls}) {
 167                 $nn->can('starttls') or
 168                         die "E: <$uri> Net::NNTP too old for STARTTLS\n";
 169                 $nn->starttls or die <<"";
 170 E: <$uri> STARTTLS requested and failed
 171
 172         }
 173         $nn;
 174 }
 175
 176 sub nn_for ($$$$) { # nn = Net::NNTP
 177         my ($self, $uri, $nn_args, $lei) = @_;
 178         my $sec = uri_section($uri);
 179         my $nntp_opt = $self->{nntp_opt}->{$sec} //= {};
 180         my $host = $uri->host;
 181         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 182         $host = '127.0.0.1' if $host eq '0';
 183         my $cred;
 184         my ($u, $p);
 185         if (defined(my $ui = $uri->userinfo)) {
 186                 require PublicInbox::GitCredential;
 187                 $cred = bless {
 188                         url => $sec,
 189                         protocol => $uri->scheme,
 190                         host => $host,
 191                 }, 'PublicInbox::GitCredential';
 192                 ($u, $p) = split(/:/, $ui, 2);
 193                 ($cred->{username}, $cred->{password}) = ($u, $p);
 194                 $cred->check_netrc unless defined $p;
 195         }
 196         my $common = $nn_args->{$sec} // {};
 197         my $nn_arg = {
 198                 Port => $uri->port,
 199                 Host => $host,
 200                 SSL => $uri->secure, # snews == nntps
 201                 %$common, # may Debug ....
 202         };
 203         my $sa = $self->{-proxy_cli};
 204         %$nn_arg = (%$nn_arg, %$sa) if $sa;
 205         my $nn = nn_new($nn_arg, $nntp_opt, $uri);
 206         if ($cred) {
 207                 $cred->fill($lei); # may prompt user here
 208                 if ($nn->authinfo($u, $p)) {
 209                         push @{$nntp_opt->{-postconn}}, [ 'authinfo', $u, $p ];
 210                 } else {
 211                         warn "E: <$uri> AUTHINFO $u XXXX failed\n";
 212                         $nn = undef;
 213                 }
 214         }
 215
 216         if ($nntp_opt->{compress}) {
 217                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 218                 if ($nn->can('compress')) {
 219                         if ($nn->compress) {
 220                                 push @{$nntp_opt->{-postconn}}, [ 'compress' ];
 221                         } else {
 222                                 warn "W: <$uri> COMPRESS failed\n";
 223                         }
 224                 } else {
 225                         delete $nntp_opt->{compress};
 226                         warn <<"";
 227 W: <$uri> COMPRESS not supported by Net::NNTP
 228 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 229
 230                 }
 231         }
 232
 233         $self->{nn_arg}->{$sec} = $nn_arg;
 234         $cred->run($nn ? 'approve' : 'reject') if $cred;
 235         $nn;
 236 }
 237
 238 sub imap_uri {
 239         my ($url) = @_;
 240         require PublicInbox::URIimap;
 241         my $uri = PublicInbox::URIimap->new($url);
 242         $uri ? $uri->canonical : undef;
 243 }
 244
 245 my %IS_NNTP = (news => 1, snews => 1, nntp => 1, nntps => 1);
 246 sub nntp_uri {
 247         my ($url) = @_;
 248         require PublicInbox::URInntps;
 249         my $uri = PublicInbox::URInntps->new($url);
 250         $uri && $IS_NNTP{$uri->scheme} && $uri->group ? $uri->canonical : undef;
 251 }
 252
 253 sub cfg_intvl ($$$) {
 254         my ($cfg, $key, $url) = @_;
 255         my $v = $cfg->urlmatch($key, $url) // return;
 256         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 257         if (ref($v) eq 'ARRAY') {
 258                 $v = join(', ', @$v);
 259                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 260         } else {
 261                 warn "W: $key=$v is not a numeric value in seconds\n";
 262         }
 263 }
 264
 265 sub cfg_bool ($$$) {
 266         my ($cfg, $key, $url) = @_;
 267         my $orig = $cfg->urlmatch($key, $url) // return;
 268         my $bool = $cfg->git_bool($orig);
 269         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 270         $bool;
 271 }
 272
 273 # flesh out common IMAP-specific data structures
 274 sub imap_common_init ($;$) {
 275         my ($self, $lei) = @_;
 276         return unless $self->{imap_order};
 277         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 278         eval { require PublicInbox::IMAPClient } or
 279                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 280         ($lei || eval { require PublicInbox::IMAPTracker }) or
 281                 die "DBD::SQLite is required for IMAP\n:$@\n";
 282         require PublicInbox::URIimap;
 283         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 284         my $mic_args = {}; # scheme://authority => Mail:IMAPClient arg
 285         for my $uri (@{$self->{imap_order}}) {
 286                 my $sec = uri_section($uri);
 287                 for my $k (qw(Starttls Debug Compress)) {
 288                         my $bool = cfg_bool($cfg, "imap.$k", $$uri) // next;
 289                         $mic_args->{$sec}->{$k} = $bool;
 290                 }
 291                 my $to = cfg_intvl($cfg, 'imap.timeout', $$uri);
 292                 $mic_args->{$sec}->{Timeout} = $to if $to;
 293                 my $sa = socks_args($cfg->urlmatch('imap.Proxy', $$uri));
 294                 $self->{imap_opt}->{$sec}->{-proxy_cfg} = $sa if $sa;
 295                 for my $k (qw(pollInterval idleInterval)) {
 296                         $to = cfg_intvl($cfg, "imap.$k", $$uri) // next;
 297                         $self->{imap_opt}->{$sec}->{$k} = $to;
 298                 }
 299                 my $k = 'imap.fetchBatchSize';
 300                 my $bs = $cfg->urlmatch($k, $$uri) // next;
 301                 if ($bs =~ /\A([0-9]+)\z/) {
 302                         $self->{imap_opt}->{$sec}->{batch_size} = $bs;
 303                 } else {
 304                         warn "$k=$bs is not an integer\n";
 305                 }
 306         }
 307         # make sure we can connect and cache the credentials in memory
 308         $self->{mic_arg} = {}; # schema://authority => IMAPClient->new args
 309         my $mics = {}; # schema://authority => IMAPClient obj
 310         for my $orig_uri (@{$self->{imap_order}}) {
 311                 my $sec = uri_section($orig_uri);
 312                 my $uri = PublicInbox::URIimap->new("$sec/");
 313                 my $mic = $mics->{$sec} //=
 314                                 mic_for($self, $uri, $mic_args, $lei) //
 315                                 die "Unable to continue\n";
 316                 next unless $self->isa('PublicInbox::NetWriter');
 317                 my $dst = $orig_uri->mailbox // next;
 318                 next if $mic->exists($dst); # already exists
 319                 $mic->create($dst) or die "CREATE $dst failed <$orig_uri>: $@";
 320         }
 321         $mics;
 322 }
 323
 324 # flesh out common NNTP-specific data structures
 325 sub nntp_common_init ($;$) {
 326         my ($self, $lei) = @_;
 327         return unless $self->{nntp_order};
 328         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 329         eval { require Net::NNTP } or
 330                 die "Net::NNTP is required for NNTP:\n$@\n";
 331         ($lei || eval { require PublicInbox::IMAPTracker }) or
 332                 die "DBD::SQLite is required for NNTP\n:$@\n";
 333         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 334         my $nn_args = {}; # scheme://authority => Net::NNTP->new arg
 335         for my $uri (@{$self->{nntp_order}}) {
 336                 my $sec = uri_section($uri);
 337                 my $args = $nn_args->{$sec} //= {};
 338
 339                 # Debug and Timeout are passed to Net::NNTP->new
 340                 my $v = cfg_bool($cfg, 'nntp.Debug', $$uri);
 341                 $args->{Debug} = $v if defined $v;
 342                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $$uri);
 343                 $args->{Timeout} = $to if $to;
 344                 my $sa = socks_args($cfg->urlmatch('nntp.Proxy', $$uri));
 345                 %$args = (%$args, %$sa) if $sa;
 346
 347                 # Net::NNTP post-connect commands
 348                 for my $k (qw(starttls compress)) {
 349                         $v = cfg_bool($cfg, "nntp.$k", $$uri) // next;
 350                         $self->{nntp_opt}->{$sec}->{$k} = $v;
 351                 }
 352
 353                 # -watch internal option
 354                 for my $k (qw(pollInterval)) {
 355                         $to = cfg_intvl($cfg, "nntp.$k", $$uri) // next;
 356                         $self->{nntp_opt}->{$sec}->{$k} = $to;
 357                 }
 358         }
 359         # make sure we can connect and cache the credentials in memory
 360         $self->{nn_arg} = {}; # schema://authority => Net::NNTP->new args
 361         my %nn; # schema://authority => Net::NNTP object
 362         for my $uri (@{$self->{nntp_order}}) {
 363                 my $sec = uri_section($uri);
 364                 $nn{$sec} //= nn_for($self, $uri, $nn_args, $lei);
 365         }
 366         \%nn; # for optional {nn_cached}
 367 }
 368
 369 sub add_url {
 370         my ($self, $arg) = @_;
 371         my $uri;
 372         if ($uri = imap_uri($arg)) {
 373                 push @{$self->{imap_order}}, $uri;
 374         } elsif ($uri = nntp_uri($arg)) {
 375                 push @{$self->{nntp_order}}, $uri;
 376         } else {
 377                 push @{$self->{unsupported_url}}, $arg;
 378         }
 379 }
 380
 381 sub errors {
 382         my ($self, $lei) = @_;
 383         if (my $u = $self->{unsupported_url}) {
 384                 return "Unsupported URL(s): @$u";
 385         }
 386         if ($self->{imap_order}) {
 387                 eval { require PublicInbox::IMAPClient } or
 388                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 389         }
 390         if ($self->{nntp_order}) {
 391                 eval { require Net::NNTP } or
 392                         die "Net::NNTP is required for NNTP:\n$@\n";
 393         }
 394         my $sa = socks_args($lei ? $lei->{opt}->{proxy} : undef);
 395         $self->{-proxy_cli} = $sa if $sa;
 396         undef;
 397 }
 398
 399 sub _imap_do_msg ($$$$$) {
 400         my ($self, $url, $uid, $raw, $flags) = @_;
 401         # our target audience expects LF-only, save storage
 402         $$raw =~ s/\r\n/\n/sg;
 403         my $kw = [];
 404         for my $f (split(/ /, $flags)) {
 405                 if (my $k = $IMAPflags2kw{$f}) {
 406                         push @$kw, $k;
 407                 } elsif ($f eq "\\Recent") { # not in JMAP
 408                 } elsif ($f eq "\\Deleted") { # not in JMAP
 409                         return;
 410                 } elsif ($self->{verbose}) {
 411                         warn "# unknown IMAP flag $f <$url/;UID=$uid>\n";
 412                 }
 413         }
 414         @$kw = sort @$kw; # for all UI/UX purposes
 415         my ($eml_cb, @args) = @{$self->{eml_each}};
 416         $eml_cb->($url, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 417 }
 418
 419 sub run_commit_cb ($) {
 420         my ($self) = @_;
 421         my $cmt_cb_args = $self->{on_commit} or return;
 422         my ($cb, @args) = @$cmt_cb_args;
 423         $cb->(@args);
 424 }
 425
 426 sub itrk_last ($$;$$) {
 427         my ($self, $uri, $r_uidval, $mic) = @_;
 428         return (undef, undef, $r_uidval) unless $self->{incremental};
 429         my ($itrk, $l_uid, $l_uidval);
 430         if (defined(my $lms = $self->{-lms_ro})) { # LeiMailSync or 0
 431                 $uri->uidvalidity($r_uidval) if defined $r_uidval;
 432                 if ($mic) {
 433                         my $auth = $mic->Authmechanism // '';
 434                         $uri->auth($auth) if $auth eq 'ANONYMOUS';
 435                         my $user = $mic->User;
 436                         $uri->user($user) if defined($user);
 437                 }
 438                 my $x;
 439                 $l_uid = ($lms && ($x = $lms->location_stats($$uri))) ?
 440                                 $x->{'uid.max'} : undef;
 441                 # itrk remains undef, lei/store worker writes to
 442                 # mail_sync.sqlite3
 443         } else {
 444                 $itrk = PublicInbox::IMAPTracker->new($$uri);
 445                 ($l_uidval, $l_uid) = $itrk->get_last($$uri);
 446         }
 447         ($itrk, $l_uid, $l_uidval //= $r_uidval);
 448 }
 449
 450 sub _imap_fetch_all ($$$) {
 451         my ($self, $mic, $orig_uri) = @_;
 452         my $sec = uri_section($orig_uri);
 453         my $mbx = $orig_uri->mailbox;
 454         $mic->Clear(1); # trim results history
 455         $mic->examine($mbx) or return "E: EXAMINE $mbx ($sec) failed: $!";
 456         my ($r_uidval, $r_uidnext);
 457         for ($mic->Results) {
 458                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 459                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 460                 last if $r_uidval && $r_uidnext;
 461         }
 462         $r_uidval //= $mic->uidvalidity($mbx) //
 463                 return "E: $orig_uri cannot get UIDVALIDITY";
 464         $r_uidnext //= $mic->uidnext($mbx) //
 465                 return "E: $orig_uri cannot get UIDNEXT";
 466         my $expect = $orig_uri->uidvalidity // $r_uidval;
 467         return <<EOF if $expect != $r_uidval;
 468 E: $orig_uri UIDVALIDITY mismatch (got $r_uidval)
 469 EOF
 470
 471         my $uri = $orig_uri->clone;
 472         my ($itrk, $l_uid, $l_uidval) = itrk_last($self, $uri, $r_uidval, $mic);
 473         return <<EOF if $l_uidval != $r_uidval;
 474 E: $uri UIDVALIDITY mismatch
 475 E: local=$l_uidval != remote=$r_uidval
 476 EOF
 477         $uri->uidvalidity($r_uidval);
 478         $l_uid //= 0;
 479         my $r_uid = $r_uidnext - 1;
 480         return <<EOF if $l_uid > $r_uid;
 481 E: $uri local UID exceeds remote ($l_uid > $r_uid)
 482 E: $uri strangely, UIDVALIDLITY matches ($l_uidval)
 483 EOF
 484         return if $l_uid >= $r_uid; # nothing to do
 485         $l_uid ||= 1;
 486         my ($mod, $shard) = @{$self->{shard_info} // []};
 487         unless ($self->{quiet}) {
 488                 my $m = $mod ? " [(UID % $mod) == $shard]" : '';
 489                 warn "# $uri fetching UID $l_uid:$r_uid$m\n";
 490         }
 491         $mic->Uid(1); # the default, we hope
 492         my $bs = $self->{imap_opt}->{$sec}->{batch_size} // 1;
 493         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 494         my $key = $req;
 495         $key =~ s/\.PEEK//;
 496         my ($uids, $batch);
 497         my $err;
 498         do {
 499                 # I wish "UID FETCH $START:*" could work, but:
 500                 # 1) servers do not need to return results in any order
 501                 # 2) Mail::IMAPClient doesn't offer a streaming API
 502                 unless ($uids = $mic->search("UID $l_uid:*")) {
 503                         return if $!{EINTR} && $self->{quit};
 504                         return "E: $uri UID SEARCH $l_uid:* error: $!";
 505                 }
 506                 return if scalar(@$uids) == 0;
 507
 508                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 509                 # responses, so sort it ourselves.  Order matters so
 510                 # IMAPTracker can store the newest UID.
 511                 @$uids = sort { $a <=> $b } @$uids;
 512
 513                 # Did we actually get new messages?
 514                 return if $uids->[0] < $l_uid;
 515
 516                 $l_uid = $uids->[-1] + 1; # for next search
 517                 my $last_uid;
 518                 my $n = $self->{max_batch};
 519
 520                 @$uids = grep { ($_ % $mod) == $shard } @$uids if $mod;
 521                 while (scalar @$uids) {
 522                         my @batch = splice(@$uids, 0, $bs);
 523                         $batch = join(',', @batch);
 524                         local $0 = "UID:$batch $mbx $sec";
 525                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 526                         unless ($r) { # network error?
 527                                 last if $!{EINTR} && $self->{quit};
 528                                 $err = "E: $uri UID FETCH $batch error: $!";
 529                                 last;
 530                         }
 531                         for my $uid (@batch) {
 532                                 # messages get deleted, so holes appear
 533                                 my $per_uid = delete $r->{$uid} // next;
 534                                 my $raw = delete($per_uid->{$key}) // next;
 535                                 _imap_do_msg($self, $$uri, $uid, \$raw,
 536                                                 $per_uid->{FLAGS});
 537                                 $last_uid = $uid;
 538                                 last if $self->{quit};
 539                         }
 540                         last if $self->{quit};
 541                 }
 542                 run_commit_cb($self);
 543                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 544         } until ($err || $self->{quit});
 545         $err;
 546 }
 547
 548 # uses cached auth info prepared by mic_for
 549 sub mic_get {
 550         my ($self, $uri) = @_;
 551         my $sec = uri_section($uri);
 552         # see if caller saved result of imap_common_init
 553         my $cached = $self->{mics_cached};
 554         if ($cached) {
 555                 my $mic = $cached->{$sec};
 556                 return $mic if $mic && $mic->IsConnected;
 557                 delete $cached->{$sec};
 558         }
 559         my $mic_arg = $self->{mic_arg}->{$sec} or
 560                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 561         if (defined(my $cb_name = $mic_arg->{Authcallback})) {
 562                 if (ref($cb_name) ne 'CODE') {
 563                         $mic_arg->{Authcallback} = $self->can($cb_name);
 564                 }
 565         }
 566         my $mic = mic_new($self, $mic_arg, $sec, $uri);
 567         $cached //= {}; # invalid placeholder if no cache enabled
 568         $mic && $mic->IsConnected ? ($cached->{$sec} = $mic) : undef;
 569 }
 570
 571 sub imap_each {
 572         my ($self, $url, $eml_cb, @args) = @_;
 573         my $uri = ref($url) ? $url : PublicInbox::URIimap->new($url);
 574         my $sec = uri_section($uri);
 575         local $0 = $uri->mailbox." $sec";
 576         my $mic = mic_get($self, $uri);
 577         my $err;
 578         if ($mic) {
 579                 local $self->{eml_each} = [ $eml_cb, @args ];
 580                 $err = _imap_fetch_all($self, $mic, $uri);
 581         } else {
 582                 $err = "E: <$uri> not connected: $!";
 583         }
 584         die $err if $err && $self->{-can_die};
 585         warn $err if $err;
 586         $mic;
 587 }
 588
 589 # may used cached auth info prepared by nn_for once
 590 sub nn_get {
 591         my ($self, $uri) = @_;
 592         my $sec = uri_section($uri);
 593         # see if caller saved result of nntp_common_init
 594         my $cached = $self->{nn_cached} // {};
 595         my $nn;
 596         $nn = delete($cached->{$sec}) and return $nn;
 597         my $nn_arg = $self->{nn_arg}->{$sec} or
 598                         die "BUG: no Net::NNTP->new arg for $sec";
 599         my $nntp_opt = $self->{nntp_opt}->{$sec};
 600         $nn = nn_new($nn_arg, $nntp_opt, $uri) or return;
 601         if (my $postconn = $nntp_opt->{-postconn}) {
 602                 for my $m_arg (@$postconn) {
 603                         my ($method, @args) = @$m_arg;
 604                         $nn->$method(@args) and next;
 605                         die "E: <$uri> $method failed\n";
 606                         return;
 607                 }
 608         }
 609         $nn;
 610 }
 611
 612 sub _nntp_fetch_all ($$$) {
 613         my ($self, $nn, $uri) = @_;
 614         my ($group, $num_a, $num_b) = $uri->group;
 615         my $sec = uri_section($uri);
 616         my ($nr, $beg, $end) = $nn->group($group);
 617         unless (defined($nr)) {
 618                 my $msg = ndump($nn->message);
 619                 return "E: GROUP $group <$sec> $msg";
 620         }
 621
 622         # IMAPTracker is also used for tracking NNTP, UID == article number
 623         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 624         # expensive.  So we assume newsgroups don't change:
 625         my ($itrk, $l_art) = itrk_last($self, $uri);
 626
 627         # allow users to specify articles to refetch
 628         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 629         # nntp://example.com/inbox.foo/$num_a-$num_b
 630         $beg = $num_a if defined($num_a) && $num_a < $beg;
 631         $end = $num_b if defined($num_b) && $num_b < $end;
 632         if (defined $l_art) {
 633                 return if $l_art >= $end; # nothing to do
 634                 $beg = $l_art + 1;
 635         }
 636         my ($err, $art, $last_art, $kw); # kw stays undef, no keywords in NNTP
 637         unless ($self->{quiet}) {
 638                 warn "# $uri fetching ARTICLE $beg..$end\n";
 639         }
 640         my $n = $self->{max_batch};
 641         my $url = $$uri;
 642         for ($beg..$end) {
 643                 last if $self->{quit};
 644                 $art = $_;
 645                 if (--$n < 0) {
 646                         run_commit_cb($self);
 647                         $itrk->update_last(0, $last_art) if $itrk;
 648                         $n = $self->{max_batch};
 649                 }
 650                 my $raw = $nn->article($art);
 651                 unless (defined($raw)) {
 652                         my $msg = ndump($nn->message);
 653                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 654                                 $err = "E: $msg";
 655                                 last;
 656                         } else { # probably just a deleted message (spam)
 657                                 warn "W: $msg";
 658                                 next;
 659                         }
 660                 }
 661                 $raw = join('', @$raw);
 662                 $raw =~ s/\r\n/\n/sg;
 663                 my ($eml_cb, @args) = @{$self->{eml_each}};
 664                 $eml_cb->($url, $art, $kw, PublicInbox::Eml->new(\$raw), @args);
 665                 $last_art = $art;
 666         }
 667         run_commit_cb($self);
 668         $itrk->update_last(0, $last_art) if $itrk;
 669         $err;
 670 }
 671
 672 sub nntp_each {
 673         my ($self, $url, $eml_cb, @args) = @_;
 674         my $uri = ref($url) ? $url : PublicInbox::URInntps->new($url);
 675         my $sec = uri_section($uri);
 676         local $0 = $uri->group ." $sec";
 677         my $nn = nn_get($self, $uri);
 678         return if $self->{quit};
 679         my $err;
 680         if ($nn) {
 681                 local $self->{eml_each} = [ $eml_cb, @args ];
 682                 $err = _nntp_fetch_all($self, $nn, $uri);
 683         } else {
 684                 $err = "E: <$uri> not connected: $!";
 685         }
 686         die $err if $err && $self->{-can_die};
 687         warn $err if $err;
 688         $nn;
 689 }
 690
 691 sub new { bless {}, shift };
 692
 693 1;