lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Config;
  11 our %IMAPflags2kw = map {; "\\\u$_" => $_ } qw(seen answered flagged draft);
  12 $IMAPflags2kw{'$Forwarded'} = 'forwarded';  # RFC 5550
  13
  14 our @EXPORT = qw(uri_section imap_uri nntp_uri);
  15
  16 sub ndump {
  17         require Data::Dumper;
  18         Data::Dumper->new(\@_)->Useqq(1)->Terse(1)->Dump;
  19 }
  20
  21 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  22 # without the mailbox, so we can share connections between different inboxes
  23 sub uri_section ($) {
  24         my ($uri) = @_;
  25         $uri->scheme . '://' . $uri->authority;
  26 }
  27
  28 sub socks_args ($) {
  29         my ($val) = @_;
  30         return if ($val // '') eq '';
  31         if ($val =~ m!\Asocks5h:// (?: \[ ([^\]]+) \] | ([^:/]+) )
  32                                         (?::([0-9]+))?/*\z!ix) {
  33                 my ($h, $p) = ($1 // $2, $3 + 0);
  34                 $h = '127.0.0.1' if $h eq '0';
  35                 eval { require IO::Socket::Socks } or die <<EOM;
  36 IO::Socket::Socks missing for socks5h://$h:$p
  37 EOM
  38                 return { ProxyAddr => $h, ProxyPort => $p };
  39         }
  40         die "$val not understood (only socks5h:// is supported)\n";
  41 }
  42
  43 sub mic_new ($$$$) {
  44         my ($self, $mic_arg, $sec, $uri) = @_;
  45         my %mic_arg = %$mic_arg;
  46         my $sa = $self->{cfg_opt}->{$sec}->{-proxy_cfg} || $self->{-proxy_cli};
  47         if ($sa) {
  48                 my %opt = %$sa;
  49                 $opt{ConnectAddr} = delete $mic_arg{Server};
  50                 $opt{ConnectPort} = delete $mic_arg{Port};
  51                 $mic_arg{Socket} = IO::Socket::Socks->new(%opt) or die
  52                         "E: <$$uri> ".eval('$IO::Socket::Socks::SOCKS_ERROR');
  53         }
  54         PublicInbox::IMAPClient->new(%mic_arg, Keepalive => 1);
  55 }
  56
  57 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  58
  59 # mic_for may prompt the user and store auth info, prepares mic_get
  60 sub mic_for ($$$$) { # mic = Mail::IMAPClient
  61         my ($self, $uri, $mic_args, $lei) = @_;
  62         require PublicInbox::GitCredential;
  63         my $cred = bless {
  64                 url => "$uri",
  65                 protocol => $uri->scheme,
  66                 host => $uri->host,
  67                 username => $uri->user,
  68                 password => $uri->password,
  69         }, 'PublicInbox::GitCredential';
  70         my $sec = uri_section($uri);
  71         my $common = $mic_args->{$sec} // {};
  72         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
  73         my $host = $cred->{host};
  74         $host = '127.0.0.1' if $host eq '0';
  75         my $mic_arg = {
  76                 Port => $uri->port,
  77                 Server => $host,
  78                 Ssl => $uri->scheme eq 'imaps',
  79                 %$common, # may set Starttls, Compress, Debug ....
  80         };
  81         $mic_arg->{Ssl} = 1 if $uri->scheme eq 'imaps';
  82         require PublicInbox::IMAPClient;
  83         my $mic = mic_new($self, $mic_arg, $sec, $uri) or
  84                         die "E: <$uri> new: $@\n";
  85         # default to using STARTTLS if it's available, but allow
  86         # it to be disabled since I usually connect to localhost
  87         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
  88                         $mic->has_capability('STARTTLS') &&
  89                         $mic->can('starttls')) {
  90                 $mic->starttls or die "E: <$uri> STARTTLS: $@\n";
  91         }
  92
  93         # do we even need credentials?
  94         if (!defined($cred->{username}) &&
  95                         $mic->has_capability('AUTH=ANONYMOUS')) {
  96                 $cred = undef;
  97         }
  98         if ($cred) {
  99                 my $p = $cred->{password} // $cred->check_netrc;
 100                 $cred->fill($lei) unless defined($p); # may prompt user here
 101                 $mic->User($mic_arg->{User} = $cred->{username});
 102                 $mic->Password($mic_arg->{Password} = $cred->{password});
 103         } else { # AUTH=ANONYMOUS
 104                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
 105                 $mic_arg->{Authcallback} = 'auth_anon_cb';
 106                 $mic->Authcallback(\&auth_anon_cb);
 107         }
 108         my $err;
 109         if ($mic->login && $mic->IsAuthenticated) {
 110                 # success! keep IMAPClient->new arg in case we get disconnected
 111                 $self->{net_arg}->{$sec} = $mic_arg;
 112                 if ($cred) {
 113                         $uri->user($cred->{username}) if !defined($uri->user);
 114                 } elsif ($mic_arg->{Authmechanism} eq 'ANONYMOUS') {
 115                         $uri->auth('ANONYMOUS') if !defined($uri->auth);
 116                 }
 117         } else {
 118                 $err = "E: <$uri> LOGIN: $@\n";
 119                 if ($cred && defined($cred->{password})) {
 120                         $err =~ s/\Q$cred->{password}\E/*******/g;
 121                 }
 122                 $mic = undef;
 123         }
 124         $cred->run($mic ? 'approve' : 'reject') if $cred && $cred->{filled};
 125         if ($err) {
 126                 $lei ? $lei->fail($err) : warn($err);
 127         }
 128         $mic;
 129 }
 130
 131 # Net::NNTP doesn't support CAPABILITIES, yet
 132 sub try_starttls ($) {
 133         my ($host) = @_;
 134         return if $host =~ /\.onion\z/s;
 135         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 136         return if $host eq '::1';
 137         1;
 138 }
 139
 140 sub nn_new ($$$) {
 141         my ($nn_arg, $nntp_cfg, $uri) = @_;
 142         my $nn;
 143         if (defined $nn_arg->{ProxyAddr}) {
 144                 require PublicInbox::NetNNTPSocks;
 145                 eval { $nn = PublicInbox::NetNNTPSocks->new_socks(%$nn_arg) };
 146                 die "E: <$uri> $@\n" if $@;
 147         } else {
 148                 $nn = Net::NNTP->new(%$nn_arg) or die "E: <$uri> new: $!\n";
 149         }
 150
 151         # default to using STARTTLS if it's available, but allow
 152         # it to be disabled for localhost/VPN users
 153         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 154                 if (!defined($nntp_cfg->{starttls}) &&
 155                                 try_starttls($nn_arg->{Host})) {
 156                         # soft fail by default
 157                         $nn->starttls or warn <<"";
 158 W: <$uri> STARTTLS tried and failed (not requested)
 159
 160                 } elsif ($nntp_cfg->{starttls}) {
 161                         # hard fail if explicitly configured
 162                         $nn->starttls or die <<"";
 163 E: <$uri> STARTTLS requested and failed
 164
 165                 }
 166         } elsif ($nntp_cfg->{starttls}) {
 167                 $nn->can('starttls') or
 168                         die "E: <$uri> Net::NNTP too old for STARTTLS\n";
 169                 $nn->starttls or die <<"";
 170 E: <$uri> STARTTLS requested and failed
 171
 172         }
 173         $nn;
 174 }
 175
 176 sub nn_for ($$$$) { # nn = Net::NNTP
 177         my ($self, $uri, $nn_args, $lei) = @_;
 178         my $sec = uri_section($uri);
 179         my $nntp_cfg = $self->{cfg_opt}->{$sec} //= {};
 180         my $host = $uri->host;
 181         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 182         $host = '127.0.0.1' if $host eq '0';
 183         my $cred;
 184         my ($u, $p);
 185         if (defined(my $ui = $uri->userinfo)) {
 186                 require PublicInbox::GitCredential;
 187                 $cred = bless {
 188                         url => $sec,
 189                         protocol => $uri->scheme,
 190                         host => $host,
 191                 }, 'PublicInbox::GitCredential';
 192                 ($u, $p) = split(/:/, $ui, 2);
 193                 ($cred->{username}, $cred->{password}) = ($u, $p);
 194                 $p //= $cred->check_netrc;
 195         }
 196         my $common = $nn_args->{$sec} // {};
 197         my $nn_arg = {
 198                 Port => $uri->port,
 199                 Host => $host,
 200                 %$common, # may Debug ....
 201         };
 202         $nn_arg->{SSL} = 1 if $uri->secure; # snews == nntps
 203         my $sa = $self->{-proxy_cli};
 204         %$nn_arg = (%$nn_arg, %$sa) if $sa;
 205         my $nn = nn_new($nn_arg, $nntp_cfg, $uri);
 206         if ($cred) {
 207                 $cred->fill($lei) unless defined($p); # may prompt user here
 208                 if ($nn->authinfo($u, $p)) {
 209                         push @{$nntp_cfg->{-postconn}}, [ 'authinfo', $u, $p ];
 210                 } else {
 211                         warn "E: <$uri> AUTHINFO $u XXXX failed\n";
 212                         $nn = undef;
 213                 }
 214         }
 215
 216         if ($nntp_cfg->{compress}) {
 217                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 218                 if ($nn->can('compress')) {
 219                         if ($nn->compress) {
 220                                 push @{$nntp_cfg->{-postconn}}, [ 'compress' ];
 221                         } else {
 222                                 warn "W: <$uri> COMPRESS failed\n";
 223                         }
 224                 } else {
 225                         delete $nntp_cfg->{compress};
 226                         warn <<"";
 227 W: <$uri> COMPRESS not supported by Net::NNTP
 228 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 229
 230                 }
 231         }
 232
 233         $self->{net_arg}->{$sec} = $nn_arg;
 234         $cred->run($nn ? 'approve' : 'reject') if $cred && $cred->{filled};
 235         $nn;
 236 }
 237
 238 sub imap_uri {
 239         my ($url, $ls_ok) = @_;
 240         require PublicInbox::URIimap;
 241         my $uri = PublicInbox::URIimap->new($url);
 242         $uri && ($ls_ok || $uri->mailbox) ? $uri->canonical : undef;
 243 }
 244
 245 my %IS_NNTP = (news => 1, snews => 1, nntp => 1, nntps => 1);
 246 sub nntp_uri {
 247         my ($url, $ls_ok) = @_;
 248         require PublicInbox::URInntps;
 249         my $uri = PublicInbox::URInntps->new($url);
 250         $uri && $IS_NNTP{$uri->scheme} && ($ls_ok || $uri->group) ?
 251                 $uri->canonical : undef;
 252 }
 253
 254 sub cfg_intvl ($$$) {
 255         my ($cfg, $key, $url) = @_;
 256         my $v = $cfg->urlmatch($key, $url) // return;
 257         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 258         if (ref($v) eq 'ARRAY') {
 259                 $v = join(', ', @$v);
 260                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 261         } else {
 262                 warn "W: $key=$v is not a numeric value in seconds\n";
 263         }
 264 }
 265
 266 sub cfg_bool ($$$) {
 267         my ($cfg, $key, $url) = @_;
 268         my $orig = $cfg->urlmatch($key, $url) // return;
 269         my $bool = $cfg->git_bool($orig);
 270         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 271         $bool;
 272 }
 273
 274 # flesh out common IMAP-specific data structures
 275 sub imap_common_init ($;$) {
 276         my ($self, $lei) = @_;
 277         return unless $self->{imap_order};
 278         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 279         eval { require PublicInbox::IMAPClient } or
 280                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 281         ($lei || eval { require PublicInbox::IMAPTracker }) or
 282                 die "DBD::SQLite is required for IMAP\n:$@\n";
 283         require PublicInbox::URIimap;
 284         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 285         my $mic_args = {}; # scheme://authority => Mail:IMAPClient arg
 286         for my $uri (@{$self->{imap_order}}) {
 287                 my $sec = uri_section($uri);
 288                 for my $k (qw(Starttls Debug Compress)) {
 289                         my $bool = cfg_bool($cfg, "imap.$k", $$uri) // next;
 290                         $mic_args->{$sec}->{$k} = $bool;
 291                 }
 292                 my $to = cfg_intvl($cfg, 'imap.timeout', $$uri);
 293                 $mic_args->{$sec}->{Timeout} = $to if $to;
 294                 my $sa = socks_args($cfg->urlmatch('imap.Proxy', $$uri));
 295                 $self->{cfg_opt}->{$sec}->{-proxy_cfg} = $sa if $sa;
 296                 for my $k (qw(pollInterval idleInterval)) {
 297                         $to = cfg_intvl($cfg, "imap.$k", $$uri) // next;
 298                         $self->{cfg_opt}->{$sec}->{$k} = $to;
 299                 }
 300                 my $k = 'imap.fetchBatchSize';
 301                 my $bs = $cfg->urlmatch($k, $$uri) // next;
 302                 if ($bs =~ /\A([0-9]+)\z/) {
 303                         $self->{cfg_opt}->{$sec}->{batch_size} = $bs;
 304                 } else {
 305                         warn "$k=$bs is not an integer\n";
 306                 }
 307         }
 308         # make sure we can connect and cache the credentials in memory
 309         my $mics = {}; # schema://authority => IMAPClient obj
 310         for my $orig_uri (@{$self->{imap_order}}) {
 311                 my $sec = uri_section($orig_uri);
 312                 my $uri = PublicInbox::URIimap->new("$sec/");
 313                 my $mic = $mics->{$sec} //=
 314                                 mic_for($self, $uri, $mic_args, $lei) //
 315                                 die "Unable to continue\n";
 316                 next unless $self->isa('PublicInbox::NetWriter');
 317                 my $dst = $orig_uri->mailbox // next;
 318                 next if $mic->exists($dst); # already exists
 319                 $mic->create($dst) or die "CREATE $dst failed <$orig_uri>: $@";
 320         }
 321         $mics;
 322 }
 323
 324 # flesh out common NNTP-specific data structures
 325 sub nntp_common_init ($;$) {
 326         my ($self, $lei) = @_;
 327         return unless $self->{nntp_order};
 328         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 329         eval { require Net::NNTP } or
 330                 die "Net::NNTP is required for NNTP:\n$@\n";
 331         ($lei || eval { require PublicInbox::IMAPTracker }) or
 332                 die "DBD::SQLite is required for NNTP\n:$@\n";
 333         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 334         my $nn_args = {}; # scheme://authority => Net::NNTP->new arg
 335         for my $uri (@{$self->{nntp_order}}) {
 336                 my $sec = uri_section($uri);
 337                 my $args = $nn_args->{$sec} //= {};
 338
 339                 # Debug and Timeout are passed to Net::NNTP->new
 340                 my $v = cfg_bool($cfg, 'nntp.Debug', $$uri);
 341                 $args->{Debug} = $v if defined $v;
 342                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $$uri);
 343                 $args->{Timeout} = $to if $to;
 344                 my $sa = socks_args($cfg->urlmatch('nntp.Proxy', $$uri));
 345                 %$args = (%$args, %$sa) if $sa;
 346
 347                 # Net::NNTP post-connect commands
 348                 for my $k (qw(starttls compress)) {
 349                         $v = cfg_bool($cfg, "nntp.$k", $$uri) // next;
 350                         $self->{cfg_opt}->{$sec}->{$k} = $v;
 351                 }
 352
 353                 # -watch internal option
 354                 for my $k (qw(pollInterval)) {
 355                         $to = cfg_intvl($cfg, "nntp.$k", $$uri) // next;
 356                         $self->{cfg_opt}->{$sec}->{$k} = $to;
 357                 }
 358         }
 359         # make sure we can connect and cache the credentials in memory
 360         my %nn; # schema://authority => Net::NNTP object
 361         for my $uri (@{$self->{nntp_order}}) {
 362                 my $sec = uri_section($uri);
 363                 $nn{$sec} //= nn_for($self, $uri, $nn_args, $lei);
 364         }
 365         \%nn; # for optional {nn_cached}
 366 }
 367
 368 sub add_url {
 369         my ($self, $arg, $ls_ok) = @_;
 370         my $uri;
 371         if ($uri = imap_uri($arg, $ls_ok)) {
 372                 $_[1] = $$uri; # canonicalized
 373                 push @{$self->{imap_order}}, $uri;
 374         } elsif ($uri = nntp_uri($arg, $ls_ok)) {
 375                 $_[1] = $$uri; # canonicalized
 376                 push @{$self->{nntp_order}}, $uri;
 377         } else {
 378                 push @{$self->{unsupported_url}}, $arg;
 379         }
 380 }
 381
 382 sub errors {
 383         my ($self, $lei) = @_;
 384         if (my $u = $self->{unsupported_url}) {
 385                 return "Unsupported URL(s): @$u";
 386         }
 387         if ($self->{imap_order}) {
 388                 eval { require PublicInbox::IMAPClient } or
 389                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 390         }
 391         if ($self->{nntp_order}) {
 392                 eval { require Net::NNTP } or
 393                         die "Net::NNTP is required for NNTP:\n$@\n";
 394         }
 395         my $sa = socks_args($lei ? $lei->{opt}->{proxy} : undef);
 396         $self->{-proxy_cli} = $sa if $sa;
 397         undef;
 398 }
 399
 400 sub flags2kw ($$$$) {
 401         my ($self, $uri, $uid, $flags) = @_;
 402         my $kw = [];
 403         for my $f (split(/ /, $flags)) {
 404                 if (my $k = $IMAPflags2kw{$f}) {
 405                         push @$kw, $k;
 406                 } elsif ($f eq "\\Recent") { # not in JMAP
 407                 } elsif ($f eq "\\Deleted") { # not in JMAP
 408                         return;
 409                 } elsif ($self->{verbose}) {
 410                         warn "# unknown IMAP flag $f <$uri/;UID=$uid>\n";
 411                 }
 412         }
 413         @$kw = sort @$kw; # for LeiSearch->kw_changed and UI/UX purposes
 414         $kw;
 415 }
 416
 417 sub _imap_do_msg ($$$$$) {
 418         my ($self, $uri, $uid, $raw, $flags) = @_;
 419         # our target audience expects LF-only, save storage
 420         $$raw =~ s/\r\n/\n/sg;
 421         my $kw = defined($flags) ?
 422                 (flags2kw($self, $uri, $uid, $flags) // return) : undef;
 423         my ($eml_cb, @args) = @{$self->{eml_each}};
 424         $eml_cb->($uri, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 425 }
 426
 427 sub run_commit_cb ($) {
 428         my ($self) = @_;
 429         my $cmt_cb_args = $self->{on_commit} or return;
 430         my ($cb, @args) = @$cmt_cb_args;
 431         $cb->(@args);
 432 }
 433
 434 sub itrk_last ($$;$$) {
 435         my ($self, $uri, $r_uidval, $mic) = @_;
 436         return (undef, undef, $r_uidval) unless $self->{incremental};
 437         my ($itrk, $l_uid, $l_uidval);
 438         if (defined(my $lms = $self->{-lms_ro})) { # LeiMailSync or 0
 439                 $uri->uidvalidity($r_uidval) if defined $r_uidval;
 440                 if ($mic) {
 441                         my $auth = $mic->Authmechanism // '';
 442                         $uri->auth($auth) if $auth eq 'ANONYMOUS';
 443                         my $user = $mic->User;
 444                         $uri->user($user) if defined($user);
 445                 }
 446                 my $x;
 447                 $l_uid = ($lms && ($x = $lms->location_stats($$uri))) ?
 448                                 $x->{'uid.max'} : undef;
 449                 # itrk remains undef, lei/store worker writes to
 450                 # mail_sync.sqlite3
 451         } else {
 452                 $itrk = PublicInbox::IMAPTracker->new($$uri);
 453                 ($l_uidval, $l_uid) = $itrk->get_last($$uri);
 454         }
 455         ($itrk, $l_uid, $l_uidval //= $r_uidval);
 456 }
 457
 458 # import flags of already-seen messages
 459 sub each_old_flags ($$$$) {
 460         my ($self, $mic, $uri, $l_uid) = @_;
 461         $l_uid ||= 1;
 462         my $sec = uri_section($uri);
 463         my $bs = ($self->{cfg_opt}->{$sec}->{batch_size} // 1) * 10000;
 464         my ($eml_cb, @args) = @{$self->{eml_each}};
 465         $self->{quiet} or warn "# $uri syncing flags 1:$l_uid\n";
 466         for (my $n = 1; $n <= $l_uid; $n += $bs) {
 467                 my $end = $n + $bs;
 468                 $end = $l_uid if $end > $l_uid;
 469                 my $r = $mic->fetch_hash("$n:$end", 'FLAGS');
 470                 if (!$r) {
 471                         return if $!{EINTR} && $self->{quit};
 472                         return "E: $uri UID FETCH $n:$end error: $!";
 473                 }
 474                 while (my ($uid, $per_uid) = each %$r) {
 475                         my $kw = flags2kw($self, $uri, $uid, $per_uid->{FLAGS})
 476                                 // next;
 477                         # LeiImport->input_net_cb
 478                         $eml_cb->($uri, $uid, $kw, undef, @args);
 479                 }
 480         }
 481 }
 482
 483 # returns true if PERMANENTFLAGS indicates FLAGS of already imported
 484 # messages are meaningful
 485 sub perm_fl_ok ($) {
 486         my ($perm_fl) = @_;
 487         return if !defined($perm_fl);
 488         for my $f (split(/[ \t]+/, $perm_fl)) {
 489                 return 1 if $IMAPflags2kw{$f};
 490         }
 491         undef;
 492 }
 493
 494 # may be overridden in NetWriter or Watch
 495 sub folder_select { $_[0]->{each_old} ? 'select' : 'examine' }
 496
 497 sub _imap_fetch_all ($$$) {
 498         my ($self, $mic, $orig_uri) = @_;
 499         my $sec = uri_section($orig_uri);
 500         my $mbx = $orig_uri->mailbox;
 501         $mic->Clear(1); # trim results history
 502
 503         # we need to check for mailbox writability to see if we care about
 504         # FLAGS from already-imported messages.
 505         my $cmd = $self->folder_select;
 506         $mic->$cmd($mbx) or return "E: \U$cmd\E $mbx ($sec) failed: $!";
 507
 508         my ($r_uidval, $r_uidnext, $perm_fl);
 509         for ($mic->Results) {
 510                 /^\* OK \[PERMANENTFLAGS \(([^\)]*)\)\].*/ and $perm_fl = $1;
 511                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 512                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 513         }
 514         $r_uidval //= $mic->uidvalidity($mbx) //
 515                 return "E: $orig_uri cannot get UIDVALIDITY";
 516         $r_uidnext //= $mic->uidnext($mbx) //
 517                 return "E: $orig_uri cannot get UIDNEXT";
 518         my $expect = $orig_uri->uidvalidity // $r_uidval;
 519         return <<EOF if $expect != $r_uidval;
 520 E: $orig_uri UIDVALIDITY mismatch (got $r_uidval)
 521 EOF
 522
 523         my $uri = $orig_uri->clone;
 524         my $single_uid = $uri->uid;
 525         my ($itrk, $l_uid, $l_uidval) = itrk_last($self, $uri, $r_uidval, $mic);
 526         if (defined($single_uid)) {
 527                 $itrk = $l_uid = undef;
 528                 $uri->uid(undef); # for eml_cb
 529         }
 530         return <<EOF if $l_uidval != $r_uidval;
 531 E: $uri UIDVALIDITY mismatch
 532 E: local=$l_uidval != remote=$r_uidval
 533 EOF
 534         $uri->uidvalidity($r_uidval);
 535         $l_uid //= 0;
 536         my $r_uid = $r_uidnext - 1;
 537         return <<EOF if $l_uid > $r_uid;
 538 E: $uri local UID exceeds remote ($l_uid > $r_uid)
 539 E: $uri strangely, UIDVALIDLITY matches ($l_uidval)
 540 EOF
 541         $mic->Uid(1); # the default, we hope
 542         my $err;
 543         my $use_fl = perm_fl_ok($perm_fl);
 544         if (!defined($single_uid) && $self->{each_old} && $use_fl) {
 545                 $err = each_old_flags($self, $mic, $uri, $l_uid);
 546                 return $err if $err;
 547         }
 548         return if $l_uid >= $r_uid; # nothing to do
 549         $l_uid ||= 1;
 550         my ($mod, $shard) = @{$self->{shard_info} // []};
 551         unless ($self->{quiet}) {
 552                 my $m = $mod ? " [(UID % $mod) == $shard]" : '';
 553                 warn "# $uri fetching UID $l_uid:$r_uid$m\n";
 554         }
 555         my $bs = $self->{cfg_opt}->{$sec}->{batch_size} // 1;
 556         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 557         my $key = $req;
 558         $key =~ s/\.PEEK//;
 559         my ($uids, $batch);
 560         do {
 561                 # I wish "UID FETCH $START:*" could work, but:
 562                 # 1) servers do not need to return results in any order
 563                 # 2) Mail::IMAPClient doesn't offer a streaming API
 564                 if (defined $single_uid) {
 565                         $uids = [ $single_uid ];
 566                 } elsif (!($uids = $mic->search("UID $l_uid:*"))) {
 567                         return if $!{EINTR} && $self->{quit};
 568                         return "E: $uri UID SEARCH $l_uid:* error: $!";
 569                 }
 570                 return if scalar(@$uids) == 0;
 571
 572                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 573                 # responses, so sort it ourselves.  Order matters so
 574                 # IMAPTracker can store the newest UID.
 575                 @$uids = sort { $a <=> $b } @$uids;
 576
 577                 # Did we actually get new messages?
 578                 return if $uids->[0] < $l_uid;
 579
 580                 $l_uid = $uids->[-1] + 1; # for next search
 581                 my $last_uid;
 582                 my $n = $self->{max_batch};
 583
 584                 @$uids = grep { ($_ % $mod) == $shard } @$uids if $mod;
 585                 while (scalar @$uids) {
 586                         my @batch = splice(@$uids, 0, $bs);
 587                         $batch = join(',', @batch);
 588                         local $0 = "UID:$batch $mbx $sec";
 589                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 590                         unless ($r) { # network error?
 591                                 last if $!{EINTR} && $self->{quit};
 592                                 $err = "E: $uri UID FETCH $batch error: $!";
 593                                 last;
 594                         }
 595                         for my $uid (@batch) {
 596                                 # messages get deleted, so holes appear
 597                                 my $per_uid = delete $r->{$uid} // next;
 598                                 my $raw = delete($per_uid->{$key}) // next;
 599                                 my $fl = $use_fl ? $per_uid->{FLAGS} : undef;
 600                                 _imap_do_msg($self, $uri, $uid, \$raw, $fl);
 601                                 $last_uid = $uid;
 602                                 last if $self->{quit};
 603                         }
 604                         last if $self->{quit};
 605                 }
 606                 run_commit_cb($self);
 607                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 608         } until ($err || $self->{quit} || defined($single_uid));
 609         $err;
 610 }
 611
 612 # uses cached auth info prepared by mic_for
 613 sub mic_get {
 614         my ($self, $uri) = @_;
 615         my $sec = uri_section($uri);
 616         # see if caller saved result of imap_common_init
 617         my $cached = $self->{mics_cached};
 618         if ($cached) {
 619                 my $mic = $cached->{$sec};
 620                 return $mic if $mic && $mic->IsConnected;
 621                 delete $cached->{$sec};
 622         }
 623         my $mic_arg = $self->{net_arg}->{$sec} or
 624                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 625         if (defined(my $cb_name = $mic_arg->{Authcallback})) {
 626                 if (ref($cb_name) ne 'CODE') {
 627                         $mic_arg->{Authcallback} = $self->can($cb_name);
 628                 }
 629         }
 630         my $mic = mic_new($self, $mic_arg, $sec, $uri);
 631         $cached //= {}; # invalid placeholder if no cache enabled
 632         $mic && $mic->IsConnected ? ($cached->{$sec} = $mic) : undef;
 633 }
 634
 635 sub imap_each {
 636         my ($self, $url, $eml_cb, @args) = @_;
 637         my $uri = ref($url) ? $url : PublicInbox::URIimap->new($url);
 638         my $sec = uri_section($uri);
 639         local $0 = $uri->mailbox." $sec";
 640         my $mic = mic_get($self, $uri);
 641         my $err;
 642         if ($mic) {
 643                 local $self->{eml_each} = [ $eml_cb, @args ];
 644                 $err = _imap_fetch_all($self, $mic, $uri);
 645         } else {
 646                 $err = "E: <$uri> not connected: $!";
 647         }
 648         die $err if $err && $self->{-can_die};
 649         warn $err if $err;
 650         $mic;
 651 }
 652
 653 # may used cached auth info prepared by nn_for once
 654 sub nn_get {
 655         my ($self, $uri) = @_;
 656         my $sec = uri_section($uri);
 657         # see if caller saved result of nntp_common_init
 658         my $cached = $self->{nn_cached} // {};
 659         my $nn;
 660         $nn = delete($cached->{$sec}) and return $nn;
 661         my $nn_arg = $self->{net_arg}->{$sec} or
 662                         die "BUG: no Net::NNTP->new arg for $sec";
 663         my $nntp_cfg = $self->{cfg_opt}->{$sec};
 664         $nn = nn_new($nn_arg, $nntp_cfg, $uri) or return;
 665         if (my $postconn = $nntp_cfg->{-postconn}) {
 666                 for my $m_arg (@$postconn) {
 667                         my ($method, @args) = @$m_arg;
 668                         $nn->$method(@args) and next;
 669                         die "E: <$uri> $method failed\n";
 670                         return;
 671                 }
 672         }
 673         $nn;
 674 }
 675
 676 sub _nntp_fetch_all ($$$) {
 677         my ($self, $nn, $uri) = @_;
 678         my ($group, $num_a, $num_b) = $uri->group;
 679         my $sec = uri_section($uri);
 680         my ($nr, $beg, $end) = $nn->group($group);
 681         unless (defined($nr)) {
 682                 my $msg = ndump($nn->message);
 683                 return "E: GROUP $group <$sec> $msg";
 684         }
 685
 686         # IMAPTracker is also used for tracking NNTP, UID == article number
 687         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 688         # expensive.  So we assume newsgroups don't change:
 689         my ($itrk, $l_art) = itrk_last($self, $uri);
 690
 691         # allow users to specify articles to refetch
 692         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 693         # nntp://example.com/inbox.foo/$num_a-$num_b
 694         $beg = $num_a if defined($num_a) && $num_a < $beg;
 695         $end = $num_b if defined($num_b) && $num_b < $end;
 696         if (defined $l_art) {
 697                 return if $l_art >= $end; # nothing to do
 698                 $beg = $l_art + 1;
 699         }
 700         my ($err, $art, $last_art, $kw); # kw stays undef, no keywords in NNTP
 701         unless ($self->{quiet}) {
 702                 warn "# $uri fetching ARTICLE $beg..$end\n";
 703         }
 704         my $n = $self->{max_batch};
 705         for ($beg..$end) {
 706                 last if $self->{quit};
 707                 $art = $_;
 708                 if (--$n < 0) {
 709                         run_commit_cb($self);
 710                         $itrk->update_last(0, $last_art) if $itrk;
 711                         $n = $self->{max_batch};
 712                 }
 713                 my $raw = $nn->article($art);
 714                 unless (defined($raw)) {
 715                         my $msg = ndump($nn->message);
 716                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 717                                 $err = "E: $msg";
 718                                 last;
 719                         } else { # probably just a deleted message (spam)
 720                                 warn "W: $msg";
 721                                 next;
 722                         }
 723                 }
 724                 $raw = join('', @$raw);
 725                 $raw =~ s/\r\n/\n/sg;
 726                 my ($eml_cb, @args) = @{$self->{eml_each}};
 727                 $eml_cb->($uri, $art, $kw, PublicInbox::Eml->new(\$raw), @args);
 728                 $last_art = $art;
 729         }
 730         run_commit_cb($self);
 731         $itrk->update_last(0, $last_art) if $itrk;
 732         $err;
 733 }
 734
 735 sub nntp_each {
 736         my ($self, $url, $eml_cb, @args) = @_;
 737         my $uri = ref($url) ? $url : PublicInbox::URInntps->new($url);
 738         my $sec = uri_section($uri);
 739         local $0 = $uri->group ." $sec";
 740         my $nn = nn_get($self, $uri);
 741         return if $self->{quit};
 742         my $err;
 743         if ($nn) {
 744                 local $self->{eml_each} = [ $eml_cb, @args ];
 745                 $err = _nntp_fetch_all($self, $nn, $uri);
 746         } else {
 747                 $err = "E: <$uri> not connected: $!";
 748         }
 749         die $err if $err && $self->{-can_die};
 750         warn $err if $err;
 751         $nn;
 752 }
 753
 754 sub new { bless {}, shift };
 755
 756 # updates $uri with UIDVALIDITY
 757 sub mic_for_folder {
 758         my ($self, $uri) = @_;
 759         my $mic = $self->mic_get($uri) or die "E: not connected: $@";
 760         my $m = $self->isa('PublicInbox::NetWriter') ? 'select' : 'examine';
 761         $mic->$m($uri->mailbox) or return;
 762         my $uidval;
 763         for ($mic->Results) {
 764                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ or next;
 765                 $uidval = $1;
 766                 last;
 767         }
 768         $uidval //= $mic->uidvalidity($uri->mailbox) or
 769                 die "E: failed to get uidvalidity from <$uri>: $@";
 770         $uri->uidvalidity($uidval);
 771         $mic;
 772 }
 773
 774
 775 1;