lib/PublicInbox/NetWriter.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common writer code for IMAP (and later, JMAP)
   5 package PublicInbox::NetWriter;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::NetReader);
   9 use PublicInbox::Smsg;
  10 use PublicInbox::MsgTime qw(msg_timestamp);
  11
  12 my %IMAPkw2flags;
  13 @IMAPkw2flags{values %PublicInbox::NetReader::IMAPflags2kw} =
  14                                 keys %PublicInbox::NetReader::IMAPflags2kw;
  15
  16 sub kw2flags ($) { join(' ', map { $IMAPkw2flags{$_} } @{$_[0]}) }
  17
  18 sub imap_append {
  19         my ($mic, $folder, $bref, $smsg, $eml) = @_;
  20         $bref //= \($eml->as_string);
  21         $smsg //= bless {}, 'PublicInbox::Smsg';
  22         bless($smsg, 'PublicInbox::Smsg') if ref($smsg) eq 'HASH';
  23         $smsg->{ts} //= msg_timestamp($eml // PublicInbox::Eml->new($$bref));
  24         my $f = kw2flags($smsg->{kw});
  25         $mic->append_string($folder, $$bref, $f, $smsg->internaldate) or
  26                 die "APPEND $folder: $@";
  27 }
  28
  29 sub folder_select { 'select' } # for PublicInbox::NetReader
  30
  31 sub imap_delete_all {
  32         my ($self, $uri) = @_;
  33         my $mic = $self->mic_for_folder($uri) or return;
  34         my $sec = $self->can('uri_section')->($uri);
  35         local $0 = $uri->mailbox." $sec";
  36         if ($mic->delete_message('1:*')) {
  37                 $mic->expunge;
  38         }
  39 }
  40
  41 sub imap_delete_1 {
  42         my ($self, $uri, $uid, $delete_mic) = @_;
  43         $$delete_mic //= $self->mic_for_folder($uri) or return;
  44         $$delete_mic->delete_message($uid);
  45 }
  46
  47 sub imap_add_kw {
  48         my ($self, $mic, $uid, $kw) = @_;
  49         $mic->store($uid, '+FLAGS.SILENT', '('.kw2flags($kw).')');
  50         $mic; # caller must ->expunge
  51 }
  52
  53 sub imap_set_kw {
  54         my ($self, $mic, $uid, $kw) = @_;
  55         $mic->store($uid, 'FLAGS.SILENT', '('.kw2flags($kw).')');
  56         $mic; # caller must ->expunge
  57 }
  58
  59 sub can_store_flags {
  60         my ($self, $mic) = @_;
  61         for ($mic->Results) {
  62                 /^\* OK \[PERMANENTFLAGS \(([^\)]*)\)\].*/ and
  63                         return $self->can('perm_fl_ok')->($1);
  64         }
  65         undef;
  66 }
  67
  68 1;