lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Config;
  11 our %IMAPflags2kw = map {; "\\\u$_" => $_ } qw(seen answered flagged draft);
  12 $IMAPflags2kw{'$Forwarded'} = 'forwarded';  # RFC 5550
  13
  14 our @EXPORT = qw(uri_section imap_uri nntp_uri);
  15
  16 sub ndump {
  17         require Data::Dumper;
  18         Data::Dumper->new(\@_)->Useqq(1)->Terse(1)->Dump;
  19 }
  20
  21 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  22 # without the mailbox, so we can share connections between different inboxes
  23 sub uri_section ($) {
  24         my ($uri) = @_;
  25         $uri->scheme . '://' . $uri->authority;
  26 }
  27
  28 sub socks_args ($) {
  29         my ($val) = @_;
  30         return if ($val // '') eq '';
  31         if ($val =~ m!\Asocks5h:// (?: \[ ([^\]]+) \] | ([^:/]+) )
  32                                         (?::([0-9]+))?/*\z!ix) {
  33                 my ($h, $p) = ($1 // $2, $3 + 0);
  34                 $h = '127.0.0.1' if $h eq '0';
  35                 eval { require IO::Socket::Socks } or die <<EOM;
  36 IO::Socket::Socks missing for socks5h://$h:$p
  37 EOM
  38                 # for IO::Socket::Socks
  39                 return { ProxyAddr => $h, ProxyPort => $p };
  40         }
  41         die "$val not understood (only socks5h:// is supported)\n";
  42 }
  43
  44 sub mic_new ($$$$) {
  45         my ($self, $mic_arg, $sec, $uri) = @_;
  46         my %mic_arg = (%$mic_arg, Keepalive => 1);
  47         my $sa = $self->{cfg_opt}->{$sec}->{-proxy_cfg} || $self->{-proxy_cli};
  48         if ($sa) {
  49                 # this `require' needed for worker[1..Inf], since socks_args
  50                 # only got called in worker[0]
  51                 require IO::Socket::Socks;
  52                 my %opt = (%$sa, Keepalive => 1);
  53                 $opt{SocksDebug} = 1 if $mic_arg{Debug};
  54                 $opt{ConnectAddr} = delete $mic_arg{Server};
  55                 $opt{ConnectPort} = delete $mic_arg{Port};
  56                 my $s = IO::Socket::Socks->new(%opt) or die
  57                         "E: <$uri> ".eval('$IO::Socket::Socks::SOCKS_ERROR');
  58                 if ($mic_arg->{Ssl}) { # for imaps://
  59                         require IO::Socket::SSL;
  60                         $s = IO::Socket::SSL->start_SSL($s) or die
  61                                 "E: <$uri> ".(IO::Socket::SSL->errstr // '');
  62                 }
  63                 $mic_arg{Socket} = $s;
  64         }
  65         PublicInbox::IMAPClient->new(%mic_arg);
  66 }
  67
  68 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  69
  70 sub onion_hint ($$) {
  71         my ($lei, $uri) = @_;
  72         $uri->host =~ /\.onion\z/i or return "\n";
  73         my $t = $uri->isa('PublicInbox::URIimap') ? 'imap' : 'nntp';
  74         my $url = uri_section($uri);
  75         my $set_cfg = 'lei config';
  76         if (!$lei) { # public-inbox-watch
  77                 my $f = $ENV{PI_CONFIG} || '~/.public-inbox/config';
  78                 $set_cfg = "git config -f $f";
  79         }
  80         <<EOM
  81
  82 Assuming you have Tor configured and running locally on port 9050,
  83 try configuring a socks5h:// proxy:
  84
  85         url=$url
  86         $set_cfg $t.\$url.proxy socks5h://127.0.0.1:9050
  87
  88 ...before retrying your current command
  89 EOM
  90 }
  91
  92 # mic_for may prompt the user and store auth info, prepares mic_get
  93 sub mic_for ($$$$) { # mic = Mail::IMAPClient
  94         my ($self, $uri, $mic_common, $lei) = @_;
  95         require PublicInbox::GitCredential;
  96         my $cred = bless {
  97                 url => "$uri",
  98                 protocol => $uri->scheme,
  99                 host => $uri->host,
 100                 username => $uri->user,
 101                 password => $uri->password,
 102         }, 'PublicInbox::GitCredential';
 103         my $sec = uri_section($uri);
 104         my $common = $mic_common->{$sec} // {};
 105         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
 106         my $host = $cred->{host};
 107         $host = '127.0.0.1' if $host eq '0';
 108         my $mic_arg = {
 109                 Port => $uri->port,
 110                 Server => $host,
 111                 %$common, # may set Starttls, Compress, Debug ....
 112         };
 113         $mic_arg->{Ssl} = 1 if $uri->scheme eq 'imaps';
 114         require PublicInbox::IMAPClient;
 115         my $mic = mic_new($self, $mic_arg, $sec, $uri);
 116         ($mic && $mic->IsConnected) or
 117                 die "E: <$uri> new: $@".onion_hint($lei, $uri);
 118
 119         # default to using STARTTLS if it's available, but allow
 120         # it to be disabled since I usually connect to localhost
 121         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
 122                         $mic->has_capability('STARTTLS') &&
 123                         $mic->can('starttls')) {
 124                 $mic->starttls or die "E: <$uri> STARTTLS: $@\n";
 125         }
 126
 127         # do we even need credentials?
 128         if (!defined($cred->{username}) &&
 129                         $mic->has_capability('AUTH=ANONYMOUS')) {
 130                 $cred = undef;
 131         }
 132         if ($cred) {
 133                 my $p = $cred->{password} // $cred->check_netrc($lei);
 134                 $cred->fill($lei) unless defined($p); # may prompt user here
 135                 $mic->User($mic_arg->{User} = $cred->{username});
 136                 $mic->Password($mic_arg->{Password} = $cred->{password});
 137         } else { # AUTH=ANONYMOUS
 138                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
 139                 $mic_arg->{Authcallback} = 'auth_anon_cb';
 140                 $mic->Authcallback(\&auth_anon_cb);
 141         }
 142         my $err;
 143         if ($mic->login && $mic->IsAuthenticated) {
 144                 # success! keep IMAPClient->new arg in case we get disconnected
 145                 $self->{net_arg}->{$sec} = $mic_arg;
 146                 if ($cred) {
 147                         $uri->user($cred->{username}) if !defined($uri->user);
 148                 } elsif ($mic_arg->{Authmechanism} eq 'ANONYMOUS') {
 149                         $uri->auth('ANONYMOUS') if !defined($uri->auth);
 150                 }
 151         } else {
 152                 $err = "E: <$uri> LOGIN: $@\n";
 153                 if ($cred && defined($cred->{password})) {
 154                         $err =~ s/\Q$cred->{password}\E/*******/g;
 155                 }
 156                 $mic = undef;
 157         }
 158         $cred->run($mic ? 'approve' : 'reject') if $cred && $cred->{filled};
 159         if ($err) {
 160                 $lei ? $lei->fail($err) : warn($err);
 161         }
 162         $mic;
 163 }
 164
 165 # Net::NNTP doesn't support CAPABILITIES, yet
 166 sub try_starttls ($) {
 167         my ($host) = @_;
 168         return if $host =~ /\.onion\z/s;
 169         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 170         return if $host eq '::1';
 171         1;
 172 }
 173
 174 sub nn_new ($$$) {
 175         my ($nn_arg, $nntp_cfg, $uri) = @_;
 176         my $nn;
 177         if (defined $nn_arg->{ProxyAddr}) {
 178                 require PublicInbox::NetNNTPSocks;
 179                 $nn_arg->{SocksDebug} = 1 if $nn_arg->{Debug};
 180                 eval { $nn = PublicInbox::NetNNTPSocks->new_socks(%$nn_arg) };
 181                 die "E: <$uri> $@\n" if $@;
 182         } else {
 183                 $nn = Net::NNTP->new(%$nn_arg) or return;
 184         }
 185         setsockopt($nn, Socket::SOL_SOCKET(), Socket::SO_KEEPALIVE(), 1);
 186
 187         # default to using STARTTLS if it's available, but allow
 188         # it to be disabled for localhost/VPN users
 189         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 190                 if (!defined($nntp_cfg->{starttls}) &&
 191                                 try_starttls($nn_arg->{Host})) {
 192                         # soft fail by default
 193                         $nn->starttls or warn <<"";
 194 W: <$uri> STARTTLS tried and failed (not requested)
 195
 196                 } elsif ($nntp_cfg->{starttls}) {
 197                         # hard fail if explicitly configured
 198                         $nn->starttls or die <<"";
 199 E: <$uri> STARTTLS requested and failed
 200
 201                 }
 202         } elsif ($nntp_cfg->{starttls}) {
 203                 $nn->can('starttls') or
 204                         die "E: <$uri> Net::NNTP too old for STARTTLS\n";
 205                 $nn->starttls or die <<"";
 206 E: <$uri> STARTTLS requested and failed
 207
 208         }
 209         $nn;
 210 }
 211
 212 sub nn_for ($$$$) { # nn = Net::NNTP
 213         my ($self, $uri, $nn_common, $lei) = @_;
 214         my $sec = uri_section($uri);
 215         my $nntp_cfg = $self->{cfg_opt}->{$sec} //= {};
 216         my $host = $uri->host;
 217         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 218         $host = '127.0.0.1' if $host eq '0';
 219         my $cred;
 220         my ($u, $p);
 221         if (defined(my $ui = $uri->userinfo)) {
 222                 require PublicInbox::GitCredential;
 223                 $cred = bless {
 224                         url => $sec,
 225                         protocol => $uri->scheme,
 226                         host => $host,
 227                 }, 'PublicInbox::GitCredential';
 228                 ($u, $p) = split(/:/, $ui, 2);
 229                 ($cred->{username}, $cred->{password}) = ($u, $p);
 230                 $p //= $cred->check_netrc($lei);
 231         }
 232         my $common = $nn_common->{$sec} // {};
 233         my $nn_arg = {
 234                 Port => $uri->port,
 235                 Host => $host,
 236                 %$common, # may Debug ....
 237         };
 238         $nn_arg->{SSL} = 1 if $uri->secure; # snews == nntps
 239         my $sa = $self->{-proxy_cli};
 240         %$nn_arg = (%$nn_arg, %$sa) if $sa;
 241         my $nn = nn_new($nn_arg, $nntp_cfg, $uri) or
 242                 die "E: <$uri> new: $@".onion_hint($lei, $uri);
 243         if ($cred) {
 244                 $cred->fill($lei) unless defined($p); # may prompt user here
 245                 if ($nn->authinfo($u, $p)) {
 246                         push @{$nntp_cfg->{-postconn}}, [ 'authinfo', $u, $p ];
 247                 } else {
 248                         warn "E: <$uri> AUTHINFO $u XXXX failed\n";
 249                         $nn = undef;
 250                 }
 251         }
 252
 253         if ($nntp_cfg->{compress}) {
 254                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 255                 if ($nn->can('compress')) {
 256                         if ($nn->compress) {
 257                                 push @{$nntp_cfg->{-postconn}}, [ 'compress' ];
 258                         } else {
 259                                 warn "W: <$uri> COMPRESS failed\n";
 260                         }
 261                 } else {
 262                         delete $nntp_cfg->{compress};
 263                         warn <<"";
 264 W: <$uri> COMPRESS not supported by Net::NNTP
 265 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 266
 267                 }
 268         }
 269
 270         $self->{net_arg}->{$sec} = $nn_arg;
 271         $cred->run($nn ? 'approve' : 'reject') if $cred && $cred->{filled};
 272         $nn;
 273 }
 274
 275 sub imap_uri {
 276         my ($url, $ls_ok) = @_;
 277         require PublicInbox::URIimap;
 278         my $uri = PublicInbox::URIimap->new($url);
 279         $uri && ($ls_ok || $uri->mailbox) ? $uri->canonical : undef;
 280 }
 281
 282 my %IS_NNTP = (news => 1, snews => 1, nntp => 1, nntps => 1);
 283 sub nntp_uri {
 284         my ($url, $ls_ok) = @_;
 285         require PublicInbox::URInntps;
 286         my $uri = PublicInbox::URInntps->new($url);
 287         $uri && $IS_NNTP{$uri->scheme} && ($ls_ok || $uri->group) ?
 288                 $uri->canonical : undef;
 289 }
 290
 291 sub cfg_intvl ($$$) {
 292         my ($cfg, $key, $url) = @_;
 293         my $v = $cfg->urlmatch($key, $url) // return;
 294         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 295         if (ref($v) eq 'ARRAY') {
 296                 $v = join(', ', @$v);
 297                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 298         } else {
 299                 warn "W: $key=$v is not a numeric value in seconds\n";
 300         }
 301 }
 302
 303 sub cfg_bool ($$$) {
 304         my ($cfg, $key, $url) = @_;
 305         my $orig = $cfg->urlmatch($key, $url) // return;
 306         my $bool = $cfg->git_bool($orig);
 307         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 308         $bool;
 309 }
 310
 311 # flesh out common IMAP-specific data structures
 312 sub imap_common_init ($;$) {
 313         my ($self, $lei) = @_;
 314         return unless $self->{imap_order};
 315         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 316         eval { require PublicInbox::IMAPClient } or
 317                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 318         ($lei || eval { require PublicInbox::IMAPTracker }) or
 319                 die "DBD::SQLite is required for IMAP\n:$@\n";
 320         require PublicInbox::URIimap;
 321         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 322         my $mic_common = {}; # scheme://authority => Mail:IMAPClient arg
 323         for my $uri (@{$self->{imap_order}}) {
 324                 my $sec = uri_section($uri);
 325
 326                 # knobs directly for Mail::IMAPClient->new
 327                 for my $k (qw(Starttls Debug Compress Ignoresizeerrors)) {
 328                         my $bool = cfg_bool($cfg, "imap.$k", $$uri) // next;
 329                         $mic_common->{$sec}->{$k} = $bool;
 330                 }
 331                 my $to = cfg_intvl($cfg, 'imap.timeout', $$uri);
 332                 $mic_common->{$sec}->{Timeout} = $to if $to;
 333
 334                 # knobs we use ourselves:
 335                 my $sa = socks_args($cfg->urlmatch('imap.Proxy', $$uri));
 336                 $self->{cfg_opt}->{$sec}->{-proxy_cfg} = $sa if $sa;
 337                 for my $k (qw(pollInterval idleInterval)) {
 338                         $to = cfg_intvl($cfg, "imap.$k", $$uri) // next;
 339                         $self->{cfg_opt}->{$sec}->{$k} = $to;
 340                 }
 341                 my $k = 'imap.fetchBatchSize';
 342                 my $bs = $cfg->urlmatch($k, $$uri) // next;
 343                 if ($bs =~ /\A([0-9]+)\z/) {
 344                         $self->{cfg_opt}->{$sec}->{batch_size} = $bs;
 345                 } else {
 346                         warn "$k=$bs is not an integer\n";
 347                 }
 348         }
 349         # make sure we can connect and cache the credentials in memory
 350         my $mics = {}; # schema://authority => IMAPClient obj
 351         for my $orig_uri (@{$self->{imap_order}}) {
 352                 my $sec = uri_section($orig_uri);
 353                 my $uri = PublicInbox::URIimap->new("$sec/");
 354                 my $mic = $mics->{$sec} //=
 355                                 mic_for($self, $uri, $mic_common, $lei) //
 356                                 die "Unable to continue\n";
 357                 next unless $self->isa('PublicInbox::NetWriter');
 358                 my $dst = $orig_uri->mailbox // next;
 359                 next if $mic->exists($dst); # already exists
 360                 $mic->create($dst) or die "CREATE $dst failed <$orig_uri>: $@";
 361         }
 362         $mics;
 363 }
 364
 365 # flesh out common NNTP-specific data structures
 366 sub nntp_common_init ($;$) {
 367         my ($self, $lei) = @_;
 368         return unless $self->{nntp_order};
 369         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 370         eval { require Net::NNTP } or
 371                 die "Net::NNTP is required for NNTP:\n$@\n";
 372         ($lei || eval { require PublicInbox::IMAPTracker }) or
 373                 die "DBD::SQLite is required for NNTP\n:$@\n";
 374         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 375         my $nn_common = {}; # scheme://authority => Net::NNTP->new arg
 376         for my $uri (@{$self->{nntp_order}}) {
 377                 my $sec = uri_section($uri);
 378                 my $args = $nn_common->{$sec} //= {};
 379
 380                 # Debug and Timeout are passed to Net::NNTP->new
 381                 my $v = cfg_bool($cfg, 'nntp.Debug', $$uri);
 382                 $args->{Debug} = $v if defined $v;
 383                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $$uri);
 384                 $args->{Timeout} = $to if $to;
 385                 my $sa = socks_args($cfg->urlmatch('nntp.Proxy', $$uri));
 386                 %$args = (%$args, %$sa) if $sa;
 387
 388                 # Net::NNTP post-connect commands
 389                 for my $k (qw(starttls compress)) {
 390                         $v = cfg_bool($cfg, "nntp.$k", $$uri) // next;
 391                         $self->{cfg_opt}->{$sec}->{$k} = $v;
 392                 }
 393
 394                 # -watch internal option
 395                 for my $k (qw(pollInterval)) {
 396                         $to = cfg_intvl($cfg, "nntp.$k", $$uri) // next;
 397                         $self->{cfg_opt}->{$sec}->{$k} = $to;
 398                 }
 399         }
 400         # make sure we can connect and cache the credentials in memory
 401         my %nn; # schema://authority => Net::NNTP object
 402         for my $uri (@{$self->{nntp_order}}) {
 403                 my $sec = uri_section($uri);
 404                 $nn{$sec} //= nn_for($self, $uri, $nn_common, $lei);
 405         }
 406         \%nn; # for optional {nn_cached}
 407 }
 408
 409 sub add_url {
 410         my ($self, $arg, $ls_ok) = @_;
 411         my $uri;
 412         if ($uri = imap_uri($arg, $ls_ok)) {
 413                 $_[1] = $$uri; # canonicalized
 414                 push @{$self->{imap_order}}, $uri;
 415         } elsif ($uri = nntp_uri($arg, $ls_ok)) {
 416                 $_[1] = $$uri; # canonicalized
 417                 push @{$self->{nntp_order}}, $uri;
 418         } else {
 419                 push @{$self->{unsupported_url}}, $arg;
 420         }
 421 }
 422
 423 sub errors {
 424         my ($self, $lei) = @_;
 425         if (my $u = $self->{unsupported_url}) {
 426                 return "Unsupported URL(s): @$u";
 427         }
 428         if ($self->{imap_order}) {
 429                 eval { require PublicInbox::IMAPClient } or
 430                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 431         }
 432         if ($self->{nntp_order}) {
 433                 eval { require Net::NNTP } or
 434                         die "Net::NNTP is required for NNTP:\n$@\n";
 435         }
 436         my $sa = socks_args($lei ? $lei->{opt}->{proxy} : undef);
 437         $self->{-proxy_cli} = $sa if $sa;
 438         undef;
 439 }
 440
 441 sub flags2kw ($$$$) {
 442         my ($self, $uri, $uid, $flags) = @_;
 443         my $kw = [];
 444         for my $f (split(/ /, $flags)) {
 445                 if (my $k = $IMAPflags2kw{$f}) {
 446                         push @$kw, $k;
 447                 } elsif ($f eq "\\Recent") { # not in JMAP
 448                 } elsif ($f eq "\\Deleted") { # not in JMAP
 449                         return;
 450                 } elsif ($self->{verbose}) {
 451                         warn "# unknown IMAP flag $f <$uri/;UID=$uid>\n";
 452                 }
 453         }
 454         @$kw = sort @$kw; # for LeiSearch->kw_changed and UI/UX purposes
 455         $kw;
 456 }
 457
 458 sub _imap_do_msg ($$$$$) {
 459         my ($self, $uri, $uid, $raw, $flags) = @_;
 460         # our target audience expects LF-only, save storage
 461         $$raw =~ s/\r\n/\n/sg;
 462         my $kw = defined($flags) ?
 463                 (flags2kw($self, $uri, $uid, $flags) // return) : undef;
 464         my ($eml_cb, @args) = @{$self->{eml_each}};
 465         $eml_cb->($uri, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 466 }
 467
 468 sub run_commit_cb ($) {
 469         my ($self) = @_;
 470         my $cmt_cb_args = $self->{on_commit} or return;
 471         my ($cb, @args) = @$cmt_cb_args;
 472         $cb->(@args);
 473 }
 474
 475 sub itrk_last ($$;$$) {
 476         my ($self, $uri, $r_uidval, $mic) = @_;
 477         return (undef, undef, $r_uidval) unless $self->{incremental};
 478         my ($itrk, $l_uid, $l_uidval);
 479         if (defined(my $lms = $self->{-lms_ro})) { # LeiMailSync or 0
 480                 $uri->uidvalidity($r_uidval) if defined $r_uidval;
 481                 if ($mic) {
 482                         my $auth = $mic->Authmechanism // '';
 483                         $uri->auth($auth) if $auth eq 'ANONYMOUS';
 484                         my $user = $mic->User;
 485                         $uri->user($user) if defined($user);
 486                 }
 487                 my $x;
 488                 $l_uid = ($lms && ($x = $lms->location_stats($$uri))) ?
 489                                 $x->{'uid.max'} : undef;
 490                 # itrk remains undef, lei/store worker writes to
 491                 # mail_sync.sqlite3
 492         } else {
 493                 $itrk = PublicInbox::IMAPTracker->new($$uri);
 494                 ($l_uidval, $l_uid) = $itrk->get_last($$uri);
 495         }
 496         ($itrk, $l_uid, $l_uidval //= $r_uidval);
 497 }
 498
 499 # import flags of already-seen messages
 500 sub each_old_flags ($$$$) {
 501         my ($self, $mic, $uri, $l_uid) = @_;
 502         $l_uid ||= 1;
 503         my $sec = uri_section($uri);
 504         my $bs = ($self->{cfg_opt}->{$sec}->{batch_size} // 1) * 10000;
 505         my ($eml_cb, @args) = @{$self->{eml_each}};
 506         $self->{quiet} or warn "# $uri syncing flags 1:$l_uid\n";
 507         for (my $n = 1; $n <= $l_uid; $n += $bs) {
 508                 my $end = $n + $bs;
 509                 $end = $l_uid if $end > $l_uid;
 510                 my $r = $mic->fetch_hash("$n:$end", 'FLAGS');
 511                 if (!$r) {
 512                         return if $!{EINTR} && $self->{quit};
 513                         return "E: $uri UID FETCH $n:$end error: $!";
 514                 }
 515                 while (my ($uid, $per_uid) = each %$r) {
 516                         my $kw = flags2kw($self, $uri, $uid, $per_uid->{FLAGS})
 517                                 // next;
 518                         # LeiImport->input_net_cb
 519                         $eml_cb->($uri, $uid, $kw, undef, @args);
 520                 }
 521         }
 522 }
 523
 524 # returns true if PERMANENTFLAGS indicates FLAGS of already imported
 525 # messages are meaningful
 526 sub perm_fl_ok ($) {
 527         my ($perm_fl) = @_;
 528         return if !defined($perm_fl);
 529         for my $f (split(/[ \t]+/, $perm_fl)) {
 530                 return 1 if $IMAPflags2kw{$f};
 531         }
 532         undef;
 533 }
 534
 535 # may be overridden in NetWriter or Watch
 536 sub folder_select { $_[0]->{each_old} ? 'select' : 'examine' }
 537
 538 sub _imap_fetch_all ($$$) {
 539         my ($self, $mic, $orig_uri) = @_;
 540         my $sec = uri_section($orig_uri);
 541         my $mbx = $orig_uri->mailbox;
 542         $mic->Clear(1); # trim results history
 543
 544         # we need to check for mailbox writability to see if we care about
 545         # FLAGS from already-imported messages.
 546         my $cmd = $self->folder_select;
 547         $mic->$cmd($mbx) or return "E: \U$cmd\E $mbx ($sec) failed: $!";
 548
 549         my ($r_uidval, $r_uidnext, $perm_fl);
 550         for ($mic->Results) {
 551                 /^\* OK \[PERMANENTFLAGS \(([^\)]*)\)\].*/ and $perm_fl = $1;
 552                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 553                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 554         }
 555         $r_uidval //= $mic->uidvalidity($mbx) //
 556                 return "E: $orig_uri cannot get UIDVALIDITY";
 557         $r_uidnext //= $mic->uidnext($mbx) //
 558                 return "E: $orig_uri cannot get UIDNEXT";
 559         my $expect = $orig_uri->uidvalidity // $r_uidval;
 560         return <<EOF if $expect != $r_uidval;
 561 E: $orig_uri UIDVALIDITY mismatch (got $r_uidval)
 562 EOF
 563
 564         my $uri = $orig_uri->clone;
 565         my $single_uid = $uri->uid;
 566         my ($itrk, $l_uid, $l_uidval) = itrk_last($self, $uri, $r_uidval, $mic);
 567         if (defined($single_uid)) {
 568                 $itrk = $l_uid = undef;
 569                 $uri->uid(undef); # for eml_cb
 570         }
 571         return <<EOF if $l_uidval != $r_uidval;
 572 E: $uri UIDVALIDITY mismatch
 573 E: local=$l_uidval != remote=$r_uidval
 574 EOF
 575         $uri->uidvalidity($r_uidval);
 576         $l_uid //= 0;
 577         my $r_uid = $r_uidnext - 1;
 578         return <<EOF if $l_uid > $r_uid;
 579 E: $uri local UID exceeds remote ($l_uid > $r_uid)
 580 E: $uri strangely, UIDVALIDLITY matches ($l_uidval)
 581 EOF
 582         $mic->Uid(1); # the default, we hope
 583         my $err;
 584         my $use_fl = perm_fl_ok($perm_fl);
 585         if (!defined($single_uid) && $self->{each_old} && $use_fl) {
 586                 $err = each_old_flags($self, $mic, $uri, $l_uid);
 587                 return $err if $err;
 588         }
 589         return if $l_uid >= $r_uid; # nothing to do
 590         $l_uid ||= 1;
 591         my ($mod, $shard) = @{$self->{shard_info} // []};
 592         unless ($self->{quiet}) {
 593                 my $m = $mod ? " [(UID % $mod) == $shard]" : '';
 594                 warn "# $uri fetching UID $l_uid:$r_uid$m\n";
 595         }
 596         my $bs = $self->{cfg_opt}->{$sec}->{batch_size} // 1;
 597         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 598         my $key = $req;
 599         $key =~ s/\.PEEK//;
 600         my ($uids, $batch);
 601         do {
 602                 # I wish "UID FETCH $START:*" could work, but:
 603                 # 1) servers do not need to return results in any order
 604                 # 2) Mail::IMAPClient doesn't offer a streaming API
 605                 if (defined $single_uid) {
 606                         $uids = [ $single_uid ];
 607                 } elsif (!($uids = $mic->search("UID $l_uid:*"))) {
 608                         return if $!{EINTR} && $self->{quit};
 609                         return "E: $uri UID SEARCH $l_uid:* error: $!";
 610                 }
 611                 return if scalar(@$uids) == 0;
 612
 613                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 614                 # responses, so sort it ourselves.  Order matters so
 615                 # IMAPTracker can store the newest UID.
 616                 @$uids = sort { $a <=> $b } @$uids;
 617
 618                 # Did we actually get new messages?
 619                 return if $uids->[0] < $l_uid;
 620
 621                 $l_uid = $uids->[-1] + 1; # for next search
 622                 my $last_uid;
 623                 my $n = $self->{max_batch};
 624
 625                 @$uids = grep { ($_ % $mod) == $shard } @$uids if $mod;
 626                 while (scalar @$uids) {
 627                         my @batch = splice(@$uids, 0, $bs);
 628                         $batch = join(',', @batch);
 629                         local $0 = "UID:$batch $mbx $sec";
 630                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 631                         unless ($r) { # network error?
 632                                 last if $!{EINTR} && $self->{quit};
 633                                 $err = "E: $uri UID FETCH $batch error: $!";
 634                                 last;
 635                         }
 636                         for my $uid (@batch) {
 637                                 # messages get deleted, so holes appear
 638                                 my $per_uid = delete $r->{$uid} // next;
 639                                 my $raw = delete($per_uid->{$key}) // next;
 640                                 my $fl = $use_fl ? $per_uid->{FLAGS} : undef;
 641                                 _imap_do_msg($self, $uri, $uid, \$raw, $fl);
 642                                 $last_uid = $uid;
 643                                 last if $self->{quit};
 644                         }
 645                         last if $self->{quit};
 646                 }
 647                 run_commit_cb($self);
 648                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 649         } until ($err || $self->{quit} || defined($single_uid));
 650         $err;
 651 }
 652
 653 # uses cached auth info prepared by mic_for
 654 sub mic_get {
 655         my ($self, $uri) = @_;
 656         my $sec = uri_section($uri);
 657         # see if caller saved result of imap_common_init
 658         my $cached = $self->{mics_cached};
 659         if ($cached) {
 660                 my $mic = $cached->{$sec};
 661                 return $mic if $mic && $mic->IsConnected;
 662                 delete $cached->{$sec};
 663         }
 664         my $mic_arg = $self->{net_arg}->{$sec} or
 665                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 666         if (defined(my $cb_name = $mic_arg->{Authcallback})) {
 667                 if (ref($cb_name) ne 'CODE') {
 668                         $mic_arg->{Authcallback} = $self->can($cb_name);
 669                 }
 670         }
 671         my $mic = mic_new($self, $mic_arg, $sec, $uri);
 672         $cached //= {}; # invalid placeholder if no cache enabled
 673         $mic && $mic->IsConnected ? ($cached->{$sec} = $mic) : undef;
 674 }
 675
 676 sub imap_each {
 677         my ($self, $url, $eml_cb, @args) = @_;
 678         my $uri = ref($url) ? $url : PublicInbox::URIimap->new($url);
 679         my $sec = uri_section($uri);
 680         local $0 = $uri->mailbox." $sec";
 681         my $mic = mic_get($self, $uri);
 682         my $err;
 683         if ($mic) {
 684                 local $self->{eml_each} = [ $eml_cb, @args ];
 685                 $err = _imap_fetch_all($self, $mic, $uri);
 686         } else {
 687                 $err = "E: <$uri> not connected: $!";
 688         }
 689         die $err if $err && $self->{-can_die};
 690         warn $err if $err;
 691         $mic;
 692 }
 693
 694 # may used cached auth info prepared by nn_for once
 695 sub nn_get {
 696         my ($self, $uri) = @_;
 697         my $sec = uri_section($uri);
 698         # see if caller saved result of nntp_common_init
 699         my $cached = $self->{nn_cached} // {};
 700         my $nn;
 701         $nn = delete($cached->{$sec}) and return $nn;
 702         my $nn_arg = $self->{net_arg}->{$sec} or
 703                         die "BUG: no Net::NNTP->new arg for $sec";
 704         my $nntp_cfg = $self->{cfg_opt}->{$sec};
 705         $nn = nn_new($nn_arg, $nntp_cfg, $uri) or return;
 706         if (my $postconn = $nntp_cfg->{-postconn}) {
 707                 for my $m_arg (@$postconn) {
 708                         my ($method, @args) = @$m_arg;
 709                         $nn->$method(@args) and next;
 710                         die "E: <$uri> $method failed\n";
 711                         return;
 712                 }
 713         }
 714         $nn;
 715 }
 716
 717 sub _nntp_fetch_all ($$$) {
 718         my ($self, $nn, $uri) = @_;
 719         my ($group, $num_a, $num_b) = $uri->group;
 720         my $sec = uri_section($uri);
 721         my ($nr, $beg, $end) = $nn->group($group);
 722         unless (defined($nr)) {
 723                 my $msg = ndump($nn->message);
 724                 return "E: GROUP $group <$sec> $msg";
 725         }
 726
 727         # IMAPTracker is also used for tracking NNTP, UID == article number
 728         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 729         # expensive.  So we assume newsgroups don't change:
 730         my ($itrk, $l_art) = itrk_last($self, $uri);
 731
 732         # allow users to specify articles to refetch
 733         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 734         # nntp://example.com/inbox.foo/$num_a-$num_b
 735         $beg = $num_a if defined($num_a) && $num_a < $beg;
 736         $end = $num_b if defined($num_b) && $num_b < $end;
 737         if (defined $l_art) {
 738                 return if $l_art >= $end; # nothing to do
 739                 $beg = $l_art + 1;
 740         }
 741         my ($err, $art, $last_art, $kw); # kw stays undef, no keywords in NNTP
 742         unless ($self->{quiet}) {
 743                 warn "# $uri fetching ARTICLE $beg..$end\n";
 744         }
 745         my $n = $self->{max_batch};
 746         for ($beg..$end) {
 747                 last if $self->{quit};
 748                 $art = $_;
 749                 if (--$n < 0) {
 750                         run_commit_cb($self);
 751                         $itrk->update_last(0, $last_art) if $itrk;
 752                         $n = $self->{max_batch};
 753                 }
 754                 my $raw = $nn->article($art);
 755                 unless (defined($raw)) {
 756                         my $msg = ndump($nn->message);
 757                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 758                                 $err = "E: $msg";
 759                                 last;
 760                         } else { # probably just a deleted message (spam)
 761                                 warn "W: $msg";
 762                                 next;
 763                         }
 764                 }
 765                 $raw = join('', @$raw);
 766                 $raw =~ s/\r\n/\n/sg;
 767                 my ($eml_cb, @args) = @{$self->{eml_each}};
 768                 $eml_cb->($uri, $art, $kw, PublicInbox::Eml->new(\$raw), @args);
 769                 $last_art = $art;
 770         }
 771         run_commit_cb($self);
 772         $itrk->update_last(0, $last_art) if $itrk;
 773         $err;
 774 }
 775
 776 sub nntp_each {
 777         my ($self, $url, $eml_cb, @args) = @_;
 778         my $uri = ref($url) ? $url : PublicInbox::URInntps->new($url);
 779         my $sec = uri_section($uri);
 780         local $0 = $uri->group ." $sec";
 781         my $nn = nn_get($self, $uri);
 782         return if $self->{quit};
 783         my $err;
 784         if ($nn) {
 785                 local $self->{eml_each} = [ $eml_cb, @args ];
 786                 $err = _nntp_fetch_all($self, $nn, $uri);
 787         } else {
 788                 $err = "E: <$uri> not connected: $!";
 789         }
 790         die $err if $err && $self->{-can_die};
 791         warn $err if $err;
 792         $nn;
 793 }
 794
 795 sub new { bless {}, shift };
 796
 797 # updates $uri with UIDVALIDITY
 798 sub mic_for_folder {
 799         my ($self, $uri) = @_;
 800         my $mic = $self->mic_get($uri) or die "E: not connected: $@";
 801         my $m = $self->isa('PublicInbox::NetWriter') ? 'select' : 'examine';
 802         $mic->$m($uri->mailbox) or return;
 803         my $uidval;
 804         for ($mic->Results) {
 805                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ or next;
 806                 $uidval = $1;
 807                 last;
 808         }
 809         $uidval //= $mic->uidvalidity($uri->mailbox) or
 810                 die "E: failed to get uidvalidity from <$uri>: $@";
 811         $uri->uidvalidity($uidval);
 812         $mic;
 813 }
 814
 815
 816 1;