lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Config;
  11 our %IMAPflags2kw = map {; "\\\u$_" => $_ } qw(seen answered flagged draft);
  12 $IMAPflags2kw{'$Forwarded'} = 'forwarded';  # RFC 5550
  13
  14 our @EXPORT = qw(uri_section imap_uri nntp_uri);
  15
  16 sub ndump {
  17         require Data::Dumper;
  18         Data::Dumper->new(\@_)->Useqq(1)->Terse(1)->Dump;
  19 }
  20
  21 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  22 # without the mailbox, so we can share connections between different inboxes
  23 sub uri_section ($) {
  24         my ($uri) = @_;
  25         $uri->scheme . '://' . $uri->authority;
  26 }
  27
  28 sub socks_args ($) {
  29         my ($val) = @_;
  30         return if ($val // '') eq '';
  31         if ($val =~ m!\Asocks5h:// (?: \[ ([^\]]+) \] | ([^:/]+) )
  32                                         (?::([0-9]+))?/*\z!ix) {
  33                 my ($h, $p) = ($1 // $2, $3 + 0);
  34                 $h = '127.0.0.1' if $h eq '0';
  35                 eval { require IO::Socket::Socks } or die <<EOM;
  36 IO::Socket::Socks missing for socks5h://$h:$p
  37 EOM
  38                 # for IO::Socket::Socks
  39                 return { ProxyAddr => $h, ProxyPort => $p };
  40         }
  41         die "$val not understood (only socks5h:// is supported)\n";
  42 }
  43
  44 sub mic_new ($$$$) {
  45         my ($self, $mic_arg, $sec, $uri) = @_;
  46         my %mic_arg = %$mic_arg;
  47         my $sa = $self->{cfg_opt}->{$sec}->{-proxy_cfg} || $self->{-proxy_cli};
  48         if ($sa) {
  49                 # this `require' needed for worker[1..Inf], since socks_args
  50                 # only got called in worker[0]
  51                 require IO::Socket::Socks;
  52
  53                 my %opt = %$sa;
  54                 $opt{SocksDebug} = 1 if $mic_arg{Debug};
  55                 $opt{ConnectAddr} = delete $mic_arg{Server};
  56                 $opt{ConnectPort} = delete $mic_arg{Port};
  57                 $mic_arg{Socket} = IO::Socket::Socks->new(%opt) or die
  58                         "E: <$$uri> ".eval('$IO::Socket::Socks::SOCKS_ERROR');
  59         }
  60         PublicInbox::IMAPClient->new(%mic_arg, Keepalive => 1);
  61 }
  62
  63 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  64
  65 sub onion_hint ($$) {
  66         my ($lei, $uri) = @_;
  67         $uri->host =~ /\.onion\z/i or return "\n";
  68         my $t = $uri->isa('PublicInbox::URIimap') ? 'imap' : 'nntp';
  69         my $url = uri_section($uri);
  70         my $set_cfg = 'lei config';
  71         if (!$lei) { # public-inbox-watch
  72                 my $f = $ENV{PI_CONFIG} || '~/.public-inbox/config';
  73                 $set_cfg = "git config -f $f";
  74         }
  75         <<EOM
  76
  77 Assuming you have Tor configured and running locally on port 9050,
  78 try configuring a socks5h:// proxy:
  79
  80         url=$url
  81         $set_cfg $t.\$url.proxy socks5h://127.0.0.1:9050
  82
  83 ...before retrying your current command
  84 EOM
  85 }
  86
  87 # mic_for may prompt the user and store auth info, prepares mic_get
  88 sub mic_for ($$$$) { # mic = Mail::IMAPClient
  89         my ($self, $uri, $mic_common, $lei) = @_;
  90         require PublicInbox::GitCredential;
  91         my $cred = bless {
  92                 url => "$uri",
  93                 protocol => $uri->scheme,
  94                 host => $uri->host,
  95                 username => $uri->user,
  96                 password => $uri->password,
  97         }, 'PublicInbox::GitCredential';
  98         my $sec = uri_section($uri);
  99         my $common = $mic_common->{$sec} // {};
 100         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
 101         my $host = $cred->{host};
 102         $host = '127.0.0.1' if $host eq '0';
 103         my $mic_arg = {
 104                 Port => $uri->port,
 105                 Server => $host,
 106                 Ssl => $uri->scheme eq 'imaps',
 107                 %$common, # may set Starttls, Compress, Debug ....
 108         };
 109         $mic_arg->{Ssl} = 1 if $uri->scheme eq 'imaps';
 110         require PublicInbox::IMAPClient;
 111         my $mic = mic_new($self, $mic_arg, $sec, $uri);
 112         ($mic && $mic->IsConnected) or
 113                 die "E: <$uri> new: $@".onion_hint($lei, $uri);
 114
 115         # default to using STARTTLS if it's available, but allow
 116         # it to be disabled since I usually connect to localhost
 117         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
 118                         $mic->has_capability('STARTTLS') &&
 119                         $mic->can('starttls')) {
 120                 $mic->starttls or die "E: <$uri> STARTTLS: $@\n";
 121         }
 122
 123         # do we even need credentials?
 124         if (!defined($cred->{username}) &&
 125                         $mic->has_capability('AUTH=ANONYMOUS')) {
 126                 $cred = undef;
 127         }
 128         if ($cred) {
 129                 my $p = $cred->{password} // $cred->check_netrc($lei);
 130                 $cred->fill($lei) unless defined($p); # may prompt user here
 131                 $mic->User($mic_arg->{User} = $cred->{username});
 132                 $mic->Password($mic_arg->{Password} = $cred->{password});
 133         } else { # AUTH=ANONYMOUS
 134                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
 135                 $mic_arg->{Authcallback} = 'auth_anon_cb';
 136                 $mic->Authcallback(\&auth_anon_cb);
 137         }
 138         my $err;
 139         if ($mic->login && $mic->IsAuthenticated) {
 140                 # success! keep IMAPClient->new arg in case we get disconnected
 141                 $self->{net_arg}->{$sec} = $mic_arg;
 142                 if ($cred) {
 143                         $uri->user($cred->{username}) if !defined($uri->user);
 144                 } elsif ($mic_arg->{Authmechanism} eq 'ANONYMOUS') {
 145                         $uri->auth('ANONYMOUS') if !defined($uri->auth);
 146                 }
 147         } else {
 148                 $err = "E: <$uri> LOGIN: $@\n";
 149                 if ($cred && defined($cred->{password})) {
 150                         $err =~ s/\Q$cred->{password}\E/*******/g;
 151                 }
 152                 $mic = undef;
 153         }
 154         $cred->run($mic ? 'approve' : 'reject') if $cred && $cred->{filled};
 155         if ($err) {
 156                 $lei ? $lei->fail($err) : warn($err);
 157         }
 158         $mic;
 159 }
 160
 161 # Net::NNTP doesn't support CAPABILITIES, yet
 162 sub try_starttls ($) {
 163         my ($host) = @_;
 164         return if $host =~ /\.onion\z/s;
 165         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 166         return if $host eq '::1';
 167         1;
 168 }
 169
 170 sub nn_new ($$$) {
 171         my ($nn_arg, $nntp_cfg, $uri) = @_;
 172         my $nn;
 173         if (defined $nn_arg->{ProxyAddr}) {
 174                 require PublicInbox::NetNNTPSocks;
 175                 $nn_arg->{SocksDebug} = 1 if $nn_arg->{Debug};
 176                 eval { $nn = PublicInbox::NetNNTPSocks->new_socks(%$nn_arg) };
 177                 die "E: <$uri> $@\n" if $@;
 178         } else {
 179                 $nn = Net::NNTP->new(%$nn_arg) or return;
 180         }
 181
 182         # default to using STARTTLS if it's available, but allow
 183         # it to be disabled for localhost/VPN users
 184         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 185                 if (!defined($nntp_cfg->{starttls}) &&
 186                                 try_starttls($nn_arg->{Host})) {
 187                         # soft fail by default
 188                         $nn->starttls or warn <<"";
 189 W: <$uri> STARTTLS tried and failed (not requested)
 190
 191                 } elsif ($nntp_cfg->{starttls}) {
 192                         # hard fail if explicitly configured
 193                         $nn->starttls or die <<"";
 194 E: <$uri> STARTTLS requested and failed
 195
 196                 }
 197         } elsif ($nntp_cfg->{starttls}) {
 198                 $nn->can('starttls') or
 199                         die "E: <$uri> Net::NNTP too old for STARTTLS\n";
 200                 $nn->starttls or die <<"";
 201 E: <$uri> STARTTLS requested and failed
 202
 203         }
 204         $nn;
 205 }
 206
 207 sub nn_for ($$$$) { # nn = Net::NNTP
 208         my ($self, $uri, $nn_common, $lei) = @_;
 209         my $sec = uri_section($uri);
 210         my $nntp_cfg = $self->{cfg_opt}->{$sec} //= {};
 211         my $host = $uri->host;
 212         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 213         $host = '127.0.0.1' if $host eq '0';
 214         my $cred;
 215         my ($u, $p);
 216         if (defined(my $ui = $uri->userinfo)) {
 217                 require PublicInbox::GitCredential;
 218                 $cred = bless {
 219                         url => $sec,
 220                         protocol => $uri->scheme,
 221                         host => $host,
 222                 }, 'PublicInbox::GitCredential';
 223                 ($u, $p) = split(/:/, $ui, 2);
 224                 ($cred->{username}, $cred->{password}) = ($u, $p);
 225                 $p //= $cred->check_netrc($lei);
 226         }
 227         my $common = $nn_common->{$sec} // {};
 228         my $nn_arg = {
 229                 Port => $uri->port,
 230                 Host => $host,
 231                 %$common, # may Debug ....
 232         };
 233         $nn_arg->{SSL} = 1 if $uri->secure; # snews == nntps
 234         my $sa = $self->{-proxy_cli};
 235         %$nn_arg = (%$nn_arg, %$sa) if $sa;
 236         my $nn = nn_new($nn_arg, $nntp_cfg, $uri) or
 237                 die "E: <$uri> new: $@".onion_hint($lei, $uri);
 238         if ($cred) {
 239                 $cred->fill($lei) unless defined($p); # may prompt user here
 240                 if ($nn->authinfo($u, $p)) {
 241                         push @{$nntp_cfg->{-postconn}}, [ 'authinfo', $u, $p ];
 242                 } else {
 243                         warn "E: <$uri> AUTHINFO $u XXXX failed\n";
 244                         $nn = undef;
 245                 }
 246         }
 247
 248         if ($nntp_cfg->{compress}) {
 249                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 250                 if ($nn->can('compress')) {
 251                         if ($nn->compress) {
 252                                 push @{$nntp_cfg->{-postconn}}, [ 'compress' ];
 253                         } else {
 254                                 warn "W: <$uri> COMPRESS failed\n";
 255                         }
 256                 } else {
 257                         delete $nntp_cfg->{compress};
 258                         warn <<"";
 259 W: <$uri> COMPRESS not supported by Net::NNTP
 260 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 261
 262                 }
 263         }
 264
 265         $self->{net_arg}->{$sec} = $nn_arg;
 266         $cred->run($nn ? 'approve' : 'reject') if $cred && $cred->{filled};
 267         $nn;
 268 }
 269
 270 sub imap_uri {
 271         my ($url, $ls_ok) = @_;
 272         require PublicInbox::URIimap;
 273         my $uri = PublicInbox::URIimap->new($url);
 274         $uri && ($ls_ok || $uri->mailbox) ? $uri->canonical : undef;
 275 }
 276
 277 my %IS_NNTP = (news => 1, snews => 1, nntp => 1, nntps => 1);
 278 sub nntp_uri {
 279         my ($url, $ls_ok) = @_;
 280         require PublicInbox::URInntps;
 281         my $uri = PublicInbox::URInntps->new($url);
 282         $uri && $IS_NNTP{$uri->scheme} && ($ls_ok || $uri->group) ?
 283                 $uri->canonical : undef;
 284 }
 285
 286 sub cfg_intvl ($$$) {
 287         my ($cfg, $key, $url) = @_;
 288         my $v = $cfg->urlmatch($key, $url) // return;
 289         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 290         if (ref($v) eq 'ARRAY') {
 291                 $v = join(', ', @$v);
 292                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 293         } else {
 294                 warn "W: $key=$v is not a numeric value in seconds\n";
 295         }
 296 }
 297
 298 sub cfg_bool ($$$) {
 299         my ($cfg, $key, $url) = @_;
 300         my $orig = $cfg->urlmatch($key, $url) // return;
 301         my $bool = $cfg->git_bool($orig);
 302         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 303         $bool;
 304 }
 305
 306 # flesh out common IMAP-specific data structures
 307 sub imap_common_init ($;$) {
 308         my ($self, $lei) = @_;
 309         return unless $self->{imap_order};
 310         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 311         eval { require PublicInbox::IMAPClient } or
 312                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 313         ($lei || eval { require PublicInbox::IMAPTracker }) or
 314                 die "DBD::SQLite is required for IMAP\n:$@\n";
 315         require PublicInbox::URIimap;
 316         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 317         my $mic_common = {}; # scheme://authority => Mail:IMAPClient arg
 318         for my $uri (@{$self->{imap_order}}) {
 319                 my $sec = uri_section($uri);
 320
 321                 # knobs directly for Mail::IMAPClient->new
 322                 for my $k (qw(Starttls Debug Compress Ignoresizeerrors)) {
 323                         my $bool = cfg_bool($cfg, "imap.$k", $$uri) // next;
 324                         $mic_common->{$sec}->{$k} = $bool;
 325                 }
 326                 my $to = cfg_intvl($cfg, 'imap.timeout', $$uri);
 327                 $mic_common->{$sec}->{Timeout} = $to if $to;
 328
 329                 # knobs we use ourselves:
 330                 my $sa = socks_args($cfg->urlmatch('imap.Proxy', $$uri));
 331                 $self->{cfg_opt}->{$sec}->{-proxy_cfg} = $sa if $sa;
 332                 for my $k (qw(pollInterval idleInterval)) {
 333                         $to = cfg_intvl($cfg, "imap.$k", $$uri) // next;
 334                         $self->{cfg_opt}->{$sec}->{$k} = $to;
 335                 }
 336                 my $k = 'imap.fetchBatchSize';
 337                 my $bs = $cfg->urlmatch($k, $$uri) // next;
 338                 if ($bs =~ /\A([0-9]+)\z/) {
 339                         $self->{cfg_opt}->{$sec}->{batch_size} = $bs;
 340                 } else {
 341                         warn "$k=$bs is not an integer\n";
 342                 }
 343         }
 344         # make sure we can connect and cache the credentials in memory
 345         my $mics = {}; # schema://authority => IMAPClient obj
 346         for my $orig_uri (@{$self->{imap_order}}) {
 347                 my $sec = uri_section($orig_uri);
 348                 my $uri = PublicInbox::URIimap->new("$sec/");
 349                 my $mic = $mics->{$sec} //=
 350                                 mic_for($self, $uri, $mic_common, $lei) //
 351                                 die "Unable to continue\n";
 352                 next unless $self->isa('PublicInbox::NetWriter');
 353                 my $dst = $orig_uri->mailbox // next;
 354                 next if $mic->exists($dst); # already exists
 355                 $mic->create($dst) or die "CREATE $dst failed <$orig_uri>: $@";
 356         }
 357         $mics;
 358 }
 359
 360 # flesh out common NNTP-specific data structures
 361 sub nntp_common_init ($;$) {
 362         my ($self, $lei) = @_;
 363         return unless $self->{nntp_order};
 364         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 365         eval { require Net::NNTP } or
 366                 die "Net::NNTP is required for NNTP:\n$@\n";
 367         ($lei || eval { require PublicInbox::IMAPTracker }) or
 368                 die "DBD::SQLite is required for NNTP\n:$@\n";
 369         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 370         my $nn_common = {}; # scheme://authority => Net::NNTP->new arg
 371         for my $uri (@{$self->{nntp_order}}) {
 372                 my $sec = uri_section($uri);
 373                 my $args = $nn_common->{$sec} //= {};
 374
 375                 # Debug and Timeout are passed to Net::NNTP->new
 376                 my $v = cfg_bool($cfg, 'nntp.Debug', $$uri);
 377                 $args->{Debug} = $v if defined $v;
 378                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $$uri);
 379                 $args->{Timeout} = $to if $to;
 380                 my $sa = socks_args($cfg->urlmatch('nntp.Proxy', $$uri));
 381                 %$args = (%$args, %$sa) if $sa;
 382
 383                 # Net::NNTP post-connect commands
 384                 for my $k (qw(starttls compress)) {
 385                         $v = cfg_bool($cfg, "nntp.$k", $$uri) // next;
 386                         $self->{cfg_opt}->{$sec}->{$k} = $v;
 387                 }
 388
 389                 # -watch internal option
 390                 for my $k (qw(pollInterval)) {
 391                         $to = cfg_intvl($cfg, "nntp.$k", $$uri) // next;
 392                         $self->{cfg_opt}->{$sec}->{$k} = $to;
 393                 }
 394         }
 395         # make sure we can connect and cache the credentials in memory
 396         my %nn; # schema://authority => Net::NNTP object
 397         for my $uri (@{$self->{nntp_order}}) {
 398                 my $sec = uri_section($uri);
 399                 $nn{$sec} //= nn_for($self, $uri, $nn_common, $lei);
 400         }
 401         \%nn; # for optional {nn_cached}
 402 }
 403
 404 sub add_url {
 405         my ($self, $arg, $ls_ok) = @_;
 406         my $uri;
 407         if ($uri = imap_uri($arg, $ls_ok)) {
 408                 $_[1] = $$uri; # canonicalized
 409                 push @{$self->{imap_order}}, $uri;
 410         } elsif ($uri = nntp_uri($arg, $ls_ok)) {
 411                 $_[1] = $$uri; # canonicalized
 412                 push @{$self->{nntp_order}}, $uri;
 413         } else {
 414                 push @{$self->{unsupported_url}}, $arg;
 415         }
 416 }
 417
 418 sub errors {
 419         my ($self, $lei) = @_;
 420         if (my $u = $self->{unsupported_url}) {
 421                 return "Unsupported URL(s): @$u";
 422         }
 423         if ($self->{imap_order}) {
 424                 eval { require PublicInbox::IMAPClient } or
 425                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 426         }
 427         if ($self->{nntp_order}) {
 428                 eval { require Net::NNTP } or
 429                         die "Net::NNTP is required for NNTP:\n$@\n";
 430         }
 431         my $sa = socks_args($lei ? $lei->{opt}->{proxy} : undef);
 432         $self->{-proxy_cli} = $sa if $sa;
 433         undef;
 434 }
 435
 436 sub flags2kw ($$$$) {
 437         my ($self, $uri, $uid, $flags) = @_;
 438         my $kw = [];
 439         for my $f (split(/ /, $flags)) {
 440                 if (my $k = $IMAPflags2kw{$f}) {
 441                         push @$kw, $k;
 442                 } elsif ($f eq "\\Recent") { # not in JMAP
 443                 } elsif ($f eq "\\Deleted") { # not in JMAP
 444                         return;
 445                 } elsif ($self->{verbose}) {
 446                         warn "# unknown IMAP flag $f <$uri/;UID=$uid>\n";
 447                 }
 448         }
 449         @$kw = sort @$kw; # for LeiSearch->kw_changed and UI/UX purposes
 450         $kw;
 451 }
 452
 453 sub _imap_do_msg ($$$$$) {
 454         my ($self, $uri, $uid, $raw, $flags) = @_;
 455         # our target audience expects LF-only, save storage
 456         $$raw =~ s/\r\n/\n/sg;
 457         my $kw = defined($flags) ?
 458                 (flags2kw($self, $uri, $uid, $flags) // return) : undef;
 459         my ($eml_cb, @args) = @{$self->{eml_each}};
 460         $eml_cb->($uri, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 461 }
 462
 463 sub run_commit_cb ($) {
 464         my ($self) = @_;
 465         my $cmt_cb_args = $self->{on_commit} or return;
 466         my ($cb, @args) = @$cmt_cb_args;
 467         $cb->(@args);
 468 }
 469
 470 sub itrk_last ($$;$$) {
 471         my ($self, $uri, $r_uidval, $mic) = @_;
 472         return (undef, undef, $r_uidval) unless $self->{incremental};
 473         my ($itrk, $l_uid, $l_uidval);
 474         if (defined(my $lms = $self->{-lms_ro})) { # LeiMailSync or 0
 475                 $uri->uidvalidity($r_uidval) if defined $r_uidval;
 476                 if ($mic) {
 477                         my $auth = $mic->Authmechanism // '';
 478                         $uri->auth($auth) if $auth eq 'ANONYMOUS';
 479                         my $user = $mic->User;
 480                         $uri->user($user) if defined($user);
 481                 }
 482                 my $x;
 483                 $l_uid = ($lms && ($x = $lms->location_stats($$uri))) ?
 484                                 $x->{'uid.max'} : undef;
 485                 # itrk remains undef, lei/store worker writes to
 486                 # mail_sync.sqlite3
 487         } else {
 488                 $itrk = PublicInbox::IMAPTracker->new($$uri);
 489                 ($l_uidval, $l_uid) = $itrk->get_last($$uri);
 490         }
 491         ($itrk, $l_uid, $l_uidval //= $r_uidval);
 492 }
 493
 494 # import flags of already-seen messages
 495 sub each_old_flags ($$$$) {
 496         my ($self, $mic, $uri, $l_uid) = @_;
 497         $l_uid ||= 1;
 498         my $sec = uri_section($uri);
 499         my $bs = ($self->{cfg_opt}->{$sec}->{batch_size} // 1) * 10000;
 500         my ($eml_cb, @args) = @{$self->{eml_each}};
 501         $self->{quiet} or warn "# $uri syncing flags 1:$l_uid\n";
 502         for (my $n = 1; $n <= $l_uid; $n += $bs) {
 503                 my $end = $n + $bs;
 504                 $end = $l_uid if $end > $l_uid;
 505                 my $r = $mic->fetch_hash("$n:$end", 'FLAGS');
 506                 if (!$r) {
 507                         return if $!{EINTR} && $self->{quit};
 508                         return "E: $uri UID FETCH $n:$end error: $!";
 509                 }
 510                 while (my ($uid, $per_uid) = each %$r) {
 511                         my $kw = flags2kw($self, $uri, $uid, $per_uid->{FLAGS})
 512                                 // next;
 513                         # LeiImport->input_net_cb
 514                         $eml_cb->($uri, $uid, $kw, undef, @args);
 515                 }
 516         }
 517 }
 518
 519 # returns true if PERMANENTFLAGS indicates FLAGS of already imported
 520 # messages are meaningful
 521 sub perm_fl_ok ($) {
 522         my ($perm_fl) = @_;
 523         return if !defined($perm_fl);
 524         for my $f (split(/[ \t]+/, $perm_fl)) {
 525                 return 1 if $IMAPflags2kw{$f};
 526         }
 527         undef;
 528 }
 529
 530 # may be overridden in NetWriter or Watch
 531 sub folder_select { $_[0]->{each_old} ? 'select' : 'examine' }
 532
 533 sub _imap_fetch_all ($$$) {
 534         my ($self, $mic, $orig_uri) = @_;
 535         my $sec = uri_section($orig_uri);
 536         my $mbx = $orig_uri->mailbox;
 537         $mic->Clear(1); # trim results history
 538
 539         # we need to check for mailbox writability to see if we care about
 540         # FLAGS from already-imported messages.
 541         my $cmd = $self->folder_select;
 542         $mic->$cmd($mbx) or return "E: \U$cmd\E $mbx ($sec) failed: $!";
 543
 544         my ($r_uidval, $r_uidnext, $perm_fl);
 545         for ($mic->Results) {
 546                 /^\* OK \[PERMANENTFLAGS \(([^\)]*)\)\].*/ and $perm_fl = $1;
 547                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 548                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 549         }
 550         $r_uidval //= $mic->uidvalidity($mbx) //
 551                 return "E: $orig_uri cannot get UIDVALIDITY";
 552         $r_uidnext //= $mic->uidnext($mbx) //
 553                 return "E: $orig_uri cannot get UIDNEXT";
 554         my $expect = $orig_uri->uidvalidity // $r_uidval;
 555         return <<EOF if $expect != $r_uidval;
 556 E: $orig_uri UIDVALIDITY mismatch (got $r_uidval)
 557 EOF
 558
 559         my $uri = $orig_uri->clone;
 560         my $single_uid = $uri->uid;
 561         my ($itrk, $l_uid, $l_uidval) = itrk_last($self, $uri, $r_uidval, $mic);
 562         if (defined($single_uid)) {
 563                 $itrk = $l_uid = undef;
 564                 $uri->uid(undef); # for eml_cb
 565         }
 566         return <<EOF if $l_uidval != $r_uidval;
 567 E: $uri UIDVALIDITY mismatch
 568 E: local=$l_uidval != remote=$r_uidval
 569 EOF
 570         $uri->uidvalidity($r_uidval);
 571         $l_uid //= 0;
 572         my $r_uid = $r_uidnext - 1;
 573         return <<EOF if $l_uid > $r_uid;
 574 E: $uri local UID exceeds remote ($l_uid > $r_uid)
 575 E: $uri strangely, UIDVALIDLITY matches ($l_uidval)
 576 EOF
 577         $mic->Uid(1); # the default, we hope
 578         my $err;
 579         my $use_fl = perm_fl_ok($perm_fl);
 580         if (!defined($single_uid) && $self->{each_old} && $use_fl) {
 581                 $err = each_old_flags($self, $mic, $uri, $l_uid);
 582                 return $err if $err;
 583         }
 584         return if $l_uid >= $r_uid; # nothing to do
 585         $l_uid ||= 1;
 586         my ($mod, $shard) = @{$self->{shard_info} // []};
 587         unless ($self->{quiet}) {
 588                 my $m = $mod ? " [(UID % $mod) == $shard]" : '';
 589                 warn "# $uri fetching UID $l_uid:$r_uid$m\n";
 590         }
 591         my $bs = $self->{cfg_opt}->{$sec}->{batch_size} // 1;
 592         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 593         my $key = $req;
 594         $key =~ s/\.PEEK//;
 595         my ($uids, $batch);
 596         do {
 597                 # I wish "UID FETCH $START:*" could work, but:
 598                 # 1) servers do not need to return results in any order
 599                 # 2) Mail::IMAPClient doesn't offer a streaming API
 600                 if (defined $single_uid) {
 601                         $uids = [ $single_uid ];
 602                 } elsif (!($uids = $mic->search("UID $l_uid:*"))) {
 603                         return if $!{EINTR} && $self->{quit};
 604                         return "E: $uri UID SEARCH $l_uid:* error: $!";
 605                 }
 606                 return if scalar(@$uids) == 0;
 607
 608                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 609                 # responses, so sort it ourselves.  Order matters so
 610                 # IMAPTracker can store the newest UID.
 611                 @$uids = sort { $a <=> $b } @$uids;
 612
 613                 # Did we actually get new messages?
 614                 return if $uids->[0] < $l_uid;
 615
 616                 $l_uid = $uids->[-1] + 1; # for next search
 617                 my $last_uid;
 618                 my $n = $self->{max_batch};
 619
 620                 @$uids = grep { ($_ % $mod) == $shard } @$uids if $mod;
 621                 while (scalar @$uids) {
 622                         my @batch = splice(@$uids, 0, $bs);
 623                         $batch = join(',', @batch);
 624                         local $0 = "UID:$batch $mbx $sec";
 625                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 626                         unless ($r) { # network error?
 627                                 last if $!{EINTR} && $self->{quit};
 628                                 $err = "E: $uri UID FETCH $batch error: $!";
 629                                 last;
 630                         }
 631                         for my $uid (@batch) {
 632                                 # messages get deleted, so holes appear
 633                                 my $per_uid = delete $r->{$uid} // next;
 634                                 my $raw = delete($per_uid->{$key}) // next;
 635                                 my $fl = $use_fl ? $per_uid->{FLAGS} : undef;
 636                                 _imap_do_msg($self, $uri, $uid, \$raw, $fl);
 637                                 $last_uid = $uid;
 638                                 last if $self->{quit};
 639                         }
 640                         last if $self->{quit};
 641                 }
 642                 run_commit_cb($self);
 643                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 644         } until ($err || $self->{quit} || defined($single_uid));
 645         $err;
 646 }
 647
 648 # uses cached auth info prepared by mic_for
 649 sub mic_get {
 650         my ($self, $uri) = @_;
 651         my $sec = uri_section($uri);
 652         # see if caller saved result of imap_common_init
 653         my $cached = $self->{mics_cached};
 654         if ($cached) {
 655                 my $mic = $cached->{$sec};
 656                 return $mic if $mic && $mic->IsConnected;
 657                 delete $cached->{$sec};
 658         }
 659         my $mic_arg = $self->{net_arg}->{$sec} or
 660                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 661         if (defined(my $cb_name = $mic_arg->{Authcallback})) {
 662                 if (ref($cb_name) ne 'CODE') {
 663                         $mic_arg->{Authcallback} = $self->can($cb_name);
 664                 }
 665         }
 666         my $mic = mic_new($self, $mic_arg, $sec, $uri);
 667         $cached //= {}; # invalid placeholder if no cache enabled
 668         $mic && $mic->IsConnected ? ($cached->{$sec} = $mic) : undef;
 669 }
 670
 671 sub imap_each {
 672         my ($self, $url, $eml_cb, @args) = @_;
 673         my $uri = ref($url) ? $url : PublicInbox::URIimap->new($url);
 674         my $sec = uri_section($uri);
 675         local $0 = $uri->mailbox." $sec";
 676         my $mic = mic_get($self, $uri);
 677         my $err;
 678         if ($mic) {
 679                 local $self->{eml_each} = [ $eml_cb, @args ];
 680                 $err = _imap_fetch_all($self, $mic, $uri);
 681         } else {
 682                 $err = "E: <$uri> not connected: $!";
 683         }
 684         die $err if $err && $self->{-can_die};
 685         warn $err if $err;
 686         $mic;
 687 }
 688
 689 # may used cached auth info prepared by nn_for once
 690 sub nn_get {
 691         my ($self, $uri) = @_;
 692         my $sec = uri_section($uri);
 693         # see if caller saved result of nntp_common_init
 694         my $cached = $self->{nn_cached} // {};
 695         my $nn;
 696         $nn = delete($cached->{$sec}) and return $nn;
 697         my $nn_arg = $self->{net_arg}->{$sec} or
 698                         die "BUG: no Net::NNTP->new arg for $sec";
 699         my $nntp_cfg = $self->{cfg_opt}->{$sec};
 700         $nn = nn_new($nn_arg, $nntp_cfg, $uri) or return;
 701         if (my $postconn = $nntp_cfg->{-postconn}) {
 702                 for my $m_arg (@$postconn) {
 703                         my ($method, @args) = @$m_arg;
 704                         $nn->$method(@args) and next;
 705                         die "E: <$uri> $method failed\n";
 706                         return;
 707                 }
 708         }
 709         $nn;
 710 }
 711
 712 sub _nntp_fetch_all ($$$) {
 713         my ($self, $nn, $uri) = @_;
 714         my ($group, $num_a, $num_b) = $uri->group;
 715         my $sec = uri_section($uri);
 716         my ($nr, $beg, $end) = $nn->group($group);
 717         unless (defined($nr)) {
 718                 my $msg = ndump($nn->message);
 719                 return "E: GROUP $group <$sec> $msg";
 720         }
 721
 722         # IMAPTracker is also used for tracking NNTP, UID == article number
 723         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 724         # expensive.  So we assume newsgroups don't change:
 725         my ($itrk, $l_art) = itrk_last($self, $uri);
 726
 727         # allow users to specify articles to refetch
 728         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 729         # nntp://example.com/inbox.foo/$num_a-$num_b
 730         $beg = $num_a if defined($num_a) && $num_a < $beg;
 731         $end = $num_b if defined($num_b) && $num_b < $end;
 732         if (defined $l_art) {
 733                 return if $l_art >= $end; # nothing to do
 734                 $beg = $l_art + 1;
 735         }
 736         my ($err, $art, $last_art, $kw); # kw stays undef, no keywords in NNTP
 737         unless ($self->{quiet}) {
 738                 warn "# $uri fetching ARTICLE $beg..$end\n";
 739         }
 740         my $n = $self->{max_batch};
 741         for ($beg..$end) {
 742                 last if $self->{quit};
 743                 $art = $_;
 744                 if (--$n < 0) {
 745                         run_commit_cb($self);
 746                         $itrk->update_last(0, $last_art) if $itrk;
 747                         $n = $self->{max_batch};
 748                 }
 749                 my $raw = $nn->article($art);
 750                 unless (defined($raw)) {
 751                         my $msg = ndump($nn->message);
 752                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 753                                 $err = "E: $msg";
 754                                 last;
 755                         } else { # probably just a deleted message (spam)
 756                                 warn "W: $msg";
 757                                 next;
 758                         }
 759                 }
 760                 $raw = join('', @$raw);
 761                 $raw =~ s/\r\n/\n/sg;
 762                 my ($eml_cb, @args) = @{$self->{eml_each}};
 763                 $eml_cb->($uri, $art, $kw, PublicInbox::Eml->new(\$raw), @args);
 764                 $last_art = $art;
 765         }
 766         run_commit_cb($self);
 767         $itrk->update_last(0, $last_art) if $itrk;
 768         $err;
 769 }
 770
 771 sub nntp_each {
 772         my ($self, $url, $eml_cb, @args) = @_;
 773         my $uri = ref($url) ? $url : PublicInbox::URInntps->new($url);
 774         my $sec = uri_section($uri);
 775         local $0 = $uri->group ." $sec";
 776         my $nn = nn_get($self, $uri);
 777         return if $self->{quit};
 778         my $err;
 779         if ($nn) {
 780                 local $self->{eml_each} = [ $eml_cb, @args ];
 781                 $err = _nntp_fetch_all($self, $nn, $uri);
 782         } else {
 783                 $err = "E: <$uri> not connected: $!";
 784         }
 785         die $err if $err && $self->{-can_die};
 786         warn $err if $err;
 787         $nn;
 788 }
 789
 790 sub new { bless {}, shift };
 791
 792 # updates $uri with UIDVALIDITY
 793 sub mic_for_folder {
 794         my ($self, $uri) = @_;
 795         my $mic = $self->mic_get($uri) or die "E: not connected: $@";
 796         my $m = $self->isa('PublicInbox::NetWriter') ? 'select' : 'examine';
 797         $mic->$m($uri->mailbox) or return;
 798         my $uidval;
 799         for ($mic->Results) {
 800                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ or next;
 801                 $uidval = $1;
 802                 last;
 803         }
 804         $uidval //= $mic->uidvalidity($uri->mailbox) or
 805                 die "E: failed to get uidvalidity from <$uri>: $@";
 806         $uri->uidvalidity($uidval);
 807         $mic;
 808 }
 809
 810
 811 1;