lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Config;
  11 our %IMAPflags2kw = map {; "\\\u$_" => $_ } qw(seen answered flagged draft);
  12 $IMAPflags2kw{'$Forwarded'} = 'forwarded';  # RFC 5550
  13
  14 our @EXPORT = qw(uri_section imap_uri nntp_uri);
  15
  16 sub ndump {
  17         require Data::Dumper;
  18         Data::Dumper->new(\@_)->Useqq(1)->Terse(1)->Dump;
  19 }
  20
  21 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  22 # without the mailbox, so we can share connections between different inboxes
  23 sub uri_section ($) {
  24         my ($uri) = @_;
  25         $uri->scheme . '://' . $uri->authority;
  26 }
  27
  28 sub socks_args ($) {
  29         my ($val) = @_;
  30         return if ($val // '') eq '';
  31         if ($val =~ m!\Asocks5h:// (?: \[ ([^\]]+) \] | ([^:/]+) )
  32                                         (?::([0-9]+))?/*\z!ix) {
  33                 my ($h, $p) = ($1 // $2, $3 + 0);
  34                 $h = '127.0.0.1' if $h eq '0';
  35                 eval { require IO::Socket::Socks } or die <<EOM;
  36 IO::Socket::Socks missing for socks5h://$h:$p
  37 EOM
  38                 return { ProxyAddr => $h, ProxyPort => $p };
  39         }
  40         die "$val not understood (only socks5h:// is supported)\n";
  41 }
  42
  43 sub mic_new ($$$$) {
  44         my ($self, $mic_arg, $sec, $uri) = @_;
  45         my %socks;
  46         my $sa = $self->{imap_opt}->{$sec}->{-proxy_cfg} || $self->{-proxy_cli};
  47         if ($sa) {
  48                 my %opt = %$sa;
  49                 $opt{ConnectAddr} = delete $mic_arg->{Server};
  50                 $opt{ConnectPort} = delete $mic_arg->{Port};
  51                 $socks{Socket} = IO::Socket::Socks->new(%opt) or die
  52                         "E: <$$uri> ".eval('$IO::Socket::Socks::SOCKS_ERROR');
  53         }
  54         PublicInbox::IMAPClient->new(%$mic_arg, %socks, Keepalive => 1);
  55 }
  56
  57 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  58
  59 # mic_for may prompt the user and store auth info, prepares mic_get
  60 sub mic_for ($$$$) { # mic = Mail::IMAPClient
  61         my ($self, $uri, $mic_args, $lei) = @_;
  62         require PublicInbox::GitCredential;
  63         my $cred = bless {
  64                 url => "$uri",
  65                 protocol => $uri->scheme,
  66                 host => $uri->host,
  67                 username => $uri->user,
  68                 password => $uri->password,
  69         }, 'PublicInbox::GitCredential';
  70         my $sec = uri_section($uri);
  71         my $common = $mic_args->{$sec} // {};
  72         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
  73         my $host = $cred->{host};
  74         $host = '127.0.0.1' if $host eq '0';
  75         my $mic_arg = {
  76                 Port => $uri->port,
  77                 Server => $host,
  78                 Ssl => $uri->scheme eq 'imaps',
  79                 %$common, # may set Starttls, Compress, Debug ....
  80         };
  81         $mic_arg->{Ssl} = 1 if $uri->scheme eq 'imaps';
  82         require PublicInbox::IMAPClient;
  83         my $mic = mic_new($self, $mic_arg, $sec, $uri) or
  84                         die "E: <$uri> new: $@\n";
  85         # default to using STARTTLS if it's available, but allow
  86         # it to be disabled since I usually connect to localhost
  87         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
  88                         $mic->has_capability('STARTTLS') &&
  89                         $mic->can('starttls')) {
  90                 $mic->starttls or die "E: <$uri> STARTTLS: $@\n";
  91         }
  92
  93         # do we even need credentials?
  94         if (!defined($cred->{username}) &&
  95                         $mic->has_capability('AUTH=ANONYMOUS')) {
  96                 $cred = undef;
  97         }
  98         if ($cred) {
  99                 my $p = $cred->{password} // $cred->check_netrc;
 100                 $cred->fill($lei) unless defined($p); # may prompt user here
 101                 $mic->User($mic_arg->{User} = $cred->{username});
 102                 $mic->Password($mic_arg->{Password} = $cred->{password});
 103         } else { # AUTH=ANONYMOUS
 104                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
 105                 $mic_arg->{Authcallback} = 'auth_anon_cb';
 106                 $mic->Authcallback(\&auth_anon_cb);
 107         }
 108         my $err;
 109         if ($mic->login && $mic->IsAuthenticated) {
 110                 # success! keep IMAPClient->new arg in case we get disconnected
 111                 $self->{mic_arg}->{$sec} = $mic_arg;
 112                 if ($cred) {
 113                         $uri->user($cred->{username}) if !defined($uri->user);
 114                 } elsif ($mic_arg->{Authmechanism} eq 'ANONYMOUS') {
 115                         $uri->auth('ANONYMOUS') if !defined($uri->auth);
 116                 }
 117         } else {
 118                 $err = "E: <$uri> LOGIN: $@\n";
 119                 if ($cred && defined($cred->{password})) {
 120                         $err =~ s/\Q$cred->{password}\E/*******/g;
 121                 }
 122                 $mic = undef;
 123         }
 124         $cred->run($mic ? 'approve' : 'reject') if $cred && $cred->{filled};
 125         if ($err) {
 126                 $lei ? $lei->fail($err) : warn($err);
 127         }
 128         $mic;
 129 }
 130
 131 # Net::NNTP doesn't support CAPABILITIES, yet
 132 sub try_starttls ($) {
 133         my ($host) = @_;
 134         return if $host =~ /\.onion\z/s;
 135         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 136         return if $host eq '::1';
 137         1;
 138 }
 139
 140 sub nn_new ($$$) {
 141         my ($nn_arg, $nntp_opt, $uri) = @_;
 142         my $nn;
 143         if (defined $nn_arg->{ProxyAddr}) {
 144                 require PublicInbox::NetNNTPSocks;
 145                 eval { $nn = PublicInbox::NetNNTPSocks->new_socks(%$nn_arg) };
 146                 die "E: <$uri> $@\n" if $@;
 147         } else {
 148                 $nn = Net::NNTP->new(%$nn_arg) or die "E: <$uri> new: $!\n";
 149         }
 150
 151         # default to using STARTTLS if it's available, but allow
 152         # it to be disabled for localhost/VPN users
 153         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 154                 if (!defined($nntp_opt->{starttls}) &&
 155                                 try_starttls($nn_arg->{Host})) {
 156                         # soft fail by default
 157                         $nn->starttls or warn <<"";
 158 W: <$uri> STARTTLS tried and failed (not requested)
 159
 160                 } elsif ($nntp_opt->{starttls}) {
 161                         # hard fail if explicitly configured
 162                         $nn->starttls or die <<"";
 163 E: <$uri> STARTTLS requested and failed
 164
 165                 }
 166         } elsif ($nntp_opt->{starttls}) {
 167                 $nn->can('starttls') or
 168                         die "E: <$uri> Net::NNTP too old for STARTTLS\n";
 169                 $nn->starttls or die <<"";
 170 E: <$uri> STARTTLS requested and failed
 171
 172         }
 173         $nn;
 174 }
 175
 176 sub nn_for ($$$$) { # nn = Net::NNTP
 177         my ($self, $uri, $nn_args, $lei) = @_;
 178         my $sec = uri_section($uri);
 179         my $nntp_opt = $self->{nntp_opt}->{$sec} //= {};
 180         my $host = $uri->host;
 181         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 182         $host = '127.0.0.1' if $host eq '0';
 183         my $cred;
 184         my ($u, $p);
 185         if (defined(my $ui = $uri->userinfo)) {
 186                 require PublicInbox::GitCredential;
 187                 $cred = bless {
 188                         url => $sec,
 189                         protocol => $uri->scheme,
 190                         host => $host,
 191                 }, 'PublicInbox::GitCredential';
 192                 ($u, $p) = split(/:/, $ui, 2);
 193                 ($cred->{username}, $cred->{password}) = ($u, $p);
 194                 $p //= $cred->check_netrc;
 195         }
 196         my $common = $nn_args->{$sec} // {};
 197         my $nn_arg = {
 198                 Port => $uri->port,
 199                 Host => $host,
 200                 %$common, # may Debug ....
 201         };
 202         $nn_arg->{SSL} = 1 if $uri->secure; # snews == nntps
 203         my $sa = $self->{-proxy_cli};
 204         %$nn_arg = (%$nn_arg, %$sa) if $sa;
 205         my $nn = nn_new($nn_arg, $nntp_opt, $uri);
 206         if ($cred) {
 207                 $cred->fill($lei) unless defined($p); # may prompt user here
 208                 if ($nn->authinfo($u, $p)) {
 209                         push @{$nntp_opt->{-postconn}}, [ 'authinfo', $u, $p ];
 210                 } else {
 211                         warn "E: <$uri> AUTHINFO $u XXXX failed\n";
 212                         $nn = undef;
 213                 }
 214         }
 215
 216         if ($nntp_opt->{compress}) {
 217                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 218                 if ($nn->can('compress')) {
 219                         if ($nn->compress) {
 220                                 push @{$nntp_opt->{-postconn}}, [ 'compress' ];
 221                         } else {
 222                                 warn "W: <$uri> COMPRESS failed\n";
 223                         }
 224                 } else {
 225                         delete $nntp_opt->{compress};
 226                         warn <<"";
 227 W: <$uri> COMPRESS not supported by Net::NNTP
 228 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 229
 230                 }
 231         }
 232
 233         $self->{nn_arg}->{$sec} = $nn_arg;
 234         $cred->run($nn ? 'approve' : 'reject') if $cred && $cred->{filled};
 235         $nn;
 236 }
 237
 238 sub imap_uri {
 239         my ($url, $ls_ok) = @_;
 240         require PublicInbox::URIimap;
 241         my $uri = PublicInbox::URIimap->new($url);
 242         $uri && ($ls_ok || $uri->mailbox) ? $uri->canonical : undef;
 243 }
 244
 245 my %IS_NNTP = (news => 1, snews => 1, nntp => 1, nntps => 1);
 246 sub nntp_uri {
 247         my ($url, $ls_ok) = @_;
 248         require PublicInbox::URInntps;
 249         my $uri = PublicInbox::URInntps->new($url);
 250         $uri && $IS_NNTP{$uri->scheme} && ($ls_ok || $uri->group) ?
 251                 $uri->canonical : undef;
 252 }
 253
 254 sub cfg_intvl ($$$) {
 255         my ($cfg, $key, $url) = @_;
 256         my $v = $cfg->urlmatch($key, $url) // return;
 257         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 258         if (ref($v) eq 'ARRAY') {
 259                 $v = join(', ', @$v);
 260                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 261         } else {
 262                 warn "W: $key=$v is not a numeric value in seconds\n";
 263         }
 264 }
 265
 266 sub cfg_bool ($$$) {
 267         my ($cfg, $key, $url) = @_;
 268         my $orig = $cfg->urlmatch($key, $url) // return;
 269         my $bool = $cfg->git_bool($orig);
 270         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 271         $bool;
 272 }
 273
 274 # flesh out common IMAP-specific data structures
 275 sub imap_common_init ($;$) {
 276         my ($self, $lei) = @_;
 277         return unless $self->{imap_order};
 278         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 279         eval { require PublicInbox::IMAPClient } or
 280                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 281         ($lei || eval { require PublicInbox::IMAPTracker }) or
 282                 die "DBD::SQLite is required for IMAP\n:$@\n";
 283         require PublicInbox::URIimap;
 284         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 285         my $mic_args = {}; # scheme://authority => Mail:IMAPClient arg
 286         for my $uri (@{$self->{imap_order}}) {
 287                 my $sec = uri_section($uri);
 288                 for my $k (qw(Starttls Debug Compress)) {
 289                         my $bool = cfg_bool($cfg, "imap.$k", $$uri) // next;
 290                         $mic_args->{$sec}->{$k} = $bool;
 291                 }
 292                 my $to = cfg_intvl($cfg, 'imap.timeout', $$uri);
 293                 $mic_args->{$sec}->{Timeout} = $to if $to;
 294                 my $sa = socks_args($cfg->urlmatch('imap.Proxy', $$uri));
 295                 $self->{imap_opt}->{$sec}->{-proxy_cfg} = $sa if $sa;
 296                 for my $k (qw(pollInterval idleInterval)) {
 297                         $to = cfg_intvl($cfg, "imap.$k", $$uri) // next;
 298                         $self->{imap_opt}->{$sec}->{$k} = $to;
 299                 }
 300                 my $k = 'imap.fetchBatchSize';
 301                 my $bs = $cfg->urlmatch($k, $$uri) // next;
 302                 if ($bs =~ /\A([0-9]+)\z/) {
 303                         $self->{imap_opt}->{$sec}->{batch_size} = $bs;
 304                 } else {
 305                         warn "$k=$bs is not an integer\n";
 306                 }
 307         }
 308         # make sure we can connect and cache the credentials in memory
 309         $self->{mic_arg} = {}; # schema://authority => IMAPClient->new args
 310         my $mics = {}; # schema://authority => IMAPClient obj
 311         for my $orig_uri (@{$self->{imap_order}}) {
 312                 my $sec = uri_section($orig_uri);
 313                 my $uri = PublicInbox::URIimap->new("$sec/");
 314                 my $mic = $mics->{$sec} //=
 315                                 mic_for($self, $uri, $mic_args, $lei) //
 316                                 die "Unable to continue\n";
 317                 next unless $self->isa('PublicInbox::NetWriter');
 318                 my $dst = $orig_uri->mailbox // next;
 319                 next if $mic->exists($dst); # already exists
 320                 $mic->create($dst) or die "CREATE $dst failed <$orig_uri>: $@";
 321         }
 322         $mics;
 323 }
 324
 325 # flesh out common NNTP-specific data structures
 326 sub nntp_common_init ($;$) {
 327         my ($self, $lei) = @_;
 328         return unless $self->{nntp_order};
 329         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 330         eval { require Net::NNTP } or
 331                 die "Net::NNTP is required for NNTP:\n$@\n";
 332         ($lei || eval { require PublicInbox::IMAPTracker }) or
 333                 die "DBD::SQLite is required for NNTP\n:$@\n";
 334         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 335         my $nn_args = {}; # scheme://authority => Net::NNTP->new arg
 336         for my $uri (@{$self->{nntp_order}}) {
 337                 my $sec = uri_section($uri);
 338                 my $args = $nn_args->{$sec} //= {};
 339
 340                 # Debug and Timeout are passed to Net::NNTP->new
 341                 my $v = cfg_bool($cfg, 'nntp.Debug', $$uri);
 342                 $args->{Debug} = $v if defined $v;
 343                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $$uri);
 344                 $args->{Timeout} = $to if $to;
 345                 my $sa = socks_args($cfg->urlmatch('nntp.Proxy', $$uri));
 346                 %$args = (%$args, %$sa) if $sa;
 347
 348                 # Net::NNTP post-connect commands
 349                 for my $k (qw(starttls compress)) {
 350                         $v = cfg_bool($cfg, "nntp.$k", $$uri) // next;
 351                         $self->{nntp_opt}->{$sec}->{$k} = $v;
 352                 }
 353
 354                 # -watch internal option
 355                 for my $k (qw(pollInterval)) {
 356                         $to = cfg_intvl($cfg, "nntp.$k", $$uri) // next;
 357                         $self->{nntp_opt}->{$sec}->{$k} = $to;
 358                 }
 359         }
 360         # make sure we can connect and cache the credentials in memory
 361         $self->{nn_arg} = {}; # schema://authority => Net::NNTP->new args
 362         my %nn; # schema://authority => Net::NNTP object
 363         for my $uri (@{$self->{nntp_order}}) {
 364                 my $sec = uri_section($uri);
 365                 $nn{$sec} //= nn_for($self, $uri, $nn_args, $lei);
 366         }
 367         \%nn; # for optional {nn_cached}
 368 }
 369
 370 sub add_url {
 371         my ($self, $arg, $ls_ok) = @_;
 372         my $uri;
 373         if ($uri = imap_uri($arg, $ls_ok)) {
 374                 $_[1] = $$uri; # canonicalized
 375                 push @{$self->{imap_order}}, $uri;
 376         } elsif ($uri = nntp_uri($arg, $ls_ok)) {
 377                 $_[1] = $$uri; # canonicalized
 378                 push @{$self->{nntp_order}}, $uri;
 379         } else {
 380                 push @{$self->{unsupported_url}}, $arg;
 381         }
 382 }
 383
 384 sub errors {
 385         my ($self, $lei) = @_;
 386         if (my $u = $self->{unsupported_url}) {
 387                 return "Unsupported URL(s): @$u";
 388         }
 389         if ($self->{imap_order}) {
 390                 eval { require PublicInbox::IMAPClient } or
 391                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 392         }
 393         if ($self->{nntp_order}) {
 394                 eval { require Net::NNTP } or
 395                         die "Net::NNTP is required for NNTP:\n$@\n";
 396         }
 397         my $sa = socks_args($lei ? $lei->{opt}->{proxy} : undef);
 398         $self->{-proxy_cli} = $sa if $sa;
 399         undef;
 400 }
 401
 402 sub flags2kw ($$$$) {
 403         my ($self, $uri, $uid, $flags) = @_;
 404         my $kw = [];
 405         for my $f (split(/ /, $flags)) {
 406                 if (my $k = $IMAPflags2kw{$f}) {
 407                         push @$kw, $k;
 408                 } elsif ($f eq "\\Recent") { # not in JMAP
 409                 } elsif ($f eq "\\Deleted") { # not in JMAP
 410                         return;
 411                 } elsif ($self->{verbose}) {
 412                         warn "# unknown IMAP flag $f <$uri/;UID=$uid>\n";
 413                 }
 414         }
 415         @$kw = sort @$kw; # for LeiSearch->kw_changed and UI/UX purposes
 416         $kw;
 417 }
 418
 419 sub _imap_do_msg ($$$$$) {
 420         my ($self, $uri, $uid, $raw, $flags) = @_;
 421         # our target audience expects LF-only, save storage
 422         $$raw =~ s/\r\n/\n/sg;
 423         my $kw = defined($flags) ?
 424                 (flags2kw($self, $uri, $uid, $flags) // return) : undef;
 425         my ($eml_cb, @args) = @{$self->{eml_each}};
 426         $eml_cb->($uri, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 427 }
 428
 429 sub run_commit_cb ($) {
 430         my ($self) = @_;
 431         my $cmt_cb_args = $self->{on_commit} or return;
 432         my ($cb, @args) = @$cmt_cb_args;
 433         $cb->(@args);
 434 }
 435
 436 sub itrk_last ($$;$$) {
 437         my ($self, $uri, $r_uidval, $mic) = @_;
 438         return (undef, undef, $r_uidval) unless $self->{incremental};
 439         my ($itrk, $l_uid, $l_uidval);
 440         if (defined(my $lms = $self->{-lms_ro})) { # LeiMailSync or 0
 441                 $uri->uidvalidity($r_uidval) if defined $r_uidval;
 442                 if ($mic) {
 443                         my $auth = $mic->Authmechanism // '';
 444                         $uri->auth($auth) if $auth eq 'ANONYMOUS';
 445                         my $user = $mic->User;
 446                         $uri->user($user) if defined($user);
 447                 }
 448                 my $x;
 449                 $l_uid = ($lms && ($x = $lms->location_stats($$uri))) ?
 450                                 $x->{'uid.max'} : undef;
 451                 # itrk remains undef, lei/store worker writes to
 452                 # mail_sync.sqlite3
 453         } else {
 454                 $itrk = PublicInbox::IMAPTracker->new($$uri);
 455                 ($l_uidval, $l_uid) = $itrk->get_last($$uri);
 456         }
 457         ($itrk, $l_uid, $l_uidval //= $r_uidval);
 458 }
 459
 460 # import flags of already-seen messages
 461 sub each_old_flags ($$$$) {
 462         my ($self, $mic, $uri, $l_uid) = @_;
 463         $l_uid ||= 1;
 464         my $sec = uri_section($uri);
 465         my $bs = ($self->{imap_opt}->{$sec}->{batch_size} // 1) * 10000;
 466         my ($eml_cb, @args) = @{$self->{eml_each}};
 467         $self->{quiet} or warn "# $uri syncing flags 1:$l_uid\n";
 468         for (my $n = 1; $n <= $l_uid; $n += $bs) {
 469                 my $end = $n + $bs;
 470                 $end = $l_uid if $end > $l_uid;
 471                 my $r = $mic->fetch_hash("$n:$end", 'FLAGS');
 472                 if (!$r) {
 473                         return if $!{EINTR} && $self->{quit};
 474                         return "E: $uri UID FETCH $n:$end error: $!";
 475                 }
 476                 while (my ($uid, $per_uid) = each %$r) {
 477                         my $kw = flags2kw($self, $uri, $uid, $per_uid->{FLAGS})
 478                                 // next;
 479                         # LeiImport->input_net_cb
 480                         $eml_cb->($uri, $uid, $kw, undef, @args);
 481                 }
 482         }
 483 }
 484
 485 # returns true if PERMANENTFLAGS indicates FLAGS of already imported
 486 # messages are meaningful
 487 sub perm_fl_ok ($) {
 488         my ($perm_fl) = @_;
 489         return if !defined($perm_fl);
 490         for my $f (split(/[ \t]+/, $perm_fl)) {
 491                 return 1 if $IMAPflags2kw{$f};
 492         }
 493         undef;
 494 }
 495
 496 # may be overridden in NetWriter or Watch
 497 sub folder_select { $_[0]->{each_old} ? 'select' : 'examine' }
 498
 499 sub _imap_fetch_all ($$$) {
 500         my ($self, $mic, $orig_uri) = @_;
 501         my $sec = uri_section($orig_uri);
 502         my $mbx = $orig_uri->mailbox;
 503         $mic->Clear(1); # trim results history
 504
 505         # we need to check for mailbox writability to see if we care about
 506         # FLAGS from already-imported messages.
 507         my $cmd = $self->folder_select;
 508         $mic->$cmd($mbx) or return "E: \U$cmd\E $mbx ($sec) failed: $!";
 509
 510         my ($r_uidval, $r_uidnext, $perm_fl);
 511         for ($mic->Results) {
 512                 /^\* OK \[PERMANENTFLAGS \(([^\)]*)\)\].*/ and $perm_fl = $1;
 513                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 514                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 515         }
 516         $r_uidval //= $mic->uidvalidity($mbx) //
 517                 return "E: $orig_uri cannot get UIDVALIDITY";
 518         $r_uidnext //= $mic->uidnext($mbx) //
 519                 return "E: $orig_uri cannot get UIDNEXT";
 520         my $expect = $orig_uri->uidvalidity // $r_uidval;
 521         return <<EOF if $expect != $r_uidval;
 522 E: $orig_uri UIDVALIDITY mismatch (got $r_uidval)
 523 EOF
 524
 525         my $uri = $orig_uri->clone;
 526         my $single_uid = $uri->uid;
 527         my ($itrk, $l_uid, $l_uidval) = itrk_last($self, $uri, $r_uidval, $mic);
 528         if (defined($single_uid)) {
 529                 $itrk = $l_uid = undef;
 530                 $uri->uid(undef); # for eml_cb
 531         }
 532         return <<EOF if $l_uidval != $r_uidval;
 533 E: $uri UIDVALIDITY mismatch
 534 E: local=$l_uidval != remote=$r_uidval
 535 EOF
 536         $uri->uidvalidity($r_uidval);
 537         $l_uid //= 0;
 538         my $r_uid = $r_uidnext - 1;
 539         return <<EOF if $l_uid > $r_uid;
 540 E: $uri local UID exceeds remote ($l_uid > $r_uid)
 541 E: $uri strangely, UIDVALIDLITY matches ($l_uidval)
 542 EOF
 543         $mic->Uid(1); # the default, we hope
 544         my $err;
 545         my $use_fl = perm_fl_ok($perm_fl);
 546         if (!defined($single_uid) && $self->{each_old} && $use_fl) {
 547                 $err = each_old_flags($self, $mic, $uri, $l_uid);
 548                 return $err if $err;
 549         }
 550         return if $l_uid >= $r_uid; # nothing to do
 551         $l_uid ||= 1;
 552         my ($mod, $shard) = @{$self->{shard_info} // []};
 553         unless ($self->{quiet}) {
 554                 my $m = $mod ? " [(UID % $mod) == $shard]" : '';
 555                 warn "# $uri fetching UID $l_uid:$r_uid$m\n";
 556         }
 557         my $bs = $self->{imap_opt}->{$sec}->{batch_size} // 1;
 558         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 559         my $key = $req;
 560         $key =~ s/\.PEEK//;
 561         my ($uids, $batch);
 562         do {
 563                 # I wish "UID FETCH $START:*" could work, but:
 564                 # 1) servers do not need to return results in any order
 565                 # 2) Mail::IMAPClient doesn't offer a streaming API
 566                 if (defined $single_uid) {
 567                         $uids = [ $single_uid ];
 568                 } elsif (!($uids = $mic->search("UID $l_uid:*"))) {
 569                         return if $!{EINTR} && $self->{quit};
 570                         return "E: $uri UID SEARCH $l_uid:* error: $!";
 571                 }
 572                 return if scalar(@$uids) == 0;
 573
 574                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 575                 # responses, so sort it ourselves.  Order matters so
 576                 # IMAPTracker can store the newest UID.
 577                 @$uids = sort { $a <=> $b } @$uids;
 578
 579                 # Did we actually get new messages?
 580                 return if $uids->[0] < $l_uid;
 581
 582                 $l_uid = $uids->[-1] + 1; # for next search
 583                 my $last_uid;
 584                 my $n = $self->{max_batch};
 585
 586                 @$uids = grep { ($_ % $mod) == $shard } @$uids if $mod;
 587                 while (scalar @$uids) {
 588                         my @batch = splice(@$uids, 0, $bs);
 589                         $batch = join(',', @batch);
 590                         local $0 = "UID:$batch $mbx $sec";
 591                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 592                         unless ($r) { # network error?
 593                                 last if $!{EINTR} && $self->{quit};
 594                                 $err = "E: $uri UID FETCH $batch error: $!";
 595                                 last;
 596                         }
 597                         for my $uid (@batch) {
 598                                 # messages get deleted, so holes appear
 599                                 my $per_uid = delete $r->{$uid} // next;
 600                                 my $raw = delete($per_uid->{$key}) // next;
 601                                 my $fl = $use_fl ? $per_uid->{FLAGS} : undef;
 602                                 _imap_do_msg($self, $uri, $uid, \$raw, $fl);
 603                                 $last_uid = $uid;
 604                                 last if $self->{quit};
 605                         }
 606                         last if $self->{quit};
 607                 }
 608                 run_commit_cb($self);
 609                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 610         } until ($err || $self->{quit} || defined($single_uid));
 611         $err;
 612 }
 613
 614 # uses cached auth info prepared by mic_for
 615 sub mic_get {
 616         my ($self, $uri) = @_;
 617         my $sec = uri_section($uri);
 618         # see if caller saved result of imap_common_init
 619         my $cached = $self->{mics_cached};
 620         if ($cached) {
 621                 my $mic = $cached->{$sec};
 622                 return $mic if $mic && $mic->IsConnected;
 623                 delete $cached->{$sec};
 624         }
 625         my $mic_arg = $self->{mic_arg}->{$sec} or
 626                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 627         if (defined(my $cb_name = $mic_arg->{Authcallback})) {
 628                 if (ref($cb_name) ne 'CODE') {
 629                         $mic_arg->{Authcallback} = $self->can($cb_name);
 630                 }
 631         }
 632         my $mic = mic_new($self, $mic_arg, $sec, $uri);
 633         $cached //= {}; # invalid placeholder if no cache enabled
 634         $mic && $mic->IsConnected ? ($cached->{$sec} = $mic) : undef;
 635 }
 636
 637 sub imap_each {
 638         my ($self, $url, $eml_cb, @args) = @_;
 639         my $uri = ref($url) ? $url : PublicInbox::URIimap->new($url);
 640         my $sec = uri_section($uri);
 641         local $0 = $uri->mailbox." $sec";
 642         my $mic = mic_get($self, $uri);
 643         my $err;
 644         if ($mic) {
 645                 local $self->{eml_each} = [ $eml_cb, @args ];
 646                 $err = _imap_fetch_all($self, $mic, $uri);
 647         } else {
 648                 $err = "E: <$uri> not connected: $!";
 649         }
 650         die $err if $err && $self->{-can_die};
 651         warn $err if $err;
 652         $mic;
 653 }
 654
 655 # may used cached auth info prepared by nn_for once
 656 sub nn_get {
 657         my ($self, $uri) = @_;
 658         my $sec = uri_section($uri);
 659         # see if caller saved result of nntp_common_init
 660         my $cached = $self->{nn_cached} // {};
 661         my $nn;
 662         $nn = delete($cached->{$sec}) and return $nn;
 663         my $nn_arg = $self->{nn_arg}->{$sec} or
 664                         die "BUG: no Net::NNTP->new arg for $sec";
 665         my $nntp_opt = $self->{nntp_opt}->{$sec};
 666         $nn = nn_new($nn_arg, $nntp_opt, $uri) or return;
 667         if (my $postconn = $nntp_opt->{-postconn}) {
 668                 for my $m_arg (@$postconn) {
 669                         my ($method, @args) = @$m_arg;
 670                         $nn->$method(@args) and next;
 671                         die "E: <$uri> $method failed\n";
 672                         return;
 673                 }
 674         }
 675         $nn;
 676 }
 677
 678 sub _nntp_fetch_all ($$$) {
 679         my ($self, $nn, $uri) = @_;
 680         my ($group, $num_a, $num_b) = $uri->group;
 681         my $sec = uri_section($uri);
 682         my ($nr, $beg, $end) = $nn->group($group);
 683         unless (defined($nr)) {
 684                 my $msg = ndump($nn->message);
 685                 return "E: GROUP $group <$sec> $msg";
 686         }
 687
 688         # IMAPTracker is also used for tracking NNTP, UID == article number
 689         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 690         # expensive.  So we assume newsgroups don't change:
 691         my ($itrk, $l_art) = itrk_last($self, $uri);
 692
 693         # allow users to specify articles to refetch
 694         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 695         # nntp://example.com/inbox.foo/$num_a-$num_b
 696         $beg = $num_a if defined($num_a) && $num_a < $beg;
 697         $end = $num_b if defined($num_b) && $num_b < $end;
 698         if (defined $l_art) {
 699                 return if $l_art >= $end; # nothing to do
 700                 $beg = $l_art + 1;
 701         }
 702         my ($err, $art, $last_art, $kw); # kw stays undef, no keywords in NNTP
 703         unless ($self->{quiet}) {
 704                 warn "# $uri fetching ARTICLE $beg..$end\n";
 705         }
 706         my $n = $self->{max_batch};
 707         for ($beg..$end) {
 708                 last if $self->{quit};
 709                 $art = $_;
 710                 if (--$n < 0) {
 711                         run_commit_cb($self);
 712                         $itrk->update_last(0, $last_art) if $itrk;
 713                         $n = $self->{max_batch};
 714                 }
 715                 my $raw = $nn->article($art);
 716                 unless (defined($raw)) {
 717                         my $msg = ndump($nn->message);
 718                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 719                                 $err = "E: $msg";
 720                                 last;
 721                         } else { # probably just a deleted message (spam)
 722                                 warn "W: $msg";
 723                                 next;
 724                         }
 725                 }
 726                 $raw = join('', @$raw);
 727                 $raw =~ s/\r\n/\n/sg;
 728                 my ($eml_cb, @args) = @{$self->{eml_each}};
 729                 $eml_cb->($uri, $art, $kw, PublicInbox::Eml->new(\$raw), @args);
 730                 $last_art = $art;
 731         }
 732         run_commit_cb($self);
 733         $itrk->update_last(0, $last_art) if $itrk;
 734         $err;
 735 }
 736
 737 sub nntp_each {
 738         my ($self, $url, $eml_cb, @args) = @_;
 739         my $uri = ref($url) ? $url : PublicInbox::URInntps->new($url);
 740         my $sec = uri_section($uri);
 741         local $0 = $uri->group ." $sec";
 742         my $nn = nn_get($self, $uri);
 743         return if $self->{quit};
 744         my $err;
 745         if ($nn) {
 746                 local $self->{eml_each} = [ $eml_cb, @args ];
 747                 $err = _nntp_fetch_all($self, $nn, $uri);
 748         } else {
 749                 $err = "E: <$uri> not connected: $!";
 750         }
 751         die $err if $err && $self->{-can_die};
 752         warn $err if $err;
 753         $nn;
 754 }
 755
 756 sub new { bless {}, shift };
 757
 758 # updates $uri with UIDVALIDITY
 759 sub mic_for_folder {
 760         my ($self, $uri) = @_;
 761         my $mic = $self->mic_get($uri) or die "E: not connected: $@";
 762         my $m = $self->isa('PublicInbox::NetWriter') ? 'select' : 'examine';
 763         $mic->$m($uri->mailbox) or return;
 764         my $uidval;
 765         for ($mic->Results) {
 766                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ or next;
 767                 $uidval = $1;
 768                 last;
 769         }
 770         $uidval //= $mic->uidvalidity($uri->mailbox) or
 771                 die "E: failed to get uidvalidity from <$uri>: $@";
 772         $uri->uidvalidity($uidval);
 773         $mic;
 774 }
 775
 776
 777 1;