lib/PublicInbox/Over.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for XOVER, OVER in NNTP, and feeds/homepage/threads in PSGI
   5 # Unlike Msgmap, this is an _UNSTABLE_ database which can be
   6 # tweaked/updated over time and rebuilt.
   7 package PublicInbox::Over;
   8 use strict;
   9 use warnings;
  10 use DBI;
  11 use DBD::SQLite;
  12 use PublicInbox::Smsg;
  13 use Compress::Zlib qw(uncompress);
  14 use constant DEFAULT_LIMIT => 1000;
  15
  16 sub dbh_new {
  17         my ($self, $rw) = @_;
  18         my $f = delete $self->{filename};
  19         if (!-f $f) { # SQLite defaults mode to 0644, we want 0666
  20                 if ($rw) {
  21                         require PublicInbox::Spawn;
  22                         open my $fh, '+>>', $f or die "failed to open $f: $!";
  23                         PublicInbox::Spawn::nodatacow_fd(fileno($fh));
  24                 } else {
  25                         $self->{filename} = $f; # die on stat() below:
  26                 }
  27         }
  28         my (@st, $st, $dbh);
  29         my $tries = 0;
  30         do {
  31                 @st = stat($f) or die "failed to stat $f: $!";
  32                 $st = pack('dd', $st[0], $st[1]); # 0: dev, 1: inode
  33                 $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  34                         AutoCommit => 1,
  35                         RaiseError => 1,
  36                         PrintError => 0,
  37                         ReadOnly => !$rw,
  38                         sqlite_use_immediate_transaction => 1,
  39                 });
  40                 $self->{st} = $st;
  41                 @st = stat($f) or die "failed to stat $f: $!";
  42                 $st = pack('dd', $st[0], $st[1]);
  43         } while ($st ne $self->{st} && $tries++ < 3);
  44         warn "W: $f: .st_dev, .st_ino unstable\n" if $st ne $self->{st};
  45         $dbh->do('PRAGMA synchronous = OFF') if ($rw // 0) > 1;
  46         $dbh;
  47 }
  48
  49 sub new {
  50         my ($class, $f) = @_;
  51         bless { filename => $f }, $class;
  52 }
  53
  54 sub disconnect {
  55         my ($self) = @_;
  56         if (my $dbh = delete $self->{dbh}) {
  57                 delete $self->{-get_art};
  58                 $self->{filename} = $dbh->sqlite_db_filename;
  59         }
  60 }
  61
  62 sub connect { $_[0]->{dbh} //= $_[0]->dbh_new }
  63
  64 sub load_from_row ($;$) {
  65         my ($smsg, $cull) = @_;
  66         bless $smsg, 'PublicInbox::Smsg';
  67         if (defined(my $data = delete $smsg->{ddd})) {
  68                 $data = uncompress($data);
  69                 PublicInbox::Smsg::load_from_data($smsg, $data);
  70
  71                 # saves over 600K for 1000+ message threads
  72                 PublicInbox::Smsg::psgi_cull($smsg) if $cull;
  73         }
  74         $smsg
  75 }
  76
  77 sub do_get {
  78         my ($self, $sql, $opts, @args) = @_;
  79         my $dbh = $self->connect;
  80         my $lim = (($opts->{limit} || 0) + 0) || DEFAULT_LIMIT;
  81         $sql .= "LIMIT $lim";
  82         my $msgs = $dbh->selectall_arrayref($sql, { Slice => {} }, @args);
  83         my $cull = $opts->{cull};
  84         load_from_row($_, $cull) for @$msgs;
  85         $msgs
  86 }
  87
  88 sub query_xover {
  89         my ($self, $beg, $end) = @_;
  90         do_get($self, <<'', {}, $beg, $end);
  91 SELECT num,ts,ds,ddd FROM over WHERE num >= ? AND num <= ?
  92 ORDER BY num ASC
  93
  94 }
  95
  96 sub query_ts {
  97         my ($self, $ts, $prev) = @_;
  98         do_get($self, <<'', {}, $ts, $prev);
  99 SELECT num,ddd FROM over WHERE ts >= ? AND num > ?
 100 ORDER BY num ASC
 101
 102 }
 103
 104 sub get_all {
 105         my $self = shift;
 106         my $nr = scalar(@_) or return [];
 107         my $in = '?' . (',?' x ($nr - 1));
 108         do_get($self, <<"", { cull => 1, limit => $nr }, @_);
 109 SELECT num,ds,ddd FROM over WHERE num IN ($in)
 110
 111 }
 112
 113 sub nothing () { wantarray ? (0, []) : [] };
 114
 115 sub get_thread {
 116         my ($self, $mid, $prev) = @_;
 117         my $dbh = $self->connect;
 118         my $opts = { cull => 1 };
 119
 120         my $id = $dbh->selectrow_array(<<'', undef, $mid);
 121 SELECT id FROM msgid WHERE mid = ? LIMIT 1
 122
 123         defined $id or return nothing;
 124
 125         my $num = $dbh->selectrow_array(<<'', undef, $id);
 126 SELECT num FROM id2num WHERE id = ? AND num > 0
 127 ORDER BY num ASC LIMIT 1
 128
 129         defined $num or return nothing;
 130
 131         my ($tid, $sid) = $dbh->selectrow_array(<<'', undef, $num);
 132 SELECT tid,sid FROM over WHERE num = ? LIMIT 1
 133
 134         defined $tid or return nothing; # $sid may be undef
 135
 136         my $cond_all = '(tid = ? OR sid = ?) AND num > ?';
 137         my $sort_col = 'ds';
 138         $num = 0;
 139         if ($prev) { # mboxrd stream, only
 140                 $num = $prev->{num} || 0;
 141                 $sort_col = 'num';
 142         }
 143
 144         my $cols = 'num,ts,ds,ddd';
 145         unless (wantarray) {
 146                 return do_get($self, <<"", $opts, $tid, $sid, $num);
 147 SELECT $cols FROM over WHERE $cond_all
 148 ORDER BY $sort_col ASC
 149
 150         }
 151
 152         # HTML view always wants an array and never uses $prev,
 153         # but the mbox stream never wants an array and always has $prev
 154         die '$prev not supported with wantarray' if $prev;
 155         my $nr = $dbh->selectrow_array(<<"", undef, $tid, $sid, $num);
 156 SELECT COUNT(num) FROM over WHERE $cond_all
 157
 158         # giant thread, prioritize strict (tid) matches and throw
 159         # in the loose (sid) matches at the end
 160         my $msgs = do_get($self, <<"", $opts, $tid, $num);
 161 SELECT $cols FROM over WHERE tid = ? AND num > ?
 162 ORDER BY $sort_col ASC
 163
 164         # do we have room for loose matches? get the most recent ones, first:
 165         my $lim = DEFAULT_LIMIT - scalar(@$msgs);
 166         if ($lim > 0) {
 167                 $opts->{limit} = $lim;
 168                 my $loose = do_get($self, <<"", $opts, $tid, $sid, $num);
 169 SELECT $cols FROM over WHERE tid != ? AND sid = ? AND num > ?
 170 ORDER BY $sort_col DESC
 171
 172                 # TODO separate strict and loose matches here once --reindex
 173                 # is fixed to preserve `tid' properly
 174                 push @$msgs, @$loose;
 175         }
 176         ($nr, $msgs);
 177 }
 178
 179 # strict `tid' matches, only, for thread-expanded mbox.gz search results
 180 # and future CLI interface
 181 # returns true if we have IDs, undef if not
 182 sub expand_thread {
 183         my ($self, $ctx) = @_;
 184         my $dbh = $self->connect;
 185         do {
 186                 defined(my $num = $ctx->{ids}->[0]) or return;
 187                 my ($tid) = $dbh->selectrow_array(<<'', undef, $num);
 188 SELECT tid FROM over WHERE num = ?
 189
 190                 if (defined($tid)) {
 191                         my $sql = <<'';
 192 SELECT num FROM over WHERE tid = ? AND num > ?
 193 ORDER BY num ASC LIMIT 1000
 194
 195                         my $xids = $dbh->selectcol_arrayref($sql, undef, $tid,
 196                                                         $ctx->{prev} // 0);
 197                         if (scalar(@$xids)) {
 198                                 $ctx->{prev} = $xids->[-1];
 199                                 $ctx->{xids} = $xids;
 200                                 return 1; # success
 201                         }
 202                 }
 203                 $ctx->{prev} = 0;
 204                 shift @{$ctx->{ids}};
 205         } while (1);
 206 }
 207
 208 sub recent {
 209         my ($self, $opts, $after, $before) = @_;
 210         my ($s, @v);
 211         if (defined($before)) {
 212                 if (defined($after)) {
 213                         $s = '+num > 0 AND ts >= ? AND ts <= ? ORDER BY ts DESC';
 214                         @v = ($after, $before);
 215                 } else {
 216                         $s = '+num > 0 AND ts <= ? ORDER BY ts DESC';
 217                         @v = ($before);
 218                 }
 219         } else {
 220                 if (defined($after)) {
 221                         $s = '+num > 0 AND ts >= ? ORDER BY ts ASC';
 222                         @v = ($after);
 223                 } else {
 224                         $s = '+num > 0 ORDER BY ts DESC';
 225                 }
 226         }
 227         my $msgs = do_get($self, <<"", $opts, @v);
 228 SELECT ts,ds,ddd FROM over WHERE $s
 229
 230         return $msgs unless wantarray;
 231
 232         my $nr = $self->{dbh}->selectrow_array(<<'');
 233 SELECT COUNT(num) FROM over WHERE num > 0
 234
 235         ($nr, $msgs);
 236 }
 237
 238 sub get_art {
 239         my ($self, $num) = @_;
 240         # caching $sth ourselves is faster than prepare_cached
 241         my $sth = $self->{-get_art} //= $self->connect->prepare(<<'');
 242 SELECT num,tid,ds,ts,ddd FROM over WHERE num = ? LIMIT 1
 243
 244         $sth->execute($num);
 245         my $smsg = $sth->fetchrow_hashref;
 246         $smsg ? load_from_row($smsg) : undef;
 247 }
 248
 249 sub next_by_mid {
 250         my ($self, $mid, $id, $prev) = @_;
 251         my $dbh = $self->connect;
 252
 253         unless (defined $$id) {
 254                 my $sth = $dbh->prepare_cached(<<'', undef, 1);
 255         SELECT id FROM msgid WHERE mid = ? LIMIT 1
 256
 257                 $sth->execute($mid);
 258                 $$id = $sth->fetchrow_array;
 259                 defined $$id or return;
 260         }
 261         my $sth = $dbh->prepare_cached(<<"", undef, 1);
 262 SELECT num FROM id2num WHERE id = ? AND num > ?
 263 ORDER BY num ASC LIMIT 1
 264
 265         $$prev ||= 0;
 266         $sth->execute($$id, $$prev);
 267         my $num = $sth->fetchrow_array or return;
 268         $$prev = $num;
 269         get_art($self, $num);
 270 }
 271
 272 # IMAP search, this is limited by callers to UID_SLICE size (50K)
 273 sub uid_range {
 274         my ($self, $beg, $end, $sql) = @_;
 275         my $dbh = $self->connect;
 276         my $q = 'SELECT num FROM over WHERE num >= ? AND num <= ?';
 277
 278         # This is read-only, anyways; but caller should verify it's
 279         # only sending \A[0-9]+\z for ds and ts column ranges
 280         $q .= $$sql if $sql;
 281         $q .= ' ORDER BY num ASC';
 282         $dbh->selectcol_arrayref($q, undef, $beg, $end);
 283 }
 284
 285 sub max {
 286         my ($self) = @_;
 287         my $sth = $self->connect->prepare_cached(<<'', undef, 1);
 288 SELECT MAX(num) FROM over WHERE num > 0
 289
 290         $sth->execute;
 291         $sth->fetchrow_array // 0;
 292 }
 293
 294 sub imap_exists {
 295         my ($self, $uid_base, $uid_end) = @_;
 296         my $sth = $self->connect->prepare_cached(<<'', undef, 1);
 297 SELECT COUNT(num) FROM over WHERE num > ? AND num <= ?
 298
 299         $sth->execute($uid_base, $uid_end);
 300         $sth->fetchrow_array;
 301 }
 302
 303 sub check_inodes {
 304         my ($self) = @_;
 305         my $dbh = $self->{dbh} or return;
 306         my $f = $dbh->sqlite_db_filename;
 307         if (my @st = stat($f)) { # did st_dev, st_ino change?
 308                 my $st = pack('dd', $st[0], $st[1]);
 309
 310                 # don't actually reopen, just let {dbh} be recreated later
 311                 disconnect($self) if $st ne ($self->{st} // $st);
 312         } else {
 313                 warn "W: stat $f: $!\n";
 314         }
 315 }
 316
 317 1;