lib/PublicInbox/Over.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for XOVER, OVER in NNTP, and feeds/homepage/threads in PSGI
   5 # Unlike Msgmap, this is an _UNSTABLE_ database which can be
   6 # tweaked/updated over time and rebuilt.
   7 package PublicInbox::Over;
   8 use strict;
   9 use warnings;
  10 use DBI;
  11 use DBD::SQLite;
  12 use PublicInbox::Smsg;
  13 use Compress::Zlib qw(uncompress);
  14 use constant DEFAULT_LIMIT => 1000;
  15
  16 sub dbh_new {
  17         my ($self, $rw) = @_;
  18         my $f = delete $self->{filename};
  19         if (!-f $f) { # SQLite defaults mode to 0644, we want 0666
  20                 if ($rw) {
  21                         require PublicInbox::Spawn;
  22                         open my $fh, '+>>', $f or die "failed to open $f: $!";
  23                         PublicInbox::Spawn::nodatacow_fd(fileno($fh));
  24                         my $j = "$f-journal";
  25                         open $fh, '+>>', $j or die "failed to open $j: $!";
  26                         PublicInbox::Spawn::nodatacow_fd(fileno($fh));
  27                 } else {
  28                         $self->{filename} = $f; # die on stat() below:
  29                 }
  30         }
  31         my (@st, $st, $dbh);
  32         my $tries = 0;
  33         do {
  34                 @st = stat($f) or die "failed to stat $f: $!";
  35                 $st = pack('dd', $st[0], $st[1]); # 0: dev, 1: inode
  36                 $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  37                         AutoCommit => 1,
  38                         RaiseError => 1,
  39                         PrintError => 0,
  40                         ReadOnly => !$rw,
  41                         sqlite_use_immediate_transaction => 1,
  42                 });
  43                 $self->{st} = $st;
  44                 @st = stat($f) or die "failed to stat $f: $!";
  45                 $st = pack('dd', $st[0], $st[1]);
  46         } while ($st ne $self->{st} && $tries++ < 3);
  47         warn "W: $f: .st_dev, .st_ino unstable\n" if $st ne $self->{st};
  48         $dbh->do('PRAGMA synchronous = OFF') if ($rw // 0) > 1;
  49         $dbh;
  50 }
  51
  52 sub new {
  53         my ($class, $f) = @_;
  54         bless { filename => $f }, $class;
  55 }
  56
  57 sub disconnect {
  58         my ($self) = @_;
  59         if (my $dbh = delete $self->{dbh}) {
  60                 delete $self->{-get_art};
  61                 $self->{filename} = $dbh->sqlite_db_filename;
  62         }
  63 }
  64
  65 sub connect { $_[0]->{dbh} //= $_[0]->dbh_new }
  66
  67 sub load_from_row ($;$) {
  68         my ($smsg, $cull) = @_;
  69         bless $smsg, 'PublicInbox::Smsg';
  70         if (defined(my $data = delete $smsg->{ddd})) {
  71                 $data = uncompress($data);
  72                 PublicInbox::Smsg::load_from_data($smsg, $data);
  73
  74                 # saves over 600K for 1000+ message threads
  75                 PublicInbox::Smsg::psgi_cull($smsg) if $cull;
  76         }
  77         $smsg
  78 }
  79
  80 sub do_get {
  81         my ($self, $sql, $opts, @args) = @_;
  82         my $dbh = $self->connect;
  83         my $lim = (($opts->{limit} || 0) + 0) || DEFAULT_LIMIT;
  84         $sql .= "LIMIT $lim";
  85         my $msgs = $dbh->selectall_arrayref($sql, { Slice => {} }, @args);
  86         my $cull = $opts->{cull};
  87         load_from_row($_, $cull) for @$msgs;
  88         $msgs
  89 }
  90
  91 sub query_xover {
  92         my ($self, $beg, $end) = @_;
  93         do_get($self, <<'', {}, $beg, $end);
  94 SELECT num,ts,ds,ddd FROM over WHERE num >= ? AND num <= ?
  95 ORDER BY num ASC
  96
  97 }
  98
  99 sub query_ts {
 100         my ($self, $ts, $prev) = @_;
 101         do_get($self, <<'', {}, $ts, $prev);
 102 SELECT num,ddd FROM over WHERE ts >= ? AND num > ?
 103 ORDER BY num ASC
 104
 105 }
 106
 107 sub get_all {
 108         my $self = shift;
 109         my $nr = scalar(@_) or return [];
 110         my $in = '?' . (',?' x ($nr - 1));
 111         do_get($self, <<"", { cull => 1, limit => $nr }, @_);
 112 SELECT num,ds,ddd FROM over WHERE num IN ($in)
 113
 114 }
 115
 116 sub nothing () { wantarray ? (0, []) : [] };
 117
 118 sub get_thread {
 119         my ($self, $mid, $prev) = @_;
 120         my $dbh = $self->connect;
 121         my $opts = { cull => 1 };
 122
 123         my $id = $dbh->selectrow_array(<<'', undef, $mid);
 124 SELECT id FROM msgid WHERE mid = ? LIMIT 1
 125
 126         defined $id or return nothing;
 127
 128         my $num = $dbh->selectrow_array(<<'', undef, $id);
 129 SELECT num FROM id2num WHERE id = ? AND num > 0
 130 ORDER BY num ASC LIMIT 1
 131
 132         defined $num or return nothing;
 133
 134         my ($tid, $sid) = $dbh->selectrow_array(<<'', undef, $num);
 135 SELECT tid,sid FROM over WHERE num = ? LIMIT 1
 136
 137         defined $tid or return nothing; # $sid may be undef
 138
 139         my $cond_all = '(tid = ? OR sid = ?) AND num > ?';
 140         my $sort_col = 'ds';
 141         $num = 0;
 142         if ($prev) { # mboxrd stream, only
 143                 $num = $prev->{num} || 0;
 144                 $sort_col = 'num';
 145         }
 146
 147         my $cols = 'num,ts,ds,ddd';
 148         unless (wantarray) {
 149                 return do_get($self, <<"", $opts, $tid, $sid, $num);
 150 SELECT $cols FROM over WHERE $cond_all
 151 ORDER BY $sort_col ASC
 152
 153         }
 154
 155         # HTML view always wants an array and never uses $prev,
 156         # but the mbox stream never wants an array and always has $prev
 157         die '$prev not supported with wantarray' if $prev;
 158         my $nr = $dbh->selectrow_array(<<"", undef, $tid, $sid, $num);
 159 SELECT COUNT(num) FROM over WHERE $cond_all
 160
 161         # giant thread, prioritize strict (tid) matches and throw
 162         # in the loose (sid) matches at the end
 163         my $msgs = do_get($self, <<"", $opts, $tid, $num);
 164 SELECT $cols FROM over WHERE tid = ? AND num > ?
 165 ORDER BY $sort_col ASC
 166
 167         # do we have room for loose matches? get the most recent ones, first:
 168         my $lim = DEFAULT_LIMIT - scalar(@$msgs);
 169         if ($lim > 0) {
 170                 $opts->{limit} = $lim;
 171                 my $loose = do_get($self, <<"", $opts, $tid, $sid, $num);
 172 SELECT $cols FROM over WHERE tid != ? AND sid = ? AND num > ?
 173 ORDER BY $sort_col DESC
 174
 175                 # TODO separate strict and loose matches here once --reindex
 176                 # is fixed to preserve `tid' properly
 177                 push @$msgs, @$loose;
 178         }
 179         ($nr, $msgs);
 180 }
 181
 182 sub recent {
 183         my ($self, $opts, $after, $before) = @_;
 184         my ($s, @v);
 185         if (defined($before)) {
 186                 if (defined($after)) {
 187                         $s = '+num > 0 AND ts >= ? AND ts <= ? ORDER BY ts DESC';
 188                         @v = ($after, $before);
 189                 } else {
 190                         $s = '+num > 0 AND ts <= ? ORDER BY ts DESC';
 191                         @v = ($before);
 192                 }
 193         } else {
 194                 if (defined($after)) {
 195                         $s = '+num > 0 AND ts >= ? ORDER BY ts ASC';
 196                         @v = ($after);
 197                 } else {
 198                         $s = '+num > 0 ORDER BY ts DESC';
 199                 }
 200         }
 201         my $msgs = do_get($self, <<"", $opts, @v);
 202 SELECT ts,ds,ddd FROM over WHERE $s
 203
 204         return $msgs unless wantarray;
 205
 206         my $nr = $self->{dbh}->selectrow_array(<<'');
 207 SELECT COUNT(num) FROM over WHERE num > 0
 208
 209         ($nr, $msgs);
 210 }
 211
 212 sub get_art {
 213         my ($self, $num) = @_;
 214         # caching $sth ourselves is faster than prepare_cached
 215         my $sth = $self->{-get_art} //= $self->connect->prepare(<<'');
 216 SELECT num,ds,ts,ddd FROM over WHERE num = ? LIMIT 1
 217
 218         $sth->execute($num);
 219         my $smsg = $sth->fetchrow_hashref;
 220         $smsg ? load_from_row($smsg) : undef;
 221 }
 222
 223 sub next_by_mid {
 224         my ($self, $mid, $id, $prev) = @_;
 225         my $dbh = $self->connect;
 226
 227         unless (defined $$id) {
 228                 my $sth = $dbh->prepare_cached(<<'', undef, 1);
 229         SELECT id FROM msgid WHERE mid = ? LIMIT 1
 230
 231                 $sth->execute($mid);
 232                 $$id = $sth->fetchrow_array;
 233                 defined $$id or return;
 234         }
 235         my $sth = $dbh->prepare_cached(<<"", undef, 1);
 236 SELECT num FROM id2num WHERE id = ? AND num > ?
 237 ORDER BY num ASC LIMIT 1
 238
 239         $$prev ||= 0;
 240         $sth->execute($$id, $$prev);
 241         my $num = $sth->fetchrow_array or return;
 242         $$prev = $num;
 243         get_art($self, $num);
 244 }
 245
 246 # IMAP search, this is limited by callers to UID_SLICE size (50K)
 247 sub uid_range {
 248         my ($self, $beg, $end, $sql) = @_;
 249         my $dbh = $self->connect;
 250         my $q = 'SELECT num FROM over WHERE num >= ? AND num <= ?';
 251
 252         # This is read-only, anyways; but caller should verify it's
 253         # only sending \A[0-9]+\z for ds and ts column ranges
 254         $q .= $$sql if $sql;
 255         $q .= ' ORDER BY num ASC';
 256         $dbh->selectcol_arrayref($q, undef, $beg, $end);
 257 }
 258
 259 sub max {
 260         my ($self) = @_;
 261         my $sth = $self->connect->prepare_cached(<<'', undef, 1);
 262 SELECT MAX(num) FROM over WHERE num > 0
 263
 264         $sth->execute;
 265         $sth->fetchrow_array // 0;
 266 }
 267
 268 sub imap_exists {
 269         my ($self, $uid_base, $uid_end) = @_;
 270         my $sth = $self->connect->prepare_cached(<<'', undef, 1);
 271 SELECT COUNT(num) FROM over WHERE num > ? AND num <= ?
 272
 273         $sth->execute($uid_base, $uid_end);
 274         $sth->fetchrow_array;
 275 }
 276
 277 sub check_inodes {
 278         my ($self) = @_;
 279         my $dbh = $self->{dbh} or return;
 280         my $f = $dbh->sqlite_db_filename;
 281         if (my @st = stat($f)) { # did st_dev, st_ino change?
 282                 my $st = pack('dd', $st[0], $st[1]);
 283
 284                 # don't actually reopen, just let {dbh} be recreated later
 285                 disconnect($self) if $st ne ($self->{st} // $st);
 286         } else {
 287                 warn "W: stat $f: $!\n";
 288         }
 289 }
 290
 291 1;