lib/PublicInbox/NetWriter.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common writer code for IMAP (and later, JMAP)
   5 package PublicInbox::NetWriter;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::NetReader);
   9 use PublicInbox::Smsg;
  10 use PublicInbox::MsgTime qw(msg_timestamp);
  11
  12 my %IMAPkw2flags;
  13 @IMAPkw2flags{values %PublicInbox::NetReader::IMAPflags2kw} =
  14                                 keys %PublicInbox::NetReader::IMAPflags2kw;
  15
  16 sub kw2flags ($) { join(' ', map { $IMAPkw2flags{$_} } @{$_[0]}) }
  17
  18 sub imap_append {
  19         my ($mic, $folder, $bref, $smsg, $eml) = @_;
  20         $bref //= \($eml->as_string);
  21         $smsg //= bless {}, 'PublicInbox::Smsg';
  22         bless($smsg, 'PublicInbox::Smsg') if ref($smsg) eq 'HASH';
  23         $smsg->{ts} //= msg_timestamp($eml // PublicInbox::Eml->new($$bref));
  24         my $f = kw2flags($smsg->{kw});
  25         $mic->append_string($folder, $$bref, $f, $smsg->internaldate) or
  26                 die "APPEND $folder: $@";
  27 }
  28
  29 sub mic_for_folder {
  30         my ($self, $uri) = @_;
  31         my $mic = $self->mic_get($uri) or die "E: not connected: $@";
  32         $mic->select($uri->mailbox) or return;
  33         $mic;
  34 }
  35
  36 sub imap_delete_all {
  37         my ($self, $uri) = @_;
  38         my $mic = mic_for_folder($self, $uri) or return;
  39         my $sec = $self->can('uri_section')->($uri);
  40         local $0 = $uri->mailbox." $sec";
  41         if ($mic->delete_message('1:*')) {
  42                 $mic->expunge;
  43         }
  44 }
  45
  46 sub imap_delete_1 {
  47         my ($self, $uri, $uid, $delete_mic) = @_;
  48         $$delete_mic //= mic_for_folder($self, $uri) or return;
  49         $$delete_mic->delete_message($uid);
  50 }
  51
  52 sub imap_add_kw {
  53         my ($self, $mic, $uid, $kw) = @_;
  54         $mic->store($uid, '+FLAGS.SILENT', '('.kw2flags($kw).')');
  55         $mic; # caller must ->expunge
  56 }
  57
  58 sub imap_set_kw {
  59         my ($self, $mic, $uid, $kw) = @_;
  60         $mic->store($uid, 'FLAGS.SILENT', '('.kw2flags($kw).')');
  61         $mic; # caller must ->expunge
  62 }
  63
  64 1;