lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Config;
  11 our %IMAPflags2kw = map {; "\\\u$_" => $_ } qw(seen answered flagged draft);
  12 $IMAPflags2kw{'$Forwarded'} = 'forwarded';  # RFC 5550
  13
  14 our @EXPORT = qw(uri_section imap_uri nntp_uri);
  15
  16 sub ndump {
  17         require Data::Dumper;
  18         Data::Dumper->new(\@_)->Useqq(1)->Terse(1)->Dump;
  19 }
  20
  21 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  22 # without the mailbox, so we can share connections between different inboxes
  23 sub uri_section ($) {
  24         my ($uri) = @_;
  25         $uri->scheme . '://' . $uri->authority;
  26 }
  27
  28 sub socks_args ($) {
  29         my ($val) = @_;
  30         return if ($val // '') eq '';
  31         if ($val =~ m!\Asocks5h:// (?: \[ ([^\]]+) \] | ([^:/]+) )
  32                                         (?::([0-9]+))?/*\z!ix) {
  33                 my ($h, $p) = ($1 // $2, $3 + 0);
  34                 $h = '127.0.0.1' if $h eq '0';
  35                 eval { require IO::Socket::Socks } or die <<EOM;
  36 IO::Socket::Socks missing for socks5h://$h:$p
  37 EOM
  38                 return { ProxyAddr => $h, ProxyPort => $p };
  39         }
  40         die "$val not understood (only socks5h:// is supported)\n";
  41 }
  42
  43 sub mic_new ($$$$) {
  44         my ($self, $mic_arg, $sec, $uri) = @_;
  45         my %mic_arg = %$mic_arg;
  46         my $sa = $self->{cfg_opt}->{$sec}->{-proxy_cfg} || $self->{-proxy_cli};
  47         if ($sa) {
  48                 my %opt = %$sa;
  49                 $opt{ConnectAddr} = delete $mic_arg{Server};
  50                 $opt{ConnectPort} = delete $mic_arg{Port};
  51                 $mic_arg{Socket} = IO::Socket::Socks->new(%opt) or die
  52                         "E: <$$uri> ".eval('$IO::Socket::Socks::SOCKS_ERROR');
  53         }
  54         PublicInbox::IMAPClient->new(%mic_arg, Keepalive => 1);
  55 }
  56
  57 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  58
  59 sub onion_hint ($$) {
  60         my ($lei, $uri) = @_;
  61         $uri->host =~ /\.onion\z/i or return "\n";
  62         my $t = $uri->isa('PublicInbox::URIimap') ? 'imap' : 'nntp';
  63         my $url = uri_section($uri);
  64         my $set_cfg = 'lei config';
  65         if (!$lei) { # public-inbox-watch
  66                 my $f = $ENV{PI_CONFIG} || '~/.public-inbox/config';
  67                 $set_cfg = "git config -f $f";
  68         }
  69         <<EOM
  70
  71 Assuming you have Tor configured and running locally on port 9050,
  72 try configuring a socks5h:// proxy:
  73
  74         url=$url
  75         $set_cfg $t.\$url.proxy socks5h://127.0.0.1:9050
  76
  77 ...before retrying your current command
  78 EOM
  79 }
  80
  81 # mic_for may prompt the user and store auth info, prepares mic_get
  82 sub mic_for ($$$$) { # mic = Mail::IMAPClient
  83         my ($self, $uri, $mic_common, $lei) = @_;
  84         require PublicInbox::GitCredential;
  85         my $cred = bless {
  86                 url => "$uri",
  87                 protocol => $uri->scheme,
  88                 host => $uri->host,
  89                 username => $uri->user,
  90                 password => $uri->password,
  91         }, 'PublicInbox::GitCredential';
  92         my $sec = uri_section($uri);
  93         my $common = $mic_common->{$sec} // {};
  94         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
  95         my $host = $cred->{host};
  96         $host = '127.0.0.1' if $host eq '0';
  97         my $mic_arg = {
  98                 Port => $uri->port,
  99                 Server => $host,
 100                 Ssl => $uri->scheme eq 'imaps',
 101                 %$common, # may set Starttls, Compress, Debug ....
 102         };
 103         $mic_arg->{Ssl} = 1 if $uri->scheme eq 'imaps';
 104         require PublicInbox::IMAPClient;
 105         my $mic = mic_new($self, $mic_arg, $sec, $uri) or
 106                 die "E: <$uri> new: $@".onion_hint($lei, $uri);
 107
 108         # default to using STARTTLS if it's available, but allow
 109         # it to be disabled since I usually connect to localhost
 110         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
 111                         $mic->has_capability('STARTTLS') &&
 112                         $mic->can('starttls')) {
 113                 $mic->starttls or die "E: <$uri> STARTTLS: $@\n";
 114         }
 115
 116         # do we even need credentials?
 117         if (!defined($cred->{username}) &&
 118                         $mic->has_capability('AUTH=ANONYMOUS')) {
 119                 $cred = undef;
 120         }
 121         if ($cred) {
 122                 my $p = $cred->{password} // $cred->check_netrc($lei);
 123                 $cred->fill($lei) unless defined($p); # may prompt user here
 124                 $mic->User($mic_arg->{User} = $cred->{username});
 125                 $mic->Password($mic_arg->{Password} = $cred->{password});
 126         } else { # AUTH=ANONYMOUS
 127                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
 128                 $mic_arg->{Authcallback} = 'auth_anon_cb';
 129                 $mic->Authcallback(\&auth_anon_cb);
 130         }
 131         my $err;
 132         if ($mic->login && $mic->IsAuthenticated) {
 133                 # success! keep IMAPClient->new arg in case we get disconnected
 134                 $self->{net_arg}->{$sec} = $mic_arg;
 135                 if ($cred) {
 136                         $uri->user($cred->{username}) if !defined($uri->user);
 137                 } elsif ($mic_arg->{Authmechanism} eq 'ANONYMOUS') {
 138                         $uri->auth('ANONYMOUS') if !defined($uri->auth);
 139                 }
 140         } else {
 141                 $err = "E: <$uri> LOGIN: $@\n";
 142                 if ($cred && defined($cred->{password})) {
 143                         $err =~ s/\Q$cred->{password}\E/*******/g;
 144                 }
 145                 $mic = undef;
 146         }
 147         $cred->run($mic ? 'approve' : 'reject') if $cred && $cred->{filled};
 148         if ($err) {
 149                 $lei ? $lei->fail($err) : warn($err);
 150         }
 151         $mic;
 152 }
 153
 154 # Net::NNTP doesn't support CAPABILITIES, yet
 155 sub try_starttls ($) {
 156         my ($host) = @_;
 157         return if $host =~ /\.onion\z/s;
 158         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 159         return if $host eq '::1';
 160         1;
 161 }
 162
 163 sub nn_new ($$$) {
 164         my ($nn_arg, $nntp_cfg, $uri) = @_;
 165         my $nn;
 166         if (defined $nn_arg->{ProxyAddr}) {
 167                 require PublicInbox::NetNNTPSocks;
 168                 eval { $nn = PublicInbox::NetNNTPSocks->new_socks(%$nn_arg) };
 169                 die "E: <$uri> $@\n" if $@;
 170         } else {
 171                 $nn = Net::NNTP->new(%$nn_arg) or return;
 172         }
 173
 174         # default to using STARTTLS if it's available, but allow
 175         # it to be disabled for localhost/VPN users
 176         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 177                 if (!defined($nntp_cfg->{starttls}) &&
 178                                 try_starttls($nn_arg->{Host})) {
 179                         # soft fail by default
 180                         $nn->starttls or warn <<"";
 181 W: <$uri> STARTTLS tried and failed (not requested)
 182
 183                 } elsif ($nntp_cfg->{starttls}) {
 184                         # hard fail if explicitly configured
 185                         $nn->starttls or die <<"";
 186 E: <$uri> STARTTLS requested and failed
 187
 188                 }
 189         } elsif ($nntp_cfg->{starttls}) {
 190                 $nn->can('starttls') or
 191                         die "E: <$uri> Net::NNTP too old for STARTTLS\n";
 192                 $nn->starttls or die <<"";
 193 E: <$uri> STARTTLS requested and failed
 194
 195         }
 196         $nn;
 197 }
 198
 199 sub nn_for ($$$$) { # nn = Net::NNTP
 200         my ($self, $uri, $nn_common, $lei) = @_;
 201         my $sec = uri_section($uri);
 202         my $nntp_cfg = $self->{cfg_opt}->{$sec} //= {};
 203         my $host = $uri->host;
 204         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 205         $host = '127.0.0.1' if $host eq '0';
 206         my $cred;
 207         my ($u, $p);
 208         if (defined(my $ui = $uri->userinfo)) {
 209                 require PublicInbox::GitCredential;
 210                 $cred = bless {
 211                         url => $sec,
 212                         protocol => $uri->scheme,
 213                         host => $host,
 214                 }, 'PublicInbox::GitCredential';
 215                 ($u, $p) = split(/:/, $ui, 2);
 216                 ($cred->{username}, $cred->{password}) = ($u, $p);
 217                 $p //= $cred->check_netrc($lei);
 218         }
 219         my $common = $nn_common->{$sec} // {};
 220         my $nn_arg = {
 221                 Port => $uri->port,
 222                 Host => $host,
 223                 %$common, # may Debug ....
 224         };
 225         $nn_arg->{SSL} = 1 if $uri->secure; # snews == nntps
 226         my $sa = $self->{-proxy_cli};
 227         %$nn_arg = (%$nn_arg, %$sa) if $sa;
 228         my $nn = nn_new($nn_arg, $nntp_cfg, $uri) or
 229                 die "E: <$uri> new: $@".onion_hint($lei, $uri);
 230         if ($cred) {
 231                 $cred->fill($lei) unless defined($p); # may prompt user here
 232                 if ($nn->authinfo($u, $p)) {
 233                         push @{$nntp_cfg->{-postconn}}, [ 'authinfo', $u, $p ];
 234                 } else {
 235                         warn "E: <$uri> AUTHINFO $u XXXX failed\n";
 236                         $nn = undef;
 237                 }
 238         }
 239
 240         if ($nntp_cfg->{compress}) {
 241                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 242                 if ($nn->can('compress')) {
 243                         if ($nn->compress) {
 244                                 push @{$nntp_cfg->{-postconn}}, [ 'compress' ];
 245                         } else {
 246                                 warn "W: <$uri> COMPRESS failed\n";
 247                         }
 248                 } else {
 249                         delete $nntp_cfg->{compress};
 250                         warn <<"";
 251 W: <$uri> COMPRESS not supported by Net::NNTP
 252 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 253
 254                 }
 255         }
 256
 257         $self->{net_arg}->{$sec} = $nn_arg;
 258         $cred->run($nn ? 'approve' : 'reject') if $cred && $cred->{filled};
 259         $nn;
 260 }
 261
 262 sub imap_uri {
 263         my ($url, $ls_ok) = @_;
 264         require PublicInbox::URIimap;
 265         my $uri = PublicInbox::URIimap->new($url);
 266         $uri && ($ls_ok || $uri->mailbox) ? $uri->canonical : undef;
 267 }
 268
 269 my %IS_NNTP = (news => 1, snews => 1, nntp => 1, nntps => 1);
 270 sub nntp_uri {
 271         my ($url, $ls_ok) = @_;
 272         require PublicInbox::URInntps;
 273         my $uri = PublicInbox::URInntps->new($url);
 274         $uri && $IS_NNTP{$uri->scheme} && ($ls_ok || $uri->group) ?
 275                 $uri->canonical : undef;
 276 }
 277
 278 sub cfg_intvl ($$$) {
 279         my ($cfg, $key, $url) = @_;
 280         my $v = $cfg->urlmatch($key, $url) // return;
 281         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 282         if (ref($v) eq 'ARRAY') {
 283                 $v = join(', ', @$v);
 284                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 285         } else {
 286                 warn "W: $key=$v is not a numeric value in seconds\n";
 287         }
 288 }
 289
 290 sub cfg_bool ($$$) {
 291         my ($cfg, $key, $url) = @_;
 292         my $orig = $cfg->urlmatch($key, $url) // return;
 293         my $bool = $cfg->git_bool($orig);
 294         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 295         $bool;
 296 }
 297
 298 # flesh out common IMAP-specific data structures
 299 sub imap_common_init ($;$) {
 300         my ($self, $lei) = @_;
 301         return unless $self->{imap_order};
 302         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 303         eval { require PublicInbox::IMAPClient } or
 304                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 305         ($lei || eval { require PublicInbox::IMAPTracker }) or
 306                 die "DBD::SQLite is required for IMAP\n:$@\n";
 307         require PublicInbox::URIimap;
 308         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 309         my $mic_common = {}; # scheme://authority => Mail:IMAPClient arg
 310         for my $uri (@{$self->{imap_order}}) {
 311                 my $sec = uri_section($uri);
 312
 313                 # knobs directly for Mail::IMAPClient->new
 314                 for my $k (qw(Starttls Debug Compress Ignoresizeerrors)) {
 315                         my $bool = cfg_bool($cfg, "imap.$k", $$uri) // next;
 316                         $mic_common->{$sec}->{$k} = $bool;
 317                 }
 318                 my $to = cfg_intvl($cfg, 'imap.timeout', $$uri);
 319                 $mic_common->{$sec}->{Timeout} = $to if $to;
 320
 321                 # knobs we use ourselves:
 322                 my $sa = socks_args($cfg->urlmatch('imap.Proxy', $$uri));
 323                 $self->{cfg_opt}->{$sec}->{-proxy_cfg} = $sa if $sa;
 324                 for my $k (qw(pollInterval idleInterval)) {
 325                         $to = cfg_intvl($cfg, "imap.$k", $$uri) // next;
 326                         $self->{cfg_opt}->{$sec}->{$k} = $to;
 327                 }
 328                 my $k = 'imap.fetchBatchSize';
 329                 my $bs = $cfg->urlmatch($k, $$uri) // next;
 330                 if ($bs =~ /\A([0-9]+)\z/) {
 331                         $self->{cfg_opt}->{$sec}->{batch_size} = $bs;
 332                 } else {
 333                         warn "$k=$bs is not an integer\n";
 334                 }
 335         }
 336         # make sure we can connect and cache the credentials in memory
 337         my $mics = {}; # schema://authority => IMAPClient obj
 338         for my $orig_uri (@{$self->{imap_order}}) {
 339                 my $sec = uri_section($orig_uri);
 340                 my $uri = PublicInbox::URIimap->new("$sec/");
 341                 my $mic = $mics->{$sec} //=
 342                                 mic_for($self, $uri, $mic_common, $lei) //
 343                                 die "Unable to continue\n";
 344                 next unless $self->isa('PublicInbox::NetWriter');
 345                 my $dst = $orig_uri->mailbox // next;
 346                 next if $mic->exists($dst); # already exists
 347                 $mic->create($dst) or die "CREATE $dst failed <$orig_uri>: $@";
 348         }
 349         $mics;
 350 }
 351
 352 # flesh out common NNTP-specific data structures
 353 sub nntp_common_init ($;$) {
 354         my ($self, $lei) = @_;
 355         return unless $self->{nntp_order};
 356         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 357         eval { require Net::NNTP } or
 358                 die "Net::NNTP is required for NNTP:\n$@\n";
 359         ($lei || eval { require PublicInbox::IMAPTracker }) or
 360                 die "DBD::SQLite is required for NNTP\n:$@\n";
 361         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 362         my $nn_common = {}; # scheme://authority => Net::NNTP->new arg
 363         for my $uri (@{$self->{nntp_order}}) {
 364                 my $sec = uri_section($uri);
 365                 my $args = $nn_common->{$sec} //= {};
 366
 367                 # Debug and Timeout are passed to Net::NNTP->new
 368                 my $v = cfg_bool($cfg, 'nntp.Debug', $$uri);
 369                 $args->{Debug} = $v if defined $v;
 370                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $$uri);
 371                 $args->{Timeout} = $to if $to;
 372                 my $sa = socks_args($cfg->urlmatch('nntp.Proxy', $$uri));
 373                 %$args = (%$args, %$sa) if $sa;
 374
 375                 # Net::NNTP post-connect commands
 376                 for my $k (qw(starttls compress)) {
 377                         $v = cfg_bool($cfg, "nntp.$k", $$uri) // next;
 378                         $self->{cfg_opt}->{$sec}->{$k} = $v;
 379                 }
 380
 381                 # -watch internal option
 382                 for my $k (qw(pollInterval)) {
 383                         $to = cfg_intvl($cfg, "nntp.$k", $$uri) // next;
 384                         $self->{cfg_opt}->{$sec}->{$k} = $to;
 385                 }
 386         }
 387         # make sure we can connect and cache the credentials in memory
 388         my %nn; # schema://authority => Net::NNTP object
 389         for my $uri (@{$self->{nntp_order}}) {
 390                 my $sec = uri_section($uri);
 391                 $nn{$sec} //= nn_for($self, $uri, $nn_common, $lei);
 392         }
 393         \%nn; # for optional {nn_cached}
 394 }
 395
 396 sub add_url {
 397         my ($self, $arg, $ls_ok) = @_;
 398         my $uri;
 399         if ($uri = imap_uri($arg, $ls_ok)) {
 400                 $_[1] = $$uri; # canonicalized
 401                 push @{$self->{imap_order}}, $uri;
 402         } elsif ($uri = nntp_uri($arg, $ls_ok)) {
 403                 $_[1] = $$uri; # canonicalized
 404                 push @{$self->{nntp_order}}, $uri;
 405         } else {
 406                 push @{$self->{unsupported_url}}, $arg;
 407         }
 408 }
 409
 410 sub errors {
 411         my ($self, $lei) = @_;
 412         if (my $u = $self->{unsupported_url}) {
 413                 return "Unsupported URL(s): @$u";
 414         }
 415         if ($self->{imap_order}) {
 416                 eval { require PublicInbox::IMAPClient } or
 417                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 418         }
 419         if ($self->{nntp_order}) {
 420                 eval { require Net::NNTP } or
 421                         die "Net::NNTP is required for NNTP:\n$@\n";
 422         }
 423         my $sa = socks_args($lei ? $lei->{opt}->{proxy} : undef);
 424         $self->{-proxy_cli} = $sa if $sa;
 425         undef;
 426 }
 427
 428 sub flags2kw ($$$$) {
 429         my ($self, $uri, $uid, $flags) = @_;
 430         my $kw = [];
 431         for my $f (split(/ /, $flags)) {
 432                 if (my $k = $IMAPflags2kw{$f}) {
 433                         push @$kw, $k;
 434                 } elsif ($f eq "\\Recent") { # not in JMAP
 435                 } elsif ($f eq "\\Deleted") { # not in JMAP
 436                         return;
 437                 } elsif ($self->{verbose}) {
 438                         warn "# unknown IMAP flag $f <$uri/;UID=$uid>\n";
 439                 }
 440         }
 441         @$kw = sort @$kw; # for LeiSearch->kw_changed and UI/UX purposes
 442         $kw;
 443 }
 444
 445 sub _imap_do_msg ($$$$$) {
 446         my ($self, $uri, $uid, $raw, $flags) = @_;
 447         # our target audience expects LF-only, save storage
 448         $$raw =~ s/\r\n/\n/sg;
 449         my $kw = defined($flags) ?
 450                 (flags2kw($self, $uri, $uid, $flags) // return) : undef;
 451         my ($eml_cb, @args) = @{$self->{eml_each}};
 452         $eml_cb->($uri, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 453 }
 454
 455 sub run_commit_cb ($) {
 456         my ($self) = @_;
 457         my $cmt_cb_args = $self->{on_commit} or return;
 458         my ($cb, @args) = @$cmt_cb_args;
 459         $cb->(@args);
 460 }
 461
 462 sub itrk_last ($$;$$) {
 463         my ($self, $uri, $r_uidval, $mic) = @_;
 464         return (undef, undef, $r_uidval) unless $self->{incremental};
 465         my ($itrk, $l_uid, $l_uidval);
 466         if (defined(my $lms = $self->{-lms_ro})) { # LeiMailSync or 0
 467                 $uri->uidvalidity($r_uidval) if defined $r_uidval;
 468                 if ($mic) {
 469                         my $auth = $mic->Authmechanism // '';
 470                         $uri->auth($auth) if $auth eq 'ANONYMOUS';
 471                         my $user = $mic->User;
 472                         $uri->user($user) if defined($user);
 473                 }
 474                 my $x;
 475                 $l_uid = ($lms && ($x = $lms->location_stats($$uri))) ?
 476                                 $x->{'uid.max'} : undef;
 477                 # itrk remains undef, lei/store worker writes to
 478                 # mail_sync.sqlite3
 479         } else {
 480                 $itrk = PublicInbox::IMAPTracker->new($$uri);
 481                 ($l_uidval, $l_uid) = $itrk->get_last($$uri);
 482         }
 483         ($itrk, $l_uid, $l_uidval //= $r_uidval);
 484 }
 485
 486 # import flags of already-seen messages
 487 sub each_old_flags ($$$$) {
 488         my ($self, $mic, $uri, $l_uid) = @_;
 489         $l_uid ||= 1;
 490         my $sec = uri_section($uri);
 491         my $bs = ($self->{cfg_opt}->{$sec}->{batch_size} // 1) * 10000;
 492         my ($eml_cb, @args) = @{$self->{eml_each}};
 493         $self->{quiet} or warn "# $uri syncing flags 1:$l_uid\n";
 494         for (my $n = 1; $n <= $l_uid; $n += $bs) {
 495                 my $end = $n + $bs;
 496                 $end = $l_uid if $end > $l_uid;
 497                 my $r = $mic->fetch_hash("$n:$end", 'FLAGS');
 498                 if (!$r) {
 499                         return if $!{EINTR} && $self->{quit};
 500                         return "E: $uri UID FETCH $n:$end error: $!";
 501                 }
 502                 while (my ($uid, $per_uid) = each %$r) {
 503                         my $kw = flags2kw($self, $uri, $uid, $per_uid->{FLAGS})
 504                                 // next;
 505                         # LeiImport->input_net_cb
 506                         $eml_cb->($uri, $uid, $kw, undef, @args);
 507                 }
 508         }
 509 }
 510
 511 # returns true if PERMANENTFLAGS indicates FLAGS of already imported
 512 # messages are meaningful
 513 sub perm_fl_ok ($) {
 514         my ($perm_fl) = @_;
 515         return if !defined($perm_fl);
 516         for my $f (split(/[ \t]+/, $perm_fl)) {
 517                 return 1 if $IMAPflags2kw{$f};
 518         }
 519         undef;
 520 }
 521
 522 # may be overridden in NetWriter or Watch
 523 sub folder_select { $_[0]->{each_old} ? 'select' : 'examine' }
 524
 525 sub _imap_fetch_all ($$$) {
 526         my ($self, $mic, $orig_uri) = @_;
 527         my $sec = uri_section($orig_uri);
 528         my $mbx = $orig_uri->mailbox;
 529         $mic->Clear(1); # trim results history
 530
 531         # we need to check for mailbox writability to see if we care about
 532         # FLAGS from already-imported messages.
 533         my $cmd = $self->folder_select;
 534         $mic->$cmd($mbx) or return "E: \U$cmd\E $mbx ($sec) failed: $!";
 535
 536         my ($r_uidval, $r_uidnext, $perm_fl);
 537         for ($mic->Results) {
 538                 /^\* OK \[PERMANENTFLAGS \(([^\)]*)\)\].*/ and $perm_fl = $1;
 539                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 540                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 541         }
 542         $r_uidval //= $mic->uidvalidity($mbx) //
 543                 return "E: $orig_uri cannot get UIDVALIDITY";
 544         $r_uidnext //= $mic->uidnext($mbx) //
 545                 return "E: $orig_uri cannot get UIDNEXT";
 546         my $expect = $orig_uri->uidvalidity // $r_uidval;
 547         return <<EOF if $expect != $r_uidval;
 548 E: $orig_uri UIDVALIDITY mismatch (got $r_uidval)
 549 EOF
 550
 551         my $uri = $orig_uri->clone;
 552         my $single_uid = $uri->uid;
 553         my ($itrk, $l_uid, $l_uidval) = itrk_last($self, $uri, $r_uidval, $mic);
 554         if (defined($single_uid)) {
 555                 $itrk = $l_uid = undef;
 556                 $uri->uid(undef); # for eml_cb
 557         }
 558         return <<EOF if $l_uidval != $r_uidval;
 559 E: $uri UIDVALIDITY mismatch
 560 E: local=$l_uidval != remote=$r_uidval
 561 EOF
 562         $uri->uidvalidity($r_uidval);
 563         $l_uid //= 0;
 564         my $r_uid = $r_uidnext - 1;
 565         return <<EOF if $l_uid > $r_uid;
 566 E: $uri local UID exceeds remote ($l_uid > $r_uid)
 567 E: $uri strangely, UIDVALIDLITY matches ($l_uidval)
 568 EOF
 569         $mic->Uid(1); # the default, we hope
 570         my $err;
 571         my $use_fl = perm_fl_ok($perm_fl);
 572         if (!defined($single_uid) && $self->{each_old} && $use_fl) {
 573                 $err = each_old_flags($self, $mic, $uri, $l_uid);
 574                 return $err if $err;
 575         }
 576         return if $l_uid >= $r_uid; # nothing to do
 577         $l_uid ||= 1;
 578         my ($mod, $shard) = @{$self->{shard_info} // []};
 579         unless ($self->{quiet}) {
 580                 my $m = $mod ? " [(UID % $mod) == $shard]" : '';
 581                 warn "# $uri fetching UID $l_uid:$r_uid$m\n";
 582         }
 583         my $bs = $self->{cfg_opt}->{$sec}->{batch_size} // 1;
 584         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 585         my $key = $req;
 586         $key =~ s/\.PEEK//;
 587         my ($uids, $batch);
 588         do {
 589                 # I wish "UID FETCH $START:*" could work, but:
 590                 # 1) servers do not need to return results in any order
 591                 # 2) Mail::IMAPClient doesn't offer a streaming API
 592                 if (defined $single_uid) {
 593                         $uids = [ $single_uid ];
 594                 } elsif (!($uids = $mic->search("UID $l_uid:*"))) {
 595                         return if $!{EINTR} && $self->{quit};
 596                         return "E: $uri UID SEARCH $l_uid:* error: $!";
 597                 }
 598                 return if scalar(@$uids) == 0;
 599
 600                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 601                 # responses, so sort it ourselves.  Order matters so
 602                 # IMAPTracker can store the newest UID.
 603                 @$uids = sort { $a <=> $b } @$uids;
 604
 605                 # Did we actually get new messages?
 606                 return if $uids->[0] < $l_uid;
 607
 608                 $l_uid = $uids->[-1] + 1; # for next search
 609                 my $last_uid;
 610                 my $n = $self->{max_batch};
 611
 612                 @$uids = grep { ($_ % $mod) == $shard } @$uids if $mod;
 613                 while (scalar @$uids) {
 614                         my @batch = splice(@$uids, 0, $bs);
 615                         $batch = join(',', @batch);
 616                         local $0 = "UID:$batch $mbx $sec";
 617                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 618                         unless ($r) { # network error?
 619                                 last if $!{EINTR} && $self->{quit};
 620                                 $err = "E: $uri UID FETCH $batch error: $!";
 621                                 last;
 622                         }
 623                         for my $uid (@batch) {
 624                                 # messages get deleted, so holes appear
 625                                 my $per_uid = delete $r->{$uid} // next;
 626                                 my $raw = delete($per_uid->{$key}) // next;
 627                                 my $fl = $use_fl ? $per_uid->{FLAGS} : undef;
 628                                 _imap_do_msg($self, $uri, $uid, \$raw, $fl);
 629                                 $last_uid = $uid;
 630                                 last if $self->{quit};
 631                         }
 632                         last if $self->{quit};
 633                 }
 634                 run_commit_cb($self);
 635                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 636         } until ($err || $self->{quit} || defined($single_uid));
 637         $err;
 638 }
 639
 640 # uses cached auth info prepared by mic_for
 641 sub mic_get {
 642         my ($self, $uri) = @_;
 643         my $sec = uri_section($uri);
 644         # see if caller saved result of imap_common_init
 645         my $cached = $self->{mics_cached};
 646         if ($cached) {
 647                 my $mic = $cached->{$sec};
 648                 return $mic if $mic && $mic->IsConnected;
 649                 delete $cached->{$sec};
 650         }
 651         my $mic_arg = $self->{net_arg}->{$sec} or
 652                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 653         if (defined(my $cb_name = $mic_arg->{Authcallback})) {
 654                 if (ref($cb_name) ne 'CODE') {
 655                         $mic_arg->{Authcallback} = $self->can($cb_name);
 656                 }
 657         }
 658         my $mic = mic_new($self, $mic_arg, $sec, $uri);
 659         $cached //= {}; # invalid placeholder if no cache enabled
 660         $mic && $mic->IsConnected ? ($cached->{$sec} = $mic) : undef;
 661 }
 662
 663 sub imap_each {
 664         my ($self, $url, $eml_cb, @args) = @_;
 665         my $uri = ref($url) ? $url : PublicInbox::URIimap->new($url);
 666         my $sec = uri_section($uri);
 667         local $0 = $uri->mailbox." $sec";
 668         my $mic = mic_get($self, $uri);
 669         my $err;
 670         if ($mic) {
 671                 local $self->{eml_each} = [ $eml_cb, @args ];
 672                 $err = _imap_fetch_all($self, $mic, $uri);
 673         } else {
 674                 $err = "E: <$uri> not connected: $!";
 675         }
 676         die $err if $err && $self->{-can_die};
 677         warn $err if $err;
 678         $mic;
 679 }
 680
 681 # may used cached auth info prepared by nn_for once
 682 sub nn_get {
 683         my ($self, $uri) = @_;
 684         my $sec = uri_section($uri);
 685         # see if caller saved result of nntp_common_init
 686         my $cached = $self->{nn_cached} // {};
 687         my $nn;
 688         $nn = delete($cached->{$sec}) and return $nn;
 689         my $nn_arg = $self->{net_arg}->{$sec} or
 690                         die "BUG: no Net::NNTP->new arg for $sec";
 691         my $nntp_cfg = $self->{cfg_opt}->{$sec};
 692         $nn = nn_new($nn_arg, $nntp_cfg, $uri) or return;
 693         if (my $postconn = $nntp_cfg->{-postconn}) {
 694                 for my $m_arg (@$postconn) {
 695                         my ($method, @args) = @$m_arg;
 696                         $nn->$method(@args) and next;
 697                         die "E: <$uri> $method failed\n";
 698                         return;
 699                 }
 700         }
 701         $nn;
 702 }
 703
 704 sub _nntp_fetch_all ($$$) {
 705         my ($self, $nn, $uri) = @_;
 706         my ($group, $num_a, $num_b) = $uri->group;
 707         my $sec = uri_section($uri);
 708         my ($nr, $beg, $end) = $nn->group($group);
 709         unless (defined($nr)) {
 710                 my $msg = ndump($nn->message);
 711                 return "E: GROUP $group <$sec> $msg";
 712         }
 713
 714         # IMAPTracker is also used for tracking NNTP, UID == article number
 715         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 716         # expensive.  So we assume newsgroups don't change:
 717         my ($itrk, $l_art) = itrk_last($self, $uri);
 718
 719         # allow users to specify articles to refetch
 720         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 721         # nntp://example.com/inbox.foo/$num_a-$num_b
 722         $beg = $num_a if defined($num_a) && $num_a < $beg;
 723         $end = $num_b if defined($num_b) && $num_b < $end;
 724         if (defined $l_art) {
 725                 return if $l_art >= $end; # nothing to do
 726                 $beg = $l_art + 1;
 727         }
 728         my ($err, $art, $last_art, $kw); # kw stays undef, no keywords in NNTP
 729         unless ($self->{quiet}) {
 730                 warn "# $uri fetching ARTICLE $beg..$end\n";
 731         }
 732         my $n = $self->{max_batch};
 733         for ($beg..$end) {
 734                 last if $self->{quit};
 735                 $art = $_;
 736                 if (--$n < 0) {
 737                         run_commit_cb($self);
 738                         $itrk->update_last(0, $last_art) if $itrk;
 739                         $n = $self->{max_batch};
 740                 }
 741                 my $raw = $nn->article($art);
 742                 unless (defined($raw)) {
 743                         my $msg = ndump($nn->message);
 744                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 745                                 $err = "E: $msg";
 746                                 last;
 747                         } else { # probably just a deleted message (spam)
 748                                 warn "W: $msg";
 749                                 next;
 750                         }
 751                 }
 752                 $raw = join('', @$raw);
 753                 $raw =~ s/\r\n/\n/sg;
 754                 my ($eml_cb, @args) = @{$self->{eml_each}};
 755                 $eml_cb->($uri, $art, $kw, PublicInbox::Eml->new(\$raw), @args);
 756                 $last_art = $art;
 757         }
 758         run_commit_cb($self);
 759         $itrk->update_last(0, $last_art) if $itrk;
 760         $err;
 761 }
 762
 763 sub nntp_each {
 764         my ($self, $url, $eml_cb, @args) = @_;
 765         my $uri = ref($url) ? $url : PublicInbox::URInntps->new($url);
 766         my $sec = uri_section($uri);
 767         local $0 = $uri->group ." $sec";
 768         my $nn = nn_get($self, $uri);
 769         return if $self->{quit};
 770         my $err;
 771         if ($nn) {
 772                 local $self->{eml_each} = [ $eml_cb, @args ];
 773                 $err = _nntp_fetch_all($self, $nn, $uri);
 774         } else {
 775                 $err = "E: <$uri> not connected: $!";
 776         }
 777         die $err if $err && $self->{-can_die};
 778         warn $err if $err;
 779         $nn;
 780 }
 781
 782 sub new { bless {}, shift };
 783
 784 # updates $uri with UIDVALIDITY
 785 sub mic_for_folder {
 786         my ($self, $uri) = @_;
 787         my $mic = $self->mic_get($uri) or die "E: not connected: $@";
 788         my $m = $self->isa('PublicInbox::NetWriter') ? 'select' : 'examine';
 789         $mic->$m($uri->mailbox) or return;
 790         my $uidval;
 791         for ($mic->Results) {
 792                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ or next;
 793                 $uidval = $1;
 794                 last;
 795         }
 796         $uidval //= $mic->uidvalidity($uri->mailbox) or
 797                 die "E: failed to get uidvalidity from <$uri>: $@";
 798         $uri->uidvalidity($uidval);
 799         $mic;
 800 }
 801
 802
 803 1;