lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10
  11 # TODO: trim this down, this is huge
  12 our @EXPORT = qw(uri_new uri_scheme uri_section
  13                 mic_for nn_new nn_for
  14                 imap_url nntp_url
  15                 cfg_bool cfg_intvl imap_common_init
  16                 );
  17
  18 # avoid exposing deprecated "snews" to users.
  19 my %SCHEME_MAP = ('snews' => 'nntps');
  20
  21 sub uri_scheme ($) {
  22         my ($uri) = @_;
  23         my $scheme = $uri->scheme;
  24         $SCHEME_MAP{$scheme} // $scheme;
  25 }
  26
  27 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  28 # without the mailbox, so we can share connections between different inboxes
  29 sub uri_section ($) {
  30         my ($uri) = @_;
  31         uri_scheme($uri) . '://' . $uri->authority;
  32 }
  33
  34 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  35
  36 sub mic_for { # mic = Mail::IMAPClient
  37         my ($self, $url, $mic_args, $lei) = @_;
  38         require PublicInbox::URIimap;
  39         my $uri = PublicInbox::URIimap->new($url);
  40         require PublicInbox::GitCredential;
  41         my $cred = bless {
  42                 url => $url,
  43                 protocol => $uri->scheme,
  44                 host => $uri->host,
  45                 username => $uri->user,
  46                 password => $uri->password,
  47         }, 'PublicInbox::GitCredential';
  48         my $common = $mic_args->{uri_section($uri)} // {};
  49         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
  50         my $host = $cred->{host};
  51         $host = '127.0.0.1' if $host eq '0';
  52         my $mic_arg = {
  53                 Port => $uri->port,
  54                 Server => $host,
  55                 Ssl => $uri->scheme eq 'imaps',
  56                 Keepalive => 1, # SO_KEEPALIVE
  57                 %$common, # may set Starttls, Compress, Debug ....
  58         };
  59         require PublicInbox::IMAPClient;
  60         my $mic = PublicInbox::IMAPClient->new(%$mic_arg) or
  61                 die "E: <$url> new: $@\n";
  62
  63         # default to using STARTTLS if it's available, but allow
  64         # it to be disabled since I usually connect to localhost
  65         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
  66                         $mic->has_capability('STARTTLS') &&
  67                         $mic->can('starttls')) {
  68                 $mic->starttls or die "E: <$url> STARTTLS: $@\n";
  69         }
  70
  71         # do we even need credentials?
  72         if (!defined($cred->{username}) &&
  73                         $mic->has_capability('AUTH=ANONYMOUS')) {
  74                 $cred = undef;
  75         }
  76         if ($cred) {
  77                 $cred->check_netrc unless defined $cred->{password};
  78                 $cred->fill($lei); # may prompt user here
  79                 $mic->User($mic_arg->{User} = $cred->{username});
  80                 $mic->Password($mic_arg->{Password} = $cred->{password});
  81         } else { # AUTH=ANONYMOUS
  82                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
  83                 $mic_arg->{Authcallback} = 'auth_anon_cb';
  84                 $mic->Authcallback(\&auth_anon_cb);
  85         }
  86         my $err;
  87         if ($mic->login && $mic->IsAuthenticated) {
  88                 # success! keep IMAPClient->new arg in case we get disconnected
  89                 $self->{mic_arg}->{uri_section($uri)} = $mic_arg;
  90         } else {
  91                 $err = "E: <$url> LOGIN: $@\n";
  92                 if ($cred && defined($cred->{password})) {
  93                         $err =~ s/\Q$cred->{password}\E/*******/g;
  94                 }
  95                 $mic = undef;
  96         }
  97         $cred->run($mic ? 'approve' : 'reject') if $cred;
  98         if ($err) {
  99                 $lei ? $lei->fail($err) : warn($err);
 100         }
 101         $mic;
 102 }
 103
 104 sub uri_new {
 105         my ($url) = @_;
 106         require URI;
 107
 108         # URI::snews exists, URI::nntps does not, so use URI::snews
 109         $url =~ s!\Anntps://!snews://!i;
 110         URI->new($url);
 111 }
 112
 113 # Net::NNTP doesn't support CAPABILITIES, yet
 114 sub try_starttls ($) {
 115         my ($host) = @_;
 116         return if $host =~ /\.onion\z/s;
 117         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 118         return if $host eq '::1';
 119         1;
 120 }
 121
 122 sub nn_new ($$$) {
 123         my ($nn_arg, $nntp_opt, $url) = @_;
 124         my $nn = Net::NNTP->new(%$nn_arg) or die "E: <$url> new: $!\n";
 125
 126         # default to using STARTTLS if it's available, but allow
 127         # it to be disabled for localhost/VPN users
 128         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 129                 if (!defined($nntp_opt->{starttls}) &&
 130                                 try_starttls($nn_arg->{Host})) {
 131                         # soft fail by default
 132                         $nn->starttls or warn <<"";
 133 W: <$url> STARTTLS tried and failed (not requested)
 134
 135                 } elsif ($nntp_opt->{starttls}) {
 136                         # hard fail if explicitly configured
 137                         $nn->starttls or die <<"";
 138 E: <$url> STARTTLS requested and failed
 139
 140                 }
 141         } elsif ($nntp_opt->{starttls}) {
 142                 $nn->can('starttls') or
 143                         die "E: <$url> Net::NNTP too old for STARTTLS\n";
 144                 $nn->starttls or die <<"";
 145 E: <$url> STARTTLS requested and failed
 146
 147         }
 148         $nn;
 149 }
 150
 151 sub nn_for ($$$;$) { # nn = Net::NNTP
 152         my ($self, $url, $nn_args, $lei) = @_;
 153         my $uri = uri_new($url);
 154         my $sec = uri_section($uri);
 155         my $nntp_opt = $self->{nntp_opt}->{$sec} //= {};
 156         my $host = $uri->host;
 157         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 158         $host = '127.0.0.1' if $host eq '0';
 159         my $cred;
 160         my ($u, $p);
 161         if (defined(my $ui = $uri->userinfo)) {
 162                 require PublicInbox::GitCredential;
 163                 $cred = bless {
 164                         url => $sec,
 165                         protocol => uri_scheme($uri),
 166                         host => $host,
 167                 }, 'PublicInbox::GitCredential';
 168                 ($u, $p) = split(/:/, $ui, 2);
 169                 ($cred->{username}, $cred->{password}) = ($u, $p);
 170                 $cred->check_netrc unless defined $p;
 171         }
 172         my $common = $nn_args->{$sec} // {};
 173         my $nn_arg = {
 174                 Port => $uri->port,
 175                 Host => $host,
 176                 SSL => $uri->secure, # snews == nntps
 177                 %$common, # may Debug ....
 178         };
 179         my $nn = nn_new($nn_arg, $nntp_opt, $url);
 180
 181         if ($cred) {
 182                 $cred->fill($lei); # may prompt user here
 183                 if ($nn->authinfo($u, $p)) {
 184                         push @{$nntp_opt->{-postconn}}, [ 'authinfo', $u, $p ];
 185                 } else {
 186                         warn "E: <$url> AUTHINFO $u XXXX failed\n";
 187                         $nn = undef;
 188                 }
 189         }
 190
 191         if ($nntp_opt->{compress}) {
 192                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 193                 if ($nn->can('compress')) {
 194                         if ($nn->compress) {
 195                                 push @{$nntp_opt->{-postconn}}, [ 'compress' ];
 196                         } else {
 197                                 warn "W: <$url> COMPRESS failed\n";
 198                         }
 199                 } else {
 200                         delete $nntp_opt->{compress};
 201                         warn <<"";
 202 W: <$url> COMPRESS not supported by Net::NNTP
 203 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 204
 205                 }
 206         }
 207
 208         $self->{nn_arg}->{$sec} = $nn_arg;
 209         $cred->run($nn ? 'approve' : 'reject') if $cred;
 210         $nn;
 211 }
 212
 213 sub imap_url {
 214         my ($url) = @_;
 215         require PublicInbox::URIimap;
 216         my $uri = PublicInbox::URIimap->new($url);
 217         $uri ? $uri->canonical->as_string : undef;
 218 }
 219
 220 my %IS_NNTP = (news => 1, snews => 1, nntp => 1);
 221 sub nntp_url {
 222         my ($url) = @_;
 223         my $uri = uri_new($url);
 224         return unless $uri && $IS_NNTP{$uri->scheme} && $uri->group;
 225         $url = $uri->canonical->as_string;
 226         # nntps is IANA registered, snews is deprecated
 227         $url =~ s!\Asnews://!nntps://!;
 228         $url;
 229 }
 230
 231 sub cfg_intvl ($$$) {
 232         my ($cfg, $key, $url) = @_;
 233         my $v = $cfg->urlmatch($key, $url) // return;
 234         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 235         if (ref($v) eq 'ARRAY') {
 236                 $v = join(', ', @$v);
 237                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 238         } else {
 239                 warn "W: $key=$v is not a numeric value in seconds\n";
 240         }
 241 }
 242
 243 sub cfg_bool ($$$) {
 244         my ($cfg, $key, $url) = @_;
 245         my $orig = $cfg->urlmatch($key, $url) // return;
 246         my $bool = $cfg->git_bool($orig);
 247         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 248         $bool;
 249 }
 250
 251 # flesh out common IMAP-specific data structures
 252 sub imap_common_init ($;$) {
 253         my ($self, $lei) = @_;
 254         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 255         eval { require PublicInbox::IMAPClient } or
 256                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 257         eval { require PublicInbox::IMAPTracker } or
 258                 die "DBD::SQLite is required for IMAP\n:$@\n";
 259         require PublicInbox::URIimap;
 260         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 261         my $mic_args = {}; # scheme://authority => Mail:IMAPClient arg
 262         for my $url (@{$self->{imap_order}}) {
 263                 my $uri = PublicInbox::URIimap->new($url);
 264                 my $sec = uri_section($uri);
 265                 for my $k (qw(Starttls Debug Compress)) {
 266                         my $bool = cfg_bool($cfg, "imap.$k", $url) // next;
 267                         $mic_args->{$sec}->{$k} = $bool;
 268                 }
 269                 my $to = cfg_intvl($cfg, 'imap.timeout', $url);
 270                 $mic_args->{$sec}->{Timeout} = $to if $to;
 271                 for my $k (qw(pollInterval idleInterval)) {
 272                         $to = cfg_intvl($cfg, "imap.$k", $url) // next;
 273                         $self->{imap_opt}->{$sec}->{$k} = $to;
 274                 }
 275                 my $k = 'imap.fetchBatchSize';
 276                 my $bs = $cfg->urlmatch($k, $url) // next;
 277                 if ($bs =~ /\A([0-9]+)\z/) {
 278                         $self->{imap_opt}->{$sec}->{batch_size} = $bs;
 279                 } else {
 280                         warn "$k=$bs is not an integer\n";
 281                 }
 282         }
 283         # make sure we can connect and cache the credentials in memory
 284         $self->{mic_arg} = {}; # schema://authority => IMAPClient->new args
 285         my $mics = {}; # schema://authority => IMAPClient obj
 286         for my $url (@{$self->{imap_order}}) {
 287                 my $uri = PublicInbox::URIimap->new($url);
 288                 my $sec = uri_section($uri);
 289                 $mics->{$sec} //= mic_for($self, $url, $mic_args, $lei);
 290         }
 291         $mics;
 292 }
 293
 294 sub add_url {
 295         my ($self, $arg) = @_;
 296         if (my $url = imap_url($arg)) {
 297                 push @{$self->{imap_order}}, $url;
 298         } else {
 299                 push @{$self->{unsupported_url}}, $arg;
 300         }
 301 }
 302
 303 sub errors {
 304         my ($self) = @_;
 305         if (my $u = $self->{unsupported_url}) {
 306                 return "Unsupported URL(s): @$u";
 307         }
 308         if ($self->{imap_order}) {
 309                 eval { require PublicInbox::IMAPClient } or
 310                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 311         }
 312         undef;
 313 }
 314
 315 my %IMAPflags2kw = (
 316         '\Seen' => 'seen',
 317         '\Answered' => 'answered',
 318         '\Flagged' => 'flagged',
 319         '\Draft' => 'draft',
 320 );
 321
 322 sub _imap_do_msg ($$$$$) {
 323         my ($self, $url, $uid, $raw, $flags) = @_;
 324         # our target audience expects LF-only, save storage
 325         $$raw =~ s/\r\n/\n/sg;
 326         my $kw = [];
 327         for my $f (split(/ /, $flags)) {
 328                 my $k = $IMAPflags2kw{$f} // next; # TODO: X-Label?
 329                 push @$kw, $k;
 330         }
 331         my ($eml_cb, @args) = @{$self->{eml_each}};
 332         $eml_cb->($url, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 333 }
 334
 335 sub _imap_fetch_all ($$$) {
 336         my ($self, $mic, $url) = @_;
 337         my $uri = PublicInbox::URIimap->new($url);
 338         my $sec = uri_section($uri);
 339         my $mbx = $uri->mailbox;
 340         $mic->Clear(1); # trim results history
 341         $mic->examine($mbx) or return "E: EXAMINE $mbx ($sec) failed: $!";
 342         my ($r_uidval, $r_uidnext);
 343         for ($mic->Results) {
 344                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 345                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 346                 last if $r_uidval && $r_uidnext;
 347         }
 348         $r_uidval //= $mic->uidvalidity($mbx) //
 349                 return "E: $url cannot get UIDVALIDITY";
 350         $r_uidnext //= $mic->uidnext($mbx) //
 351                 return "E: $url cannot get UIDNEXT";
 352         my $itrk = $self->{incremental} ?
 353                         PublicInbox::IMAPTracker->new($url) : 0;
 354         my ($l_uidval, $l_uid) = $itrk ? $itrk->get_last : ();
 355         $l_uidval //= $r_uidval; # first time
 356         $l_uid //= 0;
 357         if ($l_uidval != $r_uidval) {
 358                 return "E: $url UIDVALIDITY mismatch\n".
 359                         "E: local=$l_uidval != remote=$r_uidval";
 360         }
 361         my $r_uid = $r_uidnext - 1;
 362         if ($l_uid > $r_uid) {
 363                 return "E: $url local UID exceeds remote ($l_uid > $r_uid)\n".
 364                         "E: $url strangely, UIDVALIDLITY matches ($l_uidval)\n";
 365         }
 366         return if $l_uid >= $r_uid; # nothing to do
 367         $l_uid ||= 1;
 368
 369         warn "# $url fetching UID $l_uid:$r_uid\n" unless $self->{quiet};
 370         $mic->Uid(1); # the default, we hope
 371         my $bs = $self->{imap_opt}->{$sec}->{batch_size} // 1;
 372         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 373         my $key = $req;
 374         $key =~ s/\.PEEK//;
 375         my ($uids, $batch);
 376         my $err;
 377         do {
 378                 # I wish "UID FETCH $START:*" could work, but:
 379                 # 1) servers do not need to return results in any order
 380                 # 2) Mail::IMAPClient doesn't offer a streaming API
 381                 $uids = $mic->search("UID $l_uid:*") or
 382                         return "E: $url UID SEARCH $l_uid:* error: $!";
 383                 return if scalar(@$uids) == 0;
 384
 385                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 386                 # responses, so sort it ourselves.  Order matters so
 387                 # IMAPTracker can store the newest UID.
 388                 @$uids = sort { $a <=> $b } @$uids;
 389
 390                 # Did we actually get new messages?
 391                 return if $uids->[0] < $l_uid;
 392
 393                 $l_uid = $uids->[-1] + 1; # for next search
 394                 my $last_uid;
 395                 my $n = $self->{max_batch};
 396                 while (scalar @$uids) {
 397                         my @batch = splice(@$uids, 0, $bs);
 398                         $batch = join(',', @batch);
 399                         local $0 = "UID:$batch $mbx $sec";
 400                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 401                         unless ($r) { # network error?
 402                                 $err = "E: $url UID FETCH $batch error: $!";
 403                                 last;
 404                         }
 405                         for my $uid (@batch) {
 406                                 # messages get deleted, so holes appear
 407                                 my $per_uid = delete $r->{$uid} // next;
 408                                 my $raw = delete($per_uid->{$key}) // next;
 409                                 _imap_do_msg($self, $url, $uid, \$raw,
 410                                                 $per_uid->{FLAGS});
 411                                 $last_uid = $uid;
 412                                 last if $self->{quit};
 413                         }
 414                         last if $self->{quit};
 415                 }
 416                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 417         } until ($err || $self->{quit});
 418         $err;
 419 }
 420
 421 sub imap_each {
 422         my ($self, $url, $eml_cb, @args) = @_;
 423         my $uri = PublicInbox::URIimap->new($url);
 424         my $sec = uri_section($uri);
 425         my $mic_arg = $self->{mic_arg}->{$sec} or
 426                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 427         local $0 = $uri->mailbox." $sec";
 428         my $cb_name = $mic_arg->{Authcallback};
 429         if (ref($cb_name) ne 'CODE') {
 430                 $mic_arg->{Authcallback} = $self->can($cb_name);
 431         }
 432         my $mic = PublicInbox::IMAPClient->new(%$mic_arg, Debug => 0);
 433         my $err;
 434         if ($mic && $mic->IsConnected) {
 435                 local $self->{eml_each} = [ $eml_cb, @args ];
 436                 $err = _imap_fetch_all($self, $mic, $url);
 437         } else {
 438                 $err = "E: not connected: $!";
 439         }
 440         $mic;
 441 }
 442
 443 sub new { bless {}, shift };
 444
 445 1;