lib/PublicInbox/Over.pm

   1 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for XOVER, OVER in NNTP, and feeds/homepage/threads in PSGI
   5 # Unlike Msgmap, this is an _UNSTABLE_ database which can be
   6 # tweaked/updated over time and rebuilt.
   7 package PublicInbox::Over;
   8 use strict;
   9 use warnings;
  10 use DBI;
  11 use DBD::SQLite;
  12 use PublicInbox::SearchMsg;
  13 use Compress::Zlib qw(uncompress);
  14
  15 sub dbh_new {
  16         my ($self) = @_;
  17         my $ro = ref($self) eq 'PublicInbox::Over';
  18         my $dbh = DBI->connect("dbi:SQLite:dbname=$self->{filename}",'','', {
  19                 AutoCommit => 1,
  20                 RaiseError => 1,
  21                 PrintError => 0,
  22                 ReadOnly => $ro,
  23                 sqlite_use_immediate_transaction => 1,
  24         });
  25         $dbh->{sqlite_unicode} = 1;
  26         $dbh;
  27 }
  28
  29 sub new {
  30         my ($class, $f) = @_;
  31         bless { filename => $f }, $class;
  32 }
  33
  34 sub disconnect { $_[0]->{dbh} = undef }
  35
  36 sub connect { $_[0]->{dbh} ||= $_[0]->dbh_new }
  37
  38 sub load_from_row {
  39         my ($smsg) = @_;
  40         bless $smsg, 'PublicInbox::SearchMsg';
  41         if (defined(my $data = delete $smsg->{ddd})) {
  42                 $data = uncompress($data);
  43                 utf8::decode($data);
  44                 $smsg->load_from_data($data);
  45         }
  46         $smsg
  47 }
  48
  49 sub do_get {
  50         my ($self, $sql, $opts, @args) = @_;
  51         my $dbh = $self->connect;
  52         my $lim = (($opts->{limit} || 0) + 0) || 1000;
  53         my $off = (($opts->{offset} || 0) + 0) || 0;
  54         $sql .= "LIMIT $lim";
  55         $sql .= " OFFSET $off" if $off > 0;
  56         my $msgs = $dbh->selectall_arrayref($sql, { Slice => {} }, @args);
  57         load_from_row($_) for @$msgs;
  58         $msgs
  59 }
  60
  61 sub query_xover {
  62         my ($self, $beg, $end) = @_;
  63         do_get($self, <<'', {}, $beg, $end);
  64 SELECT * FROM over WHERE num >= ? AND num <= ?
  65 ORDER BY num ASC
  66
  67 }
  68
  69 sub query_ts {
  70         my ($self, $ts, $prev) = @_;
  71         do_get($self, <<'', {}, $ts, $prev);
  72 SELECT num,ddd FROM over WHERE ts >= ? AND num > ?
  73 ORDER BY num ASC
  74
  75 }
  76
  77 sub nothing () { wantarray ? (0, []) : [] };
  78
  79 sub get_thread {
  80         my ($self, $mid, $opts) = @_;
  81         my $dbh = $self->connect;
  82
  83         my $id = $dbh->selectrow_array(<<'', undef, $mid);
  84 SELECT id FROM msgid WHERE mid = ? LIMIT 1
  85
  86         defined $id or return nothing;
  87
  88         my $num = $dbh->selectrow_array(<<'', undef, $id);
  89 SELECT num FROM id2num WHERE id = ? AND num > 0
  90 ORDER BY num ASC LIMIT 1
  91
  92         defined $num or return nothing;
  93
  94         my ($tid, $sid) = $dbh->selectrow_array(<<'', undef, $num);
  95 SELECT tid,sid FROM over WHERE num = ? LIMIT 1
  96
  97         defined $tid or return nothing; # $sid may be undef
  98
  99         my $cond = 'FROM over WHERE (tid = ? OR sid = ?) AND num > 0';
 100         my $msgs = do_get($self, <<"", $opts, $tid, $sid);
 101 SELECT * $cond ORDER BY ts ASC
 102
 103         return $msgs unless wantarray;
 104
 105         my $nr = $dbh->selectrow_array(<<"", undef, $tid, $sid);
 106 SELECT COUNT(num) $cond
 107
 108         ($nr, $msgs);
 109 }
 110
 111 sub recent {
 112         my ($self, $opts, $after, $before) = @_;
 113         my ($s, @v);
 114         if (defined($before)) {
 115                 if (defined($after)) {
 116                         $s = 'num > 0 AND ts >= ? AND ts <= ? ORDER BY ts DESC';
 117                         @v = ($after, $before);
 118                 } else {
 119                         $s = 'num > 0 AND ts <= ? ORDER BY ts DESC';
 120                         @v = ($before);
 121                 }
 122         } else {
 123                 if (defined($after)) {
 124                         $s = 'num > 0 AND ts >= ? ORDER BY ts ASC';
 125                         @v = ($after);
 126                 } else {
 127                         $s = 'num > 0 ORDER BY ts DESC';
 128                 }
 129         }
 130         my $msgs = do_get($self, <<"", $opts, @v);
 131 SELECT * FROM over WHERE $s
 132
 133         return $msgs unless wantarray;
 134
 135         my $nr = $self->{dbh}->selectrow_array(<<'');
 136 SELECT COUNT(num) FROM over WHERE num > 0
 137
 138         ($nr, $msgs);
 139 }
 140
 141 sub get_art {
 142         my ($self, $num) = @_;
 143         my $dbh = $self->connect;
 144         my $smsg = $dbh->selectrow_hashref(<<'', undef, $num);
 145 SELECT * from OVER where num = ? LIMIT 1
 146
 147         return load_from_row($smsg) if $smsg;
 148         undef;
 149 }
 150
 151 1;