lib/PublicInbox/NetWriter.pm

   1 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # common writer code for IMAP (and later, JMAP)
   5 package PublicInbox::NetWriter;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::NetReader);
   9 use PublicInbox::Smsg;
  10 use PublicInbox::MsgTime qw(msg_timestamp);
  11
  12 my %IMAPkw2flags;
  13 @IMAPkw2flags{values %PublicInbox::NetReader::IMAPflags2kw} =
  14                                 keys %PublicInbox::NetReader::IMAPflags2kw;
  15
  16 sub kw2flags ($) { join(' ', map { $IMAPkw2flags{$_} } @{$_[0]}) }
  17
  18 sub imap_append {
  19         my ($mic, $folder, $bref, $smsg, $eml) = @_;
  20         $bref //= \($eml->as_string);
  21         $smsg //= bless {}, 'PublicInbox::Smsg';
  22         bless($smsg, 'PublicInbox::Smsg') if ref($smsg) eq 'HASH';
  23         $smsg->{ts} //= msg_timestamp($eml // PublicInbox::Eml->new($$bref));
  24         my $f = kw2flags($smsg->{kw});
  25         $mic->append_string($folder, $$bref, $f, $smsg->internaldate) or
  26                 die "APPEND $folder: $@";
  27 }
  28
  29 # updates $uri with UIDVALIDITY
  30 sub mic_for_folder {
  31         my ($self, $uri) = @_;
  32         my $mic = $self->mic_get($uri) or die "E: not connected: $@";
  33         $mic->select($uri->mailbox) or return;
  34         my $uidval;
  35         for ($mic->Results) {
  36                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ or next;
  37                 $uidval = $1;
  38                 last;
  39         }
  40         $uidval //= $mic->uidvalidity($uri->mailbox) or
  41                 die "E: failed to get uidvalidity from <$uri>: $@";
  42         $uri->uidvalidity($uidval);
  43         $mic;
  44 }
  45
  46 sub imap_delete_all {
  47         my ($self, $uri) = @_;
  48         my $mic = mic_for_folder($self, $uri) or return;
  49         my $sec = $self->can('uri_section')->($uri);
  50         local $0 = $uri->mailbox." $sec";
  51         if ($mic->delete_message('1:*')) {
  52                 $mic->expunge;
  53         }
  54 }
  55
  56 sub imap_delete_1 {
  57         my ($self, $uri, $uid, $delete_mic) = @_;
  58         $$delete_mic //= mic_for_folder($self, $uri) or return;
  59         $$delete_mic->delete_message($uid);
  60 }
  61
  62 sub imap_add_kw {
  63         my ($self, $mic, $uid, $kw) = @_;
  64         $mic->store($uid, '+FLAGS.SILENT', '('.kw2flags($kw).')');
  65         $mic; # caller must ->expunge
  66 }
  67
  68 sub imap_set_kw {
  69         my ($self, $mic, $uid, $kw) = @_;
  70         $mic->store($uid, 'FLAGS.SILENT', '('.kw2flags($kw).')');
  71         $mic; # caller must ->expunge
  72 }
  73
  74 1;