lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Config;
  11 our %IMAPflags2kw = map {; "\\\u$_" => $_ } qw(seen answered flagged draft);
  12 $IMAPflags2kw{'$Forwarded'} = 'forwarded';  # RFC 5550
  13
  14 our @EXPORT = qw(uri_section imap_uri nntp_uri);
  15
  16 sub ndump {
  17         require Data::Dumper;
  18         Data::Dumper->new(\@_)->Useqq(1)->Terse(1)->Dump;
  19 }
  20
  21 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  22 # without the mailbox, so we can share connections between different inboxes
  23 sub uri_section ($) {
  24         my ($uri) = @_;
  25         $uri->scheme . '://' . $uri->authority;
  26 }
  27
  28 sub socks_args ($) {
  29         my ($val) = @_;
  30         return if ($val // '') eq '';
  31         if ($val =~ m!\Asocks5h:// (?: \[ ([^\]]+) \] | ([^:/]+) )
  32                                         (?::([0-9]+))?/*\z!ix) {
  33                 my ($h, $p) = ($1 // $2, $3 + 0);
  34                 $h = '127.0.0.1' if $h eq '0';
  35                 eval { require IO::Socket::Socks } or die <<EOM;
  36 IO::Socket::Socks missing for socks5h://$h:$p
  37 EOM
  38                 return { ProxyAddr => $h, ProxyPort => $p };
  39         }
  40         die "$val not understood (only socks5h:// is supported)\n";
  41 }
  42
  43 sub mic_new ($$$$) {
  44         my ($self, $mic_arg, $sec, $uri) = @_;
  45         my %mic_arg = %$mic_arg;
  46         my $sa = $self->{cfg_opt}->{$sec}->{-proxy_cfg} || $self->{-proxy_cli};
  47         if ($sa) {
  48                 my %opt = %$sa;
  49                 $opt{ConnectAddr} = delete $mic_arg{Server};
  50                 $opt{ConnectPort} = delete $mic_arg{Port};
  51                 $mic_arg{Socket} = IO::Socket::Socks->new(%opt) or die
  52                         "E: <$$uri> ".eval('$IO::Socket::Socks::SOCKS_ERROR');
  53         }
  54         PublicInbox::IMAPClient->new(%mic_arg, Keepalive => 1);
  55 }
  56
  57 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  58
  59 # mic_for may prompt the user and store auth info, prepares mic_get
  60 sub mic_for ($$$$) { # mic = Mail::IMAPClient
  61         my ($self, $uri, $mic_common, $lei) = @_;
  62         require PublicInbox::GitCredential;
  63         my $cred = bless {
  64                 url => "$uri",
  65                 protocol => $uri->scheme,
  66                 host => $uri->host,
  67                 username => $uri->user,
  68                 password => $uri->password,
  69         }, 'PublicInbox::GitCredential';
  70         my $sec = uri_section($uri);
  71         my $common = $mic_common->{$sec} // {};
  72         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
  73         my $host = $cred->{host};
  74         $host = '127.0.0.1' if $host eq '0';
  75         my $mic_arg = {
  76                 Port => $uri->port,
  77                 Server => $host,
  78                 Ssl => $uri->scheme eq 'imaps',
  79                 %$common, # may set Starttls, Compress, Debug ....
  80         };
  81         $mic_arg->{Ssl} = 1 if $uri->scheme eq 'imaps';
  82         require PublicInbox::IMAPClient;
  83         my $mic = mic_new($self, $mic_arg, $sec, $uri) or
  84                         die "E: <$uri> new: $@\n";
  85         # default to using STARTTLS if it's available, but allow
  86         # it to be disabled since I usually connect to localhost
  87         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
  88                         $mic->has_capability('STARTTLS') &&
  89                         $mic->can('starttls')) {
  90                 $mic->starttls or die "E: <$uri> STARTTLS: $@\n";
  91         }
  92
  93         # do we even need credentials?
  94         if (!defined($cred->{username}) &&
  95                         $mic->has_capability('AUTH=ANONYMOUS')) {
  96                 $cred = undef;
  97         }
  98         if ($cred) {
  99                 my $p = $cred->{password} // $cred->check_netrc($lei);
 100                 $cred->fill($lei) unless defined($p); # may prompt user here
 101                 $mic->User($mic_arg->{User} = $cred->{username});
 102                 $mic->Password($mic_arg->{Password} = $cred->{password});
 103         } else { # AUTH=ANONYMOUS
 104                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
 105                 $mic_arg->{Authcallback} = 'auth_anon_cb';
 106                 $mic->Authcallback(\&auth_anon_cb);
 107         }
 108         my $err;
 109         if ($mic->login && $mic->IsAuthenticated) {
 110                 # success! keep IMAPClient->new arg in case we get disconnected
 111                 $self->{net_arg}->{$sec} = $mic_arg;
 112                 if ($cred) {
 113                         $uri->user($cred->{username}) if !defined($uri->user);
 114                 } elsif ($mic_arg->{Authmechanism} eq 'ANONYMOUS') {
 115                         $uri->auth('ANONYMOUS') if !defined($uri->auth);
 116                 }
 117         } else {
 118                 $err = "E: <$uri> LOGIN: $@\n";
 119                 if ($cred && defined($cred->{password})) {
 120                         $err =~ s/\Q$cred->{password}\E/*******/g;
 121                 }
 122                 $mic = undef;
 123         }
 124         $cred->run($mic ? 'approve' : 'reject') if $cred && $cred->{filled};
 125         if ($err) {
 126                 $lei ? $lei->fail($err) : warn($err);
 127         }
 128         $mic;
 129 }
 130
 131 # Net::NNTP doesn't support CAPABILITIES, yet
 132 sub try_starttls ($) {
 133         my ($host) = @_;
 134         return if $host =~ /\.onion\z/s;
 135         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 136         return if $host eq '::1';
 137         1;
 138 }
 139
 140 sub nn_new ($$$) {
 141         my ($nn_arg, $nntp_cfg, $uri) = @_;
 142         my $nn;
 143         if (defined $nn_arg->{ProxyAddr}) {
 144                 require PublicInbox::NetNNTPSocks;
 145                 eval { $nn = PublicInbox::NetNNTPSocks->new_socks(%$nn_arg) };
 146                 die "E: <$uri> $@\n" if $@;
 147         } else {
 148                 $nn = Net::NNTP->new(%$nn_arg) or die "E: <$uri> new: $!\n";
 149         }
 150
 151         # default to using STARTTLS if it's available, but allow
 152         # it to be disabled for localhost/VPN users
 153         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 154                 if (!defined($nntp_cfg->{starttls}) &&
 155                                 try_starttls($nn_arg->{Host})) {
 156                         # soft fail by default
 157                         $nn->starttls or warn <<"";
 158 W: <$uri> STARTTLS tried and failed (not requested)
 159
 160                 } elsif ($nntp_cfg->{starttls}) {
 161                         # hard fail if explicitly configured
 162                         $nn->starttls or die <<"";
 163 E: <$uri> STARTTLS requested and failed
 164
 165                 }
 166         } elsif ($nntp_cfg->{starttls}) {
 167                 $nn->can('starttls') or
 168                         die "E: <$uri> Net::NNTP too old for STARTTLS\n";
 169                 $nn->starttls or die <<"";
 170 E: <$uri> STARTTLS requested and failed
 171
 172         }
 173         $nn;
 174 }
 175
 176 sub nn_for ($$$$) { # nn = Net::NNTP
 177         my ($self, $uri, $nn_common, $lei) = @_;
 178         my $sec = uri_section($uri);
 179         my $nntp_cfg = $self->{cfg_opt}->{$sec} //= {};
 180         my $host = $uri->host;
 181         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 182         $host = '127.0.0.1' if $host eq '0';
 183         my $cred;
 184         my ($u, $p);
 185         if (defined(my $ui = $uri->userinfo)) {
 186                 require PublicInbox::GitCredential;
 187                 $cred = bless {
 188                         url => $sec,
 189                         protocol => $uri->scheme,
 190                         host => $host,
 191                 }, 'PublicInbox::GitCredential';
 192                 ($u, $p) = split(/:/, $ui, 2);
 193                 ($cred->{username}, $cred->{password}) = ($u, $p);
 194                 $p //= $cred->check_netrc($lei);
 195         }
 196         my $common = $nn_common->{$sec} // {};
 197         my $nn_arg = {
 198                 Port => $uri->port,
 199                 Host => $host,
 200                 %$common, # may Debug ....
 201         };
 202         $nn_arg->{SSL} = 1 if $uri->secure; # snews == nntps
 203         my $sa = $self->{-proxy_cli};
 204         %$nn_arg = (%$nn_arg, %$sa) if $sa;
 205         my $nn = nn_new($nn_arg, $nntp_cfg, $uri);
 206         if ($cred) {
 207                 $cred->fill($lei) unless defined($p); # may prompt user here
 208                 if ($nn->authinfo($u, $p)) {
 209                         push @{$nntp_cfg->{-postconn}}, [ 'authinfo', $u, $p ];
 210                 } else {
 211                         warn "E: <$uri> AUTHINFO $u XXXX failed\n";
 212                         $nn = undef;
 213                 }
 214         }
 215
 216         if ($nntp_cfg->{compress}) {
 217                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 218                 if ($nn->can('compress')) {
 219                         if ($nn->compress) {
 220                                 push @{$nntp_cfg->{-postconn}}, [ 'compress' ];
 221                         } else {
 222                                 warn "W: <$uri> COMPRESS failed\n";
 223                         }
 224                 } else {
 225                         delete $nntp_cfg->{compress};
 226                         warn <<"";
 227 W: <$uri> COMPRESS not supported by Net::NNTP
 228 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 229
 230                 }
 231         }
 232
 233         $self->{net_arg}->{$sec} = $nn_arg;
 234         $cred->run($nn ? 'approve' : 'reject') if $cred && $cred->{filled};
 235         $nn;
 236 }
 237
 238 sub imap_uri {
 239         my ($url, $ls_ok) = @_;
 240         require PublicInbox::URIimap;
 241         my $uri = PublicInbox::URIimap->new($url);
 242         $uri && ($ls_ok || $uri->mailbox) ? $uri->canonical : undef;
 243 }
 244
 245 my %IS_NNTP = (news => 1, snews => 1, nntp => 1, nntps => 1);
 246 sub nntp_uri {
 247         my ($url, $ls_ok) = @_;
 248         require PublicInbox::URInntps;
 249         my $uri = PublicInbox::URInntps->new($url);
 250         $uri && $IS_NNTP{$uri->scheme} && ($ls_ok || $uri->group) ?
 251                 $uri->canonical : undef;
 252 }
 253
 254 sub cfg_intvl ($$$) {
 255         my ($cfg, $key, $url) = @_;
 256         my $v = $cfg->urlmatch($key, $url) // return;
 257         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 258         if (ref($v) eq 'ARRAY') {
 259                 $v = join(', ', @$v);
 260                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 261         } else {
 262                 warn "W: $key=$v is not a numeric value in seconds\n";
 263         }
 264 }
 265
 266 sub cfg_bool ($$$) {
 267         my ($cfg, $key, $url) = @_;
 268         my $orig = $cfg->urlmatch($key, $url) // return;
 269         my $bool = $cfg->git_bool($orig);
 270         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 271         $bool;
 272 }
 273
 274 # flesh out common IMAP-specific data structures
 275 sub imap_common_init ($;$) {
 276         my ($self, $lei) = @_;
 277         return unless $self->{imap_order};
 278         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 279         eval { require PublicInbox::IMAPClient } or
 280                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 281         ($lei || eval { require PublicInbox::IMAPTracker }) or
 282                 die "DBD::SQLite is required for IMAP\n:$@\n";
 283         require PublicInbox::URIimap;
 284         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 285         my $mic_common = {}; # scheme://authority => Mail:IMAPClient arg
 286         for my $uri (@{$self->{imap_order}}) {
 287                 my $sec = uri_section($uri);
 288
 289                 # knobs directly for Mail::IMAPClient->new
 290                 for my $k (qw(Starttls Debug Compress Ignoresizeerrors)) {
 291                         my $bool = cfg_bool($cfg, "imap.$k", $$uri) // next;
 292                         $mic_common->{$sec}->{$k} = $bool;
 293                 }
 294                 my $to = cfg_intvl($cfg, 'imap.timeout', $$uri);
 295                 $mic_common->{$sec}->{Timeout} = $to if $to;
 296
 297                 # knobs we use ourselves:
 298                 my $sa = socks_args($cfg->urlmatch('imap.Proxy', $$uri));
 299                 $self->{cfg_opt}->{$sec}->{-proxy_cfg} = $sa if $sa;
 300                 for my $k (qw(pollInterval idleInterval)) {
 301                         $to = cfg_intvl($cfg, "imap.$k", $$uri) // next;
 302                         $self->{cfg_opt}->{$sec}->{$k} = $to;
 303                 }
 304                 my $k = 'imap.fetchBatchSize';
 305                 my $bs = $cfg->urlmatch($k, $$uri) // next;
 306                 if ($bs =~ /\A([0-9]+)\z/) {
 307                         $self->{cfg_opt}->{$sec}->{batch_size} = $bs;
 308                 } else {
 309                         warn "$k=$bs is not an integer\n";
 310                 }
 311         }
 312         # make sure we can connect and cache the credentials in memory
 313         my $mics = {}; # schema://authority => IMAPClient obj
 314         for my $orig_uri (@{$self->{imap_order}}) {
 315                 my $sec = uri_section($orig_uri);
 316                 my $uri = PublicInbox::URIimap->new("$sec/");
 317                 my $mic = $mics->{$sec} //=
 318                                 mic_for($self, $uri, $mic_common, $lei) //
 319                                 die "Unable to continue\n";
 320                 next unless $self->isa('PublicInbox::NetWriter');
 321                 my $dst = $orig_uri->mailbox // next;
 322                 next if $mic->exists($dst); # already exists
 323                 $mic->create($dst) or die "CREATE $dst failed <$orig_uri>: $@";
 324         }
 325         $mics;
 326 }
 327
 328 # flesh out common NNTP-specific data structures
 329 sub nntp_common_init ($;$) {
 330         my ($self, $lei) = @_;
 331         return unless $self->{nntp_order};
 332         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 333         eval { require Net::NNTP } or
 334                 die "Net::NNTP is required for NNTP:\n$@\n";
 335         ($lei || eval { require PublicInbox::IMAPTracker }) or
 336                 die "DBD::SQLite is required for NNTP\n:$@\n";
 337         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 338         my $nn_common = {}; # scheme://authority => Net::NNTP->new arg
 339         for my $uri (@{$self->{nntp_order}}) {
 340                 my $sec = uri_section($uri);
 341                 my $args = $nn_common->{$sec} //= {};
 342
 343                 # Debug and Timeout are passed to Net::NNTP->new
 344                 my $v = cfg_bool($cfg, 'nntp.Debug', $$uri);
 345                 $args->{Debug} = $v if defined $v;
 346                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $$uri);
 347                 $args->{Timeout} = $to if $to;
 348                 my $sa = socks_args($cfg->urlmatch('nntp.Proxy', $$uri));
 349                 %$args = (%$args, %$sa) if $sa;
 350
 351                 # Net::NNTP post-connect commands
 352                 for my $k (qw(starttls compress)) {
 353                         $v = cfg_bool($cfg, "nntp.$k", $$uri) // next;
 354                         $self->{cfg_opt}->{$sec}->{$k} = $v;
 355                 }
 356
 357                 # -watch internal option
 358                 for my $k (qw(pollInterval)) {
 359                         $to = cfg_intvl($cfg, "nntp.$k", $$uri) // next;
 360                         $self->{cfg_opt}->{$sec}->{$k} = $to;
 361                 }
 362         }
 363         # make sure we can connect and cache the credentials in memory
 364         my %nn; # schema://authority => Net::NNTP object
 365         for my $uri (@{$self->{nntp_order}}) {
 366                 my $sec = uri_section($uri);
 367                 $nn{$sec} //= nn_for($self, $uri, $nn_common, $lei);
 368         }
 369         \%nn; # for optional {nn_cached}
 370 }
 371
 372 sub add_url {
 373         my ($self, $arg, $ls_ok) = @_;
 374         my $uri;
 375         if ($uri = imap_uri($arg, $ls_ok)) {
 376                 $_[1] = $$uri; # canonicalized
 377                 push @{$self->{imap_order}}, $uri;
 378         } elsif ($uri = nntp_uri($arg, $ls_ok)) {
 379                 $_[1] = $$uri; # canonicalized
 380                 push @{$self->{nntp_order}}, $uri;
 381         } else {
 382                 push @{$self->{unsupported_url}}, $arg;
 383         }
 384 }
 385
 386 sub errors {
 387         my ($self, $lei) = @_;
 388         if (my $u = $self->{unsupported_url}) {
 389                 return "Unsupported URL(s): @$u";
 390         }
 391         if ($self->{imap_order}) {
 392                 eval { require PublicInbox::IMAPClient } or
 393                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 394         }
 395         if ($self->{nntp_order}) {
 396                 eval { require Net::NNTP } or
 397                         die "Net::NNTP is required for NNTP:\n$@\n";
 398         }
 399         my $sa = socks_args($lei ? $lei->{opt}->{proxy} : undef);
 400         $self->{-proxy_cli} = $sa if $sa;
 401         undef;
 402 }
 403
 404 sub flags2kw ($$$$) {
 405         my ($self, $uri, $uid, $flags) = @_;
 406         my $kw = [];
 407         for my $f (split(/ /, $flags)) {
 408                 if (my $k = $IMAPflags2kw{$f}) {
 409                         push @$kw, $k;
 410                 } elsif ($f eq "\\Recent") { # not in JMAP
 411                 } elsif ($f eq "\\Deleted") { # not in JMAP
 412                         return;
 413                 } elsif ($self->{verbose}) {
 414                         warn "# unknown IMAP flag $f <$uri/;UID=$uid>\n";
 415                 }
 416         }
 417         @$kw = sort @$kw; # for LeiSearch->kw_changed and UI/UX purposes
 418         $kw;
 419 }
 420
 421 sub _imap_do_msg ($$$$$) {
 422         my ($self, $uri, $uid, $raw, $flags) = @_;
 423         # our target audience expects LF-only, save storage
 424         $$raw =~ s/\r\n/\n/sg;
 425         my $kw = defined($flags) ?
 426                 (flags2kw($self, $uri, $uid, $flags) // return) : undef;
 427         my ($eml_cb, @args) = @{$self->{eml_each}};
 428         $eml_cb->($uri, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 429 }
 430
 431 sub run_commit_cb ($) {
 432         my ($self) = @_;
 433         my $cmt_cb_args = $self->{on_commit} or return;
 434         my ($cb, @args) = @$cmt_cb_args;
 435         $cb->(@args);
 436 }
 437
 438 sub itrk_last ($$;$$) {
 439         my ($self, $uri, $r_uidval, $mic) = @_;
 440         return (undef, undef, $r_uidval) unless $self->{incremental};
 441         my ($itrk, $l_uid, $l_uidval);
 442         if (defined(my $lms = $self->{-lms_ro})) { # LeiMailSync or 0
 443                 $uri->uidvalidity($r_uidval) if defined $r_uidval;
 444                 if ($mic) {
 445                         my $auth = $mic->Authmechanism // '';
 446                         $uri->auth($auth) if $auth eq 'ANONYMOUS';
 447                         my $user = $mic->User;
 448                         $uri->user($user) if defined($user);
 449                 }
 450                 my $x;
 451                 $l_uid = ($lms && ($x = $lms->location_stats($$uri))) ?
 452                                 $x->{'uid.max'} : undef;
 453                 # itrk remains undef, lei/store worker writes to
 454                 # mail_sync.sqlite3
 455         } else {
 456                 $itrk = PublicInbox::IMAPTracker->new($$uri);
 457                 ($l_uidval, $l_uid) = $itrk->get_last($$uri);
 458         }
 459         ($itrk, $l_uid, $l_uidval //= $r_uidval);
 460 }
 461
 462 # import flags of already-seen messages
 463 sub each_old_flags ($$$$) {
 464         my ($self, $mic, $uri, $l_uid) = @_;
 465         $l_uid ||= 1;
 466         my $sec = uri_section($uri);
 467         my $bs = ($self->{cfg_opt}->{$sec}->{batch_size} // 1) * 10000;
 468         my ($eml_cb, @args) = @{$self->{eml_each}};
 469         $self->{quiet} or warn "# $uri syncing flags 1:$l_uid\n";
 470         for (my $n = 1; $n <= $l_uid; $n += $bs) {
 471                 my $end = $n + $bs;
 472                 $end = $l_uid if $end > $l_uid;
 473                 my $r = $mic->fetch_hash("$n:$end", 'FLAGS');
 474                 if (!$r) {
 475                         return if $!{EINTR} && $self->{quit};
 476                         return "E: $uri UID FETCH $n:$end error: $!";
 477                 }
 478                 while (my ($uid, $per_uid) = each %$r) {
 479                         my $kw = flags2kw($self, $uri, $uid, $per_uid->{FLAGS})
 480                                 // next;
 481                         # LeiImport->input_net_cb
 482                         $eml_cb->($uri, $uid, $kw, undef, @args);
 483                 }
 484         }
 485 }
 486
 487 # returns true if PERMANENTFLAGS indicates FLAGS of already imported
 488 # messages are meaningful
 489 sub perm_fl_ok ($) {
 490         my ($perm_fl) = @_;
 491         return if !defined($perm_fl);
 492         for my $f (split(/[ \t]+/, $perm_fl)) {
 493                 return 1 if $IMAPflags2kw{$f};
 494         }
 495         undef;
 496 }
 497
 498 # may be overridden in NetWriter or Watch
 499 sub folder_select { $_[0]->{each_old} ? 'select' : 'examine' }
 500
 501 sub _imap_fetch_all ($$$) {
 502         my ($self, $mic, $orig_uri) = @_;
 503         my $sec = uri_section($orig_uri);
 504         my $mbx = $orig_uri->mailbox;
 505         $mic->Clear(1); # trim results history
 506
 507         # we need to check for mailbox writability to see if we care about
 508         # FLAGS from already-imported messages.
 509         my $cmd = $self->folder_select;
 510         $mic->$cmd($mbx) or return "E: \U$cmd\E $mbx ($sec) failed: $!";
 511
 512         my ($r_uidval, $r_uidnext, $perm_fl);
 513         for ($mic->Results) {
 514                 /^\* OK \[PERMANENTFLAGS \(([^\)]*)\)\].*/ and $perm_fl = $1;
 515                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 516                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 517         }
 518         $r_uidval //= $mic->uidvalidity($mbx) //
 519                 return "E: $orig_uri cannot get UIDVALIDITY";
 520         $r_uidnext //= $mic->uidnext($mbx) //
 521                 return "E: $orig_uri cannot get UIDNEXT";
 522         my $expect = $orig_uri->uidvalidity // $r_uidval;
 523         return <<EOF if $expect != $r_uidval;
 524 E: $orig_uri UIDVALIDITY mismatch (got $r_uidval)
 525 EOF
 526
 527         my $uri = $orig_uri->clone;
 528         my $single_uid = $uri->uid;
 529         my ($itrk, $l_uid, $l_uidval) = itrk_last($self, $uri, $r_uidval, $mic);
 530         if (defined($single_uid)) {
 531                 $itrk = $l_uid = undef;
 532                 $uri->uid(undef); # for eml_cb
 533         }
 534         return <<EOF if $l_uidval != $r_uidval;
 535 E: $uri UIDVALIDITY mismatch
 536 E: local=$l_uidval != remote=$r_uidval
 537 EOF
 538         $uri->uidvalidity($r_uidval);
 539         $l_uid //= 0;
 540         my $r_uid = $r_uidnext - 1;
 541         return <<EOF if $l_uid > $r_uid;
 542 E: $uri local UID exceeds remote ($l_uid > $r_uid)
 543 E: $uri strangely, UIDVALIDLITY matches ($l_uidval)
 544 EOF
 545         $mic->Uid(1); # the default, we hope
 546         my $err;
 547         my $use_fl = perm_fl_ok($perm_fl);
 548         if (!defined($single_uid) && $self->{each_old} && $use_fl) {
 549                 $err = each_old_flags($self, $mic, $uri, $l_uid);
 550                 return $err if $err;
 551         }
 552         return if $l_uid >= $r_uid; # nothing to do
 553         $l_uid ||= 1;
 554         my ($mod, $shard) = @{$self->{shard_info} // []};
 555         unless ($self->{quiet}) {
 556                 my $m = $mod ? " [(UID % $mod) == $shard]" : '';
 557                 warn "# $uri fetching UID $l_uid:$r_uid$m\n";
 558         }
 559         my $bs = $self->{cfg_opt}->{$sec}->{batch_size} // 1;
 560         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 561         my $key = $req;
 562         $key =~ s/\.PEEK//;
 563         my ($uids, $batch);
 564         do {
 565                 # I wish "UID FETCH $START:*" could work, but:
 566                 # 1) servers do not need to return results in any order
 567                 # 2) Mail::IMAPClient doesn't offer a streaming API
 568                 if (defined $single_uid) {
 569                         $uids = [ $single_uid ];
 570                 } elsif (!($uids = $mic->search("UID $l_uid:*"))) {
 571                         return if $!{EINTR} && $self->{quit};
 572                         return "E: $uri UID SEARCH $l_uid:* error: $!";
 573                 }
 574                 return if scalar(@$uids) == 0;
 575
 576                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 577                 # responses, so sort it ourselves.  Order matters so
 578                 # IMAPTracker can store the newest UID.
 579                 @$uids = sort { $a <=> $b } @$uids;
 580
 581                 # Did we actually get new messages?
 582                 return if $uids->[0] < $l_uid;
 583
 584                 $l_uid = $uids->[-1] + 1; # for next search
 585                 my $last_uid;
 586                 my $n = $self->{max_batch};
 587
 588                 @$uids = grep { ($_ % $mod) == $shard } @$uids if $mod;
 589                 while (scalar @$uids) {
 590                         my @batch = splice(@$uids, 0, $bs);
 591                         $batch = join(',', @batch);
 592                         local $0 = "UID:$batch $mbx $sec";
 593                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 594                         unless ($r) { # network error?
 595                                 last if $!{EINTR} && $self->{quit};
 596                                 $err = "E: $uri UID FETCH $batch error: $!";
 597                                 last;
 598                         }
 599                         for my $uid (@batch) {
 600                                 # messages get deleted, so holes appear
 601                                 my $per_uid = delete $r->{$uid} // next;
 602                                 my $raw = delete($per_uid->{$key}) // next;
 603                                 my $fl = $use_fl ? $per_uid->{FLAGS} : undef;
 604                                 _imap_do_msg($self, $uri, $uid, \$raw, $fl);
 605                                 $last_uid = $uid;
 606                                 last if $self->{quit};
 607                         }
 608                         last if $self->{quit};
 609                 }
 610                 run_commit_cb($self);
 611                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 612         } until ($err || $self->{quit} || defined($single_uid));
 613         $err;
 614 }
 615
 616 # uses cached auth info prepared by mic_for
 617 sub mic_get {
 618         my ($self, $uri) = @_;
 619         my $sec = uri_section($uri);
 620         # see if caller saved result of imap_common_init
 621         my $cached = $self->{mics_cached};
 622         if ($cached) {
 623                 my $mic = $cached->{$sec};
 624                 return $mic if $mic && $mic->IsConnected;
 625                 delete $cached->{$sec};
 626         }
 627         my $mic_arg = $self->{net_arg}->{$sec} or
 628                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 629         if (defined(my $cb_name = $mic_arg->{Authcallback})) {
 630                 if (ref($cb_name) ne 'CODE') {
 631                         $mic_arg->{Authcallback} = $self->can($cb_name);
 632                 }
 633         }
 634         my $mic = mic_new($self, $mic_arg, $sec, $uri);
 635         $cached //= {}; # invalid placeholder if no cache enabled
 636         $mic && $mic->IsConnected ? ($cached->{$sec} = $mic) : undef;
 637 }
 638
 639 sub imap_each {
 640         my ($self, $url, $eml_cb, @args) = @_;
 641         my $uri = ref($url) ? $url : PublicInbox::URIimap->new($url);
 642         my $sec = uri_section($uri);
 643         local $0 = $uri->mailbox." $sec";
 644         my $mic = mic_get($self, $uri);
 645         my $err;
 646         if ($mic) {
 647                 local $self->{eml_each} = [ $eml_cb, @args ];
 648                 $err = _imap_fetch_all($self, $mic, $uri);
 649         } else {
 650                 $err = "E: <$uri> not connected: $!";
 651         }
 652         die $err if $err && $self->{-can_die};
 653         warn $err if $err;
 654         $mic;
 655 }
 656
 657 # may used cached auth info prepared by nn_for once
 658 sub nn_get {
 659         my ($self, $uri) = @_;
 660         my $sec = uri_section($uri);
 661         # see if caller saved result of nntp_common_init
 662         my $cached = $self->{nn_cached} // {};
 663         my $nn;
 664         $nn = delete($cached->{$sec}) and return $nn;
 665         my $nn_arg = $self->{net_arg}->{$sec} or
 666                         die "BUG: no Net::NNTP->new arg for $sec";
 667         my $nntp_cfg = $self->{cfg_opt}->{$sec};
 668         $nn = nn_new($nn_arg, $nntp_cfg, $uri) or return;
 669         if (my $postconn = $nntp_cfg->{-postconn}) {
 670                 for my $m_arg (@$postconn) {
 671                         my ($method, @args) = @$m_arg;
 672                         $nn->$method(@args) and next;
 673                         die "E: <$uri> $method failed\n";
 674                         return;
 675                 }
 676         }
 677         $nn;
 678 }
 679
 680 sub _nntp_fetch_all ($$$) {
 681         my ($self, $nn, $uri) = @_;
 682         my ($group, $num_a, $num_b) = $uri->group;
 683         my $sec = uri_section($uri);
 684         my ($nr, $beg, $end) = $nn->group($group);
 685         unless (defined($nr)) {
 686                 my $msg = ndump($nn->message);
 687                 return "E: GROUP $group <$sec> $msg";
 688         }
 689
 690         # IMAPTracker is also used for tracking NNTP, UID == article number
 691         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 692         # expensive.  So we assume newsgroups don't change:
 693         my ($itrk, $l_art) = itrk_last($self, $uri);
 694
 695         # allow users to specify articles to refetch
 696         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 697         # nntp://example.com/inbox.foo/$num_a-$num_b
 698         $beg = $num_a if defined($num_a) && $num_a < $beg;
 699         $end = $num_b if defined($num_b) && $num_b < $end;
 700         if (defined $l_art) {
 701                 return if $l_art >= $end; # nothing to do
 702                 $beg = $l_art + 1;
 703         }
 704         my ($err, $art, $last_art, $kw); # kw stays undef, no keywords in NNTP
 705         unless ($self->{quiet}) {
 706                 warn "# $uri fetching ARTICLE $beg..$end\n";
 707         }
 708         my $n = $self->{max_batch};
 709         for ($beg..$end) {
 710                 last if $self->{quit};
 711                 $art = $_;
 712                 if (--$n < 0) {
 713                         run_commit_cb($self);
 714                         $itrk->update_last(0, $last_art) if $itrk;
 715                         $n = $self->{max_batch};
 716                 }
 717                 my $raw = $nn->article($art);
 718                 unless (defined($raw)) {
 719                         my $msg = ndump($nn->message);
 720                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 721                                 $err = "E: $msg";
 722                                 last;
 723                         } else { # probably just a deleted message (spam)
 724                                 warn "W: $msg";
 725                                 next;
 726                         }
 727                 }
 728                 $raw = join('', @$raw);
 729                 $raw =~ s/\r\n/\n/sg;
 730                 my ($eml_cb, @args) = @{$self->{eml_each}};
 731                 $eml_cb->($uri, $art, $kw, PublicInbox::Eml->new(\$raw), @args);
 732                 $last_art = $art;
 733         }
 734         run_commit_cb($self);
 735         $itrk->update_last(0, $last_art) if $itrk;
 736         $err;
 737 }
 738
 739 sub nntp_each {
 740         my ($self, $url, $eml_cb, @args) = @_;
 741         my $uri = ref($url) ? $url : PublicInbox::URInntps->new($url);
 742         my $sec = uri_section($uri);
 743         local $0 = $uri->group ." $sec";
 744         my $nn = nn_get($self, $uri);
 745         return if $self->{quit};
 746         my $err;
 747         if ($nn) {
 748                 local $self->{eml_each} = [ $eml_cb, @args ];
 749                 $err = _nntp_fetch_all($self, $nn, $uri);
 750         } else {
 751                 $err = "E: <$uri> not connected: $!";
 752         }
 753         die $err if $err && $self->{-can_die};
 754         warn $err if $err;
 755         $nn;
 756 }
 757
 758 sub new { bless {}, shift };
 759
 760 # updates $uri with UIDVALIDITY
 761 sub mic_for_folder {
 762         my ($self, $uri) = @_;
 763         my $mic = $self->mic_get($uri) or die "E: not connected: $@";
 764         my $m = $self->isa('PublicInbox::NetWriter') ? 'select' : 'examine';
 765         $mic->$m($uri->mailbox) or return;
 766         my $uidval;
 767         for ($mic->Results) {
 768                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ or next;
 769                 $uidval = $1;
 770                 last;
 771         }
 772         $uidval //= $mic->uidvalidity($uri->mailbox) or
 773                 die "E: failed to get uidvalidity from <$uri>: $@";
 774         $uri->uidvalidity($uidval);
 775         $mic;
 776 }
 777
 778
 779 1;