lib/PublicInbox/NetWriter.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common writer code for IMAP (and later, JMAP)
   5 package PublicInbox::NetWriter;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::NetReader);
   9 use PublicInbox::Smsg;
  10 use PublicInbox::MsgTime qw(msg_timestamp);
  11
  12 my %IMAPkw2flags;
  13 @IMAPkw2flags{values %PublicInbox::NetReader::IMAPflags2kw} =
  14                                 keys %PublicInbox::NetReader::IMAPflags2kw;
  15
  16 sub kw2flags ($) { join(' ', map { $IMAPkw2flags{$_} } @{$_[0]}) }
  17
  18 sub imap_append {
  19         my ($mic, $folder, $bref, $smsg, $eml) = @_;
  20         $bref //= \($eml->as_string);
  21         $smsg //= bless {}, 'PublicInbox::Smsg';
  22         bless($smsg, 'PublicInbox::Smsg') if ref($smsg) eq 'HASH';
  23         $smsg->{ts} //= msg_timestamp($eml // PublicInbox::Eml->new($$bref));
  24         my $f = kw2flags($smsg->{kw});
  25         $mic->append_string($folder, $$bref, $f, $smsg->internaldate) or
  26                 die "APPEND $folder: $@";
  27 }
  28
  29 sub mic_for_folder {
  30         my ($self, $uri) = @_;
  31         if (!ref($uri)) {
  32                 my $u = PublicInbox::URIimap->new($uri);
  33                 $_[1] = $uri = $u;
  34         }
  35         my $mic = $self->mic_get($uri) or die "E: not connected: $@";
  36         $mic->select($uri->mailbox) or return;
  37         $mic;
  38 }
  39
  40 sub imap_delete_all {
  41         my ($self, $url) = @_;
  42         my $mic = mic_for_folder($self, my $uri = $url) or return;
  43         my $sec = $self->can('uri_section')->($uri);
  44         local $0 = $uri->mailbox." $sec";
  45         if ($mic->delete_message('1:*')) {
  46                 $mic->expunge;
  47         }
  48 }
  49
  50 sub imap_delete_1 {
  51         my ($self, $url, $uid, $delete_mic) = @_;
  52         $$delete_mic //= mic_for_folder($self, my $uri = $url) or return;
  53         $$delete_mic->delete_message($uid);
  54 }
  55
  56 sub imap_set_kw {
  57         my ($self, $url, $uid, $kw) = @_;
  58         my $mic = mic_for_folder($self, my $uri = $url) or return;
  59         $mic->set_flag(kw2flags($kw), $uid);
  60         $mic; # caller must ->expunge
  61 }
  62
  63 sub imap_unset_kw {
  64         my ($self, $url, $uid, $kw) = @_;
  65         my $mic = mic_for_folder($self, my $uri = $url) or return;
  66         $mic->unset_flag(kw2flags($kw), $uid);
  67         $mic; # caller must ->expunge
  68 }
  69
  70 1;