lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Config;
  11 our %IMAPflags2kw = map {; "\\\u$_" => $_ } qw(seen answered flagged draft);
  12 $IMAPflags2kw{'$Forwarded'} = 'forwarded';  # RFC 5550
  13
  14 our @EXPORT = qw(uri_section imap_uri nntp_uri);
  15
  16 sub ndump {
  17         require Data::Dumper;
  18         Data::Dumper->new(\@_)->Useqq(1)->Terse(1)->Dump;
  19 }
  20
  21 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  22 # without the mailbox, so we can share connections between different inboxes
  23 sub uri_section ($) {
  24         my ($uri) = @_;
  25         $uri->scheme . '://' . $uri->authority;
  26 }
  27
  28 sub socks_args ($) {
  29         my ($val) = @_;
  30         return if ($val // '') eq '';
  31         if ($val =~ m!\Asocks5h:// (?: \[ ([^\]]+) \] | ([^:/]+) )
  32                                         (?::([0-9]+))?/*\z!ix) {
  33                 my ($h, $p) = ($1 // $2, $3 + 0);
  34                 $h = '127.0.0.1' if $h eq '0';
  35                 eval { require IO::Socket::Socks } or die <<EOM;
  36 IO::Socket::Socks missing for socks5h://$h:$p
  37 EOM
  38                 return { ProxyAddr => $h, ProxyPort => $p };
  39         }
  40         die "$val not understood (only socks5h:// is supported)\n";
  41 }
  42
  43 sub mic_new ($$$$) {
  44         my ($self, $mic_arg, $sec, $uri) = @_;
  45         my %socks;
  46         my $sa = $self->{imap_opt}->{$sec}->{-proxy_cfg} || $self->{-proxy_cli};
  47         if ($sa) {
  48                 my %opt = %$sa;
  49                 $opt{ConnectAddr} = delete $mic_arg->{Server};
  50                 $opt{ConnectPort} = delete $mic_arg->{Port};
  51                 $socks{Socket} = IO::Socket::Socks->new(%opt) or die
  52                         "E: <$$uri> ".eval('$IO::Socket::Socks::SOCKS_ERROR');
  53         }
  54         PublicInbox::IMAPClient->new(%$mic_arg, %socks);
  55 }
  56
  57 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  58
  59 # mic_for may prompt the user and store auth info, prepares mic_get
  60 sub mic_for ($$$$) { # mic = Mail::IMAPClient
  61         my ($self, $uri, $mic_args, $lei) = @_;
  62         require PublicInbox::GitCredential;
  63         my $cred = bless {
  64                 url => "$uri",
  65                 protocol => $uri->scheme,
  66                 host => $uri->host,
  67                 username => $uri->user,
  68                 password => $uri->password,
  69         }, 'PublicInbox::GitCredential';
  70         my $sec = uri_section($uri);
  71         my $common = $mic_args->{$sec} // {};
  72         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
  73         my $host = $cred->{host};
  74         $host = '127.0.0.1' if $host eq '0';
  75         my $mic_arg = {
  76                 Port => $uri->port,
  77                 Server => $host,
  78                 Ssl => $uri->scheme eq 'imaps',
  79                 Keepalive => 1, # SO_KEEPALIVE
  80                 %$common, # may set Starttls, Compress, Debug ....
  81         };
  82         require PublicInbox::IMAPClient;
  83         my $mic = mic_new($self, $mic_arg, $sec, $uri) or
  84                         die "E: <$uri> new: $@\n";
  85         # default to using STARTTLS if it's available, but allow
  86         # it to be disabled since I usually connect to localhost
  87         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
  88                         $mic->has_capability('STARTTLS') &&
  89                         $mic->can('starttls')) {
  90                 $mic->starttls or die "E: <$uri> STARTTLS: $@\n";
  91         }
  92
  93         # do we even need credentials?
  94         if (!defined($cred->{username}) &&
  95                         $mic->has_capability('AUTH=ANONYMOUS')) {
  96                 $cred = undef;
  97         }
  98         if ($cred) {
  99                 $cred->check_netrc unless defined $cred->{password};
 100                 $cred->fill($lei); # may prompt user here
 101                 $mic->User($mic_arg->{User} = $cred->{username});
 102                 $mic->Password($mic_arg->{Password} = $cred->{password});
 103         } else { # AUTH=ANONYMOUS
 104                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
 105                 $mic_arg->{Authcallback} = 'auth_anon_cb';
 106                 $mic->Authcallback(\&auth_anon_cb);
 107         }
 108         my $err;
 109         if ($mic->login && $mic->IsAuthenticated) {
 110                 # success! keep IMAPClient->new arg in case we get disconnected
 111                 $self->{mic_arg}->{$sec} = $mic_arg;
 112                 if ($cred) {
 113                         $uri->user($cred->{username}) if !defined($uri->user);
 114                 } elsif ($mic_arg->{Authmechanism} eq 'ANONYMOUS') {
 115                         $uri->auth('ANONYMOUS') if !defined($uri->auth);
 116                 }
 117         } else {
 118                 $err = "E: <$uri> LOGIN: $@\n";
 119                 if ($cred && defined($cred->{password})) {
 120                         $err =~ s/\Q$cred->{password}\E/*******/g;
 121                 }
 122                 $mic = undef;
 123         }
 124         $cred->run($mic ? 'approve' : 'reject') if $cred;
 125         if ($err) {
 126                 $lei ? $lei->fail($err) : warn($err);
 127         }
 128         $mic;
 129 }
 130
 131 # Net::NNTP doesn't support CAPABILITIES, yet
 132 sub try_starttls ($) {
 133         my ($host) = @_;
 134         return if $host =~ /\.onion\z/s;
 135         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 136         return if $host eq '::1';
 137         1;
 138 }
 139
 140 sub nn_new ($$$) {
 141         my ($nn_arg, $nntp_opt, $uri) = @_;
 142         my $nn;
 143         if (defined $nn_arg->{ProxyAddr}) {
 144                 require PublicInbox::NetNNTPSocks;
 145                 eval { $nn = PublicInbox::NetNNTPSocks->new_socks(%$nn_arg) };
 146                 die "E: <$uri> $@\n" if $@;
 147         } else {
 148                 $nn = Net::NNTP->new(%$nn_arg) or die "E: <$uri> new: $!\n";
 149         }
 150
 151         # default to using STARTTLS if it's available, but allow
 152         # it to be disabled for localhost/VPN users
 153         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 154                 if (!defined($nntp_opt->{starttls}) &&
 155                                 try_starttls($nn_arg->{Host})) {
 156                         # soft fail by default
 157                         $nn->starttls or warn <<"";
 158 W: <$uri> STARTTLS tried and failed (not requested)
 159
 160                 } elsif ($nntp_opt->{starttls}) {
 161                         # hard fail if explicitly configured
 162                         $nn->starttls or die <<"";
 163 E: <$uri> STARTTLS requested and failed
 164
 165                 }
 166         } elsif ($nntp_opt->{starttls}) {
 167                 $nn->can('starttls') or
 168                         die "E: <$uri> Net::NNTP too old for STARTTLS\n";
 169                 $nn->starttls or die <<"";
 170 E: <$uri> STARTTLS requested and failed
 171
 172         }
 173         $nn;
 174 }
 175
 176 sub nn_for ($$$$) { # nn = Net::NNTP
 177         my ($self, $uri, $nn_args, $lei) = @_;
 178         my $sec = uri_section($uri);
 179         my $nntp_opt = $self->{nntp_opt}->{$sec} //= {};
 180         my $host = $uri->host;
 181         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 182         $host = '127.0.0.1' if $host eq '0';
 183         my $cred;
 184         my ($u, $p);
 185         if (defined(my $ui = $uri->userinfo)) {
 186                 require PublicInbox::GitCredential;
 187                 $cred = bless {
 188                         url => $sec,
 189                         protocol => $uri->scheme,
 190                         host => $host,
 191                 }, 'PublicInbox::GitCredential';
 192                 ($u, $p) = split(/:/, $ui, 2);
 193                 ($cred->{username}, $cred->{password}) = ($u, $p);
 194                 $cred->check_netrc unless defined $p;
 195         }
 196         my $common = $nn_args->{$sec} // {};
 197         my $nn_arg = {
 198                 Port => $uri->port,
 199                 Host => $host,
 200                 SSL => $uri->secure, # snews == nntps
 201                 %$common, # may Debug ....
 202         };
 203         my $sa = $self->{-proxy_cli};
 204         %$nn_arg = (%$nn_arg, %$sa) if $sa;
 205         my $nn = nn_new($nn_arg, $nntp_opt, $uri);
 206         if ($cred) {
 207                 $cred->fill($lei); # may prompt user here
 208                 if ($nn->authinfo($u, $p)) {
 209                         push @{$nntp_opt->{-postconn}}, [ 'authinfo', $u, $p ];
 210                 } else {
 211                         warn "E: <$uri> AUTHINFO $u XXXX failed\n";
 212                         $nn = undef;
 213                 }
 214         }
 215
 216         if ($nntp_opt->{compress}) {
 217                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 218                 if ($nn->can('compress')) {
 219                         if ($nn->compress) {
 220                                 push @{$nntp_opt->{-postconn}}, [ 'compress' ];
 221                         } else {
 222                                 warn "W: <$uri> COMPRESS failed\n";
 223                         }
 224                 } else {
 225                         delete $nntp_opt->{compress};
 226                         warn <<"";
 227 W: <$uri> COMPRESS not supported by Net::NNTP
 228 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 229
 230                 }
 231         }
 232
 233         $self->{nn_arg}->{$sec} = $nn_arg;
 234         $cred->run($nn ? 'approve' : 'reject') if $cred;
 235         $nn;
 236 }
 237
 238 sub imap_uri {
 239         my ($url) = @_;
 240         require PublicInbox::URIimap;
 241         my $uri = PublicInbox::URIimap->new($url);
 242         $uri ? $uri->canonical : undef;
 243 }
 244
 245 my %IS_NNTP = (news => 1, snews => 1, nntp => 1, nntps => 1);
 246 sub nntp_uri {
 247         my ($url) = @_;
 248         require PublicInbox::URInntps;
 249         my $uri = PublicInbox::URInntps->new($url);
 250         $uri && $IS_NNTP{$uri->scheme} && $uri->group ? $uri->canonical : undef;
 251 }
 252
 253 sub cfg_intvl ($$$) {
 254         my ($cfg, $key, $url) = @_;
 255         my $v = $cfg->urlmatch($key, $url) // return;
 256         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 257         if (ref($v) eq 'ARRAY') {
 258                 $v = join(', ', @$v);
 259                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 260         } else {
 261                 warn "W: $key=$v is not a numeric value in seconds\n";
 262         }
 263 }
 264
 265 sub cfg_bool ($$$) {
 266         my ($cfg, $key, $url) = @_;
 267         my $orig = $cfg->urlmatch($key, $url) // return;
 268         my $bool = $cfg->git_bool($orig);
 269         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 270         $bool;
 271 }
 272
 273 # flesh out common IMAP-specific data structures
 274 sub imap_common_init ($;$) {
 275         my ($self, $lei) = @_;
 276         return unless $self->{imap_order};
 277         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 278         eval { require PublicInbox::IMAPClient } or
 279                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 280         ($lei || eval { require PublicInbox::IMAPTracker }) or
 281                 die "DBD::SQLite is required for IMAP\n:$@\n";
 282         require PublicInbox::URIimap;
 283         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 284         my $mic_args = {}; # scheme://authority => Mail:IMAPClient arg
 285         for my $uri (@{$self->{imap_order}}) {
 286                 my $sec = uri_section($uri);
 287                 for my $k (qw(Starttls Debug Compress)) {
 288                         my $bool = cfg_bool($cfg, "imap.$k", $$uri) // next;
 289                         $mic_args->{$sec}->{$k} = $bool;
 290                 }
 291                 my $to = cfg_intvl($cfg, 'imap.timeout', $$uri);
 292                 $mic_args->{$sec}->{Timeout} = $to if $to;
 293                 my $sa = socks_args($cfg->urlmatch('imap.Proxy', $$uri));
 294                 $self->{imap_opt}->{$sec}->{-proxy_cfg} = $sa if $sa;
 295                 for my $k (qw(pollInterval idleInterval)) {
 296                         $to = cfg_intvl($cfg, "imap.$k", $$uri) // next;
 297                         $self->{imap_opt}->{$sec}->{$k} = $to;
 298                 }
 299                 my $k = 'imap.fetchBatchSize';
 300                 my $bs = $cfg->urlmatch($k, $$uri) // next;
 301                 if ($bs =~ /\A([0-9]+)\z/) {
 302                         $self->{imap_opt}->{$sec}->{batch_size} = $bs;
 303                 } else {
 304                         warn "$k=$bs is not an integer\n";
 305                 }
 306         }
 307         # make sure we can connect and cache the credentials in memory
 308         $self->{mic_arg} = {}; # schema://authority => IMAPClient->new args
 309         my $mics = {}; # schema://authority => IMAPClient obj
 310         for my $orig_uri (@{$self->{imap_order}}) {
 311                 my $sec = uri_section($orig_uri);
 312                 my $uri = PublicInbox::URIimap->new("$sec/");
 313                 my $mic = $mics->{$sec} //=
 314                                 mic_for($self, $uri, $mic_args, $lei) //
 315                                 die "Unable to continue\n";
 316                 next unless $self->isa('PublicInbox::NetWriter');
 317                 my $dst = $orig_uri->mailbox // next;
 318                 next if $mic->exists($dst); # already exists
 319                 $mic->create($dst) or die "CREATE $dst failed <$orig_uri>: $@";
 320         }
 321         $mics;
 322 }
 323
 324 # flesh out common NNTP-specific data structures
 325 sub nntp_common_init ($;$) {
 326         my ($self, $lei) = @_;
 327         return unless $self->{nntp_order};
 328         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 329         eval { require Net::NNTP } or
 330                 die "Net::NNTP is required for NNTP:\n$@\n";
 331         ($lei || eval { require PublicInbox::IMAPTracker }) or
 332                 die "DBD::SQLite is required for NNTP\n:$@\n";
 333         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 334         my $nn_args = {}; # scheme://authority => Net::NNTP->new arg
 335         for my $uri (@{$self->{nntp_order}}) {
 336                 my $sec = uri_section($uri);
 337                 my $args = $nn_args->{$sec} //= {};
 338
 339                 # Debug and Timeout are passed to Net::NNTP->new
 340                 my $v = cfg_bool($cfg, 'nntp.Debug', $$uri);
 341                 $args->{Debug} = $v if defined $v;
 342                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $$uri);
 343                 $args->{Timeout} = $to if $to;
 344                 my $sa = socks_args($cfg->urlmatch('nntp.Proxy', $$uri));
 345                 %$args = (%$args, %$sa) if $sa;
 346
 347                 # Net::NNTP post-connect commands
 348                 for my $k (qw(starttls compress)) {
 349                         $v = cfg_bool($cfg, "nntp.$k", $$uri) // next;
 350                         $self->{nntp_opt}->{$sec}->{$k} = $v;
 351                 }
 352
 353                 # -watch internal option
 354                 for my $k (qw(pollInterval)) {
 355                         $to = cfg_intvl($cfg, "nntp.$k", $$uri) // next;
 356                         $self->{nntp_opt}->{$sec}->{$k} = $to;
 357                 }
 358         }
 359         # make sure we can connect and cache the credentials in memory
 360         $self->{nn_arg} = {}; # schema://authority => Net::NNTP->new args
 361         my %nn; # schema://authority => Net::NNTP object
 362         for my $uri (@{$self->{nntp_order}}) {
 363                 my $sec = uri_section($uri);
 364                 $nn{$sec} //= nn_for($self, $uri, $nn_args, $lei);
 365         }
 366         \%nn; # for optional {nn_cached}
 367 }
 368
 369 sub add_url {
 370         my ($self, $arg) = @_;
 371         my $uri;
 372         if ($uri = imap_uri($arg)) {
 373                 push @{$self->{imap_order}}, $uri;
 374         } elsif ($uri = nntp_uri($arg)) {
 375                 push @{$self->{nntp_order}}, $uri;
 376         } else {
 377                 push @{$self->{unsupported_url}}, $arg;
 378         }
 379 }
 380
 381 sub errors {
 382         my ($self, $lei) = @_;
 383         if (my $u = $self->{unsupported_url}) {
 384                 return "Unsupported URL(s): @$u";
 385         }
 386         if ($self->{imap_order}) {
 387                 eval { require PublicInbox::IMAPClient } or
 388                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 389         }
 390         if ($self->{nntp_order}) {
 391                 eval { require Net::NNTP } or
 392                         die "Net::NNTP is required for NNTP:\n$@\n";
 393         }
 394         my $sa = socks_args($lei ? $lei->{opt}->{proxy} : undef);
 395         $self->{-proxy_cli} = $sa if $sa;
 396         undef;
 397 }
 398
 399 sub _imap_do_msg ($$$$$) {
 400         my ($self, $uri, $uid, $raw, $flags) = @_;
 401         # our target audience expects LF-only, save storage
 402         $$raw =~ s/\r\n/\n/sg;
 403         my $kw = [];
 404         for my $f (split(/ /, $flags)) {
 405                 if (my $k = $IMAPflags2kw{$f}) {
 406                         push @$kw, $k;
 407                 } elsif ($f eq "\\Recent") { # not in JMAP
 408                 } elsif ($f eq "\\Deleted") { # not in JMAP
 409                         return;
 410                 } elsif ($self->{verbose}) {
 411                         warn "# unknown IMAP flag $f <$uri/;UID=$uid>\n";
 412                 }
 413         }
 414         @$kw = sort @$kw; # for all UI/UX purposes
 415         my ($eml_cb, @args) = @{$self->{eml_each}};
 416         $eml_cb->($uri, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 417 }
 418
 419 sub run_commit_cb ($) {
 420         my ($self) = @_;
 421         my $cmt_cb_args = $self->{on_commit} or return;
 422         my ($cb, @args) = @$cmt_cb_args;
 423         $cb->(@args);
 424 }
 425
 426 sub itrk_last ($$;$$) {
 427         my ($self, $uri, $r_uidval, $mic) = @_;
 428         return (undef, undef, $r_uidval) unless $self->{incremental};
 429         my ($itrk, $l_uid, $l_uidval);
 430         if (defined(my $lms = $self->{-lms_ro})) { # LeiMailSync or 0
 431                 $uri->uidvalidity($r_uidval) if defined $r_uidval;
 432                 if ($mic) {
 433                         my $auth = $mic->Authmechanism // '';
 434                         $uri->auth($auth) if $auth eq 'ANONYMOUS';
 435                         my $user = $mic->User;
 436                         $uri->user($user) if defined($user);
 437                 }
 438                 my $x;
 439                 $l_uid = ($lms && ($x = $lms->location_stats($$uri))) ?
 440                                 $x->{'uid.max'} : undef;
 441                 # itrk remains undef, lei/store worker writes to
 442                 # mail_sync.sqlite3
 443         } else {
 444                 $itrk = PublicInbox::IMAPTracker->new($$uri);
 445                 ($l_uidval, $l_uid) = $itrk->get_last($$uri);
 446         }
 447         ($itrk, $l_uid, $l_uidval //= $r_uidval);
 448 }
 449
 450 sub _imap_fetch_all ($$$) {
 451         my ($self, $mic, $orig_uri) = @_;
 452         my $sec = uri_section($orig_uri);
 453         my $mbx = $orig_uri->mailbox;
 454         $mic->Clear(1); # trim results history
 455         $mic->examine($mbx) or return "E: EXAMINE $mbx ($sec) failed: $!";
 456         my ($r_uidval, $r_uidnext);
 457         for ($mic->Results) {
 458                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 459                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 460                 last if $r_uidval && $r_uidnext;
 461         }
 462         $r_uidval //= $mic->uidvalidity($mbx) //
 463                 return "E: $orig_uri cannot get UIDVALIDITY";
 464         $r_uidnext //= $mic->uidnext($mbx) //
 465                 return "E: $orig_uri cannot get UIDNEXT";
 466         my $expect = $orig_uri->uidvalidity // $r_uidval;
 467         return <<EOF if $expect != $r_uidval;
 468 E: $orig_uri UIDVALIDITY mismatch (got $r_uidval)
 469 EOF
 470
 471         my $uri = $orig_uri->clone;
 472         my $single_uid = $uri->uid;
 473         my ($itrk, $l_uid, $l_uidval) = itrk_last($self, $uri, $r_uidval, $mic);
 474         if (defined($single_uid)) {
 475                 $itrk = $l_uid = undef;
 476                 $uri->uid(undef); # for eml_cb
 477         }
 478         return <<EOF if $l_uidval != $r_uidval;
 479 E: $uri UIDVALIDITY mismatch
 480 E: local=$l_uidval != remote=$r_uidval
 481 EOF
 482         $uri->uidvalidity($r_uidval);
 483         $l_uid //= 0;
 484         my $r_uid = $r_uidnext - 1;
 485         return <<EOF if $l_uid > $r_uid;
 486 E: $uri local UID exceeds remote ($l_uid > $r_uid)
 487 E: $uri strangely, UIDVALIDLITY matches ($l_uidval)
 488 EOF
 489         return if $l_uid >= $r_uid; # nothing to do
 490         $l_uid ||= 1;
 491         my ($mod, $shard) = @{$self->{shard_info} // []};
 492         unless ($self->{quiet}) {
 493                 my $m = $mod ? " [(UID % $mod) == $shard]" : '';
 494                 warn "# $uri fetching UID $l_uid:$r_uid$m\n";
 495         }
 496         $mic->Uid(1); # the default, we hope
 497         my $bs = $self->{imap_opt}->{$sec}->{batch_size} // 1;
 498         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 499         my $key = $req;
 500         $key =~ s/\.PEEK//;
 501         my ($uids, $batch);
 502         my $err;
 503         do {
 504                 # I wish "UID FETCH $START:*" could work, but:
 505                 # 1) servers do not need to return results in any order
 506                 # 2) Mail::IMAPClient doesn't offer a streaming API
 507                 if (defined $single_uid) {
 508                         $uids = [ $single_uid ];
 509                 } elsif (!($uids = $mic->search("UID $l_uid:*"))) {
 510                         return if $!{EINTR} && $self->{quit};
 511                         return "E: $uri UID SEARCH $l_uid:* error: $!";
 512                 }
 513                 return if scalar(@$uids) == 0;
 514
 515                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 516                 # responses, so sort it ourselves.  Order matters so
 517                 # IMAPTracker can store the newest UID.
 518                 @$uids = sort { $a <=> $b } @$uids;
 519
 520                 # Did we actually get new messages?
 521                 return if $uids->[0] < $l_uid;
 522
 523                 $l_uid = $uids->[-1] + 1; # for next search
 524                 my $last_uid;
 525                 my $n = $self->{max_batch};
 526
 527                 @$uids = grep { ($_ % $mod) == $shard } @$uids if $mod;
 528                 while (scalar @$uids) {
 529                         my @batch = splice(@$uids, 0, $bs);
 530                         $batch = join(',', @batch);
 531                         local $0 = "UID:$batch $mbx $sec";
 532                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 533                         unless ($r) { # network error?
 534                                 last if $!{EINTR} && $self->{quit};
 535                                 $err = "E: $uri UID FETCH $batch error: $!";
 536                                 last;
 537                         }
 538                         for my $uid (@batch) {
 539                                 # messages get deleted, so holes appear
 540                                 my $per_uid = delete $r->{$uid} // next;
 541                                 my $raw = delete($per_uid->{$key}) // next;
 542                                 _imap_do_msg($self, $uri, $uid, \$raw,
 543                                                 $per_uid->{FLAGS});
 544                                 $last_uid = $uid;
 545                                 last if $self->{quit};
 546                         }
 547                         last if $self->{quit};
 548                 }
 549                 run_commit_cb($self);
 550                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 551         } until ($err || $self->{quit} || defined($single_uid));
 552         $err;
 553 }
 554
 555 # uses cached auth info prepared by mic_for
 556 sub mic_get {
 557         my ($self, $uri) = @_;
 558         my $sec = uri_section($uri);
 559         # see if caller saved result of imap_common_init
 560         my $cached = $self->{mics_cached};
 561         if ($cached) {
 562                 my $mic = $cached->{$sec};
 563                 return $mic if $mic && $mic->IsConnected;
 564                 delete $cached->{$sec};
 565         }
 566         my $mic_arg = $self->{mic_arg}->{$sec} or
 567                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 568         if (defined(my $cb_name = $mic_arg->{Authcallback})) {
 569                 if (ref($cb_name) ne 'CODE') {
 570                         $mic_arg->{Authcallback} = $self->can($cb_name);
 571                 }
 572         }
 573         my $mic = mic_new($self, $mic_arg, $sec, $uri);
 574         $cached //= {}; # invalid placeholder if no cache enabled
 575         $mic && $mic->IsConnected ? ($cached->{$sec} = $mic) : undef;
 576 }
 577
 578 sub imap_each {
 579         my ($self, $url, $eml_cb, @args) = @_;
 580         my $uri = ref($url) ? $url : PublicInbox::URIimap->new($url);
 581         my $sec = uri_section($uri);
 582         local $0 = $uri->mailbox." $sec";
 583         my $mic = mic_get($self, $uri);
 584         my $err;
 585         if ($mic) {
 586                 local $self->{eml_each} = [ $eml_cb, @args ];
 587                 $err = _imap_fetch_all($self, $mic, $uri);
 588         } else {
 589                 $err = "E: <$uri> not connected: $!";
 590         }
 591         die $err if $err && $self->{-can_die};
 592         warn $err if $err;
 593         $mic;
 594 }
 595
 596 # may used cached auth info prepared by nn_for once
 597 sub nn_get {
 598         my ($self, $uri) = @_;
 599         my $sec = uri_section($uri);
 600         # see if caller saved result of nntp_common_init
 601         my $cached = $self->{nn_cached} // {};
 602         my $nn;
 603         $nn = delete($cached->{$sec}) and return $nn;
 604         my $nn_arg = $self->{nn_arg}->{$sec} or
 605                         die "BUG: no Net::NNTP->new arg for $sec";
 606         my $nntp_opt = $self->{nntp_opt}->{$sec};
 607         $nn = nn_new($nn_arg, $nntp_opt, $uri) or return;
 608         if (my $postconn = $nntp_opt->{-postconn}) {
 609                 for my $m_arg (@$postconn) {
 610                         my ($method, @args) = @$m_arg;
 611                         $nn->$method(@args) and next;
 612                         die "E: <$uri> $method failed\n";
 613                         return;
 614                 }
 615         }
 616         $nn;
 617 }
 618
 619 sub _nntp_fetch_all ($$$) {
 620         my ($self, $nn, $uri) = @_;
 621         my ($group, $num_a, $num_b) = $uri->group;
 622         my $sec = uri_section($uri);
 623         my ($nr, $beg, $end) = $nn->group($group);
 624         unless (defined($nr)) {
 625                 my $msg = ndump($nn->message);
 626                 return "E: GROUP $group <$sec> $msg";
 627         }
 628
 629         # IMAPTracker is also used for tracking NNTP, UID == article number
 630         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 631         # expensive.  So we assume newsgroups don't change:
 632         my ($itrk, $l_art) = itrk_last($self, $uri);
 633
 634         # allow users to specify articles to refetch
 635         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 636         # nntp://example.com/inbox.foo/$num_a-$num_b
 637         $beg = $num_a if defined($num_a) && $num_a < $beg;
 638         $end = $num_b if defined($num_b) && $num_b < $end;
 639         if (defined $l_art) {
 640                 return if $l_art >= $end; # nothing to do
 641                 $beg = $l_art + 1;
 642         }
 643         my ($err, $art, $last_art, $kw); # kw stays undef, no keywords in NNTP
 644         unless ($self->{quiet}) {
 645                 warn "# $uri fetching ARTICLE $beg..$end\n";
 646         }
 647         my $n = $self->{max_batch};
 648         for ($beg..$end) {
 649                 last if $self->{quit};
 650                 $art = $_;
 651                 if (--$n < 0) {
 652                         run_commit_cb($self);
 653                         $itrk->update_last(0, $last_art) if $itrk;
 654                         $n = $self->{max_batch};
 655                 }
 656                 my $raw = $nn->article($art);
 657                 unless (defined($raw)) {
 658                         my $msg = ndump($nn->message);
 659                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 660                                 $err = "E: $msg";
 661                                 last;
 662                         } else { # probably just a deleted message (spam)
 663                                 warn "W: $msg";
 664                                 next;
 665                         }
 666                 }
 667                 $raw = join('', @$raw);
 668                 $raw =~ s/\r\n/\n/sg;
 669                 my ($eml_cb, @args) = @{$self->{eml_each}};
 670                 $eml_cb->($uri, $art, $kw, PublicInbox::Eml->new(\$raw), @args);
 671                 $last_art = $art;
 672         }
 673         run_commit_cb($self);
 674         $itrk->update_last(0, $last_art) if $itrk;
 675         $err;
 676 }
 677
 678 sub nntp_each {
 679         my ($self, $url, $eml_cb, @args) = @_;
 680         my $uri = ref($url) ? $url : PublicInbox::URInntps->new($url);
 681         my $sec = uri_section($uri);
 682         local $0 = $uri->group ." $sec";
 683         my $nn = nn_get($self, $uri);
 684         return if $self->{quit};
 685         my $err;
 686         if ($nn) {
 687                 local $self->{eml_each} = [ $eml_cb, @args ];
 688                 $err = _nntp_fetch_all($self, $nn, $uri);
 689         } else {
 690                 $err = "E: <$uri> not connected: $!";
 691         }
 692         die $err if $err && $self->{-can_die};
 693         warn $err if $err;
 694         $nn;
 695 }
 696
 697 sub new { bless {}, shift };
 698
 699 1;