lib/PublicInbox/NetReader.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common reader code for IMAP and NNTP (and maybe JMAP)
   5 package PublicInbox::NetReader;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(Exporter PublicInbox::IPC);
   9 use PublicInbox::Eml;
  10 use PublicInbox::Config;
  11 our %IMAPflags2kw = map {; "\\\u$_" => $_ } qw(seen answered flagged draft);
  12 $IMAPflags2kw{'$Forwarded'} = 'forwarded';  # RFC 5550
  13
  14 our @EXPORT = qw(uri_section imap_uri nntp_uri);
  15
  16 sub ndump {
  17         require Data::Dumper;
  18         Data::Dumper->new(\@_)->Useqq(1)->Terse(1)->Dump;
  19 }
  20
  21 # returns the git config section name, e.g [imap "imaps://user@example.com"]
  22 # without the mailbox, so we can share connections between different inboxes
  23 sub uri_section ($) {
  24         my ($uri) = @_;
  25         $uri->scheme . '://' . $uri->authority;
  26 }
  27
  28 sub socks_args ($) {
  29         my ($val) = @_;
  30         return if ($val // '') eq '';
  31         if ($val =~ m!\Asocks5h:// (?: \[ ([^\]]+) \] | ([^:/]+) )
  32                                         (?::([0-9]+))?/*\z!ix) {
  33                 my ($h, $p) = ($1 // $2, $3 + 0);
  34                 $h = '127.0.0.1' if $h eq '0';
  35                 eval { require IO::Socket::Socks } or die <<EOM;
  36 IO::Socket::Socks missing for socks5h://$h:$p
  37 EOM
  38                 return { ProxyAddr => $h, ProxyPort => $p };
  39         }
  40         die "$val not understood (only socks5h:// is supported)\n";
  41 }
  42
  43 sub mic_new ($$$$) {
  44         my ($self, $mic_arg, $sec, $uri) = @_;
  45         my %socks;
  46         my $sa = $self->{imap_opt}->{$sec}->{-proxy_cfg} || $self->{-proxy_cli};
  47         if ($sa) {
  48                 my %opt = %$sa;
  49                 $opt{ConnectAddr} = delete $mic_arg->{Server};
  50                 $opt{ConnectPort} = delete $mic_arg->{Port};
  51                 $socks{Socket} = IO::Socket::Socks->new(%opt) or die
  52                         "E: <$$uri> ".eval('$IO::Socket::Socks::SOCKS_ERROR');
  53         }
  54         PublicInbox::IMAPClient->new(%$mic_arg, %socks);
  55 }
  56
  57 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
  58
  59 # mic_for may prompt the user and store auth info, prepares mic_get
  60 sub mic_for ($$$$) { # mic = Mail::IMAPClient
  61         my ($self, $uri, $mic_args, $lei) = @_;
  62         require PublicInbox::GitCredential;
  63         my $cred = bless {
  64                 url => "$uri",
  65                 protocol => $uri->scheme,
  66                 host => $uri->host,
  67                 username => $uri->user,
  68                 password => $uri->password,
  69         }, 'PublicInbox::GitCredential';
  70         my $sec = uri_section($uri);
  71         my $common = $mic_args->{$sec} // {};
  72         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
  73         my $host = $cred->{host};
  74         $host = '127.0.0.1' if $host eq '0';
  75         my $mic_arg = {
  76                 Port => $uri->port,
  77                 Server => $host,
  78                 Ssl => $uri->scheme eq 'imaps',
  79                 Keepalive => 1, # SO_KEEPALIVE
  80                 %$common, # may set Starttls, Compress, Debug ....
  81         };
  82         $mic_arg->{Ssl} = 1 if $uri->scheme eq 'imaps';
  83         require PublicInbox::IMAPClient;
  84         my $mic = mic_new($self, $mic_arg, $sec, $uri) or
  85                         die "E: <$uri> new: $@\n";
  86         # default to using STARTTLS if it's available, but allow
  87         # it to be disabled since I usually connect to localhost
  88         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
  89                         $mic->has_capability('STARTTLS') &&
  90                         $mic->can('starttls')) {
  91                 $mic->starttls or die "E: <$uri> STARTTLS: $@\n";
  92         }
  93
  94         # do we even need credentials?
  95         if (!defined($cred->{username}) &&
  96                         $mic->has_capability('AUTH=ANONYMOUS')) {
  97                 $cred = undef;
  98         }
  99         if ($cred) {
 100                 my $p = $cred->{password} // $cred->check_netrc;
 101                 $cred->fill($lei) unless defined($p); # may prompt user here
 102                 $mic->User($mic_arg->{User} = $cred->{username});
 103                 $mic->Password($mic_arg->{Password} = $cred->{password});
 104         } else { # AUTH=ANONYMOUS
 105                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
 106                 $mic_arg->{Authcallback} = 'auth_anon_cb';
 107                 $mic->Authcallback(\&auth_anon_cb);
 108         }
 109         my $err;
 110         if ($mic->login && $mic->IsAuthenticated) {
 111                 # success! keep IMAPClient->new arg in case we get disconnected
 112                 $self->{mic_arg}->{$sec} = $mic_arg;
 113                 if ($cred) {
 114                         $uri->user($cred->{username}) if !defined($uri->user);
 115                 } elsif ($mic_arg->{Authmechanism} eq 'ANONYMOUS') {
 116                         $uri->auth('ANONYMOUS') if !defined($uri->auth);
 117                 }
 118         } else {
 119                 $err = "E: <$uri> LOGIN: $@\n";
 120                 if ($cred && defined($cred->{password})) {
 121                         $err =~ s/\Q$cred->{password}\E/*******/g;
 122                 }
 123                 $mic = undef;
 124         }
 125         $cred->run($mic ? 'approve' : 'reject') if $cred && $cred->{filled};
 126         if ($err) {
 127                 $lei ? $lei->fail($err) : warn($err);
 128         }
 129         $mic;
 130 }
 131
 132 # Net::NNTP doesn't support CAPABILITIES, yet
 133 sub try_starttls ($) {
 134         my ($host) = @_;
 135         return if $host =~ /\.onion\z/s;
 136         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 137         return if $host eq '::1';
 138         1;
 139 }
 140
 141 sub nn_new ($$$) {
 142         my ($nn_arg, $nntp_opt, $uri) = @_;
 143         my $nn;
 144         if (defined $nn_arg->{ProxyAddr}) {
 145                 require PublicInbox::NetNNTPSocks;
 146                 eval { $nn = PublicInbox::NetNNTPSocks->new_socks(%$nn_arg) };
 147                 die "E: <$uri> $@\n" if $@;
 148         } else {
 149                 $nn = Net::NNTP->new(%$nn_arg) or die "E: <$uri> new: $!\n";
 150         }
 151
 152         # default to using STARTTLS if it's available, but allow
 153         # it to be disabled for localhost/VPN users
 154         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 155                 if (!defined($nntp_opt->{starttls}) &&
 156                                 try_starttls($nn_arg->{Host})) {
 157                         # soft fail by default
 158                         $nn->starttls or warn <<"";
 159 W: <$uri> STARTTLS tried and failed (not requested)
 160
 161                 } elsif ($nntp_opt->{starttls}) {
 162                         # hard fail if explicitly configured
 163                         $nn->starttls or die <<"";
 164 E: <$uri> STARTTLS requested and failed
 165
 166                 }
 167         } elsif ($nntp_opt->{starttls}) {
 168                 $nn->can('starttls') or
 169                         die "E: <$uri> Net::NNTP too old for STARTTLS\n";
 170                 $nn->starttls or die <<"";
 171 E: <$uri> STARTTLS requested and failed
 172
 173         }
 174         $nn;
 175 }
 176
 177 sub nn_for ($$$$) { # nn = Net::NNTP
 178         my ($self, $uri, $nn_args, $lei) = @_;
 179         my $sec = uri_section($uri);
 180         my $nntp_opt = $self->{nntp_opt}->{$sec} //= {};
 181         my $host = $uri->host;
 182         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 183         $host = '127.0.0.1' if $host eq '0';
 184         my $cred;
 185         my ($u, $p);
 186         if (defined(my $ui = $uri->userinfo)) {
 187                 require PublicInbox::GitCredential;
 188                 $cred = bless {
 189                         url => $sec,
 190                         protocol => $uri->scheme,
 191                         host => $host,
 192                 }, 'PublicInbox::GitCredential';
 193                 ($u, $p) = split(/:/, $ui, 2);
 194                 ($cred->{username}, $cred->{password}) = ($u, $p);
 195                 $p //= $cred->check_netrc;
 196         }
 197         my $common = $nn_args->{$sec} // {};
 198         my $nn_arg = {
 199                 Port => $uri->port,
 200                 Host => $host,
 201                 %$common, # may Debug ....
 202         };
 203         $nn_arg->{SSL} = 1 if $uri->secure; # snews == nntps
 204         my $sa = $self->{-proxy_cli};
 205         %$nn_arg = (%$nn_arg, %$sa) if $sa;
 206         my $nn = nn_new($nn_arg, $nntp_opt, $uri);
 207         if ($cred) {
 208                 $cred->fill($lei) unless defined($p); # may prompt user here
 209                 if ($nn->authinfo($u, $p)) {
 210                         push @{$nntp_opt->{-postconn}}, [ 'authinfo', $u, $p ];
 211                 } else {
 212                         warn "E: <$uri> AUTHINFO $u XXXX failed\n";
 213                         $nn = undef;
 214                 }
 215         }
 216
 217         if ($nntp_opt->{compress}) {
 218                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 219                 if ($nn->can('compress')) {
 220                         if ($nn->compress) {
 221                                 push @{$nntp_opt->{-postconn}}, [ 'compress' ];
 222                         } else {
 223                                 warn "W: <$uri> COMPRESS failed\n";
 224                         }
 225                 } else {
 226                         delete $nntp_opt->{compress};
 227                         warn <<"";
 228 W: <$uri> COMPRESS not supported by Net::NNTP
 229 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 230
 231                 }
 232         }
 233
 234         $self->{nn_arg}->{$sec} = $nn_arg;
 235         $cred->run($nn ? 'approve' : 'reject') if $cred && $cred->{filled};
 236         $nn;
 237 }
 238
 239 sub imap_uri {
 240         my ($url, $ls_ok) = @_;
 241         require PublicInbox::URIimap;
 242         my $uri = PublicInbox::URIimap->new($url);
 243         $uri && ($ls_ok || $uri->mailbox) ? $uri->canonical : undef;
 244 }
 245
 246 my %IS_NNTP = (news => 1, snews => 1, nntp => 1, nntps => 1);
 247 sub nntp_uri {
 248         my ($url, $ls_ok) = @_;
 249         require PublicInbox::URInntps;
 250         my $uri = PublicInbox::URInntps->new($url);
 251         $uri && $IS_NNTP{$uri->scheme} && ($ls_ok || $uri->group) ?
 252                 $uri->canonical : undef;
 253 }
 254
 255 sub cfg_intvl ($$$) {
 256         my ($cfg, $key, $url) = @_;
 257         my $v = $cfg->urlmatch($key, $url) // return;
 258         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 259         if (ref($v) eq 'ARRAY') {
 260                 $v = join(', ', @$v);
 261                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 262         } else {
 263                 warn "W: $key=$v is not a numeric value in seconds\n";
 264         }
 265 }
 266
 267 sub cfg_bool ($$$) {
 268         my ($cfg, $key, $url) = @_;
 269         my $orig = $cfg->urlmatch($key, $url) // return;
 270         my $bool = $cfg->git_bool($orig);
 271         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 272         $bool;
 273 }
 274
 275 # flesh out common IMAP-specific data structures
 276 sub imap_common_init ($;$) {
 277         my ($self, $lei) = @_;
 278         return unless $self->{imap_order};
 279         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 280         eval { require PublicInbox::IMAPClient } or
 281                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 282         ($lei || eval { require PublicInbox::IMAPTracker }) or
 283                 die "DBD::SQLite is required for IMAP\n:$@\n";
 284         require PublicInbox::URIimap;
 285         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 286         my $mic_args = {}; # scheme://authority => Mail:IMAPClient arg
 287         for my $uri (@{$self->{imap_order}}) {
 288                 my $sec = uri_section($uri);
 289                 for my $k (qw(Starttls Debug Compress)) {
 290                         my $bool = cfg_bool($cfg, "imap.$k", $$uri) // next;
 291                         $mic_args->{$sec}->{$k} = $bool;
 292                 }
 293                 my $to = cfg_intvl($cfg, 'imap.timeout', $$uri);
 294                 $mic_args->{$sec}->{Timeout} = $to if $to;
 295                 my $sa = socks_args($cfg->urlmatch('imap.Proxy', $$uri));
 296                 $self->{imap_opt}->{$sec}->{-proxy_cfg} = $sa if $sa;
 297                 for my $k (qw(pollInterval idleInterval)) {
 298                         $to = cfg_intvl($cfg, "imap.$k", $$uri) // next;
 299                         $self->{imap_opt}->{$sec}->{$k} = $to;
 300                 }
 301                 my $k = 'imap.fetchBatchSize';
 302                 my $bs = $cfg->urlmatch($k, $$uri) // next;
 303                 if ($bs =~ /\A([0-9]+)\z/) {
 304                         $self->{imap_opt}->{$sec}->{batch_size} = $bs;
 305                 } else {
 306                         warn "$k=$bs is not an integer\n";
 307                 }
 308         }
 309         # make sure we can connect and cache the credentials in memory
 310         $self->{mic_arg} = {}; # schema://authority => IMAPClient->new args
 311         my $mics = {}; # schema://authority => IMAPClient obj
 312         for my $orig_uri (@{$self->{imap_order}}) {
 313                 my $sec = uri_section($orig_uri);
 314                 my $uri = PublicInbox::URIimap->new("$sec/");
 315                 my $mic = $mics->{$sec} //=
 316                                 mic_for($self, $uri, $mic_args, $lei) //
 317                                 die "Unable to continue\n";
 318                 next unless $self->isa('PublicInbox::NetWriter');
 319                 my $dst = $orig_uri->mailbox // next;
 320                 next if $mic->exists($dst); # already exists
 321                 $mic->create($dst) or die "CREATE $dst failed <$orig_uri>: $@";
 322         }
 323         $mics;
 324 }
 325
 326 # flesh out common NNTP-specific data structures
 327 sub nntp_common_init ($;$) {
 328         my ($self, $lei) = @_;
 329         return unless $self->{nntp_order};
 330         $self->{quiet} = 1 if $lei && $lei->{opt}->{quiet};
 331         eval { require Net::NNTP } or
 332                 die "Net::NNTP is required for NNTP:\n$@\n";
 333         ($lei || eval { require PublicInbox::IMAPTracker }) or
 334                 die "DBD::SQLite is required for NNTP\n:$@\n";
 335         my $cfg = $self->{pi_cfg} // $lei->_lei_cfg;
 336         my $nn_args = {}; # scheme://authority => Net::NNTP->new arg
 337         for my $uri (@{$self->{nntp_order}}) {
 338                 my $sec = uri_section($uri);
 339                 my $args = $nn_args->{$sec} //= {};
 340
 341                 # Debug and Timeout are passed to Net::NNTP->new
 342                 my $v = cfg_bool($cfg, 'nntp.Debug', $$uri);
 343                 $args->{Debug} = $v if defined $v;
 344                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $$uri);
 345                 $args->{Timeout} = $to if $to;
 346                 my $sa = socks_args($cfg->urlmatch('nntp.Proxy', $$uri));
 347                 %$args = (%$args, %$sa) if $sa;
 348
 349                 # Net::NNTP post-connect commands
 350                 for my $k (qw(starttls compress)) {
 351                         $v = cfg_bool($cfg, "nntp.$k", $$uri) // next;
 352                         $self->{nntp_opt}->{$sec}->{$k} = $v;
 353                 }
 354
 355                 # -watch internal option
 356                 for my $k (qw(pollInterval)) {
 357                         $to = cfg_intvl($cfg, "nntp.$k", $$uri) // next;
 358                         $self->{nntp_opt}->{$sec}->{$k} = $to;
 359                 }
 360         }
 361         # make sure we can connect and cache the credentials in memory
 362         $self->{nn_arg} = {}; # schema://authority => Net::NNTP->new args
 363         my %nn; # schema://authority => Net::NNTP object
 364         for my $uri (@{$self->{nntp_order}}) {
 365                 my $sec = uri_section($uri);
 366                 $nn{$sec} //= nn_for($self, $uri, $nn_args, $lei);
 367         }
 368         \%nn; # for optional {nn_cached}
 369 }
 370
 371 sub add_url {
 372         my ($self, $arg, $ls_ok) = @_;
 373         my $uri;
 374         if ($uri = imap_uri($arg, $ls_ok)) {
 375                 $_[1] = $$uri; # canonicalized
 376                 push @{$self->{imap_order}}, $uri;
 377         } elsif ($uri = nntp_uri($arg, $ls_ok)) {
 378                 $_[1] = $$uri; # canonicalized
 379                 push @{$self->{nntp_order}}, $uri;
 380         } else {
 381                 push @{$self->{unsupported_url}}, $arg;
 382         }
 383 }
 384
 385 sub errors {
 386         my ($self, $lei) = @_;
 387         if (my $u = $self->{unsupported_url}) {
 388                 return "Unsupported URL(s): @$u";
 389         }
 390         if ($self->{imap_order}) {
 391                 eval { require PublicInbox::IMAPClient } or
 392                         die "Mail::IMAPClient is required for IMAP:\n$@\n";
 393         }
 394         if ($self->{nntp_order}) {
 395                 eval { require Net::NNTP } or
 396                         die "Net::NNTP is required for NNTP:\n$@\n";
 397         }
 398         my $sa = socks_args($lei ? $lei->{opt}->{proxy} : undef);
 399         $self->{-proxy_cli} = $sa if $sa;
 400         undef;
 401 }
 402
 403 sub flags2kw ($$$$) {
 404         my ($self, $uri, $uid, $flags) = @_;
 405         my $kw = [];
 406         for my $f (split(/ /, $flags)) {
 407                 if (my $k = $IMAPflags2kw{$f}) {
 408                         push @$kw, $k;
 409                 } elsif ($f eq "\\Recent") { # not in JMAP
 410                 } elsif ($f eq "\\Deleted") { # not in JMAP
 411                         return;
 412                 } elsif ($self->{verbose}) {
 413                         warn "# unknown IMAP flag $f <$uri/;UID=$uid>\n";
 414                 }
 415         }
 416         @$kw = sort @$kw; # for LeiSearch->kw_changed and UI/UX purposes
 417         $kw;
 418 }
 419
 420 sub _imap_do_msg ($$$$$) {
 421         my ($self, $uri, $uid, $raw, $flags) = @_;
 422         # our target audience expects LF-only, save storage
 423         $$raw =~ s/\r\n/\n/sg;
 424         my $kw = defined($flags) ?
 425                 (flags2kw($self, $uri, $uid, $flags) // return) : undef;
 426         my ($eml_cb, @args) = @{$self->{eml_each}};
 427         $eml_cb->($uri, $uid, $kw, PublicInbox::Eml->new($raw), @args);
 428 }
 429
 430 sub run_commit_cb ($) {
 431         my ($self) = @_;
 432         my $cmt_cb_args = $self->{on_commit} or return;
 433         my ($cb, @args) = @$cmt_cb_args;
 434         $cb->(@args);
 435 }
 436
 437 sub itrk_last ($$;$$) {
 438         my ($self, $uri, $r_uidval, $mic) = @_;
 439         return (undef, undef, $r_uidval) unless $self->{incremental};
 440         my ($itrk, $l_uid, $l_uidval);
 441         if (defined(my $lms = $self->{-lms_ro})) { # LeiMailSync or 0
 442                 $uri->uidvalidity($r_uidval) if defined $r_uidval;
 443                 if ($mic) {
 444                         my $auth = $mic->Authmechanism // '';
 445                         $uri->auth($auth) if $auth eq 'ANONYMOUS';
 446                         my $user = $mic->User;
 447                         $uri->user($user) if defined($user);
 448                 }
 449                 my $x;
 450                 $l_uid = ($lms && ($x = $lms->location_stats($$uri))) ?
 451                                 $x->{'uid.max'} : undef;
 452                 # itrk remains undef, lei/store worker writes to
 453                 # mail_sync.sqlite3
 454         } else {
 455                 $itrk = PublicInbox::IMAPTracker->new($$uri);
 456                 ($l_uidval, $l_uid) = $itrk->get_last($$uri);
 457         }
 458         ($itrk, $l_uid, $l_uidval //= $r_uidval);
 459 }
 460
 461 # import flags of already-seen messages
 462 sub each_old_flags ($$$$) {
 463         my ($self, $mic, $uri, $l_uid) = @_;
 464         $l_uid ||= 1;
 465         my $sec = uri_section($uri);
 466         my $bs = ($self->{imap_opt}->{$sec}->{batch_size} // 1) * 10000;
 467         my ($eml_cb, @args) = @{$self->{eml_each}};
 468         $self->{quiet} or warn "# $uri syncing flags 1:$l_uid\n";
 469         for (my $n = 1; $n <= $l_uid; $n += $bs) {
 470                 my $end = $n + $bs;
 471                 $end = $l_uid if $end > $l_uid;
 472                 my $r = $mic->fetch_hash("$n:$end", 'FLAGS');
 473                 if (!$r) {
 474                         return if $!{EINTR} && $self->{quit};
 475                         return "E: $uri UID FETCH $n:$end error: $!";
 476                 }
 477                 while (my ($uid, $per_uid) = each %$r) {
 478                         my $kw = flags2kw($self, $uri, $uid, $per_uid->{FLAGS})
 479                                 // next;
 480                         # LeiImport->input_net_cb
 481                         $eml_cb->($uri, $uid, $kw, undef, @args);
 482                 }
 483         }
 484 }
 485
 486 # returns true if PERMANENTFLAGS indicates FLAGS of already imported
 487 # messages are meaningful
 488 sub perm_fl_ok ($) {
 489         my ($perm_fl) = @_;
 490         return if !defined($perm_fl);
 491         for my $f (split(/[ \t]+/, $perm_fl)) {
 492                 return 1 if $IMAPflags2kw{$f};
 493         }
 494         undef;
 495 }
 496
 497 # may be overridden in NetWriter or Watch
 498 sub folder_select { $_[0]->{each_old} ? 'select' : 'examine' }
 499
 500 sub _imap_fetch_all ($$$) {
 501         my ($self, $mic, $orig_uri) = @_;
 502         my $sec = uri_section($orig_uri);
 503         my $mbx = $orig_uri->mailbox;
 504         $mic->Clear(1); # trim results history
 505
 506         # we need to check for mailbox writability to see if we care about
 507         # FLAGS from already-imported messages.
 508         my $cmd = $self->folder_select;
 509         $mic->$cmd($mbx) or return "E: \U$cmd\E $mbx ($sec) failed: $!";
 510
 511         my ($r_uidval, $r_uidnext, $perm_fl);
 512         for ($mic->Results) {
 513                 /^\* OK \[PERMANENTFLAGS \(([^\)]*)\)\].*/ and $perm_fl = $1;
 514                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 515                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 516         }
 517         $r_uidval //= $mic->uidvalidity($mbx) //
 518                 return "E: $orig_uri cannot get UIDVALIDITY";
 519         $r_uidnext //= $mic->uidnext($mbx) //
 520                 return "E: $orig_uri cannot get UIDNEXT";
 521         my $expect = $orig_uri->uidvalidity // $r_uidval;
 522         return <<EOF if $expect != $r_uidval;
 523 E: $orig_uri UIDVALIDITY mismatch (got $r_uidval)
 524 EOF
 525
 526         my $uri = $orig_uri->clone;
 527         my $single_uid = $uri->uid;
 528         my ($itrk, $l_uid, $l_uidval) = itrk_last($self, $uri, $r_uidval, $mic);
 529         if (defined($single_uid)) {
 530                 $itrk = $l_uid = undef;
 531                 $uri->uid(undef); # for eml_cb
 532         }
 533         return <<EOF if $l_uidval != $r_uidval;
 534 E: $uri UIDVALIDITY mismatch
 535 E: local=$l_uidval != remote=$r_uidval
 536 EOF
 537         $uri->uidvalidity($r_uidval);
 538         $l_uid //= 0;
 539         my $r_uid = $r_uidnext - 1;
 540         return <<EOF if $l_uid > $r_uid;
 541 E: $uri local UID exceeds remote ($l_uid > $r_uid)
 542 E: $uri strangely, UIDVALIDLITY matches ($l_uidval)
 543 EOF
 544         $mic->Uid(1); # the default, we hope
 545         my $err;
 546         my $use_fl = perm_fl_ok($perm_fl);
 547         if (!defined($single_uid) && $self->{each_old} && $use_fl) {
 548                 $err = each_old_flags($self, $mic, $uri, $l_uid);
 549                 return $err if $err;
 550         }
 551         return if $l_uid >= $r_uid; # nothing to do
 552         $l_uid ||= 1;
 553         my ($mod, $shard) = @{$self->{shard_info} // []};
 554         unless ($self->{quiet}) {
 555                 my $m = $mod ? " [(UID % $mod) == $shard]" : '';
 556                 warn "# $uri fetching UID $l_uid:$r_uid$m\n";
 557         }
 558         my $bs = $self->{imap_opt}->{$sec}->{batch_size} // 1;
 559         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 560         my $key = $req;
 561         $key =~ s/\.PEEK//;
 562         my ($uids, $batch);
 563         do {
 564                 # I wish "UID FETCH $START:*" could work, but:
 565                 # 1) servers do not need to return results in any order
 566                 # 2) Mail::IMAPClient doesn't offer a streaming API
 567                 if (defined $single_uid) {
 568                         $uids = [ $single_uid ];
 569                 } elsif (!($uids = $mic->search("UID $l_uid:*"))) {
 570                         return if $!{EINTR} && $self->{quit};
 571                         return "E: $uri UID SEARCH $l_uid:* error: $!";
 572                 }
 573                 return if scalar(@$uids) == 0;
 574
 575                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 576                 # responses, so sort it ourselves.  Order matters so
 577                 # IMAPTracker can store the newest UID.
 578                 @$uids = sort { $a <=> $b } @$uids;
 579
 580                 # Did we actually get new messages?
 581                 return if $uids->[0] < $l_uid;
 582
 583                 $l_uid = $uids->[-1] + 1; # for next search
 584                 my $last_uid;
 585                 my $n = $self->{max_batch};
 586
 587                 @$uids = grep { ($_ % $mod) == $shard } @$uids if $mod;
 588                 while (scalar @$uids) {
 589                         my @batch = splice(@$uids, 0, $bs);
 590                         $batch = join(',', @batch);
 591                         local $0 = "UID:$batch $mbx $sec";
 592                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 593                         unless ($r) { # network error?
 594                                 last if $!{EINTR} && $self->{quit};
 595                                 $err = "E: $uri UID FETCH $batch error: $!";
 596                                 last;
 597                         }
 598                         for my $uid (@batch) {
 599                                 # messages get deleted, so holes appear
 600                                 my $per_uid = delete $r->{$uid} // next;
 601                                 my $raw = delete($per_uid->{$key}) // next;
 602                                 my $fl = $use_fl ? $per_uid->{FLAGS} : undef;
 603                                 _imap_do_msg($self, $uri, $uid, \$raw, $fl);
 604                                 $last_uid = $uid;
 605                                 last if $self->{quit};
 606                         }
 607                         last if $self->{quit};
 608                 }
 609                 run_commit_cb($self);
 610                 $itrk->update_last($r_uidval, $last_uid) if $itrk;
 611         } until ($err || $self->{quit} || defined($single_uid));
 612         $err;
 613 }
 614
 615 # uses cached auth info prepared by mic_for
 616 sub mic_get {
 617         my ($self, $uri) = @_;
 618         my $sec = uri_section($uri);
 619         # see if caller saved result of imap_common_init
 620         my $cached = $self->{mics_cached};
 621         if ($cached) {
 622                 my $mic = $cached->{$sec};
 623                 return $mic if $mic && $mic->IsConnected;
 624                 delete $cached->{$sec};
 625         }
 626         my $mic_arg = $self->{mic_arg}->{$sec} or
 627                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 628         if (defined(my $cb_name = $mic_arg->{Authcallback})) {
 629                 if (ref($cb_name) ne 'CODE') {
 630                         $mic_arg->{Authcallback} = $self->can($cb_name);
 631                 }
 632         }
 633         my $mic = mic_new($self, $mic_arg, $sec, $uri);
 634         $cached //= {}; # invalid placeholder if no cache enabled
 635         $mic && $mic->IsConnected ? ($cached->{$sec} = $mic) : undef;
 636 }
 637
 638 sub imap_each {
 639         my ($self, $url, $eml_cb, @args) = @_;
 640         my $uri = ref($url) ? $url : PublicInbox::URIimap->new($url);
 641         my $sec = uri_section($uri);
 642         local $0 = $uri->mailbox." $sec";
 643         my $mic = mic_get($self, $uri);
 644         my $err;
 645         if ($mic) {
 646                 local $self->{eml_each} = [ $eml_cb, @args ];
 647                 $err = _imap_fetch_all($self, $mic, $uri);
 648         } else {
 649                 $err = "E: <$uri> not connected: $!";
 650         }
 651         die $err if $err && $self->{-can_die};
 652         warn $err if $err;
 653         $mic;
 654 }
 655
 656 # may used cached auth info prepared by nn_for once
 657 sub nn_get {
 658         my ($self, $uri) = @_;
 659         my $sec = uri_section($uri);
 660         # see if caller saved result of nntp_common_init
 661         my $cached = $self->{nn_cached} // {};
 662         my $nn;
 663         $nn = delete($cached->{$sec}) and return $nn;
 664         my $nn_arg = $self->{nn_arg}->{$sec} or
 665                         die "BUG: no Net::NNTP->new arg for $sec";
 666         my $nntp_opt = $self->{nntp_opt}->{$sec};
 667         $nn = nn_new($nn_arg, $nntp_opt, $uri) or return;
 668         if (my $postconn = $nntp_opt->{-postconn}) {
 669                 for my $m_arg (@$postconn) {
 670                         my ($method, @args) = @$m_arg;
 671                         $nn->$method(@args) and next;
 672                         die "E: <$uri> $method failed\n";
 673                         return;
 674                 }
 675         }
 676         $nn;
 677 }
 678
 679 sub _nntp_fetch_all ($$$) {
 680         my ($self, $nn, $uri) = @_;
 681         my ($group, $num_a, $num_b) = $uri->group;
 682         my $sec = uri_section($uri);
 683         my ($nr, $beg, $end) = $nn->group($group);
 684         unless (defined($nr)) {
 685                 my $msg = ndump($nn->message);
 686                 return "E: GROUP $group <$sec> $msg";
 687         }
 688
 689         # IMAPTracker is also used for tracking NNTP, UID == article number
 690         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 691         # expensive.  So we assume newsgroups don't change:
 692         my ($itrk, $l_art) = itrk_last($self, $uri);
 693
 694         # allow users to specify articles to refetch
 695         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 696         # nntp://example.com/inbox.foo/$num_a-$num_b
 697         $beg = $num_a if defined($num_a) && $num_a < $beg;
 698         $end = $num_b if defined($num_b) && $num_b < $end;
 699         if (defined $l_art) {
 700                 return if $l_art >= $end; # nothing to do
 701                 $beg = $l_art + 1;
 702         }
 703         my ($err, $art, $last_art, $kw); # kw stays undef, no keywords in NNTP
 704         unless ($self->{quiet}) {
 705                 warn "# $uri fetching ARTICLE $beg..$end\n";
 706         }
 707         my $n = $self->{max_batch};
 708         for ($beg..$end) {
 709                 last if $self->{quit};
 710                 $art = $_;
 711                 if (--$n < 0) {
 712                         run_commit_cb($self);
 713                         $itrk->update_last(0, $last_art) if $itrk;
 714                         $n = $self->{max_batch};
 715                 }
 716                 my $raw = $nn->article($art);
 717                 unless (defined($raw)) {
 718                         my $msg = ndump($nn->message);
 719                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 720                                 $err = "E: $msg";
 721                                 last;
 722                         } else { # probably just a deleted message (spam)
 723                                 warn "W: $msg";
 724                                 next;
 725                         }
 726                 }
 727                 $raw = join('', @$raw);
 728                 $raw =~ s/\r\n/\n/sg;
 729                 my ($eml_cb, @args) = @{$self->{eml_each}};
 730                 $eml_cb->($uri, $art, $kw, PublicInbox::Eml->new(\$raw), @args);
 731                 $last_art = $art;
 732         }
 733         run_commit_cb($self);
 734         $itrk->update_last(0, $last_art) if $itrk;
 735         $err;
 736 }
 737
 738 sub nntp_each {
 739         my ($self, $url, $eml_cb, @args) = @_;
 740         my $uri = ref($url) ? $url : PublicInbox::URInntps->new($url);
 741         my $sec = uri_section($uri);
 742         local $0 = $uri->group ." $sec";
 743         my $nn = nn_get($self, $uri);
 744         return if $self->{quit};
 745         my $err;
 746         if ($nn) {
 747                 local $self->{eml_each} = [ $eml_cb, @args ];
 748                 $err = _nntp_fetch_all($self, $nn, $uri);
 749         } else {
 750                 $err = "E: <$uri> not connected: $!";
 751         }
 752         die $err if $err && $self->{-can_die};
 753         warn $err if $err;
 754         $nn;
 755 }
 756
 757 sub new { bless {}, shift };
 758
 759 # updates $uri with UIDVALIDITY
 760 sub mic_for_folder {
 761         my ($self, $uri) = @_;
 762         my $mic = $self->mic_get($uri) or die "E: not connected: $@";
 763         my $m = $self->isa('PublicInbox::NetWriter') ? 'select' : 'examine';
 764         $mic->$m($uri->mailbox) or return;
 765         my $uidval;
 766         for ($mic->Results) {
 767                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ or next;
 768                 $uidval = $1;
 769                 last;
 770         }
 771         $uidval //= $mic->uidvalidity($uri->mailbox) or
 772                 die "E: failed to get uidvalidity from <$uri>: $@";
 773         $uri->uidvalidity($uidval);
 774         $mic;
 775 }
 776
 777
 778 1;