lib/PublicInbox/Over.pm

   1 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for XOVER, OVER in NNTP, and feeds/homepage/threads in PSGI
   5 # Unlike Msgmap, this is an _UNSTABLE_ database which can be
   6 # tweaked/updated over time and rebuilt.
   7 package PublicInbox::Over;
   8 use strict;
   9 use warnings;
  10 use DBI;
  11 use DBD::SQLite;
  12 use PublicInbox::SearchMsg;
  13 use Compress::Zlib qw(uncompress);
  14
  15 sub dbh_new {
  16         my ($self) = @_;
  17         my $ro = ref($self) eq 'PublicInbox::Over';
  18         my $dbh = DBI->connect("dbi:SQLite:dbname=$self->{filename}",'','', {
  19                 AutoCommit => 1,
  20                 RaiseError => 1,
  21                 PrintError => 0,
  22                 ReadOnly => $ro,
  23                 sqlite_use_immediate_transaction => 1,
  24         });
  25         $dbh->{sqlite_unicode} = 1;
  26         $dbh;
  27 }
  28
  29 sub new {
  30         my ($class, $f) = @_;
  31         bless { filename => $f }, $class;
  32 }
  33
  34 sub disconnect { $_[0]->{dbh} = undef }
  35
  36 sub connect { $_[0]->{dbh} ||= $_[0]->dbh_new }
  37
  38 sub load_from_row {
  39         my ($smsg) = @_;
  40         bless $smsg, 'PublicInbox::SearchMsg';
  41         if (defined(my $data = delete $smsg->{ddd})) {
  42                 $data = uncompress($data);
  43                 utf8::decode($data);
  44                 $smsg->load_from_data($data);
  45         }
  46         $smsg
  47 }
  48
  49 sub do_get {
  50         my ($self, $sql, $opts, @args) = @_;
  51         my $dbh = $self->connect;
  52         my $lim = (($opts->{limit} || 0) + 0) || 1000;
  53         my $off = (($opts->{offset} || 0) + 0) || 0;
  54         $sql .= "LIMIT $lim OFFSET $off";
  55         my $msgs = $dbh->selectall_arrayref($sql, { Slice => {} }, @args);
  56         load_from_row($_) for @$msgs;
  57         $msgs
  58 }
  59
  60 sub query_xover {
  61         my ($self, $beg, $end, $off) = @_;
  62         do_get($self, <<'', { offset => $off }, $beg, $end);
  63 SELECT * FROM over WHERE num >= ? AND num <= ?
  64 ORDER BY num ASC
  65
  66 }
  67
  68 sub query_ts {
  69         my ($self, $ts, $opts) = @_;
  70         do_get($self, <<'', $opts, $ts);
  71 SELECT * FROM over WHERE num > 0 AND ts >= ?
  72 ORDER BY ts ASC
  73
  74 }
  75
  76 sub get_thread {
  77         my ($self, $mid, $opts) = @_;
  78         my $dbh = $self->connect;
  79         my ($tid, $sid) = $dbh->selectrow_array(<<'', undef, $mid);
  80 SELECT tid,sid FROM over
  81 LEFT JOIN id2num ON over.num = id2num.num
  82 LEFT JOIN msgid ON id2num.id = msgid.id
  83 WHERE msgid.mid = ? AND over.num > 0
  84 LIMIT 1
  85
  86         my $cond = 'FROM over WHERE (tid = ? OR sid = ?) AND num > 0';
  87         my $msgs = do_get($self, <<"", $opts, $tid, $sid);
  88 SELECT * $cond
  89 ORDER BY ts ASC
  90
  91         my $nr = $dbh->selectrow_array(<<"", undef, $tid, $sid);
  92 SELECT COUNT(num) $cond
  93
  94         { total => $nr, msgs => $msgs };
  95 }
  96
  97 sub recent {
  98         my ($self, $opts) = @_;
  99         my $msgs = do_get($self, <<'', $opts);
 100 SELECT * FROM over WHERE num > 0
 101 ORDER BY ts DESC
 102
 103         my $nr = $self->{dbh}->selectrow_array(<<'');
 104 SELECT COUNT(num) FROM over WHERE num > 0
 105
 106         { total => $nr, msgs => $msgs };
 107 }
 108
 109 sub get_art {
 110         my ($self, $num) = @_;
 111         my $dbh = $self->connect;
 112         my $smsg = $dbh->selectrow_hashref(<<'', undef, $num);
 113 SELECT * from OVER where num = ? LIMIT 1
 114
 115         return load_from_row($smsg) if $smsg;
 116         undef;
 117 }
 118
 119 1;